arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 PHDRS {
  17         text PT_LOAD FLAGS(5);  /* R_E */
  18         data PT_LOAD FLAGS(7);  /* RWE */
  19         user PT_LOAD FLAGS(7);  /* RWE */
  20         data.init PT_LOAD FLAGS(7);     /* RWE */
  21         note PT_NOTE FLAGS(4);  /* R__ */
  22 }
  23 SECTIONS
  24 {
  25   . = __START_KERNEL;
  26   phys_startup_64 = startup_64 - LOAD_OFFSET;
  27   _text = .;                    /* Text and read-only data */
  28   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  29         /* First the code that has to be first for bootstrapping */
  30         *(.bootstrap.text)
  31         /* Then all the functions that are "hot" in profiles, to group them
  32            onto the same hugetlb entry */
  33         #include "functionlist"
  34         /* Then the rest */
  35         *(.text)
  36         SCHED_TEXT
  37         LOCK_TEXT
  38         KPROBES_TEXT
  39         *(.fixup)
  40         *(.gnu.warning)
  41         } :text = 0x9090
  42                                 /* out-of-line lock text */
  43   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  44
  45   _etext = .;                   /* End of text section */
  46
  47   . = ALIGN(16);                /* Exception table */
  48   __start___ex_table = .;
  49   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  50   __stop___ex_table = .;
  51
  52   RODATA
  53
  54   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  55                                 /* Data */
  56   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  57         *(.data)
  58         CONSTRUCTORS
  59         } :data
  60
  61   _edata = .;                   /* End of data section */
  62
  63   . = ALIGN(PAGE_SIZE);
  64   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  65   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  66         *(.data.cacheline_aligned)
  67   }
  68   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  69   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  70         *(.data.read_mostly)
  71   }
  72
  73 #define VSYSCALL_ADDR (-10*1024*1024)
  74 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  75 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  76
  77 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  78 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  79
  80 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  81 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  82
  83   . = VSYSCALL_ADDR;
  84   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  85   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  86
  87   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  88   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  89   xtime_lock = VVIRT(.xtime_lock);
  90
  91   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
  92   vxtime = VVIRT(.vxtime);
  93
  94   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
  95   vgetcpu_mode = VVIRT(.vgetcpu_mode);
  96
  97   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
  98   sys_tz = VVIRT(.sys_tz);
  99
 100   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 101   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 102
 103   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 104   xtime = VVIRT(.xtime);
 105
 106   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 107   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 108   jiffies = VVIRT(.jiffies);
 109
 110   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 111   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 112   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 113
 114   . = VSYSCALL_VIRT_ADDR + 4096;
 115
 116 #undef VSYSCALL_ADDR
 117 #undef VSYSCALL_PHYS_ADDR
 118 #undef VSYSCALL_VIRT_ADDR
 119 #undef VLOAD_OFFSET
 120 #undef VLOAD
 121 #undef VVIRT_OFFSET
 122 #undef VVIRT
 123
 124   . = ALIGN(8192);              /* init_task */
 125   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 126         *(.data.init_task)
 127   }:data.init
 128
 129   . = ALIGN(4096);
 130   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 131         *(.data.page_aligned)
 132   }
 133
 134   /* might get freed after init */
 135   . = ALIGN(4096);
 136   __smp_alt_begin = .;
 137   __smp_alt_instructions = .;
 138   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 139         *(.smp_altinstructions)
 140   }
 141   __smp_alt_instructions_end = .;
 142   . = ALIGN(8);
 143   __smp_locks = .;
 144   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 145         *(.smp_locks)
 146   }
 147   __smp_locks_end = .;
 148   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 149         *(.smp_altinstr_replacement)
 150   }
 151   . = ALIGN(4096);
 152   __smp_alt_end = .;
 153
 154   . = ALIGN(4096);              /* Init code and data */
 155   __init_begin = .;
 156   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 157         _sinittext = .;
 158         *(.init.text)
 159         _einittext = .;
 160   }
 161   __initdata_begin = .;
 162   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 163   __initdata_end = .;
 164   . = ALIGN(16);
 165   __setup_start = .;
 166   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 167   __setup_end = .;
 168   __initcall_start = .;
 169   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 170         INITCALLS
 171   }
 172   __initcall_end = .;
 173   __con_initcall_start = .;
 174   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 175         *(.con_initcall.init)
 176   }
 177   __con_initcall_end = .;
 178   SECURITY_INIT
 179   . = ALIGN(8);
 180   __alt_instructions = .;
 181   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 182         *(.altinstructions)
 183   }
 184   __alt_instructions_end = .;
 185   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 186         *(.altinstr_replacement)
 187   }
 188   /* .exit.text is discard at runtime, not link time, to deal with references
 189      from .altinstructions and .eh_frame */
 190   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 191   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 192   . = ALIGN(4096);
 193   __initramfs_start = .;
 194   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 195   __initramfs_end = .;
 196     . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 197   __per_cpu_start = .;
 198   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 199   __per_cpu_end = .;
 200   . = ALIGN(4096);
 201   __init_end = .;
 202
 203   . = ALIGN(4096);
 204   __nosave_begin = .;
 205   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 206   . = ALIGN(4096);
 207   __nosave_end = .;
 208
 209   __bss_start = .;              /* BSS */
 210   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 211         *(.bss.page_aligned)
 212         *(.bss)
 213         }
 214   __bss_stop = .;
 215
 216   _end = . ;
 217
 218   /* Sections to be discarded */
 219   /DISCARD/ : {
 220         *(.exitcall.exit)
 221 #ifndef CONFIG_UNWIND_INFO
 222         *(.eh_frame)
 223 #endif
 224         }
 225
 226   STABS_DEBUG
 227
 228   DWARF_DEBUG
 229 }