[webpac] / WebPac.pm

package WebPac;

use base 'CGI::Application';
use strict;

use HTML::Pager;
use HTML::FillInForm;
use SWISH;
use Text::Iconv;
use DBI;

use lib '..';
use index_DBI;
use back2html;

# configuration options
# FIXME they really should go in configuration file!
my $TEMPLATE_PATH = '/data/webpac/template_html';
my $CHARSET = 'ISO-8859-2';
my $SWISH = '/usr/bin/swish-e';
my $INDEX = '/data/webpac/index/isis.index';
my $MAX_HITS = 500;
my $ON_PAGE = 10;

Text::Iconv->raise_error(0);     # Conversion errors raise exceptions

my $from_utf8 = Text::Iconv->new('UTF8', $CHARSET);

sub setup {
        my $self = shift;
        $self->tmpl_path($TEMPLATE_PATH);
        $self->run_modes(
                'search' => 'show_search_form',
                'results' => 'show_results_list',
#               'user' => 'show_user_detail',
                'index' => 'show_index',
        );
        $self->start_mode('search');
        $self->mode_param('rm');

        $self->header_props(-charset=>$CHARSET);
}

sub show_search_form {
        my $self = shift;

        # Get the CGI.pm query object
        my $q = $self->query();

        my $tmpl = $self->load_tmpl('search.html');
        my $html = $tmpl->output;

        my $fif = new HTML::FillInForm;

        return $fif->fill(scalarref => \$html, fobject => $q,
                target => 'search');
}
 
sub show_results_list {
        my $self = shift;

        my $q = $self->query();

        my @swish_results;      # results from swish

        # load template for this page

        my @s_arr;      # all queries are located here

        my @path_arr = $q->param('path');
        my $full = $q->param('full');

        for(my $i = 1; $i <=10; $i++) {

                return show_index($self, $i) if ($q->param("f".$i."_index"));
                next if (! $q->param("f$i"));
                next if (! $q->param("v$i"));

                # re-write query from +/- to and/and not
                my $s;
                my $search = $q->param("v$i");
                while ($search =~ s/\s*("[^"]+")\s*/ /) {
                        $s .= "$1 ";
                }
                $search =~ s/^\s+//;
                $search =~ s/\s+$//;

                foreach (split(/\s+/,$search)) {
                        if (m/^([+-])(\S+)/) {
                                $s.= ($s) ? "and " : "";
                                $s.="not " if ($1 eq "-");
                                $s.="$2* ";
                        } else {
                                $s.="$_* ";
                        }
                }
                $s =~ s/\*+/*/g;

                push @s_arr,$q->param("f$i")."_swish=($s)";
        }

        my $tmpl = $self->load_tmpl('results.html');

        # call swish
        my $sh = SWISH->connect('Fork',
                prog     => $SWISH,
                indexes  => $INDEX,
                properties  => [qw/swishdocpath swishrank swishtitle headline html/],
                results  => sub {
                        my ($sh,$hit) = @_;

                        push @swish_results, {
                                nr => ($#swish_results + 2),
                                path => $hit->swishdocpath,
                                headline => $from_utf8->convert($hit->headline),
                                html => back2html($from_utf8->convert($hit->html)),
                                rank => $hit->swishrank };

                },
                #startnum => 0,
                maxhits => $MAX_HITS
        );

        die $SWISH::errstr unless $sh;

        # construct swish query
        my $sw_q = join(" and ",@s_arr);
        if (@path_arr) {
                $sw_q .= "and (swishdocpath=\"";
                $sw_q .= join("\" or swishdocpath=\"",@path_arr);
                $sw_q .= "\")";
                $tmpl->param('full',1); # show full records
        }

        my $hits = $sh->query($sw_q);

        $tmpl->param('hits',$hits);
        $tmpl->param('search',$sw_q);

        $tmpl->param('PAGER_offset',$q->param("PAGER_offset") || 0);
        $tmpl->param('last_PAGER_offset',$q->param("last_PAGER_offset") || 0);

        # create a Pager object
        my $pager = HTML::Pager->new(
                # required parameters
                query => $q,
                get_data_callback => sub {
                        my ($offset, $rows) = @_;

                        my @result;
                        for (my $i=0; $i<$rows; $i++) {
                                push @result, $swish_results[$offset+$i] if $swish_results[$offset+$i];
                        }
                        return \@result;
                },
                rows => $hits,
                page_size => $ON_PAGE,
                # some optional parameters
                persist_vars => [
                        'rm',
                        'f1', 'v1',
                        'f2', 'v2',
                        'f3', 'v3',
                        'f4', 'v4',
                        'f5', 'v5',
                        'f6', 'v6',
                        'f7', 'v7',
                        'f8', 'v8',
                        'f9', 'v9',
                        ],
                #cell_space_color => '#000000',
                #cell_background_color => '#ffffff',
                #nav_background_color => '#dddddd',
                #javascript_presubmit => 'last_minute_javascript()',
                debug => 1,
                template => $tmpl,
        );

        my $html = $pager->output;

        return $html;
}
 
sub show_index {
        my $self = shift;
        my $i = shift;          # field number

        my $q = $self->query();

        my $field = $q->param("f$i");
        my $limit = $q->param("v$i");

        my $html;

        my $index = new index_DBI();

        my $total = $index->check($field);
        if (! $total) {
                my $tmpl = $self->load_tmpl('no_index.html');
                $tmpl->param('field',$field);
                $html = $tmpl->output;
                return $html;
        }

        my $tmpl = $self->load_tmpl('index_res.html');
        $tmpl->param('field',$field);
        $tmpl->param('limit',$limit);
        $tmpl->param('total',$total);

# FIXME I should set offset and leave out limit from fetch!!
#       if (! $q->param("PAGER_offset") {
#               $q->param("Pager_offet)
#       }

        my $pager = HTML::Pager->new(
                query => $q,
                get_data_callback => sub {
                        my ($offset, $rows) = @_;

                        my @result = $index->fetch($field,'item',$limit, $offset, $rows);
                        return \@result;
                },
                rows => $total,
                page_size => $ON_PAGE,
                persist_vars => [
                        'rm', 
                        "f$i", "v$i", "f".$i."_index", 
                        'offset',
                        ],
                debug => 1,
                template => $tmpl,
        );

        return $pager->output;
}

1;