arch/xtensa/kernel/vmlinux.lds.S

   1 /*
   2  * arch/xtensa/kernel/vmlinux.lds.S
   3  *
   4  * Xtensa linker script
   5  *
   6  * This file is subject to the terms and conditions of the GNU General Public
   7  * License.  See the file "COPYING" in the main directory of this archive
   8  * for more details.
   9  *
  10  * Copyright (C) 2001 - 2005 Tensilica Inc.
  11  *
  12  * Chris Zankel <chris@zankel.net>
  13  * Marc Gauthier <marc@tensilica.com, marc@alumni.uwaterloo.ca>
  14  * Joe Taylor <joe@tensilica.com, joetylr@yahoo.com>
  15  */
  16
  17 #include <asm-generic/vmlinux.lds.h>
  18
  19 #define _NOCLANGUAGE
  20 #include <xtensa/config/core.h>
  21 #include <xtensa/config/system.h>
  22 OUTPUT_ARCH(xtensa)
  23 ENTRY(_start)
  24
  25 #if XCHAL_MEMORY_ORDER == XTHAL_BIGENDIAN
  26 jiffies = jiffies_64 + 4;
  27 #else
  28 jiffies = jiffies_64;
  29 #endif
  30
  31 #define KERNELOFFSET 0x1000
  32
  33 /* Note: In the following macros, it would be nice to specify only the
  34    vector name and section kind and construct "sym" and "section" using
  35    CPP concatenation, but that does not work reliably.  Concatenating a
  36    string with "." produces an invalid token.  CPP will not print a
  37    warning because it thinks this is an assembly file, but it leaves
  38    them as multiple tokens and there may or may not be whitespace
  39    between them.  */
  40
  41 /* Macro for a relocation entry */
  42
  43 #define RELOCATE_ENTRY(sym, section)            \
  44         LONG(sym ## _start);                    \
  45         LONG(sym ## _end);                      \
  46         LONG(LOADADDR(section))
  47
  48 /* Macro to define a section for a vector.
  49  *
  50  * Use of the MIN function catches the types of errors illustrated in
  51  * the following example:
  52  *
  53  * Assume the section .DoubleExceptionVector.literal is completely
  54  * full.  Then a programmer adds code to .DoubleExceptionVector.text
  55  * that produces another literal.  The final literal position will
  56  * overlay onto the first word of the adjacent code section
  57  * .DoubleExceptionVector.text.  (In practice, the literals will
  58  * overwrite the code, and the first few instructions will be
  59  * garbage.)
  60  */
  61
  62 #define SECTION_VECTOR(sym, section, addr, max_prevsec_size, prevsec)       \
  63   section addr : AT((MIN(LOADADDR(prevsec) + max_prevsec_size,              \
  64                          LOADADDR(prevsec) + SIZEOF(prevsec)) + 3) & ~ 3)   \
  65   {                                                                         \
  66     . = ALIGN(4);                                                           \
  67     sym ## _start = ABSOLUTE(.);                                            \
  68     *(section)                                                              \
  69     sym ## _end = ABSOLUTE(.);                                              \
  70   }
  71
  72 /*
  73  *  Mapping of input sections to output sections when linking.
  74  */
  75
  76 SECTIONS
  77 {
  78   . = XCHAL_KSEG_CACHED_VADDR + KERNELOFFSET;
  79   /* .text section */
  80
  81   _text = .;
  82   _stext = .;
  83   _ftext = .;
  84
  85   .text :
  86   {
  87     /* The .head.text section must be the first section! */
  88     *(.head.text)
  89     *(.literal .text)
  90     *(.srom.text)
  91     VMLINUX_SYMBOL(__sched_text_start) = .;
  92     *(.sched.literal .sched.text)
  93     VMLINUX_SYMBOL(__sched_text_end) = .;
  94     VMLINUX_SYMBOL(__lock_text_start) = .;
  95     *(.spinlock.literal .spinlock.text)
  96     VMLINUX_SYMBOL(__lock_text_end) = .;
  97
  98   }
  99   _etext = .;
 100
 101   . = ALIGN(16);
 102
 103   RODATA
 104
 105   /*  Relocation table */
 106
 107   . = ALIGN(16);
 108   __boot_reloc_table_start = ABSOLUTE(.);
 109
 110   __relocate : {
 111
 112     RELOCATE_ENTRY(_WindowVectors_text,
 113                    .WindowVectors.text);
 114 #if 0
 115     RELOCATE_ENTRY(_KernelExceptionVector_literal,
 116                    .KernelExceptionVector.literal);
 117 #endif
 118     RELOCATE_ENTRY(_KernelExceptionVector_text,
 119                    .KernelExceptionVector.text);
 120 #if 0
 121     RELOCATE_ENTRY(_UserExceptionVector_literal,
 122                    .UserExceptionVector.literal);
 123 #endif
 124     RELOCATE_ENTRY(_UserExceptionVector_text,
 125                    .UserExceptionVector.text);
 126     RELOCATE_ENTRY(_DoubleExceptionVector_literal,
 127                    .DoubleExceptionVector.literal);
 128     RELOCATE_ENTRY(_DoubleExceptionVector_text,
 129                    .DoubleExceptionVector.text);
 130   }
 131   __boot_reloc_table_end = ABSOLUTE(.) ;
 132
 133   .fixup   : { *(.fixup) }
 134
 135   . = ALIGN(16);
 136
 137   __ex_table : {
 138     __start___ex_table = .;
 139     *(__ex_table)
 140     __stop___ex_table = .;
 141   }
 142
 143   /* Data section */
 144
 145   . = ALIGN(XCHAL_ICACHE_LINESIZE);
 146   _fdata = .;
 147   .data :
 148   {
 149     *(.data) CONSTRUCTORS
 150     . = ALIGN(XCHAL_ICACHE_LINESIZE);
 151     *(.data.cacheline_aligned)
 152   }
 153
 154   _edata = .;
 155
 156   /* The initial task */
 157   . = ALIGN(8192);
 158   .data.init_task : { *(.data.init_task) }
 159
 160   /* Initialization code and data: */
 161
 162   . = ALIGN(1<<XCHAL_MMU_MIN_PTE_PAGE_SIZE);
 163   __init_begin = .;
 164   .init.text : {
 165         _sinittext = .;
 166         *(.init.literal) *(.init.text)
 167         _einittext = .;
 168   }
 169
 170   .init.data :
 171   {
 172     *(.init.data)
 173     . = ALIGN(0x4);
 174     __tagtable_begin = .;
 175     *(.taglist)
 176     __tagtable_end = .;
 177   }
 178
 179   . = ALIGN(XCHAL_ICACHE_LINESIZE);
 180
 181   __setup_start = .;
 182   .init.setup : { *(.init.setup) }
 183   __setup_end = .;
 184
 185   __initcall_start = .;
 186   .initcall.init : {
 187         INITCALLS
 188   }
 189   __initcall_end = .;
 190
 191   __con_initcall_start = .;
 192   .con_initcall.init : { *(.con_initcall.init) }
 193   __con_initcall_end = .;
 194
 195   SECURITY_INIT
 196
 197   . = ALIGN(4);
 198
 199   __start___ftr_fixup = .;
 200   __ftr_fixup : { *(__ftr_fixup) }
 201   __stop___ftr_fixup = .;
 202
 203   . = ALIGN(32);
 204   __per_cpu_start = .;
 205   .data.percpu  : { *(.data.percpu) }
 206   __per_cpu_end = .;
 207
 208   . = ALIGN(4096);
 209   __initramfs_start =.;
 210   .init.ramfs : { *(.init.ramfs) }
 211   __initramfs_end = .;
 212
 213   /* We need this dummy segment here */
 214
 215   . = ALIGN(4);
 216   .dummy : { LONG(0) }
 217
 218   /* The vectors are relocated to the real position at startup time */
 219
 220   SECTION_VECTOR (_WindowVectors_text,
 221                   .WindowVectors.text,
 222                   XCHAL_WINDOW_VECTORS_VADDR, 4,
 223                   .dummy)
 224   SECTION_VECTOR (_DebugInterruptVector_literal,
 225                   .DebugInterruptVector.literal,
 226                   XCHAL_INTLEVEL_VECTOR_VADDR(XCHAL_DEBUGLEVEL) - 4,
 227                   SIZEOF(.WindowVectors.text),
 228                   .WindowVectors.text)
 229   SECTION_VECTOR (_DebugInterruptVector_text,
 230                   .DebugInterruptVector.text,
 231                   XCHAL_INTLEVEL_VECTOR_VADDR(XCHAL_DEBUGLEVEL),
 232                   4,
 233                   .DebugInterruptVector.literal)
 234   SECTION_VECTOR (_KernelExceptionVector_literal,
 235                   .KernelExceptionVector.literal,
 236                   XCHAL_KERNELEXC_VECTOR_VADDR - 4,
 237                   SIZEOF(.DebugInterruptVector.text),
 238                   .DebugInterruptVector.text)
 239   SECTION_VECTOR (_KernelExceptionVector_text,
 240                   .KernelExceptionVector.text,
 241                   XCHAL_KERNELEXC_VECTOR_VADDR,
 242                   4,
 243                   .KernelExceptionVector.literal)
 244   SECTION_VECTOR (_UserExceptionVector_literal,
 245                   .UserExceptionVector.literal,
 246                   XCHAL_USEREXC_VECTOR_VADDR - 4,
 247                   SIZEOF(.KernelExceptionVector.text),
 248                   .KernelExceptionVector.text)
 249   SECTION_VECTOR (_UserExceptionVector_text,
 250                   .UserExceptionVector.text,
 251                   XCHAL_USEREXC_VECTOR_VADDR,
 252                   4,
 253                   .UserExceptionVector.literal)
 254   SECTION_VECTOR (_DoubleExceptionVector_literal,
 255                   .DoubleExceptionVector.literal,
 256                   XCHAL_DOUBLEEXC_VECTOR_VADDR - 16,
 257                   SIZEOF(.UserExceptionVector.text),
 258                   .UserExceptionVector.text)
 259   SECTION_VECTOR (_DoubleExceptionVector_text,
 260                   .DoubleExceptionVector.text,
 261                   XCHAL_DOUBLEEXC_VECTOR_VADDR,
 262                   32,
 263                   .DoubleExceptionVector.literal)
 264
 265   . = (LOADADDR( .DoubleExceptionVector.text ) + SIZEOF( .DoubleExceptionVector.text ) + 3) & ~ 3;
 266   . = ALIGN(1<<XCHAL_MMU_MIN_PTE_PAGE_SIZE);
 267
 268   __init_end = .;
 269
 270   . = ALIGN(8192);
 271
 272   /* BSS section */
 273   _bss_start = .;
 274   .sbss : { *(.sbss) *(.scommon) }
 275   .bss : { *(COMMON) *(.bss) }
 276   _bss_end = .;
 277   _end = .;
 278
 279   /* only used by the boot loader  */
 280
 281   . = ALIGN(0x10);
 282   .bootstrap : { *(.bootstrap.literal .bootstrap.text .bootstrap.data) }
 283
 284   . = ALIGN(0x1000);
 285   __initrd_start = .;
 286   .initrd : { *(.initrd) }
 287   __initrd_end = .;
 288
 289   .ResetVector.text XCHAL_RESET_VECTOR_VADDR :
 290   {
 291     *(.ResetVector.text)
 292   }
 293
 294
 295   /* Sections to be discarded */
 296   /DISCARD/ :
 297   {
 298         *(.text.exit)
 299         *(.text.exit.literal)
 300         *(.data.exit)
 301         *(.exitcall.exit)
 302   }
 303
 304
 305   .debug  0 :  { *(.debug) }
 306   .line  0 :  { *(.line) }
 307   .debug_srcinfo  0 :  { *(.debug_srcinfo) }
 308   .debug_sfnames  0 :  { *(.debug_sfnames) }
 309   .debug_aranges  0 :  { *(.debug_aranges) }
 310   .debug_pubnames  0 :  { *(.debug_pubnames) }
 311   .debug_info  0 :  { *(.debug_info) }
 312   .debug_abbrev  0 :  { *(.debug_abbrev) }
 313   .debug_line  0 :  { *(.debug_line) }
 314   .debug_frame  0 :  { *(.debug_frame) }
 315   .debug_str  0 :  { *(.debug_str) }
 316   .debug_loc  0 :  { *(.debug_loc) }
 317   .debug_macinfo  0 :  { *(.debug_macinfo) }
 318   .debug_weaknames  0 :  { *(.debug_weaknames) }
 319   .debug_funcnames  0 :  { *(.debug_funcnames) }
 320   .debug_typenames  0 :  { *(.debug_typenames) }
 321   .debug_varnames  0 :  { *(.debug_varnames) }
 322
 323   .xt.insn 0 :
 324   {
 325     *(.xt.insn)
 326     *(.gnu.linkonce.x*)
 327   }
 328
 329   .xt.lit 0 :
 330   {
 331     *(.xt.lit)
 332     *(.gnu.linkonce.p*)
 333   }
 334 }