git.rot13.org Git - webpac/blob - WebPac.pm

   1 package WebPac;
   2
   3 use base 'CGI::Application';
   4 use strict;
   5
   6 use HTML::FillInForm;
   7 use SWISH::API;
   8 use Text::Iconv;
   9 use DBI;
  10 use Config::IniFiles;
  11 use Text::Unaccent;
  12 use Data::Pageset;
  13 use POSIX qw(locale_h);
  14
  15 use lib '..';
  16 use index_DBI_filter;
  17 use back2html;
  18
  19
  20 # read global.conf configuration
  21 my $cfg_global = new Config::IniFiles( -file => '../global.conf' ) || die "can't open 'global.conf'";
  22
  23 # configuration options from global.conf
  24 my $TEMPLATE_PATH = $cfg_global->val('webpac', 'template_html') || die "need template_html in global.conf, section webpac";
  25 my $CHARSET = $cfg_global->val('webpac', 'charset') || 'ISO-8859-1';
  26 my $SWISH = $cfg_global->val('webpac', 'swish') || '/usr/bin/swish-e';
  27 my $INDEX = $cfg_global->val('webpac', 'index') || die "need index in global.conf, section webpac";
  28 my $MAX_HITS = $cfg_global->val('webpac', 'max_hits') || 0;
  29 my $ON_PAGE =$cfg_global->val('webpac', 'on_page') || 10;
  30 my $MIN_WILDCARD =$cfg_global->val('webpac', 'min_wildcard') || 1;
  31 my $TEMPLATE =$cfg_global->val('webpac', 'template');
  32 my $UNAC_FILTER =$cfg_global->val('global', 'my_unac_filter');
  33 my $BASE_PATH =$cfg_global->val('webpac', 'base_path');
  34 # for pager
  35 my $pages_per_set = $cfg_global->val('webpac', 'pages_per_set') || 10;
  36 my $locale = $cfg_global->val('locale') || 'hr_HR';
  37
  38 Text::Iconv->raise_error(0);     # Conversion errors raise exceptions
  39
  40 my $from_utf8 = Text::Iconv->new('UTF8', $CHARSET);
  41
  42 setlocale(LC_CTYPE, $locale);
  43 setlocale(LC_COLLATE, $locale);
  44
  45 if ($UNAC_FILTER) {
  46         require $UNAC_FILTER;
  47 } else {
  48         sub WebPac::my_unac_string {
  49                 my ($charset, $string) = (@_);
  50                 return $string;
  51         }
  52 }
  53
  54 # use path from cgi script to support templates in subdirs
  55 sub url_ex {
  56         my $q = shift || die "suff2file needs CGI object!";
  57         my $tpl = shift || die "url_ex needs template name!";
  58         return suff2file($BASE_PATH, $q->url(-absolute => 1,-path => 1),$TEMPLATE_PATH,$tpl);
  59 }
  60
  61 sub suff2file($$$$) {
  62         my ($base_path, $p, $path, $tpl) = @_;
  63
  64         return $tpl if (! $base_path);
  65
  66         #warn "base_path: $base_path, p: $p, path: $path, tpl: $tpl\n";
  67
  68         $p =~ s#/[^/]*$##;
  69
  70         # strip everything to and including base path, leaving only
  71         # additional (virtual) path
  72         if ($base_path eq "/") {
  73                 $p =~ s,/*,,g;
  74                 my ($name,$ext) = split(/\./,$tpl);
  75                 $p = $name . "-" . $p . "." . $ext;
  76         } elsif ($p =~ s,^.*?$base_path,,) {
  77                 $p =~ s,/*,,g;
  78                 my ($name,$ext) = split(/\./,$tpl);
  79                 $p = $name . $p . "." . $ext;
  80         } else {
  81                 # if unable reset it!
  82                 $p = $tpl;
  83         }
  84
  85         if ( -e "$path/$p") {
  86                 return $p;
  87         } else {
  88                 return $tpl;
  89         }
  90
  91 }
  92
  93 sub setup {
  94         my $self = shift;
  95         $self->tmpl_path($TEMPLATE_PATH);
  96         $self->run_modes(
  97                 'search' => 'show_search_form',
  98                 'results' => 'show_results_list',
  99 #               'user' => 'show_user_detail',
 100                 'index' => 'show_index',
 101         );
 102         $self->start_mode('search');
 103         $self->mode_param('rm');
 104
 105         $self->header_props(-charset=>$CHARSET);
 106 }
 107
 108 sub in_template {
 109         my $q = shift || die "need CGI object!";
 110         my $html = shift || die "This page is left unintentionally blank";
 111         return $html if (! defined($TEMPLATE));
 112
 113         my ($dir,$tpl);
 114         if ($TEMPLATE =~ m,^(.*?/*)([^/]+)$,) {
 115                 ($dir,$tpl) = ($1,$2);
 116         } else {
 117                 die "can't parse TEMPLATE path";
 118         }
 119
 120         my $master_tpl = suff2file($BASE_PATH, $q->url(-absolute => 1, -path => 1),$dir,$tpl);
 121         if (open(T, $master_tpl)) {
 122                 my $template_html = join("\n",<T>);
 123                 close(T);
 124                 $template_html =~ s/##webpac##/$html/gsi;
 125                 return $template_html;
 126         } else {
 127                 return "Can't read template '$master_tpl'";
 128         }
 129 }
 130
 131 #--------------------------------------------------------------------------
 132
 133 #
 134 # make pager navigation and fill template variables
 135 # compatibile with HTML::Pager
 136 #
 137
 138 sub make_pager($$$) {
 139         my ($q,$tmpl,$pager) = @_;
 140
 141         #
 142         # pager navigation
 143         #
 144         my ($pager_prev,$pager_next, $pager_jump) = ('','','');
 145
 146         my $nav_fmt=qq{ <a href="%s">%s</a> };
 147
 148         if ($pager->current_page() > $pager->first_page) {
 149                 $q->param('PAGER_offset', $pager->current_page - 1);
 150                 $pager_prev .= sprintf($nav_fmt,$q->url(-relative=>1, -query=>1),'&lt;&lt;');
 151         }
 152
 153         if ($pager->previous_set) {
 154                 $q->param('PAGER_offset', $pager->previous_set);
 155                 $pager_prev .= sprintf($nav_fmt,$q->url(-relative=>1, -query=>1),'..');
 156         }
 157
 158
 159         foreach my $p (@{$pager->pages_in_set()}) {
 160                 next if ($p <= 0);
 161                 if($p == $pager->current_page()) {
 162                         $pager_jump .= "<b>$p</b> ";
 163                 } else {
 164                         $q->param('PAGER_offset', $p);
 165                         $pager_jump .= sprintf($nav_fmt,$q->url(-relative=>1, -query=>1),$p);
 166                 }
 167         }
 168
 169         if ($pager->next_set) {
 170                 $q->param('PAGER_offset', $pager->next_set);
 171                 $pager_next .= sprintf($nav_fmt,$q->url(-relative=>1, -query=>1),'..');
 172         }
 173
 174         if ($pager->current_page() < $pager->last_page) {
 175                 $q->param('PAGER_offset', $pager->current_page + 1);
 176                 $pager_next .= sprintf($nav_fmt,$q->url(-relative=>1, -query=>1),'&gt;&gt;');
 177         }
 178
 179         $tmpl->param('PAGER_PREV', $pager_prev);
 180         $tmpl->param('PAGER_JUMP', $pager_jump);
 181         $tmpl->param('PAGER_NEXT', $pager_next);
 182
 183 }
 184
 185 #
 186 # put persisten variables in template
 187 #
 188
 189 sub make_pager_vars {
 190         my $q = shift @_;
 191         my $tmpl = shift @_;
 192         my @persist_vars = @_;
 193         my $hidden_vars = '';
 194         my $hidden_search = '';
 195         foreach my $v (@persist_vars) {
 196                 foreach my $val ($q->param($v)) {
 197                         next if (! $val || $val eq '');
 198                         $val =~ s/"/&quot;/g;
 199                         $hidden_vars .= '<input type="hidden" name="'.$v.'" value="'.$val.'"/>'."\n";
 200                         $hidden_search .= '<input type="hidden" name="'.$v.'" value="'.$val.'"/>'."\n" if ($v ne "rm");
 201                 }
 202         }
 203
 204         $tmpl->param('PAGER_HIDDEN', $hidden_vars);
 205         $tmpl->param('SEARCH_HIDDEN', $hidden_search);
 206         $tmpl->param('PAGER_JAVASCRIPT', qq#
 207 <SCRIPT LANGUAGE="Javascript">
 208 <!-- Begin
 209         // dummy emulator for HTML::Pager templates
 210         function PAGER_set_offset_and_submit() {
 211                 return true;
 212         }
 213 // End -->
 214 </script>
 215         #);
 216 }
 217
 218 #--------------------------------------------------------------------------
 219
 220 sub show_search_form {
 221         my $self = shift;
 222
 223         # Get the CGI.pm query object
 224         my $q = $self->query();
 225
 226         my $tmpl = $self->load_tmpl(url_ex($q,'search.html'));
 227         my $html = $tmpl->output;
 228
 229         my $fif = new HTML::FillInForm;
 230
 231         return in_template($q,$fif->fill(scalarref => \$html, fobject => $q,
 232                 target => 'search'));
 233 }
 234
 235 sub show_results_list {
 236         my $self = shift;
 237
 238         my $q = $self->query();
 239
 240         # submit was reset?
 241         if ($q->param('reset')) {
 242                 $q->delete_all;
 243                 return $self->show_search_form();
 244         }
 245
 246         # load template for this page
 247
 248         my @s_arr;      # all queries are located here
 249
 250         my @path_arr = $q->param('path');
 251         my $full = $q->param('full');
 252
 253         my @persist_vars = ( 'rm', 'persist_search' );
 254         my $url_params = {
 255                 'rm' => 'results',
 256                 'show_full' => 1,
 257                 'last_PAGER_offset' => ($q->param('PAGER_offset') || 0),
 258         };
 259
 260         my @persist_search_vars;
 261         my $url_params_persist = {};
 262         if ($q->param("persist_search")) {
 263                 @persist_search_vars = split(/\s*,\s*/, $q->param("persist_search"));
 264                 $url_params_persist->{'persist_search'} = $q->url_param("persist_search");
 265                 $url_params->{'persist_search'} = $q->url_param("persist_search");
 266         }
 267
 268         # support parametars "f" and "v" for start
 269         for(my $i = 0; $i <=30; $i++) {
 270
 271                 $i = '' if ($i == 0);
 272
 273                 return show_index($self, $i) if ($q->param("f".$i."_index"));
 274
 275                 next if (! $q->param("v$i") || $q->param("v$i") eq '');
 276                 next if (! $q->param("f$i"));
 277
 278                 my $persist = grep(/^$i$/,@persist_search_vars);
 279
 280                 push @persist_vars, "f$i";
 281                 push @persist_vars, "v$i";
 282                 push @persist_vars, "e$i" if ($q->param("e$i"));
 283
 284                 # create url parametars (and persistent ones)
 285
 286                 $url_params->{"f$i"} = $q->url_param("f$i");
 287                 $url_params_persist->{"f$i"} = $q->url_param("f$i") if ($persist);
 288
 289                 my @v;
 290
 291                 foreach my $v ($q->url_param("v$i")) {
 292                         # escape quotes so that phrase search work
 293                         $v =~ s/"/%22/g;
 294                         push @v, $v;
 295                 }
 296                 $url_params->{"v$i"} = \@v;
 297                 $url_params_persist->{"v$i"} = \@v if ($persist);
 298
 299                 if ($q->param("e$i")) {
 300                         $url_params->{"e$i"} = $q->url_param("e$i");
 301 #                       $url_params_persist->{"e$i"} = $q->url_param("e$i");
 302                 }
 303
 304                 my $wc="*";     # swish wildcard
 305                 $wc="" if ($i eq "");   # don't apply wildcard on field 0
 306
 307                 # re-write query from +/- to and/and not
 308                 my @param_vals = $q->param("v$i");
 309                 my @swish_q;
 310                 my ($pre,$post,$exact) = ('','','');
 311                 while (my $search = shift @param_vals) {
 312                         my $s;
 313                         # remove accents
 314                         $search = my_unac_string($CHARSET,$search);
 315                         while ($search =~ s/\s*("[^"]+")\s*/ /) {
 316                                 $s .= "$1 ";
 317                         }
 318                         $search =~ s/^\s+//;
 319                         $search =~ s/\s+$//;
 320
 321                         # filed e[nr] is exact match bitmask
 322                         # 1 = beginning, 2=end, 3=both
 323                         my $exact_flag = $q->param("e$i") || 0;
 324                         $pre = '"xxbxx ' if ($exact_flag & 1);
 325                         $post = ' xxexx"' if ($exact_flag & 2);
 326                         # add qotes on other side
 327                         if ($q->param("e$i")) {
 328                                 $pre = '"' if (! $pre);
 329                                 $post = '"' if (! $post);
 330                                 # what about wildcards?
 331                                 $wc = '';
 332                                 $wc = '*' if ($q->param("e$i") & 4);
 333                                 $exact = '_exact';
 334                         }
 335
 336                         foreach (split(/\s+/,$search)) {
 337                                 if (m/^([+-])(\S+)/) {
 338                                         $s.= ($s) ? "and " : "";
 339                                         $s.="not " if ($1 eq "-");
 340                                         $s.=$2.$wc." ";
 341                                 } elsif (m/^\s*(and|or|not)\s*$/i) {
 342                                         $s.=$_." ";
 343                                 # don't add * to words with less than x chars
 344                                 } elsif (length($_) <= $MIN_WILDCARD) {
 345                                         $s.=$_." ";
 346                                 } else {
 347                                         $s.=$_.$wc." ";
 348                                 }
 349                         }
 350                         $s =~ s/\*+/*/g;
 351                         $s =~ s/[()]//g;        # () are used in query language
 352                         $s = $pre.$s.$post if ($q->param("e$i"));
 353                         push @swish_q,$s;
 354                 }
 355                 # FIXME default operator for multi-value fields is or. There is
 356                 # no way to change it, except here for now. Is there need?
 357                 push @s_arr, $q->param("f$i")."_swish".$exact."=(".join(" or ",@swish_q).")";
 358         }
 359
 360         my $tmpl = $self->load_tmpl(url_ex($q,'results.html'), global_vars => 1, die_on_bad_params => 0);
 361
 362         sub esc_html {
 363                 my $html = shift;
 364                 $html =~ s/</&lt;/g;
 365                 $html =~ s/>/&gt;/g;
 366                 return $html;
 367         }
 368
 369         my $sort = 'swishrank';
 370         if ($q->param("sort")) {
 371                 $sort = 'headline';
 372                 push @persist_vars, "sort";
 373         }
 374
 375         my $sortby = $q->param("sortby");
 376         if ($sortby) {
 377                 $sort = $sortby;
 378                 push @persist_vars, "sortby";
 379         }
 380         # used to filter entries in index and swish
 381         my $filter = $q->param("filter");
 382
 383         # construct swish query
 384         my $sw_q = join(" and ",@s_arr);
 385         if (@path_arr && $q->param('show_full')) {
 386                 $sw_q .= " and (swishdocpath=\"";
 387                 $sw_q .= join("\" or swishdocpath=\"",@path_arr);
 388                 $sw_q .= "\")";
 389                 $tmpl->param('full',1); # show full records
 390 #       } elsif (@path_arr && $#path_arr == 0) {
 391 #               # I will assume that it's a filter since there isn't show_full
 392 #               $filter = shift @path_arr;
 393         } elsif ($q->param('show_full')) {
 394                 # just show full path, no path defined
 395                 $tmpl->param('full',1);
 396         } else {
 397                 $tmpl->param('full',0);
 398         }
 399
 400         if ($filter) {
 401                 $sw_q .= " and (swishdocpath=\"$filter\")" unless (@path_arr);
 402                 push @persist_vars, "filter";
 403                 $url_params->{'filter'} = $filter;
 404                 $url_params_persist->{'filter'} = $filter;
 405         }
 406
 407         my $swish_msg = ' ';
 408
 409         # create new swish instance
 410         my $swish = SWISH::API->new($INDEX);
 411         $swish_msg .= $swish->ErrorString." ".$swish->LastErrorMsg if $swish->Error;
 412
 413         # execute query and get number of results from SWISH-E
 414         my $search = $swish->New_Search_Object;
 415
 416         $search->SetSort($sort);
 417
 418         my $results = $search->Execute($sw_q);
 419         $swish_msg .= $swish->ErrorString." ".$swish->LastErrorMsg if $swish->Error;
 420
 421         my $hits = $results->Hits;
 422
 423         $tmpl->param('hits',$hits);
 424         my $search_msg = $sw_q;
 425         $search_msg .= '<em>'.$swish_msg.'</em>' if ($swish_msg);
 426         $tmpl->param('search', $search_msg);
 427
 428         $tmpl->param('PAGER_offset',$q->param("PAGER_offset") || 0);
 429         $tmpl->param('last_PAGER_offset',$q->param("last_PAGER_offset") || 0);
 430
 431         # URL parametars for search results
 432         sub cook_url_params {
 433                 my $hash = shift || return;
 434                 return join("&", map {
 435                         my $var = $_;
 436                         if (ref($hash->{$var}) eq 'ARRAY') {
 437                                 join('&',
 438                                         map { $var.'='.$_ } @{$hash->{$var}}
 439                                 );
 440                         } else {
 441                                 $var."=".$hash->{$var};
 442                         }
 443                 } keys %{$hash});
 444         }
 445
 446         $tmpl->param('url_params',"?".cook_url_params($url_params));
 447         $tmpl->param('url_params_paths',"?".cook_url_params($url_params).'&'.join("&",map { my $t = $_; $t =~ s/\#/%23/g; "path=$t"; } @path_arr));
 448
 449
 450
 451         #
 452         # build pager
 453         #
 454
 455         my $current_page = $q->param('PAGER_offset') || 1;
 456
 457         my $pager = Data::Pageset->new({
 458                 'total_entries' => $hits,
 459                 'entries_per_page' => $ON_PAGE,
 460                 'current_page' => $current_page,
 461                 'pages_per_set' => $pages_per_set,
 462         });
 463
 464         $results->SeekResult( $pager->first - 1 );
 465
 466         # get number of entries on this page
 467         my $i = $pager->entries_on_this_page;
 468
 469         # results from swish for template
 470         my @pager_data_list;
 471
 472         for(my $i=$pager->first; $i<=$pager->last; $i++) {
 473
 474                 my $result = $results->NextResult;
 475                 last if (! $result);
 476
 477                 my $r = {
 478                         nr => $i,
 479                         path => $result->Property('swishdocpath'),
 480                         headline => esc_html($from_utf8->convert($result->Property('headline'))),
 481                         rank => $result->Property('swishrank')
 482                 };
 483
 484                 #$r->{html} = back2html($from_utf8->convert($result->Property('html')), cook_url_params($url_params_persist)) if ($q->param('show_full'));
 485                 $r->{html} = back2html($from_utf8->convert($result->Property('html')), $filter ? 'filter='.$filter : '') if ($q->param('show_full'));
 486
 487                 push @pager_data_list, $r;
 488         }
 489
 490
 491
 492         # put something in template
 493         make_pager($q, $tmpl, $pager);
 494         make_pager_vars($q, $tmpl, @persist_vars);
 495         $tmpl->param('PAGER_DATA_LIST', \@pager_data_list);
 496
 497         my $html = $tmpl->output;
 498
 499         return in_template($q,$html);
 500 }
 501
 502 sub show_index {
 503         my $self = shift;
 504         my $i = shift;          # field number
 505
 506         my $q = $self->query();
 507
 508         my $field = $q->param("f$i");
 509         my $limit = $q->param("v$i");
 510
 511         my $filter = $q->param("filter");
 512
 513         my $html;
 514
 515         my $index = new index_DBI(
 516                 $cfg_global->val('global', 'dbi_dbd'),
 517                 $cfg_global->val('global', 'dbi_dsn'),
 518                 $cfg_global->val('global', 'dbi_user'),
 519                 $cfg_global->val('global', 'dbi_passwd') || ''
 520         );
 521
 522         my $total = $index->count($field,$limit,$filter);
 523
 524         if (! defined($total)) {
 525                 my $tmpl = $self->load_tmpl(url_ex($q,'no_index.html'));
 526                 $tmpl->param('field',$field);
 527                 $html = $tmpl->output;
 528                 return $html;
 529         }
 530
 531         my $tmpl = $self->load_tmpl(url_ex($q,'index_res.html'), global_vars => 1, die_on_bad_params => 0);
 532         $tmpl->param('field',$field);
 533         $tmpl->param('limit',$limit);
 534         $tmpl->param('total',$total);
 535         $tmpl->param('filter',$filter);
 536
 537 # FIXME I should set offset and leave out limit from fetch!!
 538 #       if (! $q->param("PAGER_offset") {
 539 #               $q->param("Pager_offet)
 540 #       }
 541
 542
 543         #
 544         # build pager
 545         #
 546         my $pager = Data::Pageset->new({
 547                 'total_entries' => $total,
 548                 'entries_per_page' => $ON_PAGE,
 549                 'current_page' => $q->param('PAGER_offset') || 1,
 550                 'pages_per_set' => $pages_per_set
 551         });
 552
 553         my @persist_vars = qw{rm f$i v$i f$i_index offset};
 554
 555         make_pager($q, $tmpl, $pager);
 556         make_pager_vars($q, $tmpl, @persist_vars);
 557
 558         my @pager_data_list = $index->fetch($field,$limit, $pager->first - 1, $pager->entries_on_this_page, $filter);
 559         $tmpl->param('PAGER_DATA_LIST', \@pager_data_list);
 560
 561         return in_template($q,$tmpl->output);
 562 }
 563
 564 1;