arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 #include <linux/config.h>
  11
  12 #include <asm/thread_info.h>
  13 #include <asm/ptrace.h>
  14 #include <asm/unistd.h>
  15
  16 #include "entry-header.S"
  17
  18
  19         .align  5
  20 /*
  21  * This is the fast syscall return path.  We do as little as
  22  * possible here, and this includes saving r0 back into the SVC
  23  * stack.
  24  */
  25 ret_fast_syscall:
  26         disable_irq                             @ disable interrupts
  27         ldr     r1, [tsk, #TI_FLAGS]
  28         tst     r1, #_TIF_WORK_MASK
  29         bne     fast_work_pending
  30
  31         @ fast_restore_user_regs
  32         ldr     r1, [sp, #S_OFF + S_PSR]        @ get calling cpsr
  33         ldr     lr, [sp, #S_OFF + S_PC]!        @ get pc
  34         msr     spsr_cxsf, r1                   @ save in spsr_svc
  35         ldmdb   sp, {r1 - lr}^                  @ get calling r1 - lr
  36         mov     r0, r0
  37         add     sp, sp, #S_FRAME_SIZE - S_PC
  38         movs    pc, lr                          @ return & move spsr_svc into cpsr
  39
  40 /*
  41  * Ok, we need to do extra processing, enter the slow path.
  42  */
  43 fast_work_pending:
  44         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  45 work_pending:
  46         tst     r1, #_TIF_NEED_RESCHED
  47         bne     work_resched
  48         tst     r1, #_TIF_NOTIFY_RESUME | _TIF_SIGPENDING
  49         beq     no_work_pending
  50         mov     r0, sp                          @ 'regs'
  51         mov     r2, why                         @ 'syscall'
  52         bl      do_notify_resume
  53         disable_irq                             @ disable interrupts
  54         b       no_work_pending
  55
  56 work_resched:
  57         bl      schedule
  58 /*
  59  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  60  */
  61 ENTRY(ret_to_user)
  62 ret_slow_syscall:
  63         disable_irq                             @ disable interrupts
  64         ldr     r1, [tsk, #TI_FLAGS]
  65         tst     r1, #_TIF_WORK_MASK
  66         bne     work_pending
  67 no_work_pending:
  68         @ slow_restore_user_regs
  69         ldr     r1, [sp, #S_PSR]                @ get calling cpsr
  70         ldr     lr, [sp, #S_PC]!                @ get pc
  71         msr     spsr_cxsf, r1                   @ save in spsr_svc
  72         ldmdb   sp, {r0 - lr}^                  @ get calling r1 - lr
  73         mov     r0, r0
  74         add     sp, sp, #S_FRAME_SIZE - S_PC
  75         movs    pc, lr                          @ return & move spsr_svc into cpsr
  76
  77 /*
  78  * This is how we return from a fork.
  79  */
  80 ENTRY(ret_from_fork)
  81         bl      schedule_tail
  82         get_thread_info tsk
  83         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  84         mov     why, #1
  85         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  86         beq     ret_slow_syscall
  87         mov     r1, sp
  88         mov     r0, #1                          @ trace exit [IP = 1]
  89         bl      syscall_trace
  90         b       ret_slow_syscall
  91
  92
  93 #include "calls.S"
  94
  95 /*=============================================================================
  96  * SWI handler
  97  *-----------------------------------------------------------------------------
  98  */
  99
 100         /* If we're optimising for StrongARM the resulting code won't
 101            run on an ARM7 and we can save a couple of instructions.
 102                                                                 --pb */
 103 #ifdef CONFIG_CPU_ARM710
 104         .macro  arm710_bug_check, instr, temp
 105         and     \temp, \instr, #0x0f000000      @ check for SWI
 106         teq     \temp, #0x0f000000
 107         bne     .Larm700bug
 108         .endm
 109
 110 .Larm700bug:
 111         ldr     r0, [sp, #S_PSR]                @ Get calling cpsr
 112         sub     lr, lr, #4
 113         str     lr, [r8]
 114         msr     spsr_cxsf, r0
 115         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 116         mov     r0, r0
 117         ldr     lr, [sp, #S_PC]                 @ Get PC
 118         add     sp, sp, #S_FRAME_SIZE
 119         movs    pc, lr
 120 #else
 121         .macro  arm710_bug_check, instr, temp
 122         .endm
 123 #endif
 124
 125         .align  5
 126 ENTRY(vector_swi)
 127         sub     sp, sp, #S_FRAME_SIZE
 128         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 129         add     r8, sp, #S_PC
 130         stmdb   r8, {sp, lr}^                   @ Calling sp, lr
 131         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 132         str     lr, [sp, #S_PC]                 @ Save calling PC
 133         str     r8, [sp, #S_PSR]                @ Save CPSR
 134         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 135         zero_fp
 136
 137         /*
 138          * Get the system call number.
 139          */
 140 #ifdef CONFIG_ARM_THUMB
 141         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 142         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 143         ldreq   scno, [lr, #-4]
 144 #else
 145         ldr     scno, [lr, #-4]                 @ get SWI instruction
 146 #endif
 147         arm710_bug_check scno, ip
 148
 149 #ifdef CONFIG_ALIGNMENT_TRAP
 150         ldr     ip, __cr_alignment
 151         ldr     ip, [ip]
 152         mcr     p15, 0, ip, c1, c0              @ update control register
 153 #endif
 154         enable_irq
 155
 156         str     r4, [sp, #-S_OFF]!              @ push fifth arg
 157
 158         get_thread_info tsk
 159         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
 160         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 161         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 162         adr     tbl, sys_call_table             @ load syscall table pointer
 163         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
 164         bne     __sys_trace
 165
 166         adr     lr, ret_fast_syscall            @ return address
 167         cmp     scno, #NR_syscalls              @ check upper syscall limit
 168         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 169
 170         add     r1, sp, #S_OFF
 171 2:      mov     why, #0                         @ no longer a real syscall
 172         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 173         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 174         bcs     arm_syscall
 175         b       sys_ni_syscall                  @ not private func
 176
 177         /*
 178          * This is the really slow path.  We're going to be doing
 179          * context switches, and waiting for our parent to respond.
 180          */
 181 __sys_trace:
 182         add     r1, sp, #S_OFF
 183         mov     r0, #0                          @ trace entry [IP = 0]
 184         bl      syscall_trace
 185
 186         adr     lr, __sys_trace_return          @ return address
 187         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 188         cmp     scno, #NR_syscalls              @ check upper syscall limit
 189         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 190         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 191         b       2b
 192
 193 __sys_trace_return:
 194         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 195         mov     r1, sp
 196         mov     r0, #1                          @ trace exit [IP = 1]
 197         bl      syscall_trace
 198         b       ret_slow_syscall
 199
 200         .align  5
 201 #ifdef CONFIG_ALIGNMENT_TRAP
 202         .type   __cr_alignment, #object
 203 __cr_alignment:
 204         .word   cr_alignment
 205 #endif
 206
 207         .type   sys_call_table, #object
 208 ENTRY(sys_call_table)
 209 #include "calls.S"
 210
 211 /*============================================================================
 212  * Special system call wrappers
 213  */
 214 @ r0 = syscall number
 215 @ r5 = syscall table
 216                 .type   sys_syscall, #function
 217 sys_syscall:
 218                 eor     scno, r0, #__NR_SYSCALL_BASE
 219                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 220                 cmpne   scno, #NR_syscalls      @ check range
 221                 stmloia sp, {r5, r6}            @ shuffle args
 222                 movlo   r0, r1
 223                 movlo   r1, r2
 224                 movlo   r2, r3
 225                 movlo   r3, r4
 226                 ldrlo   pc, [tbl, scno, lsl #2]
 227                 b       sys_ni_syscall
 228
 229 sys_fork_wrapper:
 230                 add     r0, sp, #S_OFF
 231                 b       sys_fork
 232
 233 sys_vfork_wrapper:
 234                 add     r0, sp, #S_OFF
 235                 b       sys_vfork
 236
 237 sys_execve_wrapper:
 238                 add     r3, sp, #S_OFF
 239                 b       sys_execve
 240
 241 sys_clone_wrapper:
 242                 add     ip, sp, #S_OFF
 243                 str     ip, [sp, #4]
 244                 b       sys_clone
 245
 246 sys_sigsuspend_wrapper:
 247                 add     r3, sp, #S_OFF
 248                 b       sys_sigsuspend
 249
 250 sys_rt_sigsuspend_wrapper:
 251                 add     r2, sp, #S_OFF
 252                 b       sys_rt_sigsuspend
 253
 254 sys_sigreturn_wrapper:
 255                 add     r0, sp, #S_OFF
 256                 b       sys_sigreturn
 257
 258 sys_rt_sigreturn_wrapper:
 259                 add     r0, sp, #S_OFF
 260                 b       sys_rt_sigreturn
 261
 262 sys_sigaltstack_wrapper:
 263                 ldr     r2, [sp, #S_OFF + S_SP]
 264                 b       do_sigaltstack
 265
 266 sys_futex_wrapper:
 267                 str     r5, [sp, #4]            @ push sixth arg
 268                 b       sys_futex
 269
 270 /*
 271  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 272  * offset, we return EINVAL.
 273  */
 274 sys_mmap2:
 275 #if PAGE_SHIFT > 12
 276                 tst     r5, #PGOFF_MASK
 277                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 278                 streq   r5, [sp, #4]
 279                 beq     do_mmap2
 280                 mov     r0, #-EINVAL
 281                 RETINSTR(mov,pc, lr)
 282 #else
 283                 str     r5, [sp, #4]
 284                 b       do_mmap2
 285 #endif