bin/BackupPC

   1 #!/bin/perl -T
   2 #============================================================= -*-perl-*-
   3 #
   4 # BackupPC: Main program for PC backups.
   5 #
   6 # DESCRIPTION
   7 #
   8 #   BackupPC reads the configuration and status information from
   9 #   $TopDir/conf.  It then runs and manages all the backup activity.
  10 #
  11 #   As specified by $Conf{WakeupSchedule}, BackupPC wakes up periodically
  12 #   to queue backups on all the PCs.  This is a four step process:
  13 #     1) For each host and DHCP address backup requests are queued on the
  14 #        background command queue.
  15 #     2) For each PC, BackupPC_dump is forked.  Several of these may
  16 #        be run in parallel, based on the configuration.
  17 #     3) For each complete, good, backup, BackupPC_link is forked.
  18 #        Only one of these tasks runs at a time.
  19 #     4) In the background BackupPC_trashClean is run to remove any expired
  20 #        backups.  Once each night, BackupPC_nightly is run to complete some
  21 #        additional administrative tasks (pool cleaning etc).
  22 #
  23 #   BackupPC also listens for connections on a unix domain socket and
  24 #   the tcp port $Conf{ServerPort}, which are used by various
  25 #   sub-programs and the CGI script BackupPC_Admin for status reporting
  26 #   and user-initiated backup or backup cancel requests.
  27 #
  28 # AUTHOR
  29 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  30 #
  31 # COPYRIGHT
  32 #   Copyright (C) 2001  Craig Barratt
  33 #
  34 #   This program is free software; you can redistribute it and/or modify
  35 #   it under the terms of the GNU General Public License as published by
  36 #   the Free Software Foundation; either version 2 of the License, or
  37 #   (at your option) any later version.
  38 #
  39 #   This program is distributed in the hope that it will be useful,
  40 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  41 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  42 #   GNU General Public License for more details.
  43 #
  44 #   You should have received a copy of the GNU General Public License
  45 #   along with this program; if not, write to the Free Software
  46 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  47 #
  48 #========================================================================
  49 #
  50 # Version 1.5.0, released 2 Aug 2002.
  51 #
  52 # See http://backuppc.sourceforge.net.
  53 #
  54 #========================================================================
  55
  56 use strict;
  57 use vars qw(%Status %Info $Hosts);
  58 use lib "__INSTALLDIR__/lib";
  59 use BackupPC::Lib;
  60 use BackupPC::FileZIO;
  61
  62 use File::Path;
  63 use Data::Dumper;
  64 use Getopt::Std;
  65 use Socket;
  66 use Carp;
  67 use Digest::MD5;
  68
  69 ###########################################################################
  70 # Handle command line options
  71 ###########################################################################
  72 my %opts;
  73 getopts("d", \%opts);
  74 if ( @ARGV != 0 ) {
  75     print("usage: $0 [-d]\n");
  76     exit(1);
  77 }
  78
  79 ###########################################################################
  80 # Initialize major data structures and variables
  81 ###########################################################################
  82
  83 #
  84 # Get an instance of BackupPC::Lib and get some shortcuts.
  85 #
  86 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
  87 my $TopDir = $bpc->TopDir();
  88 my $BinDir = $bpc->BinDir();
  89 my %Conf   = $bpc->Conf();
  90
  91 #
  92 # Verify we are running as the correct user
  93 #
  94 if ( $Conf{BackupPCUserVerify}
  95         && $> != (my $uid = (getpwnam($Conf{BackupPCUser}))[2]) ) {
  96     die "Wrong user: my userid is $>, instead of $uid ($Conf{BackupPCUser})\n";
  97 }
  98
  99 #
 100 # %Status maintain status information about each host.
 101 # It is a hash of hashes, whose first index is the host.
 102 #
 103 %Status     = ();
 104
 105 #
 106 # %Info is a hash giving general information about BackupPC status.
 107 #
 108 %Info       = ();
 109
 110 #
 111 # Read old status
 112 #
 113 if ( -f "$TopDir/log/status.pl" && !(my $ret = do "$TopDir/log/status.pl") ) {
 114    die "couldn't parse $TopDir/log/status.pl: $@" if $@;
 115    die "couldn't do $TopDir/log/status.pl: $!"    unless defined $ret;
 116    die "couldn't run $TopDir/log/status.pl";
 117 }
 118
 119 #
 120 # %Jobs maintains information about currently running jobs.
 121 # It is a hash of hashes, whose first index is the host.
 122 #
 123 my %Jobs       = ();
 124
 125 #
 126 # There are three command queues:
 127 #   - @UserQueue is a queue of user initiated backup requests.
 128 #   - @BgQueue is a queue of automatically scheduled backup requests.
 129 #   - @CmdQueue is a queue of administrative jobs, including tasks
 130 #     like BackupPC_link, BackupPC_trashClean, and BackupPC_nightly
 131 # Each queue is an array of hashes.  Each hash stores information
 132 # about the command request.
 133 #
 134 my @UserQueue  = ();
 135 my @CmdQueue   = ();
 136 my @BgQueue    = ();
 137
 138 #
 139 # To quickly lookup if a given host is on a given queue, we keep
 140 # a hash of flags for each queue type.
 141 #
 142 my(%CmdQueueOn, %UserQueueOn, %BgQueueOn);
 143
 144 #
 145 # One or more clients can connect to the server to get status information
 146 # or request/cancel backups etc.  The %Clients hash maintains information
 147 # about each of these socket connections.  The hash key is an incrementing
 148 # number stored in $ClientConnCnt.  Each entry is a hash that contains
 149 # various information about the client connection.
 150 #
 151 my %Clients    = ();
 152 my $ClientConnCnt;
 153
 154 #
 155 # Read file descriptor mask used by select().  Every file descriptor
 156 # on which we expect to read (or accept) has the corresponding bit
 157 # set.
 158 #
 159 my $FDread     = '';
 160
 161 #
 162 # Unix seconds when we next wakeup.  A value of zero forces the scheduler
 163 # to compute the next wakeup time.
 164 #
 165 my $NextWakeup = 0;
 166
 167 #
 168 # Name of signal saved by catch_signal
 169 #
 170 my $SigName = "";
 171
 172 #
 173 # Misc variables
 174 #
 175 my($RunNightlyWhenIdle, $FirstWakeup, $CmdJob, $ServerInetPort);
 176
 177 #
 178 # Complete the rest of the initialization
 179 #
 180 Main_Initialize();
 181
 182 ###########################################################################
 183 # Main loop
 184 ###########################################################################
 185 while ( 1 )
 186 {
 187     #
 188     # Check if we can/should run BackupPC_nightly
 189     #
 190     Main_TryToRun_nightly();
 191
 192     #
 193     # Check if we can run a new command from @CmdQueue.
 194     #
 195     Main_TryToRun_CmdQueue();
 196
 197     #
 198     # Check if we can run a new command from @UserQueue or @BgQueue.
 199     #
 200     Main_TryToRun_Bg_or_User_Queue();
 201
 202     #
 203     # Do a select() to wait for the next interesting thing to happen
 204     # (timeout, signal, someone sends a message, child dies etc).
 205     #
 206     my $fdRead = Main_Select();
 207
 208     #
 209     # Process a signal if we received one.
 210     #
 211     if ( $SigName ) {
 212         Main_Process_Signal();
 213         $fdRead = undef;
 214     }
 215
 216     #
 217     # Check if a timeout has occurred.
 218     #
 219     Main_Check_Timeout();
 220
 221     #
 222     # Check for, and process, any messages (output) from our jobs
 223     #
 224     Main_Check_Job_Messages($fdRead);
 225
 226     #
 227     # Check for, and process, any output from our clients.  Also checks
 228     # for new connections to our SERVER_UNIX and SERVER_INET sockets.
 229     #
 230     Main_Check_Client_Messages($fdRead);
 231 }
 232
 233 ############################################################################
 234 # Main_Initialize()
 235 #
 236 # Main initialization routine.  Called once at statup.
 237 ############################################################################
 238 sub Main_Initialize
 239 {
 240     umask($Conf{UmaskMode});
 241
 242     #
 243     # Check for another running process, check that PASSWD is set and
 244     # verify executables are configured correctly.
 245     #
 246     if ( $Info{pid} ne "" && kill(0, $Info{pid}) ) {
 247         print(STDERR $bpc->timeStamp,
 248                  "Another BackupPC is running (pid $Info{pid}); quitting...\n");
 249         exit(1);
 250     }
 251     foreach my $progName ( qw(SmbClientPath NmbLookupPath PingPath DfPath
 252                               SendmailPath) ) {
 253         next if ( !defined($Conf{$progName}) || -x $Conf{$progName} );
 254         print(STDERR $bpc->timeStamp,
 255                      "\$Conf{$progName} = '$Conf{$progName}' is not a"
 256                    . " valid executable program\n");
 257         exit(1);
 258     }
 259
 260     if ( $opts{d} ) {
 261         #
 262         # daemonize by forking
 263         #
 264         defined(my $pid = fork) or die "Can't fork: $!";
 265         exit if $pid;   # parent exits
 266     }
 267
 268     #
 269     # Open the LOG file and redirect STDOUT, STDERR etc
 270     #
 271     LogFileOpen();
 272
 273     #
 274     # Read the hosts file (force a read).
 275     #
 276     exit(1) if ( !HostsUpdate(1) );
 277
 278     #
 279     # Clean up %ENV for taint checking
 280     #
 281     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
 282     $ENV{PATH} = $Conf{MyPath};
 283
 284     #
 285     # Initialize server sockets
 286     #
 287     ServerSocketInit();
 288
 289     #
 290     # Catch various signals
 291     #
 292     foreach my $sig ( qw(INT BUS SEGV PIPE TERM ALRM HUP) ) {
 293         $SIG{$sig} = \&catch_signal;
 294     }
 295
 296     #
 297     # Report that we started, and update %Info.
 298     #
 299     print(LOG $bpc->timeStamp, "BackupPC started, pid $$\n");
 300     $Info{ConfigModTime} = $bpc->ConfigMTime();
 301     $Info{pid} = $$;
 302     $Info{startTime} = time;
 303     $Info{Version} = $bpc->{Version};
 304
 305     #
 306     # Update the status left over form the last time BackupPC ran.
 307     # Requeue any pending links.
 308     #
 309     foreach my $host ( sort(keys(%$Hosts)) ) {
 310         if ( $Status{$host}{state} eq "backup in progress" ) {
 311             #
 312             # should we restart it?  skip it for now.
 313             #
 314             $Status{$host}{state} = "idle";
 315         } elsif ( $Status{$host}{state} eq "link pending"
 316                 || $Status{$host}{state} eq "link running" ) {
 317             QueueLink($host);
 318         } else {
 319             $Status{$host}{state} = "idle";
 320         }
 321         $Status{$host}{activeJob} = 0;
 322     }
 323
 324     #
 325     # Write out our initial status and save our PID
 326     #
 327     StatusWrite();
 328     if ( open(PID, ">$TopDir/log/BackupPC.pid") ) {
 329         print(PID $$);
 330         close(PID);
 331     }
 332
 333     #
 334     # For unknown reasons there is a very infrequent error about not
 335     # being able to coerce GLOBs inside the XS Data::Dumper.  I've
 336     # only seen this on a particular platform and perl version.
 337     # For now the workaround appears to be use the perl version of
 338     # XS Data::Dumper.
 339     #
 340     $Data::Dumper::Useqq = 1;
 341 }
 342
 343 ############################################################################
 344 # Main_TryToRun_nightly()
 345 #
 346 # Checks to see if we can/should run BackupPC_nightly or
 347 # BackupPC_trashClean.  If so we push the appropriate command onto
 348 # @CmdQueue.
 349 ############################################################################
 350 sub Main_TryToRun_nightly
 351 {
 352     #
 353     # Check if we should run BackupPC_nightly or BackupPC_trashClean.
 354     # BackupPC_nightly is run when the current job queue is empty.
 355     # BackupPC_trashClean is run in the background always.
 356     #
 357     my $trashCleanRunning = defined($Jobs{$bpc->trashJob}) ? 1 : 0;
 358     if ( !$trashCleanRunning && !$CmdQueueOn{$bpc->trashJob} ) {
 359         #
 360         # This should only happen once at startup, but just in case this
 361         # code will re-start BackupPC_trashClean if it quits
 362         #
 363         unshift(@CmdQueue, {
 364                 host    => $bpc->trashJob,
 365                 user    => "BackupPC",
 366                 reqTime => time,
 367                 cmd     => "$BinDir/BackupPC_trashClean"
 368             });
 369         $CmdQueueOn{$bpc->trashJob} = 1;
 370     }
 371     if ( keys(%Jobs) == $trashCleanRunning && $RunNightlyWhenIdle == 1 ) {
 372         push(@CmdQueue, {
 373                 host    => $bpc->adminJob,
 374                 user    => "BackupPC",
 375                 reqTime => time,
 376                 cmd     => "$BinDir/BackupPC_nightly"
 377             });
 378         $CmdQueueOn{$bpc->adminJob} = 1;
 379         $RunNightlyWhenIdle = 2;
 380     }
 381 }
 382
 383 ############################################################################
 384 # Main_TryToRun_CmdQueue()
 385 #
 386 # Decide if we can run a new command from the @CmdQueue.
 387 # We only run one of these at a time.  The @CmdQueue is
 388 # used to run BackupPC_link (for the corresponding host),
 389 # BackupPC_trashClean, and BackupPC_nightly using a fake
 390 # host name of $bpc->adminJob.
 391 ############################################################################
 392 sub Main_TryToRun_CmdQueue
 393 {
 394     my($req, $host);
 395     if ( $CmdJob eq "" && @CmdQueue > 0 && $RunNightlyWhenIdle != 1 ) {
 396         local(*FH);
 397         $req = pop(@CmdQueue);
 398
 399         $host = $req->{host};
 400         if ( defined($Jobs{$host}) ) {
 401             print(LOG $bpc->timeStamp,
 402                        "Botch on admin job for $host: already in use!!\n");
 403             #
 404             # This could happen during normal opertion: a user could
 405             # request a backup while a BackupPC_link is queued from
 406             # a previous backup.  But it is unlikely.  Just put this
 407             # request back on the end of the queue.
 408             #
 409             unshift(@CmdQueue, $req);
 410             return;
 411         }
 412         $CmdQueueOn{$host} = 0;
 413         my $cmd  = $req->{cmd};
 414         my $pid = open(FH, "-|");
 415         if ( !defined($pid) ) {
 416             print(LOG $bpc->timeStamp,
 417                        "can't fork for $host, request by $req->{user}\n");
 418             close(FH);
 419             next;
 420         }
 421         if ( !$pid ) {
 422             setpgrp 0,0;
 423             exec($cmd);
 424             print(LOG $bpc->timeStamp, "can't exec $cmd for $host\n");
 425             exit(0);
 426         }
 427         $Jobs{$host}{pid}       = $pid;
 428         $Jobs{$host}{fh}        = *FH;
 429         $Jobs{$host}{fn}        = fileno(FH);
 430         vec($FDread, $Jobs{$host}{fn}, 1) = 1;
 431         $Jobs{$host}{startTime} = time;
 432         $Jobs{$host}{reqTime}   = $req->{reqTime};
 433         $Jobs{$host}{cmd}       = $cmd;
 434         $Jobs{$host}{type}      = $Status{$host}{type};
 435         $Status{$host}{state}   = "link running";
 436         $Status{$host}{activeJob} = 1;
 437         $Status{$host}{endTime} = time;
 438         $CmdJob = $host if ( $host ne $bpc->trashJob );
 439         $cmd =~ s/$BinDir\///g;
 440         print(LOG $bpc->timeStamp, "Running $cmd (pid=$pid)\n");
 441     }
 442 }
 443
 444 ############################################################################
 445 # Main_TryToRun_Bg_or_User_Queue()
 446 #
 447 # Decide if we can run any new backup requests from @BgQueue
 448 # or @UserQueue.  Several of these can be run at the same time
 449 # based on %Conf settings.  Jobs from @UserQueue take priority,
 450 # and at total of $Conf{MaxBackups} + $Conf{MaxUserBackups}
 451 # simultaneous jobs can run from @UserQueue.  After @UserQueue
 452 # is exhausted, up to $Conf{MaxBackups} simultaneous jobs can
 453 # run from @BgQueue.
 454 ############################################################################
 455 sub Main_TryToRun_Bg_or_User_Queue
 456 {
 457     my($req, $host);
 458     while ( $RunNightlyWhenIdle == 0 ) {
 459         local(*FH);
 460         my(@args, @deferUserQueue, @deferBgQueue, $progName, $type);
 461         my $nJobs = keys(%Jobs);
 462         #
 463         # CmdJob and trashClean don't count towards MaxBackups / MaxUserBackups
 464         #
 465         $nJobs-- if ( $CmdJob ne "" );
 466         $nJobs-- if ( defined($Jobs{$bpc->trashJob} ) );
 467         if ( $nJobs < $Conf{MaxBackups} + $Conf{MaxUserBackups}
 468                         && @UserQueue > 0 ) {
 469             $req = pop(@UserQueue);
 470             if ( defined($Jobs{$req->{host}}) ) {
 471                 push(@deferUserQueue, $req);
 472                 next;
 473             }
 474             push(@args, $req->{doFull} ? "-f" : "-i")
 475                             if ( !$req->{restore} );
 476             $UserQueueOn{$req->{host}} = 0;
 477         } elsif ( $nJobs < $Conf{MaxBackups}
 478                         && (@CmdQueue + $nJobs)
 479                                 <= $Conf{MaxBackups} + $Conf{MaxPendingCmds}
 480                         && @BgQueue > 0 ) {
 481             my $du;
 482             if ( time - $Info{DUlastValueTime} >= 60 ) {
 483                 #
 484                 # Update our notion of disk usage no more than
 485                 # once every minute
 486                 #
 487                 $du = $bpc->CheckFileSystemUsage($TopDir);
 488                 $Info{DUlastValue}     = $du;
 489                 $Info{DUlastValueTime} = time;
 490             } else {
 491                 #
 492                 # if we recently checked it then just use the old value
 493                 #
 494                 $du = $Info{DUlastValue};
 495             }
 496             if ( $Info{DUDailyMaxReset} ) {
 497                 $Info{DUDailyMaxStartTime} = time;
 498                 $Info{DUDailyMaxReset}     = 0;
 499                 $Info{DUDailyMax}          = 0;
 500             }
 501             if ( $du > $Info{DUDailyMax} ) {
 502                 $Info{DUDailyMax}     = $du;
 503                 $Info{DUDailyMaxTime} = time;
 504             }
 505             if ( $du > $Conf{DfMaxUsagePct} ) {
 506                 my $nSkip = @BgQueue + @deferBgQueue;
 507                 print(LOG $bpc->timeStamp,
 508                            "Disk too full ($du%%); skipping $nSkip hosts\n");
 509                 $Info{DUDailySkipHostCnt} += $nSkip;
 510                 @BgQueue = ();
 511                 @deferBgQueue = ();
 512                 %BgQueueOn = ();
 513                 next;
 514             }
 515             $req = pop(@BgQueue);
 516             if ( defined($Jobs{$req->{host}}) ) {
 517                 push(@deferBgQueue, $req);
 518                 next;
 519             }
 520             $BgQueueOn{$req->{host}} = 0;
 521         } else {
 522             while ( @deferBgQueue ) {
 523                 push(@BgQueue, pop(@deferBgQueue));
 524             }
 525             while ( @deferUserQueue ) {
 526                 push(@UserQueue, pop(@deferUserQueue));
 527             }
 528             last;
 529         }
 530         $host = $req->{host};
 531         my $user = $req->{user};
 532         if ( $req->{restore} ) {
 533             $progName = "BackupPC_restore";
 534             $type     = "restore";
 535             push(@args, $req->{hostIP}, $req->{host}, $req->{reqFileName});
 536         } else {
 537             $progName = "BackupPC_dump";
 538             $type     = "backup";
 539             push(@args, "-d") if ( $req->{dhcp} );
 540             push(@args, "-e") if ( $req->{dumpExpire} );
 541             push(@args, $host);
 542         }
 543         my $pid = open(FH, "-|");
 544         if ( !defined($pid) ) {
 545             print(LOG $bpc->timeStamp,
 546                    "can't fork to run $progName for $host, request by $user\n");
 547             close(FH);
 548             next;
 549         }
 550         if ( !$pid ) {
 551             setpgrp 0,0;
 552             exec("$BinDir/$progName", @args);
 553             print(LOG $bpc->timeStamp, "can't exec $progName for $host\n");
 554             exit(0);
 555         }
 556         $Jobs{$host}{pid}        = $pid;
 557         $Jobs{$host}{fh}         = *FH;
 558         $Jobs{$host}{fn}         = fileno(FH);
 559         $Jobs{$host}{dhcp}       = $req->{dhcp};
 560         vec($FDread, $Jobs{$host}{fn}, 1) = 1;
 561         $Jobs{$host}{startTime}  = time;
 562         $Jobs{$host}{reqTime}    = $req->{reqTime};
 563         $Jobs{$host}{cmd}        = "$progName " . join(" ", @args);
 564         $Jobs{$host}{user}       = $user;
 565         $Jobs{$host}{type}       = $type;
 566         if ( !$req->{dhcp} ) {
 567             $Status{$host}{state}     = "$type starting";
 568             $Status{$host}{activeJob} = 1;
 569             $Status{$host}{startTime} = time;
 570             $Status{$host}{endTime}   = "";
 571         }
 572     }
 573 }
 574
 575 ############################################################################
 576 # Main_Select()
 577 #
 578 # If necessary, figure out when to next wakeup based on $Conf{WakeupSchedule},
 579 # and then do a select() to wait for the next thing to happen
 580 # (timeout, signal, someone sends a message, child dies etc).
 581 ############################################################################
 582 sub Main_Select
 583 {
 584     if ( $NextWakeup <= 0 ) {
 585         #
 586         # Figure out when to next wakeup based on $Conf{WakeupSchedule}.
 587         #
 588         my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst)
 589                                                 = localtime(time);
 590         my($currHours) = $hour + $min / 60 + $sec / 3600;
 591         if ( $bpc->ConfigMTime() != $Info{ConfigModTime} ) {
 592             my($mesg) = $bpc->ConfigRead()
 593                         || "Re-read config file because mtime changed";
 594             print(LOG $bpc->timeStamp, "$mesg\n");
 595             %Conf = $bpc->Conf();
 596             $Info{ConfigModTime} = $bpc->ConfigMTime();
 597             umask($Conf{UmaskMode});
 598             ServerSocketInit();
 599         }
 600         my $delta = -1;
 601         foreach my $t ( @{$Conf{WakeupSchedule} || [0..23]} ) {
 602             next if ( $t < 0 || $t > 24 );
 603             my $tomorrow = $t + 24;
 604             if ( $delta < 0
 605                 || ($tomorrow - $currHours > 0
 606                                 && $delta > $tomorrow - $currHours) ) {
 607                 $delta = $tomorrow - $currHours;
 608                 $FirstWakeup = $t == $Conf{WakeupSchedule}[0];
 609             }
 610             if ( $delta < 0
 611                     || ($t - $currHours > 0 && $delta > $t - $currHours) ) {
 612                 $delta = $t - $currHours;
 613                 $FirstWakeup = $t == $Conf{WakeupSchedule}[0];
 614             }
 615         }
 616         $NextWakeup = time + $delta * 3600;
 617         $Info{nextWakeup} = $NextWakeup;
 618         print(LOG $bpc->timeStamp, "Next wakeup is ",
 619                   $bpc->timeStamp($NextWakeup, 1), "\n");
 620     }
 621     #
 622     # Call select(), waiting until either a signal, a timeout,
 623     # any output from our jobs, or any messages from clients
 624     # connected via tcp.
 625     # select() is where we (hopefully) spend most of our time blocked...
 626     #
 627     my $timeout = $NextWakeup - time;
 628     $timeout = 1 if ( $timeout <= 0 );
 629     my $ein = $FDread;
 630     select(my $rout = $FDread, undef, $ein, $timeout);
 631
 632     return $rout;
 633 }
 634
 635 ############################################################################
 636 # Main_Process_Signal()
 637 #
 638 # Signal handler.
 639 ############################################################################
 640 sub Main_Process_Signal
 641 {
 642     #
 643     # Process signals
 644     #
 645     if ( $SigName eq "HUP" ) {
 646         my($mesg) = $bpc->ConfigRead()
 647                     || "Re-read config file because of a SIG_HUP";
 648         print(LOG $bpc->timeStamp, "$mesg\n");
 649         $Info{ConfigModTime} = $bpc->ConfigMTime();
 650         %Conf = $bpc->Conf();
 651         umask($Conf{UmaskMode});
 652         ServerSocketInit();
 653         HostsUpdate(0);
 654         $NextWakeup = 0;
 655     } elsif ( $SigName ) {
 656         print(LOG $bpc->timeStamp, "Got signal $SigName... cleaning up\n");
 657         foreach my $host ( keys(%Jobs) ) {
 658             kill(2, $Jobs{$host}{pid});
 659         }
 660         StatusWrite();
 661         unlink("$TopDir/log/BackupPC.pid");
 662         exit(1);
 663     }
 664     $SigName = "";
 665 }
 666
 667 ############################################################################
 668 # Main_Check_Timeout()
 669 #
 670 # Check if a timeout has occured, and if so, queue all the PCs for backups.
 671 # Also does log file aging on the first timeout after midnight.
 672 ############################################################################
 673 sub Main_Check_Timeout
 674 {
 675     #
 676     # Process timeouts
 677     #
 678     return if ( time < $NextWakeup || $NextWakeup <= 0 );
 679     $NextWakeup = 0;
 680     if ( $FirstWakeup ) {
 681         #
 682         # This is the first wakeup after midnight.  Do log file aging
 683         # and various house keeping.
 684         #
 685         $FirstWakeup = 0;
 686         printf(LOG "%s24hr disk usage: %d%% max, %d%% recent,"
 687                    . " %d skipped hosts\n",
 688                    $bpc->timeStamp, $Info{DUDailyMax}, $Info{DUlastValue},
 689                    $Info{DUDailySkipHostCnt});
 690         $Info{DUDailyMaxReset}        = 1;
 691         $Info{DUDailyMaxPrev}         = $Info{DUDailyMax};
 692         $Info{DUDailySkipHostCntPrev} = $Info{DUDailySkipHostCnt};
 693         $Info{DUDailySkipHostCnt}     = 0;
 694         my $lastLog = $Conf{MaxOldLogFiles} - 1;
 695         if ( -f "$TopDir/log/LOG.$lastLog" ) {
 696             print(LOG $bpc->timeStamp,
 697                        "Removing $TopDir/log/LOG.$lastLog\n");
 698             unlink("$TopDir/log/LOG.$lastLog");
 699         }
 700         if ( -f "$TopDir/log/LOG.$lastLog.z" ) {
 701             print(LOG $bpc->timeStamp,
 702                        "Removing $TopDir/log/LOG.$lastLog.z\n");
 703             unlink("$TopDir/log/LOG.$lastLog.z");
 704         }
 705         print(LOG $bpc->timeStamp, "Aging LOG files, LOG -> LOG.0 -> "
 706                    . "LOG.1 -> ... -> LOG.$lastLog\n");
 707         close(LOG);
 708         for ( my $i = $lastLog - 1 ; $i >= 0 ; $i-- ) {
 709             my $j = $i + 1;
 710             rename("$TopDir/log/LOG.$i", "$TopDir/log/LOG.$j")
 711                             if ( -f "$TopDir/log/LOG.$i" );
 712             rename("$TopDir/log/LOG.$i.z", "$TopDir/log/LOG.$j.z")
 713                             if ( -f "$TopDir/log/LOG.$i.z" );
 714         }
 715         #
 716         # Compress the log file LOG -> LOG.0.z (if enabled).
 717         # Otherwise, just rename LOG -> LOG.0.
 718         #
 719         BackupPC::FileZIO->compressCopy("$TopDir/log/LOG",
 720                                         "$TopDir/log/LOG.0.z",
 721                                         "$TopDir/log/LOG.0",
 722                                         $Conf{CompressLevel}, 1);
 723         LogFileOpen();
 724         #
 725         # Remember to run nightly script after current jobs are done
 726         #
 727         $RunNightlyWhenIdle = 1;
 728     }
 729     #
 730     # Write out the current status and then queue all the PCs
 731     #
 732     HostsUpdate(0);
 733     StatusWrite();
 734     %BgQueueOn = ()   if ( @BgQueue == 0 );
 735     %UserQueueOn = () if ( @UserQueue == 0 );
 736     %CmdQueueOn = ()  if ( @CmdQueue == 0 );
 737     QueueAllPCs();
 738 }
 739
 740 ############################################################################
 741 # Main_Check_Job_Messages($fdRead)
 742 #
 743 # Check if select() says we have bytes waiting from any of our jobs.
 744 # Handle each of the messages when complete (newline terminated).
 745 ############################################################################
 746 sub Main_Check_Job_Messages
 747 {
 748     my($fdRead) = @_;
 749     foreach my $host ( keys(%Jobs) ) {
 750         next if ( !vec($fdRead, $Jobs{$host}{fn}, 1) );
 751         my $mesg;
 752         #
 753         # do a last check to make sure there is something to read so
 754         # we are absolutely sure we won't block.
 755         #
 756         vec(my $readMask, $Jobs{$host}{fn}, 1) = 1;
 757         if ( !select($readMask, undef, undef, 0.0) ) {
 758             print(LOG $bpc->timeStamp, "Botch in Main_Check_Job_Messages:"
 759                         . " nothing to read from $host.  Debug dump:\n");
 760             my($dump) = Data::Dumper->new(
 761                          [  \%Clients, \%Jobs, \$FDread, \$fdRead],
 762                          [qw(*Clients,  *Jobs   *FDread,  *fdRead)]);
 763             $dump->Indent(1);
 764             print(LOG $dump->Dump);
 765             next;
 766         }
 767         my $nbytes = sysread($Jobs{$host}{fh}, $mesg, 1024);
 768         $Jobs{$host}{mesg} .= $mesg if ( $nbytes > 0 );
 769         #
 770         # Process any complete lines of output from this jobs.
 771         # Any output to STDOUT or STDERR from the children is processed here.
 772         #
 773         while ( $Jobs{$host}{mesg} =~ /(.*?)[\n\r]+(.*)/s ) {
 774             $mesg = $1;
 775             $Jobs{$host}{mesg} = $2;
 776             if ( $Jobs{$host}{dhcp} ) {
 777                 if ( $mesg =~ /^DHCP (\S+) (\S+)/ ) {
 778                     my $newHost = $2;
 779                     if ( defined($Jobs{$newHost}) ) {
 780                         print(LOG $bpc->timeStamp,
 781                                 "Backup on $newHost is already running\n");
 782                         kill(2, $Jobs{$host}{pid});
 783                         $nbytes = 0;
 784                         last;
 785                     }
 786                     $Jobs{$host}{dhcpHostIP} = $host;
 787                     $Status{$newHost}{dhcpHostIP} = $host;
 788                     $Jobs{$newHost} = $Jobs{$host};
 789                     delete($Jobs{$host});
 790                     $host = $newHost;
 791                     $Status{$host}{state}      = "backup starting";
 792                     $Status{$host}{activeJob}  = 1;
 793                     $Status{$host}{startTime}  = $Jobs{$host}{startTime};
 794                     $Status{$host}{endTime}    = "";
 795                     $Jobs{$host}{dhcp}         = 0;
 796                 } else {
 797                     print(LOG $bpc->timeStamp, "dhcp $host: $mesg\n");
 798                 }
 799             } elsif ( $mesg =~ /^started (.*) dump, pid=(\d+), tarPid=(-?\d+)/ ) {
 800                 $Jobs{$host}{type}    = $1;
 801                 $Jobs{$host}{xferPid} = $2;
 802                 $Jobs{$host}{tarPid}  = $3;
 803                 print(LOG $bpc->timeStamp,
 804                           "Started $1 backup on $host"
 805                           . " (pid=$Jobs{$host}{pid}, xferPid=$2",
 806                           $Jobs{$host}{tarPid} > 0
 807                                 ? ", tarPid=$Jobs{$host}{tarPid}" : "",
 808                           $Jobs{$host}{dhcpHostIP}
 809                                 ? ", dhcp=$Jobs{$host}{dhcpHostIP}" : "",
 810                           ")\n");
 811                 $Status{$host}{state}     = "backup in progress";
 812                 $Status{$host}{reason}    = "";
 813                 $Status{$host}{type}      = $1;
 814                 $Status{$host}{startTime} = time;
 815                 $Status{$host}{deadCnt}   = 0;
 816                 $Status{$host}{aliveCnt}++;
 817                 $Status{$host}{dhcpCheckCnt}--
 818                                 if ( $Status{$host}{dhcpCheckCnt} > 0 );
 819             } elsif ( $mesg =~ /^started_restore (\S+) (\S+)/ ) {
 820                 $Jobs{$host}{type}    = "restore";
 821                 $Jobs{$host}{xferPid} = $1;
 822                 $Jobs{$host}{tarPid}  = $2;
 823                 print(LOG $bpc->timeStamp,
 824                           "Started restore on $host"
 825                           . " (pid=$Jobs{$host}{pid}, xferPid=$2",
 826                           $Jobs{$host}{tarPid} > 0
 827                                 ? ", tarPid=$Jobs{$host}{tarPid}" : "",
 828                           ")\n");
 829                 $Status{$host}{state}     = "restore in progress";
 830                 $Status{$host}{reason}    = "";
 831                 $Status{$host}{type}      = "restore";
 832                 $Status{$host}{startTime} = time;
 833                 $Status{$host}{deadCnt}   = 0;
 834                 $Status{$host}{aliveCnt}++;
 835             } elsif ( $mesg =~ /^(full|incr) backup complete/ ) {
 836                 print(LOG $bpc->timeStamp, "Finished $1 backup on $host\n");
 837                 $Status{$host}{reason}    = "backup done";
 838                 delete($Status{$host}{error});
 839                 delete($Status{$host}{errorTime});
 840                 $Status{$host}{endTime}   = time;
 841             } elsif ( $mesg =~ /^restore complete/ ) {
 842                 print(LOG $bpc->timeStamp, "Finished restore on $host\n");
 843                 $Status{$host}{reason}    = "restore done";
 844                 delete($Status{$host}{error});
 845                 delete($Status{$host}{errorTime});
 846                 $Status{$host}{endTime}   = time;
 847             } elsif ( $mesg =~ /^nothing to do/ ) {
 848                 $Status{$host}{state}     = "idle";
 849                 $Status{$host}{reason}    = "nothing to do";
 850                 $Status{$host}{startTime} = time;
 851                 $Status{$host}{dhcpCheckCnt}--
 852                                 if ( $Status{$host}{dhcpCheckCnt} > 0 );
 853             } elsif ( $mesg =~ /^no ping response/
 854                             || $mesg =~ /^ping too slow/ ) {
 855                 $Status{$host}{state}     = "idle";
 856                 if ( $Status{$host}{reason} ne "backup failed" ) {
 857                     $Status{$host}{reason}    = "no ping";
 858                     $Status{$host}{startTime} = time;
 859                 }
 860                 $Status{$host}{deadCnt}++;
 861                 if ( $Status{$host}{deadCnt} >= $Conf{BlackoutBadPingLimit} ) {
 862                     $Status{$host}{aliveCnt} = 0;
 863                 }
 864             } elsif ( $mesg =~ /^dump failed: (.*)/ ) {
 865                 $Status{$host}{state}     = "idle";
 866                 $Status{$host}{reason}    = "backup failed";
 867                 $Status{$host}{error}     = $1;
 868                 $Status{$host}{errorTime} = time;
 869                 $Status{$host}{endTime}   = time;
 870                 print(LOG $bpc->timeStamp, "backup failed on $host ($1)\n");
 871             } elsif ( $mesg =~ /^log\s+(.*)/ ) {
 872                 print(LOG $bpc->timeStamp, "$1\n");
 873             } elsif ( $mesg =~ /^BackupPC_stats = (.*)/ ) {
 874                 my @f = split(/,/, $1);
 875                 $Info{"$f[0]FileCnt"}       = $f[1];
 876                 $Info{"$f[0]DirCnt"}        = $f[2];
 877                 $Info{"$f[0]Kb"}            = $f[3];
 878                 $Info{"$f[0]Kb2"}           = $f[4];
 879                 $Info{"$f[0]KbRm"}          = $f[5];
 880                 $Info{"$f[0]FileCntRm"}     = $f[6];
 881                 $Info{"$f[0]FileCntRep"}    = $f[7];
 882                 $Info{"$f[0]FileRepMax"}    = $f[8];
 883                 $Info{"$f[0]FileCntRename"} = $f[9];
 884                 $Info{"$f[0]Time"}          = time;
 885                 printf(LOG "%s%s nightly clean removed %d files of"
 886                            . " size %.2fGB\n",
 887                              $bpc->timeStamp, ucfirst($f[0]),
 888                              $Info{"$f[0]FileCntRm"},
 889                              $Info{"$f[0]KbRm"} / (1000 * 1024));
 890                 printf(LOG "%s%s is %.2fGB, %d files (%d repeated, "
 891                            . "%d max chain), %d directories\n",
 892                              $bpc->timeStamp, ucfirst($f[0]),
 893                              $Info{"$f[0]Kb"} / (1000 * 1024),
 894                              $Info{"$f[0]FileCnt"}, $Info{"$f[0]FileCntRep"},
 895                              $Info{"$f[0]FileRepMax"}, $Info{"$f[0]DirCnt"});
 896             } elsif ( $mesg =~ /^BackupPC_nightly lock_off/ ) {
 897                 $RunNightlyWhenIdle = 0;
 898             } elsif ( $mesg =~ /^processState\s+(.+)/ ) {
 899                 $Jobs{$host}{processState} = $1;
 900             } elsif ( $mesg =~ /^link\s+(.+)/ ) {
 901                 my($h) = $1;
 902                 $Status{$h}{needLink} = 1;
 903             } else {
 904                 print(LOG $bpc->timeStamp, "$host: $mesg\n");
 905             }
 906         }
 907         #
 908         # shut down the client connection if we read EOF
 909         #
 910         if ( $nbytes <= 0 ) {
 911             close($Jobs{$host}{fh});
 912             vec($FDread, $Jobs{$host}{fn}, 1) = 0;
 913             if ( $CmdJob eq $host ) {
 914                 my $cmd = $Jobs{$host}{cmd};
 915                 $cmd =~ s/$BinDir\///g;
 916                 print(LOG $bpc->timeStamp, "Finished $host ($cmd)\n");
 917                 $Status{$host}{state}    = "idle";
 918                 $Status{$host}{endTime}  = time;
 919                 $CmdJob = "";
 920                 $RunNightlyWhenIdle = 0 if ( $cmd eq "BackupPC_nightly"
 921                                             && $RunNightlyWhenIdle );
 922             } else {
 923                 #
 924                 # Queue BackupPC_link to complete the backup
 925                 # processing for this host.
 926                 #
 927                 if ( defined($Status{$host})
 928                             && ($Status{$host}{reason} eq "backup done"
 929                                 || $Status{$host}{needLink}) ) {
 930                     QueueLink($host);
 931                 } elsif ( defined($Status{$host}) ) {
 932                     $Status{$host}{state} = "idle";
 933                 }
 934             }
 935             delete($Jobs{$host});
 936             $Status{$host}{activeJob} = 0 if ( defined($Status{$host}) );
 937         }
 938     }
 939     #
 940     # When we are idle (empty Jobs, CmdQueue, BgQueue, UserQueue) we
 941     # do a pass over %Status updating the deadCnt and aliveCnt for
 942     # DHCP hosts.  The reason we need to do this later is we can't
 943     # be sure whether a DHCP host is alive or dead until we have passed
 944     # over all the DHCP pool.
 945     #
 946     return if ( @CmdQueue || @BgQueue || @UserQueue || keys(%Jobs) > 1 );
 947     foreach my $host ( keys(%Status) ) {
 948         next if ( $Status{$host}{dhcpCheckCnt} <= 0 );
 949         $Status{$host}{deadCnt} += $Status{$host}{dhcpCheckCnt};
 950         $Status{$host}{dhcpCheckCnt} = 0;
 951         if ( $Status{$host}{deadCnt} >= $Conf{BlackoutBadPingLimit} ) {
 952             $Status{$host}{aliveCnt} = 0;
 953         }
 954     }
 955 }
 956
 957 ############################################################################
 958 # Main_Check_Client_Messages($fdRead)
 959 #
 960 # Check for, and process, any output from our clients.  Also checks
 961 # for new connections to our SERVER_UNIX and SERVER_INET sockets.
 962 ############################################################################
 963 sub Main_Check_Client_Messages
 964 {
 965     my($fdRead) = @_;
 966     foreach my $client ( keys(%Clients) ) {
 967         next if ( !vec($fdRead, $Clients{$client}{fn}, 1) );
 968         my($mesg, $host);
 969         #
 970         # do a last check to make sure there is something to read so
 971         # we are absolutely sure we won't block.
 972         #
 973         vec(my $readMask, $Clients{$client}{fn}, 1) = 1;
 974         if ( !select($readMask, undef, undef, 0.0) ) {
 975             print(LOG $bpc->timeStamp, "Botch in Main_Check_Client_Messages:"
 976                         . " nothing to read from $client.  Debug dump:\n");
 977             my($dump) = Data::Dumper->new(
 978                          [  \%Clients, \%Jobs, \$FDread, \$fdRead],
 979                          [qw(*Clients,  *Jobs   *FDread,  *fdRead)]);
 980             $dump->Indent(1);
 981             print(LOG $dump->Dump);
 982             next;
 983         }
 984         my $nbytes = sysread($Clients{$client}{fh}, $mesg, 1024);
 985         $Clients{$client}{mesg} .= $mesg if ( $nbytes > 0 );
 986         #
 987         # Process any complete lines received from this client.
 988         #
 989         while ( $Clients{$client}{mesg} =~ /(.*?)[\n\r]+(.*)/s ) {
 990             my($reply);
 991             my $cmd = $1;
 992             $Clients{$client}{mesg} = $2;
 993             #
 994             # Authenticate the message by checking the MD5 digest
 995             #
 996             my $md5 = Digest::MD5->new;
 997             if ( $cmd !~ /^(.{22}) (.*)/
 998                 || ($md5->add($Clients{$client}{seed}
 999                             . $Clients{$client}{mesgCnt}
1000                             . $Conf{ServerMesgSecret} . $2),
1001                      $md5->b64digest ne $1) ) {
1002                 print(LOG $bpc->timeStamp, "Corrupted message '$cmd' from"
1003                             . " client '$Clients{$client}{clientName}':"
1004                             . " shutting down client connection\n");
1005                 $nbytes = 0;
1006                 last;
1007             }
1008             $Clients{$client}{mesgCnt}++;
1009             $cmd = $2;
1010             if ( $cmd =~ /^stop (\S+)\s+(\S+)\s+(\S*)/ ) {
1011                 $host = $1;
1012                 my $user = $2;
1013                 my $backoff = $3;
1014                 if ( $CmdJob ne $host && defined($Status{$host})
1015                                       && defined($Jobs{$host}) ) {
1016                     print(LOG $bpc->timeStamp,
1017                                "Stopping current backup of $host,"
1018                              . " request by $user (backoff=$backoff)\n");
1019                     kill(2, $Jobs{$host}{pid});
1020                     vec($FDread, $Jobs{$host}{fn}, 1) = 0;
1021                     close($Jobs{$host}{fh});
1022                     delete($Jobs{$host});
1023                     $Status{$host}{state}     = "idle";
1024                     $Status{$host}{reason}    = "backup canceled by $user";
1025                     $Status{$host}{activeJob} = 0;
1026                     $Status{$host}{startTime} = time;
1027                     $reply = "ok: backup of $host cancelled";
1028                 } elsif ( $BgQueueOn{$host} || $UserQueueOn{$host} ) {
1029                     print(LOG $bpc->timeStamp,
1030                                "Stopping pending backup of $host,"
1031                              . " request by $user (backoff=$backoff)\n");
1032                     @BgQueue = grep($_->{host} ne $host, @BgQueue);
1033                     @UserQueue = grep($_->{host} ne $host, @UserQueue);
1034                     $BgQueueOn{$host} = $UserQueueOn{$host} = 0;
1035                     $reply = "ok: pending backup of $host cancelled";
1036                 } else {
1037                     print(LOG $bpc->timeStamp,
1038                                "Nothing to do for stop backup of $host,"
1039                              . " request by $user (backoff=$backoff)\n");
1040                     $reply = "ok: no backup was pending or running";
1041                 }
1042                 if ( defined($Status{$host}) && $backoff ne "" ) {
1043                     if ( $backoff > 0 ) {
1044                         $Status{$host}{backoffTime} = time + $backoff * 3600;
1045                     } else {
1046                         delete($Status{$host}{backoffTime});
1047                     }
1048                 }
1049             } elsif ( $cmd =~ /^backup all$/ ) {
1050                 QueueAllPCs();
1051             } elsif ( $cmd =~ /^backup (\S+)\s+(\S+)\s+(\S+)\s+(\S+)/ ) {
1052                 my $hostIP = $1;
1053                 $host = $2;
1054                 my $user = $3;
1055                 my $doFull = $4;
1056                 if ( !defined($Status{$host}) ) {
1057                     print(LOG $bpc->timeStamp,
1058                                "User $user requested backup of unknown host"
1059                              . " $host\n");
1060                     $reply = "error: unknown host $host";
1061                 } elsif ( defined($Jobs{$host})
1062                                 && $Jobs{$host}{type} ne "restore" ) {
1063                     print(LOG $bpc->timeStamp,
1064                                "User $user requested backup of $host,"
1065                              . " but one is currently running\n");
1066                     $reply = "error: backup of $host is already running";
1067                 } else {
1068                     print(LOG $bpc->timeStamp,
1069                                "User $user requested backup of $host"
1070                              . " ($hostIP)\n");
1071                     if ( $BgQueueOn{$hostIP} ) {
1072                         @BgQueue = grep($_->{host} ne $hostIP, @BgQueue);
1073                         $BgQueueOn{$hostIP} = 0;
1074                     }
1075                     if ( $UserQueueOn{$hostIP} ) {
1076                         @UserQueue = grep($_->{host} ne $hostIP, @UserQueue);
1077                         $UserQueueOn{$hostIP} = 0;
1078                     }
1079                     unshift(@UserQueue, {
1080                                 host    => $hostIP,
1081                                 user    => $user,
1082                                 reqTime => time,
1083                                 doFull  => $doFull,
1084                                 dhcp    => $hostIP eq $host ? 0 : 1,
1085                         });
1086                     $UserQueueOn{$hostIP} = 1;
1087                     $reply = "ok: requested backup of $host";
1088                 }
1089             } elsif ( $cmd =~ /^restore (\S+)\s+(\S+)\s+(\S+)\s+(\S+)/ ) {
1090                 my $hostIP = $1;
1091                 $host      = $2;
1092                 my $user   = $3;
1093                 my $reqFileName = $4;
1094                 if ( !defined($Status{$host}) ) {
1095                     print(LOG $bpc->timeStamp,
1096                                "User $user requested restore to unknown host"
1097                              . " $host");
1098                     $reply = "restore error: unknown host $host";
1099                 } else {
1100                     print(LOG $bpc->timeStamp,
1101                                "User $user requested restore to $host"
1102                              . " ($hostIP)\n");
1103                     unshift(@UserQueue, {
1104                                 host    => $host,
1105                                 hostIP  => $hostIP,
1106                                 reqFileName => $reqFileName,
1107                                 reqTime => time,
1108                                 dhcp    => 0,
1109                                 restore => 1,
1110                         });
1111                     $UserQueueOn{$host} = 1;
1112                     if ( defined($Jobs{$host}) ) {
1113                         $reply = "ok: requested restore of $host, but a"
1114                                . " job is currently running,"
1115                                . " so this request will start later";
1116                     } else {
1117                         $reply = "ok: requested restore of $host";
1118                     }
1119                 }
1120             } elsif ( $cmd =~ /^status\s*(.*)/ ) {
1121                 my($args) = $1;
1122                 my($dump, @values, @names);
1123                 foreach my $type ( split(/\s+/, $args) ) {
1124                     if ( $type =~ /^queues/ ) {
1125                         push(@values,  \@BgQueue, \@UserQueue, \@CmdQueue);
1126                         push(@names, qw(*BgQueue   *UserQueue   *CmdQueue));
1127                     } elsif ( $type =~ /^jobs/ ) {
1128                         push(@values,  \%Jobs);
1129                         push(@names, qw(*Jobs));
1130                     } elsif ( $type =~ /^queueLen/ ) {
1131                         push(@values,  {
1132                                 BgQueue   => scalar(@BgQueue),
1133                                 UserQueue => scalar(@UserQueue),
1134                                 CmdQueue  => scalar(@CmdQueue),
1135                             });
1136                         push(@names, qw(*QueueLen));
1137                     } elsif ( $type =~ /^info/ ) {
1138                         push(@values,  \%Info);
1139                         push(@names, qw(*Info));
1140                     } elsif ( $type =~ /^hosts/ ) {
1141                         push(@values,  \%Status);
1142                         push(@names, qw(*Status));
1143                     } elsif ( $type =~ /^host\((.*)\)/
1144                                         && defined($Status{$1}) ) {
1145                         push(@values,  {
1146                                 %{$Status{$1}},
1147                                 BgQueueOn => $BgQueueOn{$1},
1148                                 UserQueueOn => $UserQueueOn{$1},
1149                                 CmdQueueOn => $CmdQueueOn{$1},
1150                             });
1151                         push(@names, qw(*StatusHost));
1152                     } else {
1153                         print(LOG $bpc->timeStamp,
1154                                   "Unknown status request $type\n");
1155                     }
1156                 }
1157                 $dump = Data::Dumper->new(\@values, \@names);
1158                 $dump->Indent(0);
1159                 $reply = $dump->Dump;
1160             } elsif ( $cmd =~ /^link\s+(.+)/ ) {
1161                 my($host) = $1;
1162                 QueueLink($host);
1163             } elsif ( $cmd =~ /^log\s+(.*)/ ) {
1164                 print(LOG $bpc->timeStamp, "$1\n");
1165             } elsif ( $cmd =~ /^quit/ || $cmd =~ /^exit/ ) {
1166                 $nbytes = 0;
1167                 last;
1168             } else {
1169                 print(LOG $bpc->timeStamp, "Unknown command $cmd\n");
1170                 $reply = "error: bad command $cmd";
1171             }
1172             #
1173             # send a reply to the client, at a minimum "ok\n".
1174             #
1175             $reply = "ok" if ( $reply eq "" );
1176             $reply .= "\n";
1177             syswrite($Clients{$client}{fh}, $reply, length($reply));
1178         }
1179         #
1180         # Detect possible denial-of-service attack from sending a huge line
1181         # (ie: never terminated).  32K seems to be plenty big enough as
1182         # a limit.
1183         #
1184         if ( length($Clients{$client}{mesg}) > 32 * 1024 ) {
1185             print(LOG $bpc->timeStamp, "Line too long from client"
1186                         . " '$Clients{$client}{clientName}':"
1187                         . " shutting down client connection\n");
1188             $nbytes = 0;
1189         }
1190         #
1191         # Shut down the client connection if we read EOF
1192         #
1193         if ( $nbytes <= 0 ) {
1194             close($Clients{$client}{fh});
1195             vec($FDread, $Clients{$client}{fn}, 1) = 0;
1196             delete($Clients{$client});
1197         }
1198     }
1199     #
1200     # Accept any new connections on each of our listen sockets
1201     #
1202     if ( vec($fdRead, fileno(SERVER_UNIX), 1) ) {
1203         local(*CLIENT);
1204         my $paddr = accept(CLIENT, SERVER_UNIX);
1205         $ClientConnCnt++;
1206         $Clients{$ClientConnCnt}{clientName} = "unix socket";
1207         $Clients{$ClientConnCnt}{mesg} = "";
1208         $Clients{$ClientConnCnt}{fh}   = *CLIENT;
1209         $Clients{$ClientConnCnt}{fn}   = fileno(CLIENT);
1210         vec($FDread, $Clients{$ClientConnCnt}{fn}, 1) = 1;
1211         #
1212         # Generate and send unique seed for MD5 digests to avoid
1213         # replay attacks.  See BackupPC::Lib::ServerMesg().
1214         #
1215         my $seed = time . ",$ClientConnCnt,$$,0\n";
1216         $Clients{$ClientConnCnt}{seed}    = $seed;
1217         $Clients{$ClientConnCnt}{mesgCnt} = 0;
1218         syswrite($Clients{$ClientConnCnt}{fh}, $seed, length($seed));
1219     }
1220     if ( $ServerInetPort > 0 && vec($fdRead, fileno(SERVER_INET), 1) ) {
1221         local(*CLIENT);
1222         my $paddr = accept(CLIENT, SERVER_INET);
1223         my($port,$iaddr) = sockaddr_in($paddr);
1224         my $name = gethostbyaddr($iaddr, AF_INET);
1225         $ClientConnCnt++;
1226         $Clients{$ClientConnCnt}{mesg} = "";
1227         $Clients{$ClientConnCnt}{fh}   = *CLIENT;
1228         $Clients{$ClientConnCnt}{fn}   = fileno(CLIENT);
1229         $Clients{$ClientConnCnt}{clientName} = "$name:$port";
1230         vec($FDread, $Clients{$ClientConnCnt}{fn}, 1) = 1;
1231         #
1232         # Generate and send unique seed for MD5 digests to avoid
1233         # replay attacks.  See BackupPC::Lib::ServerMesg().
1234         #
1235         my $seed = time . ",$ClientConnCnt,$$,$port\n";
1236         $Clients{$ClientConnCnt}{seed}    = $seed;
1237         $Clients{$ClientConnCnt}{mesgCnt} = 0;
1238         syswrite($Clients{$ClientConnCnt}{fh}, $seed, length($seed));
1239     }
1240 }
1241
1242 ###########################################################################
1243 # Miscellaneous subroutines
1244 ###########################################################################
1245
1246 #
1247 # Write the current status to $TopDir/log/status.pl
1248 #
1249 sub StatusWrite
1250 {
1251     my($dump) = Data::Dumper->new(
1252              [  \%Info, \%Status],
1253              [qw(*Info   *Status)]);
1254     $dump->Indent(1);
1255     if ( open(STATUS, ">$TopDir/log/status.pl") ) {
1256         print(STATUS $dump->Dump);
1257         close(STATUS);
1258     }
1259 }
1260
1261 #
1262 # Queue all the hosts for backup.  This means queuing all the fixed
1263 # ip hosts and all the dhcp address ranges.  We also additionally
1264 # queue the dhcp hosts with a -e flag to check for expired dumps.
1265 #
1266 sub QueueAllPCs
1267 {
1268     foreach my $host ( sort(keys(%$Hosts)) ) {
1269         delete($Status{$host}{backoffTime})
1270                 if ( defined($Status{$host}{backoffTime})
1271                   && $Status{$host}{backoffTime} < time );
1272         next if ( defined($Jobs{$host})
1273                 || $BgQueueOn{$host}
1274                 || $UserQueueOn{$host}
1275                 || $CmdQueueOn{$host} );
1276         if ( $Hosts->{$host}{dhcp} ) {
1277             $Status{$host}{dhcpCheckCnt}++;
1278             if ( $RunNightlyWhenIdle ) {
1279                 #
1280                 # Once per night queue a check for DHCP hosts that just
1281                 # checks for expired dumps.  We need to do this to handle
1282                 # the case when a DHCP host has not been on the network for
1283                 # a long time, and some of the old dumps need to be expired.
1284                 # Normally expiry checks are done by BackupPC_dump only
1285                 # after the DHCP hosts has been detected on the network.
1286                 #
1287                 unshift(@BgQueue,
1288                     {host => $host, user => "BackupPC", reqTime => time,
1289                      dhcp => 0, dumpExpire => 1});
1290                 $BgQueueOn{$host} = 1;
1291             }
1292         } else {
1293             #
1294             # this is a fixed ip host: queue it
1295             #
1296             unshift(@BgQueue,
1297                 {host => $host, user => "BackupPC", reqTime => time,
1298                  dhcp => $Hosts->{$host}{dhcp}});
1299             $BgQueueOn{$host} = 1;
1300         }
1301     }
1302     foreach my $dhcp ( @{$Conf{DHCPAddressRanges}} ) {
1303         for ( my $i = $dhcp->{first} ; $i <= $dhcp->{last} ; $i++ ) {
1304             my $ipAddr = "$dhcp->{ipAddrBase}.$i";
1305             next if ( defined($Jobs{$ipAddr})
1306                     || $BgQueueOn{$ipAddr}
1307                     || $UserQueueOn{$ipAddr}
1308                     || $CmdQueueOn{$ipAddr} );
1309             #
1310             # this is a potential dhcp ip address (we don't know the
1311             # host name yet): queue it
1312             #
1313             unshift(@BgQueue,
1314                 {host => $ipAddr, user => "BackupPC", reqTime => time,
1315                  dhcp => 1});
1316             $BgQueueOn{$ipAddr} = 1;
1317         }
1318     }
1319 }
1320
1321 #
1322 # Queue a BackupPC_link for the given host
1323 #
1324 sub QueueLink
1325 {
1326     my($host) = @_;
1327
1328     return if ( $CmdQueueOn{$host} );
1329     $Status{$host}{state}    = "link pending";
1330     $Status{$host}{needLink} = 0;
1331     unshift(@CmdQueue, {
1332             host    => $host,
1333             user    => "BackupPC",
1334             reqTime => time,
1335             cmd     => "$BinDir/BackupPC_link $host"
1336         });
1337     $CmdQueueOn{$host} = 1;
1338 }
1339
1340 #
1341 # Read the hosts file, and update Status if any hosts have been
1342 # added or deleted.  We also track the mtime so the only need to
1343 # update the hosts file on changes.
1344 #
1345 # This function is called at startup, SIGHUP, and on each wakeup.
1346 # It returns 1 on success and undef on failure.
1347 #
1348 sub HostsUpdate
1349 {
1350     my($force) = @_;
1351     my $newHosts;
1352     #
1353     # Nothing to do if we already have the current hosts file
1354     #
1355     return 1 if ( !$force && defined($Hosts)
1356                           && $Info{HostsModTime} == $bpc->HostsMTime() );
1357     if ( !defined($newHosts = $bpc->HostInfoRead()) ) {
1358         print(LOG $bpc->timeStamp, "Can't read hosts file!\n");
1359         return;
1360     }
1361     print(LOG $bpc->timeStamp, "Reading hosts file\n");
1362     $Hosts = $newHosts;
1363     $Info{HostsModTime} = $bpc->HostsMTime();
1364     #
1365     # Now update %Status in case any hosts have been added or deleted
1366     #
1367     foreach my $host ( sort(keys(%$Hosts)) ) {
1368         next if ( defined($Status{$host}) );
1369         $Status{$host}{state} = "idle";
1370         print(LOG $bpc->timeStamp, "Added host $host to backup list\n");
1371     }
1372     foreach my $host ( sort(keys(%Status)) ) {
1373         next if ( $host eq $bpc->trashJob
1374                      || $host eq $bpc->adminJob
1375                      || defined($Hosts->{$host})
1376                      || defined($Jobs{$host})
1377                      || $BgQueueOn{$host}
1378                      || $UserQueueOn{$host}
1379                      || $CmdQueueOn{$host} );
1380         print(LOG $bpc->timeStamp, "Deleted host $host from backup list\n");
1381         delete($Status{$host});
1382     }
1383     return 1;
1384 }
1385
1386 #
1387 # Remember the signal name for later processing
1388 #
1389 sub catch_signal
1390 {
1391     if ( $SigName ) {
1392         $SigName = shift;
1393         foreach my $host ( keys(%Jobs) ) {
1394             kill(2, $Jobs{$host}{pid});
1395         }
1396         #
1397         # In case we are inside the exit handler, reopen the log file
1398         #
1399         close(LOG);
1400         LogFileOpen();
1401         print(LOG "Fatal error: unhandled signal $SigName\n");
1402         unlink("$TopDir/log/BackupPC.pid");
1403         confess("Got new signal $SigName... quitting\n");
1404     }
1405     $SigName = shift;
1406 }
1407
1408 #
1409 # Open the log file and point STDOUT and STDERR there too
1410 #
1411 sub LogFileOpen
1412 {
1413     mkpath("$TopDir/log", 0, 0777) if ( !-d "$TopDir/log" );
1414     open(LOG, ">>$TopDir/log/LOG")
1415             || die("Can't create LOG file $TopDir/log/LOG");
1416     close(STDOUT);
1417     close(STDERR);
1418     open(STDOUT, ">&LOG");
1419     open(STDERR, ">&LOG");
1420     select(LOG);    $| = 1;
1421     select(STDERR); $| = 1;
1422     select(STDOUT); $| = 1;
1423 }
1424
1425 #
1426 # Initialize the unix-domain and internet-domain sockets that
1427 # we listen to for client connections (from the CGI script and
1428 # some of the BackupPC sub-programs).
1429 #
1430 sub ServerSocketInit
1431 {
1432     if ( !defined(fileno(SERVER_UNIX)) ) {
1433         #
1434         # one-time only: initialize unix-domain socket
1435         #
1436         if ( !socket(SERVER_UNIX, PF_UNIX, SOCK_STREAM, 0) ) {
1437             print(LOG $bpc->timeStamp, "unix socket() failed: $!\n");
1438             exit(1);
1439         }
1440         my $sockFile = "$TopDir/log/BackupPC.sock";
1441         unlink($sockFile);
1442         if ( !bind(SERVER_UNIX, sockaddr_un($sockFile)) ) {
1443             print(LOG $bpc->timeStamp, "unix bind() failed: $!\n");
1444             exit(1);
1445         }
1446         if ( !listen(SERVER_UNIX, SOMAXCONN) ) {
1447             print(LOG $bpc->timeStamp, "unix listen() failed: $!\n");
1448             exit(1);
1449         }
1450         vec($FDread, fileno(SERVER_UNIX), 1) = 1;
1451     }
1452     return if ( $ServerInetPort == $Conf{ServerPort} );
1453     if ( $ServerInetPort > 0 ) {
1454         vec($FDread, fileno(SERVER_INET), 1) = 0;
1455         close(SERVER_INET);
1456         $ServerInetPort = -1;
1457     }
1458     if ( $Conf{ServerPort} > 0 ) {
1459         #
1460         # Setup a socket to listen on $Conf{ServerPort}
1461         #
1462         my $proto = getprotobyname('tcp');
1463         if ( !socket(SERVER_INET, PF_INET, SOCK_STREAM, $proto) ) {
1464             print(LOG $bpc->timeStamp, "inet socket() failed: $!\n");
1465             exit(1);
1466         }
1467         if ( !setsockopt(SERVER_INET, SOL_SOCKET, SO_REUSEADDR, pack("l",1)) ) {
1468             print(LOG $bpc->timeStamp, "setsockopt() failed: $!\n");
1469             exit(1);
1470         }
1471         if ( !bind(SERVER_INET, sockaddr_in($Conf{ServerPort}, INADDR_ANY)) ) {
1472             print(LOG $bpc->timeStamp, "inet bind() failed: $!\n");
1473             exit(1);
1474         }
1475         if ( !listen(SERVER_INET, SOMAXCONN) ) {
1476             print(LOG $bpc->timeStamp, "inet listen() failed: $!\n");
1477             exit(1);
1478         }
1479         vec($FDread, fileno(SERVER_INET), 1) = 1;
1480         $ServerInetPort = $Conf{ServerPort};
1481     }
1482 }