C4/Context.pm

   1 package C4::Context;
   2 # Copyright 2002 Katipo Communications
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use vars qw($VERSION $AUTOLOAD $context @context_stack $servers $memcached $ismemcached);
  22 BEGIN {
  23         if ($ENV{'HTTP_USER_AGENT'})    {
  24                 require CGI::Carp;
  25         # FIXME for future reference, CGI::Carp doc says
  26         #  "Note that fatalsToBrowser does not work with mod_perl version 2.0 and higher."
  27                 import CGI::Carp qw(fatalsToBrowser);
  28                         sub handle_errors {
  29                             my $msg = shift;
  30                             my $debug_level;
  31                             eval {C4::Context->dbh();};
  32                             if ($@){
  33                                 $debug_level = 1;
  34                             }
  35                             else {
  36                                 $debug_level =  C4::Context->preference("DebugLevel");
  37                             }
  38
  39                 print q(<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN"
  40                             "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
  41                        <html lang="en" xml:lang="en"  xmlns="http://www.w3.org/1999/xhtml">
  42                        <head><title>Koha Error</title></head>
  43                        <body>
  44                 );
  45                                 if ($debug_level eq "2"){
  46                                         # debug 2 , print extra info too.
  47                                         my %versions = get_versions();
  48
  49                 # a little example table with various version info";
  50                                         print "
  51                                                 <h1>Koha error</h1>
  52                                                 <p>The following fatal error has occurred:</p>
  53                         <pre><code>$msg</code></pre>
  54                                                 <table>
  55                                                 <tr><th>Apache</th><td>  $versions{apacheVersion}</td></tr>
  56                                                 <tr><th>Koha</th><td>    $versions{kohaVersion}</td></tr>
  57                                                 <tr><th>Koha DB</th><td> $versions{kohaDbVersion}</td></tr>
  58                                                 <tr><th>MySQL</th><td>   $versions{mysqlVersion}</td></tr>
  59                                                 <tr><th>OS</th><td>      $versions{osVersion}</td></tr>
  60                                                 <tr><th>Perl</th><td>    $versions{perlVersion}</td></tr>
  61                                                 </table>";
  62
  63                                 } elsif ($debug_level eq "1"){
  64                                         print "
  65                                                 <h1>Koha error</h1>
  66                                                 <p>The following fatal error has occurred:</p>
  67                         <pre><code>$msg</code></pre>";
  68                                 } else {
  69                                         print "<p>production mode - trapped fatal error</p>";
  70                                 }
  71                 print "</body></html>";
  72                         }
  73                 #CGI::Carp::set_message(\&handle_errors);
  74                 ## give a stack backtrace if KOHA_BACKTRACES is set
  75                 ## can't rely on DebugLevel for this, as we're not yet connected
  76                 if ($ENV{KOHA_BACKTRACES}) {
  77                         $main::SIG{__DIE__} = \&CGI::Carp::confess;
  78                 }
  79     }   # else there is no browser to send fatals to!
  80
  81     # Check if there are memcached servers set
  82     $servers = $ENV{'MEMCACHED_SERVERS'};
  83     if ($servers) {
  84         # Load required libraries and create the memcached object
  85         require Cache::Memcached;
  86         $memcached = Cache::Memcached->new({
  87         servers => [ $servers ],
  88         debug   => 0,
  89         compress_threshold => 10_000,
  90         expire_time => 600,
  91         namespace => $ENV{'MEMCACHED_NAMESPACE'} || 'koha'
  92     });
  93         # Verify memcached available (set a variable and test the output)
  94     $ismemcached = $memcached->set('ismemcached','1');
  95     }
  96
  97     $VERSION = '3.07.00.049';
  98 }
  99
 100 use DBI;
 101 use ZOOM;
 102 use XML::Simple;
 103 use C4::Boolean;
 104 use C4::Debug;
 105 use POSIX ();
 106 use DateTime::TimeZone;
 107 use Module::Load::Conditional qw(can_load);
 108 use Carp;
 109
 110 =head1 NAME
 111
 112 C4::Context - Maintain and manipulate the context of a Koha script
 113
 114 =head1 SYNOPSIS
 115
 116   use C4::Context;
 117
 118   use C4::Context("/path/to/koha-conf.xml");
 119
 120   $config_value = C4::Context->config("config_variable");
 121
 122   $koha_preference = C4::Context->preference("preference");
 123
 124   $db_handle = C4::Context->dbh;
 125
 126   $Zconn = C4::Context->Zconn;
 127
 128   $stopwordhash = C4::Context->stopwords;
 129
 130 =head1 DESCRIPTION
 131
 132 When a Koha script runs, it makes use of a certain number of things:
 133 configuration settings in F</etc/koha/koha-conf.xml>, a connection to the Koha
 134 databases, and so forth. These things make up the I<context> in which
 135 the script runs.
 136
 137 This module takes care of setting up the context for a script:
 138 figuring out which configuration file to load, and loading it, opening
 139 a connection to the right database, and so forth.
 140
 141 Most scripts will only use one context. They can simply have
 142
 143   use C4::Context;
 144
 145 at the top.
 146
 147 Other scripts may need to use several contexts. For instance, if a
 148 library has two databases, one for a certain collection, and the other
 149 for everything else, it might be necessary for a script to use two
 150 different contexts to search both databases. Such scripts should use
 151 the C<&set_context> and C<&restore_context> functions, below.
 152
 153 By default, C4::Context reads the configuration from
 154 F</etc/koha/koha-conf.xml>. This may be overridden by setting the C<$KOHA_CONF>
 155 environment variable to the pathname of a configuration file to use.
 156
 157 =head1 METHODS
 158
 159 =cut
 160
 161 #'
 162 # In addition to what is said in the POD above, a Context object is a
 163 # reference-to-hash with the following fields:
 164 #
 165 # config
 166 #    A reference-to-hash whose keys and values are the
 167 #    configuration variables and values specified in the config
 168 #    file (/etc/koha/koha-conf.xml).
 169 # dbh
 170 #    A handle to the appropriate database for this context.
 171 # dbh_stack
 172 #    Used by &set_dbh and &restore_dbh to hold other database
 173 #    handles for this context.
 174 # Zconn
 175 #     A connection object for the Zebra server
 176
 177 # Koha's main configuration file koha-conf.xml
 178 # is searched for according to this priority list:
 179 #
 180 # 1. Path supplied via use C4::Context '/path/to/koha-conf.xml'
 181 # 2. Path supplied in KOHA_CONF environment variable.
 182 # 3. Path supplied in INSTALLED_CONFIG_FNAME, as long
 183 #    as value has changed from its default of
 184 #    '__KOHA_CONF_DIR__/koha-conf.xml', as happens
 185 #    when Koha is installed in 'standard' or 'single'
 186 #    mode.
 187 # 4. Path supplied in CONFIG_FNAME.
 188 #
 189 # The first entry that refers to a readable file is used.
 190
 191 use constant CONFIG_FNAME => "/etc/koha/koha-conf.xml";
 192                 # Default config file, if none is specified
 193
 194 my $INSTALLED_CONFIG_FNAME = '__KOHA_CONF_DIR__/koha-conf.xml';
 195                 # path to config file set by installer
 196                 # __KOHA_CONF_DIR__ is set by rewrite-confg.PL
 197                 # when Koha is installed in 'standard' or 'single'
 198                 # mode.  If Koha was installed in 'dev' mode,
 199                 # __KOHA_CONF_DIR__ is *not* rewritten; instead
 200                 # developers should set the KOHA_CONF environment variable
 201
 202 $context = undef;        # Initially, no context is set
 203 @context_stack = ();        # Initially, no saved contexts
 204
 205
 206 =head2 KOHAVERSION
 207
 208 returns the kohaversion stored in kohaversion.pl file
 209
 210 =cut
 211
 212 sub KOHAVERSION {
 213     my $cgidir = C4::Context->intranetdir;
 214
 215     # Apparently the GIT code does not run out of a CGI-BIN subdirectory
 216     # but distribution code does?  (Stan, 1jan08)
 217     if(-d $cgidir . "/cgi-bin"){
 218         my $cgidir .= "/cgi-bin";
 219     }
 220
 221     do $cgidir."/kohaversion.pl" || die "NO $cgidir/kohaversion.pl";
 222     return kohaversion();
 223 }
 224
 225 =head2 final_linear_version
 226
 227 Returns the version number of the final update to run in updatedatabase.pl.
 228 This number is equal to the version in kohaversion.pl
 229
 230 =cut
 231
 232 sub final_linear_version {
 233     return KOHAVERSION;
 234 }
 235
 236 =head2 read_config_file
 237
 238 Reads the specified Koha config file.
 239
 240 Returns an object containing the configuration variables. The object's
 241 structure is a bit complex to the uninitiated ... take a look at the
 242 koha-conf.xml file as well as the XML::Simple documentation for details. Or,
 243 here are a few examples that may give you what you need:
 244
 245 The simple elements nested within the <config> element:
 246
 247     my $pass = $koha->{'config'}->{'pass'};
 248
 249 The <listen> elements:
 250
 251     my $listen = $koha->{'listen'}->{'biblioserver'}->{'content'};
 252
 253 The elements nested within the <server> element:
 254
 255     my $ccl2rpn = $koha->{'server'}->{'biblioserver'}->{'cql2rpn'};
 256
 257 Returns undef in case of error.
 258
 259 =cut
 260
 261 sub read_config_file {          # Pass argument naming config file to read
 262     my $koha = XMLin(shift, keyattr => ['id'], forcearray => ['listen', 'server', 'serverinfo'], suppressempty => '');
 263
 264     if ($ismemcached) {
 265       $memcached->set('kohaconf',$koha);
 266     }
 267
 268     return $koha;                       # Return value: ref-to-hash holding the configuration
 269 }
 270
 271 =head2 ismemcached
 272
 273 Returns the value of the $ismemcached variable (0/1)
 274
 275 =cut
 276
 277 sub ismemcached {
 278     return $ismemcached;
 279 }
 280
 281 =head2 memcached
 282
 283 If $ismemcached is true, returns the $memcache variable.
 284 Returns undef otherwise
 285
 286 =cut
 287
 288 sub memcached {
 289     if ($ismemcached) {
 290       return $memcached;
 291     } else {
 292       return;
 293     }
 294 }
 295
 296 =head2 db_schema2dbi
 297
 298     my $dbd_driver_name = C4::Context::db_schema2dbi($scheme);
 299
 300 This routines translates a database type to part of the name
 301 of the appropriate DBD driver to use when establishing a new
 302 database connection.  It recognizes 'mysql' and 'Pg'; if any
 303 other scheme is supplied it defaults to 'mysql'.
 304
 305 =cut
 306
 307 sub db_scheme2dbi {
 308     my $scheme = shift // '';
 309     return $scheme eq 'Pg' ? $scheme : 'mysql';
 310 }
 311
 312 sub import {
 313     # Create the default context ($C4::Context::Context)
 314     # the first time the module is called
 315     # (a config file can be optionaly passed)
 316
 317     # default context allready exists?
 318     return if $context;
 319
 320     # no ? so load it!
 321     my ($pkg,$config_file) = @_ ;
 322     my $new_ctx = __PACKAGE__->new($config_file);
 323     return unless $new_ctx;
 324
 325     # if successfully loaded, use it by default
 326     $new_ctx->set_context;
 327     1;
 328 }
 329
 330 =head2 new
 331
 332   $context = new C4::Context;
 333   $context = new C4::Context("/path/to/koha-conf.xml");
 334
 335 Allocates a new context. Initializes the context from the specified
 336 file, which defaults to either the file given by the C<$KOHA_CONF>
 337 environment variable, or F</etc/koha/koha-conf.xml>.
 338
 339 It saves the koha-conf.xml values in the declared memcached server(s)
 340 if currently available and uses those values until them expire and
 341 re-reads them.
 342
 343 C<&new> does not set this context as the new default context; for
 344 that, use C<&set_context>.
 345
 346 =cut
 347
 348 #'
 349 # Revision History:
 350 # 2004-08-10 A. Tarallo: Added check if the conf file is not empty
 351 sub new {
 352     my $class = shift;
 353     my $conf_fname = shift;        # Config file to load
 354     my $self = {};
 355
 356     # check that the specified config file exists and is not empty
 357     undef $conf_fname unless
 358         (defined $conf_fname && -s $conf_fname);
 359     # Figure out a good config file to load if none was specified.
 360     if (!defined($conf_fname))
 361     {
 362         # If the $KOHA_CONF environment variable is set, use
 363         # that. Otherwise, use the built-in default.
 364         if (exists $ENV{"KOHA_CONF"} and $ENV{'KOHA_CONF'} and -s  $ENV{"KOHA_CONF"}) {
 365             $conf_fname = $ENV{"KOHA_CONF"};
 366         } elsif ($INSTALLED_CONFIG_FNAME !~ /__KOHA_CONF_DIR/ and -s $INSTALLED_CONFIG_FNAME) {
 367             # NOTE: be careful -- don't change __KOHA_CONF_DIR in the above
 368             # regex to anything else -- don't want installer to rewrite it
 369             $conf_fname = $INSTALLED_CONFIG_FNAME;
 370         } elsif (-s CONFIG_FNAME) {
 371             $conf_fname = CONFIG_FNAME;
 372         } else {
 373             warn "unable to locate Koha configuration file koha-conf.xml";
 374             return;
 375         }
 376     }
 377
 378     if ($ismemcached) {
 379         # retreive from memcached
 380         $self = $memcached->get('kohaconf');
 381         if (not defined $self) {
 382             # not in memcached yet
 383             $self = read_config_file($conf_fname);
 384         }
 385     } else {
 386         # non-memcached env, read from file
 387         $self = read_config_file($conf_fname);
 388     }
 389
 390     $self->{"config_file"} = $conf_fname;
 391     warn "read_config_file($conf_fname) returned undef" if !defined($self->{"config"});
 392     return if !defined($self->{"config"});
 393
 394     $self->{"dbh"} = undef;        # Database handle
 395     $self->{"Zconn"} = undef;    # Zebra Connections
 396     $self->{"stopwords"} = undef; # stopwords list
 397     $self->{"marcfromkohafield"} = undef; # the hash with relations between koha table fields and MARC field/subfield
 398     $self->{"userenv"} = undef;        # User env
 399     $self->{"activeuser"} = undef;        # current active user
 400     $self->{"shelves"} = undef;
 401     $self->{tz} = undef; # local timezone object
 402
 403     bless $self, $class;
 404     return $self;
 405 }
 406
 407 =head2 set_context
 408
 409   $context = new C4::Context;
 410   $context->set_context();
 411 or
 412   set_context C4::Context $context;
 413
 414   ...
 415   restore_context C4::Context;
 416
 417 In some cases, it might be necessary for a script to use multiple
 418 contexts. C<&set_context> saves the current context on a stack, then
 419 sets the context to C<$context>, which will be used in future
 420 operations. To restore the previous context, use C<&restore_context>.
 421
 422 =cut
 423
 424 #'
 425 sub set_context
 426 {
 427     my $self = shift;
 428     my $new_context;    # The context to set
 429
 430     # Figure out whether this is a class or instance method call.
 431     #
 432     # We're going to make the assumption that control got here
 433     # through valid means, i.e., that the caller used an instance
 434     # or class method call, and that control got here through the
 435     # usual inheritance mechanisms. The caller can, of course,
 436     # break this assumption by playing silly buggers, but that's
 437     # harder to do than doing it properly, and harder to check
 438     # for.
 439     if (ref($self) eq "")
 440     {
 441         # Class method. The new context is the next argument.
 442         $new_context = shift;
 443     } else {
 444         # Instance method. The new context is $self.
 445         $new_context = $self;
 446     }
 447
 448     # Save the old context, if any, on the stack
 449     push @context_stack, $context if defined($context);
 450
 451     # Set the new context
 452     $context = $new_context;
 453 }
 454
 455 =head2 restore_context
 456
 457   &restore_context;
 458
 459 Restores the context set by C<&set_context>.
 460
 461 =cut
 462
 463 #'
 464 sub restore_context
 465 {
 466     my $self = shift;
 467
 468     if ($#context_stack < 0)
 469     {
 470         # Stack underflow.
 471         die "Context stack underflow";
 472     }
 473
 474     # Pop the old context and set it.
 475     $context = pop @context_stack;
 476
 477     # FIXME - Should this return something, like maybe the context
 478     # that was current when this was called?
 479 }
 480
 481 =head2 config
 482
 483   $value = C4::Context->config("config_variable");
 484
 485   $value = C4::Context->config_variable;
 486
 487 Returns the value of a variable specified in the configuration file
 488 from which the current context was created.
 489
 490 The second form is more compact, but of course may conflict with
 491 method names. If there is a configuration variable called "new", then
 492 C<C4::Config-E<gt>new> will not return it.
 493
 494 =cut
 495
 496 sub _common_config {
 497         my $var = shift;
 498         my $term = shift;
 499     return if !defined($context->{$term});
 500        # Presumably $self->{$term} might be
 501        # undefined if the config file given to &new
 502        # didn't exist, and the caller didn't bother
 503        # to check the return value.
 504
 505     # Return the value of the requested config variable
 506     return $context->{$term}->{$var};
 507 }
 508
 509 sub config {
 510         return _common_config($_[1],'config');
 511 }
 512 sub zebraconfig {
 513         return _common_config($_[1],'server');
 514 }
 515 sub ModZebrations {
 516         return _common_config($_[1],'serverinfo');
 517 }
 518
 519 =head2 preference
 520
 521   $sys_preference = C4::Context->preference('some_variable');
 522
 523 Looks up the value of the given system preference in the
 524 systempreferences table of the Koha database, and returns it. If the
 525 variable is not set or does not exist, undef is returned.
 526
 527 In case of an error, this may return 0.
 528
 529 Note: It is impossible to tell the difference between system
 530 preferences which do not exist, and those whose values are set to NULL
 531 with this method.
 532
 533 =cut
 534
 535 # FIXME: running this under mod_perl will require a means of
 536 # flushing the caching mechanism.
 537
 538 my %sysprefs;
 539 my $use_syspref_cache = 1;
 540
 541 sub preference {
 542     my $self = shift;
 543     my $var  = shift;    # The system preference to return
 544
 545     if ($use_syspref_cache && exists $sysprefs{lc $var}) {
 546         return $sysprefs{lc $var};
 547     }
 548
 549     my $dbh  = C4::Context->dbh or return 0;
 550
 551     my $value;
 552     if ( defined $ENV{"OVERRIDE_SYSPREF_$var"} ) {
 553         $value = $ENV{"OVERRIDE_SYSPREF_$var"};
 554     } else {
 555         # Look up systempreferences.variable==$var
 556         my $sql = q{
 557             SELECT  value
 558             FROM    systempreferences
 559             WHERE   variable = ?
 560             LIMIT   1
 561         };
 562         $value = $dbh->selectrow_array( $sql, {}, lc $var );
 563     }
 564
 565     $sysprefs{lc $var} = $value;
 566     return $value;
 567 }
 568
 569 sub boolean_preference {
 570     my $self = shift;
 571     my $var = shift;        # The system preference to return
 572     my $it = preference($self, $var);
 573     return defined($it)? C4::Boolean::true_p($it): undef;
 574 }
 575
 576 =head2 enable_syspref_cache
 577
 578   C4::Context->enable_syspref_cache();
 579
 580 Enable the in-memory syspref cache used by C4::Context. This is the
 581 default behavior.
 582
 583 =cut
 584
 585 sub enable_syspref_cache {
 586     my ($self) = @_;
 587     $use_syspref_cache = 1;
 588 }
 589
 590 =head2 disable_syspref_cache
 591
 592   C4::Context->disable_syspref_cache();
 593
 594 Disable the in-memory syspref cache used by C4::Context. This should be
 595 used with Plack and other persistent environments.
 596
 597 =cut
 598
 599 sub disable_syspref_cache {
 600     my ($self) = @_;
 601     $use_syspref_cache = 0;
 602     $self->clear_syspref_cache();
 603 }
 604
 605 =head2 clear_syspref_cache
 606
 607   C4::Context->clear_syspref_cache();
 608
 609 cleans the internal cache of sysprefs. Please call this method if
 610 you update the systempreferences table. Otherwise, your new changes
 611 will not be seen by this process.
 612
 613 =cut
 614
 615 sub clear_syspref_cache {
 616     %sysprefs = ();
 617 }
 618
 619 =head2 set_preference
 620
 621   C4::Context->set_preference( $variable, $value );
 622
 623 This updates a preference's value both in the systempreferences table and in
 624 the sysprefs cache.
 625
 626 =cut
 627
 628 sub set_preference {
 629     my $self = shift;
 630     my $var = lc(shift);
 631     my $value = shift;
 632
 633     my $dbh = C4::Context->dbh or return 0;
 634
 635     my $type = $dbh->selectrow_array( "SELECT type FROM systempreferences WHERE variable = ?", {}, $var );
 636
 637     $value = 0 if ( $type && $type eq 'YesNo' && $value eq '' );
 638
 639     my $sth = $dbh->prepare( "
 640       INSERT INTO systempreferences
 641         ( variable, value )
 642         VALUES( ?, ? )
 643         ON DUPLICATE KEY UPDATE value = VALUES(value)
 644     " );
 645
 646     if($sth->execute( $var, $value )) {
 647         $sysprefs{$var} = $value;
 648     }
 649     $sth->finish;
 650 }
 651
 652 # AUTOLOAD
 653 # This implements C4::Config->foo, and simply returns
 654 # C4::Context->config("foo"), as described in the documentation for
 655 # &config, above.
 656
 657 # FIXME - Perhaps this should be extended to check &config first, and
 658 # then &preference if that fails. OTOH, AUTOLOAD could lead to crappy
 659 # code, so it'd probably be best to delete it altogether so as not to
 660 # encourage people to use it.
 661 sub AUTOLOAD
 662 {
 663     my $self = shift;
 664
 665     $AUTOLOAD =~ s/.*:://;        # Chop off the package name,
 666                     # leaving only the function name.
 667     return $self->config($AUTOLOAD);
 668 }
 669
 670 =head2 Zconn
 671
 672   $Zconn = C4::Context->Zconn
 673
 674 Returns a connection to the Zebra database for the current
 675 context. If no connection has yet been made, this method
 676 creates one and connects.
 677
 678 C<$self>
 679
 680 C<$server> one of the servers defined in the koha-conf.xml file
 681
 682 C<$async> whether this is a asynchronous connection
 683
 684 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 685
 686
 687 =cut
 688
 689 sub Zconn {
 690     my $self=shift;
 691     my $server=shift;
 692     my $async=shift;
 693     my $auth=shift;
 694     my $piggyback=shift;
 695     my $syntax=shift;
 696     if ( defined($context->{"Zconn"}->{$server}) && (0 == $context->{"Zconn"}->{$server}->errcode()) ) {
 697         return $context->{"Zconn"}->{$server};
 698     # No connection object or it died. Create one.
 699     }else {
 700         # release resources if we're closing a connection and making a new one
 701         # FIXME: this needs to be smarter -- an error due to a malformed query or
 702         # a missing index does not necessarily require us to close the connection
 703         # and make a new one, particularly for a batch job.  However, at
 704         # first glance it does not look like there's a way to easily check
 705         # the basic health of a ZOOM::Connection
 706         $context->{"Zconn"}->{$server}->destroy() if defined($context->{"Zconn"}->{$server});
 707
 708         $context->{"Zconn"}->{$server} = &_new_Zconn($server,$async,$auth,$piggyback,$syntax);
 709         return $context->{"Zconn"}->{$server};
 710     }
 711 }
 712
 713 =head2 _new_Zconn
 714
 715 $context->{"Zconn"} = &_new_Zconn($server,$async);
 716
 717 Internal function. Creates a new database connection from the data given in the current context and returns it.
 718
 719 C<$server> one of the servers defined in the koha-conf.xml file
 720
 721 C<$async> whether this is a asynchronous connection
 722
 723 C<$auth> whether this connection has rw access (1) or just r access (0 or NULL)
 724
 725 =cut
 726
 727 sub _new_Zconn {
 728     my ($server,$async,$auth,$piggyback,$syntax) = @_;
 729
 730     my $tried=0; # first attempt
 731     my $Zconn; # connection object
 732     my $elementSetName;
 733     my $index_mode;
 734
 735     $server //= "biblioserver";
 736     $syntax //= "XML";
 737
 738     if ( $server eq 'biblioserver' ) {
 739         $index_mode = $context->{'config'}->{'zebra_bib_index_mode'} // 'grs1';
 740     } elsif ( $server eq 'authorityserver' ) {
 741         $index_mode = $context->{'config'}->{'zebra_auth_index_mode'} // 'dom';
 742     }
 743
 744     if ( $index_mode eq 'grs1' ) {
 745
 746         $elementSetName = 'F';
 747         $syntax = ( $context->preference("marcflavour") eq 'UNIMARC' )
 748                 ? 'unimarc'
 749                 : 'usmarc';
 750
 751     } else {
 752
 753         $elementSetName = 'marcxml';
 754         $syntax = 'XML';
 755     }
 756
 757     my $host = $context->{'listen'}->{$server}->{'content'};
 758     my $servername = $context->{"config"}->{$server};
 759     my $user = $context->{"serverinfo"}->{$server}->{"user"};
 760     my $password = $context->{"serverinfo"}->{$server}->{"password"};
 761     $auth = 1 if($user && $password);
 762     retry:
 763     eval {
 764         # set options
 765         my $o = new ZOOM::Options();
 766         $o->option(user=>$user) if $auth;
 767         $o->option(password=>$password) if $auth;
 768         $o->option(async => 1) if $async;
 769         $o->option(count => $piggyback) if $piggyback;
 770         $o->option(cqlfile=> $context->{"server"}->{$server}->{"cql2rpn"});
 771         $o->option(cclfile=> $context->{"serverinfo"}->{$server}->{"ccl2rpn"});
 772         $o->option(preferredRecordSyntax => $syntax);
 773         $o->option(elementSetName => $elementSetName);
 774         $o->option(databaseName => ($servername?$servername:"biblios"));
 775
 776         # create a new connection object
 777         $Zconn= create ZOOM::Connection($o);
 778
 779         # forge to server
 780         $Zconn->connect($host, 0);
 781
 782         # check for errors and warn
 783         if ($Zconn->errcode() !=0) {
 784             warn "something wrong with the connection: ". $Zconn->errmsg();
 785         }
 786
 787     };
 788
 789     return $Zconn;
 790 }
 791
 792 # _new_dbh
 793 # Internal helper function (not a method!). This creates a new
 794 # database connection from the data given in the current context, and
 795 # returns it.
 796 sub _new_dbh
 797 {
 798
 799     ## $context
 800     ## correct name for db_schme
 801     my $db_driver = db_scheme2dbi($context->config("db_scheme"));
 802
 803     my $db_name   = $context->config("database");
 804     my $db_host   = $context->config("hostname");
 805     my $db_port   = $context->config("port") || '';
 806     my $db_user   = $context->config("user");
 807     my $db_passwd = $context->config("pass");
 808     # MJR added or die here, as we can't work without dbh
 809     my $dbh = DBI->connect("DBI:$db_driver:dbname=$db_name;host=$db_host;port=$db_port",
 810     $db_user, $db_passwd, {'RaiseError' => $ENV{DEBUG}?1:0 }) or die $DBI::errstr;
 811
 812     # Check for the existence of a systempreference table; if we don't have this, we don't
 813     # have a valid database and should not set RaiseError in order to allow the installer
 814     # to run; installer will not run otherwise since we raise all db errors
 815
 816     eval {
 817                 local $dbh->{PrintError} = 0;
 818                 local $dbh->{RaiseError} = 1;
 819                 $dbh->do(qq{SELECT * FROM systempreferences WHERE 1 = 0 });
 820     };
 821
 822     if ($@) {
 823         $dbh->{RaiseError} = 0;
 824     }
 825
 826         my $tz = $ENV{TZ};
 827     if ( $db_driver eq 'mysql' ) {
 828         # Koha 3.0 is utf-8, so force utf8 communication between mySQL and koha, whatever the mysql default config.
 829         # this is better than modifying my.cnf (and forcing all communications to be in utf8)
 830         $dbh->{'mysql_enable_utf8'}=1; #enable
 831         $dbh->do("set NAMES 'utf8'");
 832         ($tz) and $dbh->do(qq(SET time_zone = "$tz"));
 833     }
 834     elsif ( $db_driver eq 'Pg' ) {
 835             $dbh->do( "set client_encoding = 'UTF8';" );
 836         ($tz) and $dbh->do(qq(SET TIME ZONE = "$tz"));
 837     }
 838     return $dbh;
 839 }
 840
 841 =head2 dbh
 842
 843   $dbh = C4::Context->dbh;
 844
 845 Returns a database handle connected to the Koha database for the
 846 current context. If no connection has yet been made, this method
 847 creates one, and connects to the database.
 848
 849 This database handle is cached for future use: if you call
 850 C<C4::Context-E<gt>dbh> twice, you will get the same handle both
 851 times. If you need a second database handle, use C<&new_dbh> and
 852 possibly C<&set_dbh>.
 853
 854 =cut
 855
 856 #'
 857 sub dbh
 858 {
 859     my $self = shift;
 860     my $sth;
 861
 862     if (defined($context->{"dbh"}) && $context->{"dbh"}->ping()) {
 863         return $context->{"dbh"};
 864     }
 865
 866     # No database handle or it died . Create one.
 867     $context->{"dbh"} = &_new_dbh();
 868
 869     return $context->{"dbh"};
 870 }
 871
 872 =head2 new_dbh
 873
 874   $dbh = C4::Context->new_dbh;
 875
 876 Creates a new connection to the Koha database for the current context,
 877 and returns the database handle (a C<DBI::db> object).
 878
 879 The handle is not saved anywhere: this method is strictly a
 880 convenience function; the point is that it knows which database to
 881 connect to so that the caller doesn't have to know.
 882
 883 =cut
 884
 885 #'
 886 sub new_dbh
 887 {
 888     my $self = shift;
 889
 890     return &_new_dbh();
 891 }
 892
 893 =head2 set_dbh
 894
 895   $my_dbh = C4::Connect->new_dbh;
 896   C4::Connect->set_dbh($my_dbh);
 897   ...
 898   C4::Connect->restore_dbh;
 899
 900 C<&set_dbh> and C<&restore_dbh> work in a manner analogous to
 901 C<&set_context> and C<&restore_context>.
 902
 903 C<&set_dbh> saves the current database handle on a stack, then sets
 904 the current database handle to C<$my_dbh>.
 905
 906 C<$my_dbh> is assumed to be a good database handle.
 907
 908 =cut
 909
 910 #'
 911 sub set_dbh
 912 {
 913     my $self = shift;
 914     my $new_dbh = shift;
 915
 916     # Save the current database handle on the handle stack.
 917     # We assume that $new_dbh is all good: if the caller wants to
 918     # screw himself by passing an invalid handle, that's fine by
 919     # us.
 920     push @{$context->{"dbh_stack"}}, $context->{"dbh"};
 921     $context->{"dbh"} = $new_dbh;
 922 }
 923
 924 =head2 restore_dbh
 925
 926   C4::Context->restore_dbh;
 927
 928 Restores the database handle saved by an earlier call to
 929 C<C4::Context-E<gt>set_dbh>.
 930
 931 =cut
 932
 933 #'
 934 sub restore_dbh
 935 {
 936     my $self = shift;
 937
 938     if ($#{$context->{"dbh_stack"}} < 0)
 939     {
 940         # Stack underflow
 941         die "DBH stack underflow";
 942     }
 943
 944     # Pop the old database handle and set it.
 945     $context->{"dbh"} = pop @{$context->{"dbh_stack"}};
 946
 947     # FIXME - If it is determined that restore_context should
 948     # return something, then this function should, too.
 949 }
 950
 951 =head2 queryparser
 952
 953   $queryparser = C4::Context->queryparser
 954
 955 Returns a handle to an initialized Koha::QueryParser::Driver::PQF object.
 956
 957 =cut
 958
 959 sub queryparser {
 960     my $self = shift;
 961     unless (defined $context->{"queryparser"}) {
 962         $context->{"queryparser"} = &_new_queryparser();
 963     }
 964
 965     return
 966       defined( $context->{"queryparser"} )
 967       ? $context->{"queryparser"}->new
 968       : undef;
 969 }
 970
 971 =head2 _new_queryparser
 972
 973 Internal helper function to create a new QueryParser object. QueryParser
 974 is loaded dynamically so as to keep the lack of the QueryParser library from
 975 getting in anyone's way.
 976
 977 =cut
 978
 979 sub _new_queryparser {
 980     my $qpmodules = {
 981         'OpenILS::QueryParser'           => undef,
 982         'Koha::QueryParser::Driver::PQF' => undef
 983     };
 984     if ( can_load( 'modules' => $qpmodules ) ) {
 985         my $QParser     = Koha::QueryParser::Driver::PQF->new();
 986         my $config_file = $context->config('queryparser_config');
 987         $config_file ||= '/etc/koha/searchengine/queryparser.yaml';
 988         if ( $QParser->load_config($config_file) ) {
 989             # TODO: allow indexes to be configured in the database
 990             return $QParser;
 991         }
 992     }
 993     return;
 994 }
 995
 996 =head2 marcfromkohafield
 997
 998   $dbh = C4::Context->marcfromkohafield;
 999
1000 Returns a hash with marcfromkohafield.
1001
1002 This hash is cached for future use: if you call
1003 C<C4::Context-E<gt>marcfromkohafield> twice, you will get the same hash without real DB access
1004
1005 =cut
1006
1007 #'
1008 sub marcfromkohafield
1009 {
1010     my $retval = {};
1011
1012     # If the hash already exists, return it.
1013     return $context->{"marcfromkohafield"} if defined($context->{"marcfromkohafield"});
1014
1015     # No hash. Create one.
1016     $context->{"marcfromkohafield"} = &_new_marcfromkohafield();
1017
1018     return $context->{"marcfromkohafield"};
1019 }
1020
1021 # _new_marcfromkohafield
1022 # Internal helper function (not a method!). This creates a new
1023 # hash with stopwords
1024 sub _new_marcfromkohafield
1025 {
1026     my $dbh = C4::Context->dbh;
1027     my $marcfromkohafield;
1028     my $sth = $dbh->prepare("select frameworkcode,kohafield,tagfield,tagsubfield from marc_subfield_structure where kohafield > ''");
1029     $sth->execute;
1030     while (my ($frameworkcode,$kohafield,$tagfield,$tagsubfield) = $sth->fetchrow) {
1031         my $retval = {};
1032         $marcfromkohafield->{$frameworkcode}->{$kohafield} = [$tagfield,$tagsubfield];
1033     }
1034     return $marcfromkohafield;
1035 }
1036
1037 =head2 stopwords
1038
1039   $dbh = C4::Context->stopwords;
1040
1041 Returns a hash with stopwords.
1042
1043 This hash is cached for future use: if you call
1044 C<C4::Context-E<gt>stopwords> twice, you will get the same hash without real DB access
1045
1046 =cut
1047
1048 #'
1049 sub stopwords
1050 {
1051     my $retval = {};
1052
1053     # If the hash already exists, return it.
1054     return $context->{"stopwords"} if defined($context->{"stopwords"});
1055
1056     # No hash. Create one.
1057     $context->{"stopwords"} = &_new_stopwords();
1058
1059     return $context->{"stopwords"};
1060 }
1061
1062 # _new_stopwords
1063 # Internal helper function (not a method!). This creates a new
1064 # hash with stopwords
1065 sub _new_stopwords
1066 {
1067     my $dbh = C4::Context->dbh;
1068     my $stopwordlist;
1069     my $sth = $dbh->prepare("select word from stopwords");
1070     $sth->execute;
1071     while (my $stopword = $sth->fetchrow_array) {
1072         $stopwordlist->{$stopword} = uc($stopword);
1073     }
1074     $stopwordlist->{A} = "A" unless $stopwordlist;
1075     return $stopwordlist;
1076 }
1077
1078 =head2 userenv
1079
1080   C4::Context->userenv;
1081
1082 Retrieves a hash for user environment variables.
1083
1084 This hash shall be cached for future use: if you call
1085 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1086
1087 =cut
1088
1089 #'
1090 sub userenv {
1091     my $var = $context->{"activeuser"};
1092     if (defined $var and defined $context->{"userenv"}->{$var}) {
1093         return $context->{"userenv"}->{$var};
1094     } else {
1095         return;
1096     }
1097 }
1098
1099 =head2 set_userenv
1100
1101   C4::Context->set_userenv($usernum, $userid, $usercnum, $userfirstname,
1102                   $usersurname, $userbranch, $userflags, $emailaddress, $branchprinter,
1103                   $persona);
1104
1105 Establish a hash of user environment variables.
1106
1107 set_userenv is called in Auth.pm
1108
1109 =cut
1110
1111 #'
1112 sub set_userenv {
1113     my ($usernum, $userid, $usercnum, $userfirstname, $usersurname, $userbranch, $branchname, $userflags, $emailaddress, $branchprinter, $persona)= @_;
1114     my $var=$context->{"activeuser"} || '';
1115     my $cell = {
1116         "number"     => $usernum,
1117         "id"         => $userid,
1118         "cardnumber" => $usercnum,
1119         "firstname"  => $userfirstname,
1120         "surname"    => $usersurname,
1121         #possibly a law problem
1122         "branch"     => $userbranch,
1123         "branchname" => $branchname,
1124         "flags"      => $userflags,
1125         "emailaddress"     => $emailaddress,
1126         "branchprinter"    => $branchprinter,
1127         "persona"    => $persona,
1128     };
1129     $context->{userenv}->{$var} = $cell;
1130     return $cell;
1131 }
1132
1133 sub set_shelves_userenv {
1134         my ($type, $shelves) = @_ or return;
1135         my $activeuser = $context->{activeuser} or return;
1136         $context->{userenv}->{$activeuser}->{barshelves} = $shelves if $type eq 'bar';
1137         $context->{userenv}->{$activeuser}->{pubshelves} = $shelves if $type eq 'pub';
1138         $context->{userenv}->{$activeuser}->{totshelves} = $shelves if $type eq 'tot';
1139 }
1140
1141 sub get_shelves_userenv {
1142         my $active;
1143         unless ($active = $context->{userenv}->{$context->{activeuser}}) {
1144                 $debug and warn "get_shelves_userenv cannot retrieve context->{userenv}->{context->{activeuser}}";
1145                 return;
1146         }
1147         my $totshelves = $active->{totshelves} or undef;
1148         my $pubshelves = $active->{pubshelves} or undef;
1149         my $barshelves = $active->{barshelves} or undef;
1150         return ($totshelves, $pubshelves, $barshelves);
1151 }
1152
1153 =head2 _new_userenv
1154
1155   C4::Context->_new_userenv($session);  # FIXME: This calling style is wrong for what looks like an _internal function
1156
1157 Builds a hash for user environment variables.
1158
1159 This hash shall be cached for future use: if you call
1160 C<C4::Context-E<gt>userenv> twice, you will get the same hash without real DB access
1161
1162 _new_userenv is called in Auth.pm
1163
1164 =cut
1165
1166 #'
1167 sub _new_userenv
1168 {
1169     shift;  # Useless except it compensates for bad calling style
1170     my ($sessionID)= @_;
1171      $context->{"activeuser"}=$sessionID;
1172 }
1173
1174 =head2 _unset_userenv
1175
1176   C4::Context->_unset_userenv;
1177
1178 Destroys the hash for activeuser user environment variables.
1179
1180 =cut
1181
1182 #'
1183
1184 sub _unset_userenv
1185 {
1186     my ($sessionID)= @_;
1187     undef $context->{"activeuser"} if ($context->{"activeuser"} eq $sessionID);
1188 }
1189
1190
1191 =head2 get_versions
1192
1193   C4::Context->get_versions
1194
1195 Gets various version info, for core Koha packages, Currently called from carp handle_errors() sub, to send to browser if 'DebugLevel' syspref is set to '2'.
1196
1197 =cut
1198
1199 #'
1200
1201 # A little example sub to show more debugging info for CGI::Carp
1202 sub get_versions {
1203     my %versions;
1204     $versions{kohaVersion}  = KOHAVERSION();
1205     $versions{kohaDbVersion} = C4::Context->preference('version');
1206     $versions{osVersion} = join(" ", POSIX::uname());
1207     $versions{perlVersion} = $];
1208     {
1209         no warnings qw(exec); # suppress warnings if unable to find a program in $PATH
1210         $versions{mysqlVersion}  = `mysql -V`;
1211         $versions{apacheVersion} = `httpd -v`;
1212         $versions{apacheVersion} = `httpd2 -v`            unless  $versions{apacheVersion} ;
1213         $versions{apacheVersion} = `apache2 -v`           unless  $versions{apacheVersion} ;
1214         $versions{apacheVersion} = `/usr/sbin/apache2 -v` unless  $versions{apacheVersion} ;
1215     }
1216     return %versions;
1217 }
1218
1219
1220 =head2 tz
1221
1222   C4::Context->tz
1223
1224   Returns a DateTime::TimeZone object for the system timezone
1225
1226 =cut
1227
1228 sub tz {
1229     my $self = shift;
1230     if (!defined $context->{tz}) {
1231         $context->{tz} = DateTime::TimeZone->new(name => 'local');
1232     }
1233     return $context->{tz};
1234 }
1235
1236
1237 =head2 IsSuperLibrarian
1238
1239     C4::Context->IsSuperlibrarian();
1240
1241 =cut
1242
1243 sub IsSuperLibrarian {
1244     my $userenv = C4::Context->userenv;
1245
1246     unless ( $userenv and exists $userenv->{flags} ) {
1247         # If we reach this without a user environment,
1248         # assume that we're running from a command-line script,
1249         # and act as a superlibrarian.
1250         carp("C4::Context->userenv not defined!");
1251         return 1;
1252     }
1253
1254     return ($userenv->{flags}//0) % 2;
1255 }
1256
1257 1;
1258 __END__
1259
1260 =head1 ENVIRONMENT
1261
1262 =head2 C<KOHA_CONF>
1263
1264 Specifies the configuration file to read.
1265
1266 =head1 SEE ALSO
1267
1268 XML::Simple
1269
1270 =head1 AUTHORS
1271
1272 Andrew Arensburger <arensb at ooblick dot com>
1273
1274 Joshua Ferraro <jmf at liblime dot com>
1275
1276 =cut