Koha/Exporter/Record.pm

   1 package Koha::Exporter::Record;
   2
   3 use Modern::Perl;
   4 use MARC::File::XML;
   5 use MARC::File::USMARC;
   6
   7 use C4::AuthoritiesMarc;
   8 use C4::Biblio;
   9 use C4::Record;
  10 use Koha::CsvProfiles;
  11
  12 sub _get_record_for_export {
  13     my ($params)           = @_;
  14     my $record_type        = $params->{record_type};
  15     my $record_id          = $params->{record_id};
  16     my $dont_export_fields = $params->{dont_export_fields};
  17     my $clean              = $params->{clean};
  18
  19     my $record;
  20     if ( $record_type eq 'auths' ) {
  21         $record = _get_authority_for_export( { %$params, authid => $record_id } );
  22     } elsif ( $record_type eq 'bibs' ) {
  23         $record = _get_biblio_for_export( { %$params, biblionumber => $record_id } );
  24     } else {
  25
  26         # TODO log "record_type not supported"
  27         return;
  28     }
  29
  30     if ($dont_export_fields) {
  31         for my $f ( split / /, $dont_export_fields ) {
  32             if ( $f =~ m/^(\d{3})(.)?$/ ) {
  33                 my ( $field, $subfield ) = ( $1, $2 );
  34
  35                 # skip if this record doesn't have this field
  36                 if ( defined $record->field($field) ) {
  37                     if ( defined $subfield ) {
  38                         my @tags = $record->field($field);
  39                         foreach my $t (@tags) {
  40                             $t->delete_subfields($subfield);
  41                         }
  42                     } else {
  43                         $record->delete_fields( $record->field($field) );
  44                     }
  45                 }
  46             }
  47         }
  48     }
  49     C4::Biblio::RemoveAllNsb($record) if $clean;
  50     return $record;
  51 }
  52
  53 sub _get_authority_for_export {
  54     my ($params) = @_;
  55     my $authid = $params->{authid} || return;
  56     my $authority = Koha::MetadataRecord::Authority->get_from_authid($authid);
  57     return unless $authority;
  58     return $authority->record;
  59 }
  60
  61 sub _get_biblio_for_export {
  62     my ($params)     = @_;
  63     my $biblionumber = $params->{biblionumber};
  64     my $itemnumbers  = $params->{itemnumbers};
  65     my $export_items = $params->{export_items} // 1;
  66     my $only_export_items_for_branch = $params->{only_export_items_for_branch};
  67
  68     my $record = eval { C4::Biblio::GetMarcBiblio($biblionumber); };
  69
  70     return if $@ or not defined $record;
  71
  72     if ($export_items) {
  73         C4::Biblio::EmbedItemsInMarcBiblio( $record, $biblionumber, $itemnumbers );
  74         if ($only_export_items_for_branch) {
  75             my ( $homebranchfield, $homebranchsubfield ) = GetMarcFromKohaField( 'items.homebranch', '' );    # Should be GetFrameworkCode( $biblionumber )?
  76
  77             for my $itemfield ( $record->field($homebranchfield) ) {
  78                 my $homebranch = $itemfield->subfield($homebranchsubfield);
  79                 if ( $only_export_items_for_branch ne $homebranch ) {
  80                     $record->delete_field($itemfield);
  81                 }
  82             }
  83         }
  84     }
  85     return $record;
  86 }
  87
  88 sub export {
  89     my ($params) = @_;
  90
  91     my $record_type        = $params->{record_type};
  92     my $record_ids         = $params->{record_ids} || [];
  93     my $format             = $params->{format};
  94     my $itemnumbers        = $params->{itemnumbers} || [];    # Does not make sense with record_type eq auths
  95     my $export_items       = $params->{export_items};
  96     my $dont_export_fields = $params->{dont_export_fields};
  97     my $csv_profile_id     = $params->{csv_profile_id};
  98     my $output_filepath    = $params->{output_filepath};
  99
 100     return unless $record_type;
 101     return unless @$record_ids;
 102
 103     my $fh;
 104     if ( $output_filepath ) {
 105         open $fh, '>', $output_filepath or die "Cannot open file $output_filepath ($!)";
 106         select $fh;
 107         binmode $fh, ':encoding(UTF-8)' unless $format eq 'csv';
 108     } else {
 109         binmode STDOUT, ':encoding(UTF-8)' unless $format eq 'csv';
 110     }
 111
 112     if ( $format eq 'iso2709' ) {
 113         for my $record_id (@$record_ids) {
 114             my $record = _get_record_for_export( { %$params, record_id => $record_id } );
 115             my $errorcount_on_decode = eval { scalar( MARC::File::USMARC->decode( $record->as_usmarc )->warnings() ) };
 116             if ( $errorcount_on_decode or $@ ) {
 117                 warn $@ if $@;
 118                 warn "record (number $record_id) is invalid and therefore not exported because its reopening generates warnings above";
 119                 next;
 120             }
 121             print $record->as_usmarc();
 122         }
 123     } elsif ( $format eq 'xml' ) {
 124         my $marcflavour = C4::Context->preference("marcflavour");
 125         MARC::File::XML->default_record_format( ( $marcflavour eq 'UNIMARC' && $record_type eq 'auths' ) ? 'UNIMARCAUTH' : $marcflavour );
 126
 127         print MARC::File::XML::header();
 128         print "\n";
 129         for my $record_id (@$record_ids) {
 130             my $record = _get_record_for_export( { %$params, record_id => $record_id } );
 131             print MARC::File::XML::record($record);
 132             print "\n";
 133         }
 134         print MARC::File::XML::footer();
 135         print "\n";
 136     } elsif ( $format eq 'csv' ) {
 137         $csv_profile_id ||= Koha::CsvProfiles->search({ profile => C4::Context->preference('ExportWithCsvProfile') })->export_format_id;
 138         print marc2csv( $record_ids, $csv_profile_id, $itemnumbers );
 139     }
 140
 141     close $fh if $output_filepath;
 142 }
 143
 144 1;
 145
 146 __END__
 147
 148 =head1 NAME
 149
 150 Koha::Exporter::Records - module to export records (biblios and authorities)
 151
 152 =head1 SYNOPSIS
 153
 154 This module provides a public subroutine to export records as xml, csv or iso2709.
 155
 156 =head2 FUNCTIONS
 157
 158 =head3 export
 159
 160     Koha::Exporter::Record::export($params);
 161
 162 $params is a hashref with some keys:
 163
 164 It will displays on STDOUT the generated file.
 165
 166 =over 4
 167
 168 =item record_type
 169
 170   Must be set to 'bibs' or 'auths'
 171
 172 =item record_ids
 173
 174   The list of the records to export (a list of biblionumber or authid)
 175
 176 =item format
 177
 178   The format must be 'csv', 'xml' or 'iso2709'.
 179
 180 =item itemnumbers
 181
 182   Generate the item infos only for these itemnumbers.
 183
 184   Must only be used with biblios.
 185
 186 =item export_items
 187
 188   If this flag is set, the items will be exported.
 189   Default is ON.
 190
 191 =item dont_export_fields
 192
 193   List of fields not to export.
 194
 195 =item csv_profile_id
 196
 197   If the format is csv, a csv_profile_id can be provide to overwrite the default value (syspref ExportWithCsvProfile).
 198
 199 =cut
 200
 201 =back
 202
 203 =head1 LICENSE
 204
 205 This file is part of Koha.
 206
 207 Copyright Koha Development Team
 208
 209 Koha is free software; you can redistribute it and/or modify it
 210 under the terms of the GNU General Public License as published by
 211 the Free Software Foundation; either version 3 of the License, or
 212 (at your option) any later version.
 213
 214 Koha is distributed in the hope that it will be useful, but
 215 WITHOUT ANY WARRANTY; without even the implied warranty of
 216 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
 217 GNU General Public License for more details.
 218
 219 You should have received a copy of the GNU General Public License
 220 along with Koha; if not, see <http://www.gnu.org/licenses>.