admin/searchengine/elasticsearch/mappings.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use CGI;
  20 use C4::Koha;
  21 use C4::Output;
  22 use C4::Auth;
  23
  24 use Koha::SearchEngine::Elasticsearch;
  25 use Koha::SearchMarcMaps;
  26 use Koha::SearchFields;
  27
  28 my $input = new CGI;
  29 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  30     {   template_name   => 'admin/searchengine/elasticsearch/mappings.tt',
  31         query           => $input,
  32         type            => 'intranet',
  33         authnotrequired => 0,
  34         flagsrequired   => { parameters => 'manage_search_engine_config' },
  35     }
  36 );
  37
  38 my $index = $input->param('index') || 'biblios';
  39 my $op    = $input->param('op')    || 'list';
  40 my @messages;
  41
  42 my $database = Koha::Database->new();
  43 my $schema   = $database->schema;
  44
  45 my $marc_type = lc C4::Context->preference('marcflavour');
  46
  47 if ( $op eq 'edit' ) {
  48
  49     $schema->storage->txn_begin;
  50
  51     my @field_name = $input->param('search_field_name');
  52     my @field_label = $input->param('search_field_label');
  53     my @field_type = $input->param('search_field_type');
  54     my @field_weight = $input->param('search_field_weight');
  55
  56     my @index_name          = $input->param('mapping_index_name');
  57     my @search_field_name  = $input->param('mapping_search_field_name');
  58     my @mapping_sort        = $input->param('mapping_sort');
  59     my @mapping_facet       = $input->param('mapping_facet');
  60     my @mapping_suggestible = $input->param('mapping_suggestible');
  61     my @mapping_marc_field  = $input->param('mapping_marc_field');
  62
  63     eval {
  64
  65         for my $i ( 0 .. scalar(@field_name) - 1 ) {
  66             my $field_name = $field_name[$i];
  67             my $field_label = $field_label[$i];
  68             my $field_type = $field_type[$i];
  69             my $field_weight = $field_weight[$i];
  70
  71             my $search_field = Koha::SearchFields->find( { name => $field_name }, { key => 'name' } );
  72             $search_field->label($field_label);
  73             $search_field->type($field_type);
  74             $search_field->weight($field_weight || '');
  75             $search_field->store;
  76         }
  77
  78         Koha::SearchMarcMaps->search( { marc_type => $marc_type, } )->delete;
  79
  80         for my $i ( 0 .. scalar(@index_name) - 1 ) {
  81             my $index_name          = $index_name[$i];
  82             my $search_field_name  = $search_field_name[$i];
  83             my $mapping_marc_field  = $mapping_marc_field[$i];
  84             my $mapping_facet       = $mapping_facet[$i];
  85             my $mapping_suggestible = $mapping_suggestible[$i];
  86             my $mapping_sort        = $mapping_sort[$i];
  87             $mapping_sort = undef if $mapping_sort eq 'undef';
  88
  89             my $search_field = Koha::SearchFields->find({ name => $search_field_name }, { key => 'name' });
  90             # TODO Check mapping format
  91             my $marc_field = Koha::SearchMarcMaps->find_or_create({ index_name => $index_name, marc_type => $marc_type, marc_field => $mapping_marc_field });
  92             $search_field->add_to_search_marc_maps($marc_field, { facet => $mapping_facet, suggestible => $mapping_suggestible, sort => $mapping_sort } );
  93
  94         }
  95     };
  96     if ($@) {
  97         push @messages, { type => 'error', code => 'error_on_update', message => $@, };
  98         $schema->storage->txn_rollback;
  99     } else {
 100         push @messages, { type => 'message', code => 'success_on_update' };
 101         $schema->storage->txn_commit;
 102     }
 103 }
 104 elsif( $op eq 'reset_confirmed' ) {
 105     Koha::SearchMarcMaps->delete;
 106     Koha::SearchFields->delete;
 107     Koha::SearchEngine::Elasticsearch->reset_elasticsearch_mappings;
 108     push @messages, { type => 'message', code => 'success_on_reset' };
 109 }
 110 elsif( $op eq 'reset_confirm' ) {
 111     $template->param( reset_confirm => 1 );
 112 }
 113
 114
 115 my @indexes;
 116
 117 for my $index_name (qw| biblios authorities |) {
 118     my $search_fields = Koha::SearchFields->search(
 119         { 'search_marc_map.index_name' => $index_name, 'search_marc_map.marc_type' => $marc_type, },
 120         {   join => { search_marc_to_fields => 'search_marc_map' },
 121             '+select' => [ 'search_marc_to_fields.facet', 'search_marc_to_fields.suggestible', 'search_marc_to_fields.sort', 'search_marc_map.marc_field' ],
 122             '+as'     => [ 'facet',                       'suggestible',                       'sort',                       'marc_field' ],
 123             order_by => { -asc => [qw/name marc_field/] }
 124         }
 125     );
 126
 127     my @mappings;
 128     while ( my $s = $search_fields->next ) {
 129         push @mappings,
 130           { search_field_name  => $s->name,
 131             search_field_label => $s->label,
 132             search_field_type  => $s->type,
 133             marc_field         => $s->get_column('marc_field'),
 134             sort               => $s->get_column('sort') // 'undef', # To avoid warnings "Use of uninitialized value in lc"
 135             suggestible        => $s->get_column('suggestible'),
 136             facet              => $s->get_column('facet'),
 137           };
 138     }
 139
 140     push @indexes, { index_name => $index_name, mappings => \@mappings };
 141 }
 142
 143 my $search_fields = Koha::SearchFields->search( {}, { order_by => ['name'] } );
 144 my @all_search_fields;
 145 while ( my $search_field = $search_fields->next ) {
 146     my $search_field_unblessed = $search_field->unblessed;
 147     $search_field_unblessed->{mapped_biblios} = 1 if $search_field->is_mapped_biblios;
 148     push @all_search_fields, $search_field_unblessed;
 149 }
 150
 151 $template->param(
 152     indexes           => \@indexes,
 153     all_search_fields => \@all_search_fields,
 154     messages          => \@messages,
 155 );
 156
 157 output_html_with_http_headers $input, $cookie, $template->output;