arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 #include <linux/config.h>
  11
  12 #include <asm/unistd.h>
  13
  14 #include "entry-header.S"
  15
  16
  17         .align  5
  18 /*
  19  * This is the fast syscall return path.  We do as little as
  20  * possible here, and this includes saving r0 back into the SVC
  21  * stack.
  22  */
  23 ret_fast_syscall:
  24         disable_irq                             @ disable interrupts
  25         ldr     r1, [tsk, #TI_FLAGS]
  26         tst     r1, #_TIF_WORK_MASK
  27         bne     fast_work_pending
  28
  29         @ fast_restore_user_regs
  30         ldr     r1, [sp, #S_OFF + S_PSR]        @ get calling cpsr
  31         ldr     lr, [sp, #S_OFF + S_PC]!        @ get pc
  32         msr     spsr_cxsf, r1                   @ save in spsr_svc
  33         ldmdb   sp, {r1 - lr}^                  @ get calling r1 - lr
  34         mov     r0, r0
  35         add     sp, sp, #S_FRAME_SIZE - S_PC
  36         movs    pc, lr                          @ return & move spsr_svc into cpsr
  37
  38 /*
  39  * Ok, we need to do extra processing, enter the slow path.
  40  */
  41 fast_work_pending:
  42         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  43 work_pending:
  44         tst     r1, #_TIF_NEED_RESCHED
  45         bne     work_resched
  46         tst     r1, #_TIF_NOTIFY_RESUME | _TIF_SIGPENDING
  47         beq     no_work_pending
  48         mov     r0, sp                          @ 'regs'
  49         mov     r2, why                         @ 'syscall'
  50         bl      do_notify_resume
  51         b       ret_slow_syscall                @ Check work again
  52
  53 work_resched:
  54         bl      schedule
  55 /*
  56  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  57  */
  58 ENTRY(ret_to_user)
  59 ret_slow_syscall:
  60         disable_irq                             @ disable interrupts
  61         ldr     r1, [tsk, #TI_FLAGS]
  62         tst     r1, #_TIF_WORK_MASK
  63         bne     work_pending
  64 no_work_pending:
  65         @ slow_restore_user_regs
  66         ldr     r1, [sp, #S_PSR]                @ get calling cpsr
  67         ldr     lr, [sp, #S_PC]!                @ get pc
  68         msr     spsr_cxsf, r1                   @ save in spsr_svc
  69         ldmdb   sp, {r0 - lr}^                  @ get calling r1 - lr
  70         mov     r0, r0
  71         add     sp, sp, #S_FRAME_SIZE - S_PC
  72         movs    pc, lr                          @ return & move spsr_svc into cpsr
  73
  74 /*
  75  * This is how we return from a fork.
  76  */
  77 ENTRY(ret_from_fork)
  78         bl      schedule_tail
  79         get_thread_info tsk
  80         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  81         mov     why, #1
  82         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  83         beq     ret_slow_syscall
  84         mov     r1, sp
  85         mov     r0, #1                          @ trace exit [IP = 1]
  86         bl      syscall_trace
  87         b       ret_slow_syscall
  88
  89
  90 #include "calls.S"
  91
  92 /*=============================================================================
  93  * SWI handler
  94  *-----------------------------------------------------------------------------
  95  */
  96
  97         /* If we're optimising for StrongARM the resulting code won't
  98            run on an ARM7 and we can save a couple of instructions.
  99                                                                 --pb */
 100 #ifdef CONFIG_CPU_ARM710
 101 #define A710(code...) code
 102 .Larm710bug:
 103         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 104         mov     r0, r0
 105         add     sp, sp, #S_FRAME_SIZE
 106         subs    pc, lr, #4
 107 #else
 108 #define A710(code...)
 109 #endif
 110
 111         .align  5
 112 ENTRY(vector_swi)
 113         sub     sp, sp, #S_FRAME_SIZE
 114         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 115         add     r8, sp, #S_PC
 116         stmdb   r8, {sp, lr}^                   @ Calling sp, lr
 117         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 118         str     lr, [sp, #S_PC]                 @ Save calling PC
 119         str     r8, [sp, #S_PSR]                @ Save CPSR
 120         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 121         zero_fp
 122
 123         /*
 124          * Get the system call number.
 125          */
 126
 127 #if defined(CONFIG_OABI_COMPAT)
 128
 129         /*
 130          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 131          * value to determine if it is an EABI or an old ABI call.
 132          */
 133 #ifdef CONFIG_ARM_THUMB
 134         tst     r8, #PSR_T_BIT
 135         movne   r10, #0                         @ no thumb OABI emulation
 136         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 137 #else
 138         ldr     r10, [lr, #-4]                  @ get SWI instruction
 139   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 140   A710( teq     ip, #0x0f000000                                         )
 141   A710( bne     .Larm710bug                                             )
 142 #endif
 143
 144 #elif defined(CONFIG_AEABI)
 145
 146         /*
 147          * Pure EABI user space always put syscall number into scno (r7).
 148          */
 149   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 150   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 151   A710( teq     ip, #0x0f000000                                         )
 152   A710( bne     .Larm710bug                                             )
 153
 154 #elif defined(CONFIG_ARM_THUMB)
 155
 156         /* Legacy ABI only, possibly thumb mode. */
 157         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 158         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 159         ldreq   scno, [lr, #-4]
 160
 161 #else
 162
 163         /* Legacy ABI only. */
 164         ldr     scno, [lr, #-4]                 @ get SWI instruction
 165   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 166   A710( teq     ip, #0x0f000000                                         )
 167   A710( bne     .Larm710bug                                             )
 168
 169 #endif
 170
 171 #ifdef CONFIG_ALIGNMENT_TRAP
 172         ldr     ip, __cr_alignment
 173         ldr     ip, [ip]
 174         mcr     p15, 0, ip, c1, c0              @ update control register
 175 #endif
 176         enable_irq
 177
 178         get_thread_info tsk
 179         adr     tbl, sys_call_table             @ load syscall table pointer
 180         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
 181
 182 #if defined(CONFIG_OABI_COMPAT)
 183         /*
 184          * If the swi argument is zero, this is an EABI call and we do nothing.
 185          *
 186          * If this is an old ABI call, get the syscall number into scno and
 187          * get the old ABI syscall table address.
 188          */
 189         bics    r10, r10, #0xff000000
 190         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 191         ldrne   tbl, =sys_oabi_call_table
 192 #elif !defined(CONFIG_AEABI)
 193         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 194         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 195 #endif
 196
 197         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 198         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
 199         bne     __sys_trace
 200
 201         cmp     scno, #NR_syscalls              @ check upper syscall limit
 202         adr     lr, ret_fast_syscall            @ return address
 203         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 204
 205         add     r1, sp, #S_OFF
 206 2:      mov     why, #0                         @ no longer a real syscall
 207         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 208         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 209         bcs     arm_syscall
 210         b       sys_ni_syscall                  @ not private func
 211
 212         /*
 213          * This is the really slow path.  We're going to be doing
 214          * context switches, and waiting for our parent to respond.
 215          */
 216 __sys_trace:
 217         add     r1, sp, #S_OFF
 218         mov     r0, #0                          @ trace entry [IP = 0]
 219         bl      syscall_trace
 220
 221         adr     lr, __sys_trace_return          @ return address
 222         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 223         cmp     scno, #NR_syscalls              @ check upper syscall limit
 224         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 225         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 226         b       2b
 227
 228 __sys_trace_return:
 229         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 230         mov     r1, sp
 231         mov     r0, #1                          @ trace exit [IP = 1]
 232         bl      syscall_trace
 233         b       ret_slow_syscall
 234
 235         .align  5
 236 #ifdef CONFIG_ALIGNMENT_TRAP
 237         .type   __cr_alignment, #object
 238 __cr_alignment:
 239         .word   cr_alignment
 240 #endif
 241         .ltorg
 242
 243 /*
 244  * This is the syscall table declaration for native ABI syscalls.
 245  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 246  */
 247 #define ABI(native, compat) native
 248 #ifdef CONFIG_AEABI
 249 #define OBSOLETE(syscall) sys_ni_syscall
 250 #else
 251 #define OBSOLETE(syscall) syscall
 252 #endif
 253
 254         .type   sys_call_table, #object
 255 ENTRY(sys_call_table)
 256 #include "calls.S"
 257 #undef ABI
 258 #undef OBSOLETE
 259
 260 /*============================================================================
 261  * Special system call wrappers
 262  */
 263 @ r0 = syscall number
 264 @ r8 = syscall table
 265                 .type   sys_syscall, #function
 266 sys_syscall:
 267                 eor     scno, r0, #__NR_OABI_SYSCALL_BASE
 268                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 269                 cmpne   scno, #NR_syscalls      @ check range
 270                 stmloia sp, {r5, r6}            @ shuffle args
 271                 movlo   r0, r1
 272                 movlo   r1, r2
 273                 movlo   r2, r3
 274                 movlo   r3, r4
 275                 ldrlo   pc, [tbl, scno, lsl #2]
 276                 b       sys_ni_syscall
 277
 278 sys_fork_wrapper:
 279                 add     r0, sp, #S_OFF
 280                 b       sys_fork
 281
 282 sys_vfork_wrapper:
 283                 add     r0, sp, #S_OFF
 284                 b       sys_vfork
 285
 286 sys_execve_wrapper:
 287                 add     r3, sp, #S_OFF
 288                 b       sys_execve
 289
 290 sys_clone_wrapper:
 291                 add     ip, sp, #S_OFF
 292                 str     ip, [sp, #4]
 293                 b       sys_clone
 294
 295 sys_sigsuspend_wrapper:
 296                 add     r3, sp, #S_OFF
 297                 b       sys_sigsuspend
 298
 299 sys_rt_sigsuspend_wrapper:
 300                 add     r2, sp, #S_OFF
 301                 b       sys_rt_sigsuspend
 302
 303 sys_sigreturn_wrapper:
 304                 add     r0, sp, #S_OFF
 305                 b       sys_sigreturn
 306
 307 sys_rt_sigreturn_wrapper:
 308                 add     r0, sp, #S_OFF
 309                 b       sys_rt_sigreturn
 310
 311 sys_sigaltstack_wrapper:
 312                 ldr     r2, [sp, #S_OFF + S_SP]
 313                 b       do_sigaltstack
 314
 315 sys_statfs64_wrapper:
 316                 teq     r1, #88
 317                 moveq   r1, #84
 318                 b       sys_statfs64
 319
 320 sys_fstatfs64_wrapper:
 321                 teq     r1, #88
 322                 moveq   r1, #84
 323                 b       sys_fstatfs64
 324
 325 /*
 326  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 327  * offset, we return EINVAL.
 328  */
 329 sys_mmap2:
 330 #if PAGE_SHIFT > 12
 331                 tst     r5, #PGOFF_MASK
 332                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 333                 streq   r5, [sp, #4]
 334                 beq     do_mmap2
 335                 mov     r0, #-EINVAL
 336                 RETINSTR(mov,pc, lr)
 337 #else
 338                 str     r5, [sp, #4]
 339                 b       do_mmap2
 340 #endif
 341
 342 #ifdef CONFIG_OABI_COMPAT
 343
 344 /*
 345  * These are syscalls with argument register differences
 346  */
 347
 348 sys_oabi_pread64:
 349                 stmia   sp, {r3, r4}
 350                 b       sys_pread64
 351
 352 sys_oabi_pwrite64:
 353                 stmia   sp, {r3, r4}
 354                 b       sys_pwrite64
 355
 356 sys_oabi_truncate64:
 357                 mov     r3, r2
 358                 mov     r2, r1
 359                 b       sys_truncate64
 360
 361 sys_oabi_ftruncate64:
 362                 mov     r3, r2
 363                 mov     r2, r1
 364                 b       sys_ftruncate64
 365
 366 sys_oabi_readahead:
 367                 str     r3, [sp]
 368                 mov     r3, r2
 369                 mov     r2, r1
 370                 b       sys_readahead
 371
 372 /*
 373  * Let's declare a second syscall table for old ABI binaries
 374  * using the compatibility syscall entries.
 375  */
 376 #define ABI(native, compat) compat
 377 #define OBSOLETE(syscall) syscall
 378
 379         .type   sys_oabi_call_table, #object
 380 ENTRY(sys_oabi_call_table)
 381 #include "calls.S"
 382 #undef ABI
 383 #undef OBSOLETE
 384
 385 #endif
 386