bin/BackupPC_tarIncCreate

   1 #!/usr/bin/perl -w
   2 #============================================================= -*-perl-*-
   3 #
   4 # BackupPC_tarIncCreate: create a tar archive of an existing incremental dump
   5 #
   6 #
   7 # DESCRIPTION
   8 #
   9 #   Usage: BackupPC_tarIncCreate [options]
  10 #
  11 #   Flags:
  12 #     Required options:
  13 #
  14 #       -h host         Host from which the tar archive is created.
  15 #       -n dumpNum      Dump number from which the tar archive is created.
  16 #                       A negative number means relative to the end (eg -1
  17 #                       means the most recent dump, -2 2nd most recent etc).
  18 #       -s shareName    Share name from which the tar archive is created.
  19 #
  20 #     Other options:
  21 #       -t              print summary totals
  22 #       -r pathRemove   path prefix that will be replaced with pathAdd
  23 #       -p pathAdd      new path prefix
  24 #       -b BLOCKS       BLOCKS x 512 bytes per record (default 20; same as tar)
  25 #       -w writeBufSz   write buffer size (default 1MB)
  26 #
  27 #     The -h, -n and -s options specify which dump is used to generate
  28 #     the tar archive.  The -r and -p options can be used to relocate
  29 #     the paths in the tar archive so extracted files can be placed
  30 #     in a location different from their original location.
  31 #
  32 # AUTHOR
  33 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  34 #   Ivan Klaric <iklaric@gmail.com>
  35 #   Dobrica Pavlinusic <dpavlin@rot13.org>
  36 #
  37 # COPYRIGHT
  38 #   Copyright (C) 2001-2003  Craig Barratt
  39 #
  40 #   This program is free software; you can redistribute it and/or modify
  41 #   it under the terms of the GNU General Public License as published by
  42 #   the Free Software Foundation; either version 2 of the License, or
  43 #   (at your option) any later version.
  44 #
  45 #   This program is distributed in the hope that it will be useful,
  46 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  47 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  48 #   GNU General Public License for more details.
  49 #
  50 #   You should have received a copy of the GNU General Public License
  51 #   along with this program; if not, write to the Free Software
  52 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  53 #
  54 #========================================================================
  55 #
  56 # Version 2.1.0, released 20 Jun 2004.
  57 #
  58 # See http://backuppc.sourceforge.net.
  59 #
  60 #========================================================================
  61
  62 use strict;
  63 no  utf8;
  64 use lib "__INSTALLDIR__/lib";
  65 use File::Path;
  66 use Getopt::Std;
  67 use DBI;
  68 use BackupPC::Lib;
  69 use BackupPC::Attrib qw(:all);
  70 use BackupPC::FileZIO;
  71 use BackupPC::View;
  72 use BackupPC::SearchLib;
  73 use Time::HiRes qw/time/;
  74 use POSIX qw/strftime/;
  75 use File::Which;
  76 use File::Path;
  77 use File::Slurp;
  78 use Data::Dumper;       ### FIXME
  79
  80 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
  81 my $TopDir = $bpc->TopDir();
  82 my $BinDir = $bpc->BinDir();
  83 my %Conf   = $bpc->Conf();
  84 %BackupPC::SearchLib::Conf = %Conf;
  85 my %opts;
  86 my $in_backup_increment;
  87
  88
  89 if ( !getopts("th:n:p:r:s:b:w:vd", \%opts) ) {
  90     print STDERR <<EOF;
  91 usage: $0 [options]
  92   Required options:
  93      -h host         host from which the tar archive is created
  94      -n dumpNum      dump number from which the tar archive is created
  95                      A negative number means relative to the end (eg -1
  96                      means the most recent dump, -2 2nd most recent etc).
  97      -s shareName    share name from which the tar archive is created
  98
  99   Other options:
 100      -t              print summary totals
 101      -r pathRemove   path prefix that will be replaced with pathAdd
 102      -p pathAdd      new path prefix
 103      -b BLOCKS       BLOCKS x 512 bytes per record (default 20; same as tar)
 104      -w writeBufSz   write buffer size (default 1048576 = 1MB)
 105      -v              verbose output
 106      -d              debug output
 107 EOF
 108     exit(1);
 109 }
 110
 111 if ( $opts{h} !~ /^([\w\.\s-]+)$/ ) {
 112     die "$0: bad host name '$opts{h}'\n";
 113 }
 114 my $Host = $opts{h};
 115
 116 if ( $opts{n} !~ /^(-?\d+)$/ ) {
 117     die "$0: bad dump number '$opts{n}'\n";
 118 }
 119 my $Num = $opts{n};
 120
 121 my $bin;
 122 foreach my $c (qw/gzip md5sum tee/) {
 123         $bin->{$c} = which($c) || die "$0 needs $c, install it\n";
 124 }
 125
 126 my @Backups = $bpc->BackupInfoRead($Host);
 127 my $FileCnt = 0;
 128 my $ByteCnt = 0;
 129 my $DirCnt = 0;
 130 my $SpecialCnt = 0;
 131 my $ErrorCnt = 0;
 132 my $current_tar_size = 0;
 133 my $total_increment_size = 0;
 134
 135 my $i;
 136 $Num = $Backups[@Backups + $Num]{num} if ( -@Backups <= $Num && $Num < 0 );
 137 for ( $i = 0 ; $i < @Backups ; $i++ ) {
 138     last if ( $Backups[$i]{num} == $Num );
 139 }
 140 if ( $i >= @Backups ) {
 141     die "$0: bad backup number $Num for host $Host\n";
 142 }
 143
 144 my $PathRemove = $1 if ( $opts{r} =~ /(.+)/ );
 145 my $PathAdd    = $1 if ( $opts{p} =~ /(.+)/ );
 146 if ( $opts{s} !~ /^([\w\s\.\/\$-]+)$/ && $opts{s} ne "*" ) {
 147     die "$0: bad share name '$opts{s}'\n";
 148 }
 149 our $ShareName = $opts{s};
 150 our $view = BackupPC::View->new($bpc, $Host, \@Backups);
 151
 152 # database
 153
 154 my $dsn = $Conf{SearchDSN};
 155 my $db_user = $Conf{SearchUser} || '';
 156
 157 my $dbh = DBI->connect($dsn, $db_user, "", { RaiseError => 1, AutoCommit => 0} );
 158
 159 my $sth_inc_size = $dbh->prepare(qq{
 160         update backups set
 161                 inc_size = ?,
 162                 parts = ?,
 163                 inc_deleted = false
 164         where id = ? });
 165 my $sth_backup_parts = $dbh->prepare(qq{
 166         insert into backup_parts (
 167                 backup_id,
 168                 part_nr,
 169                 tar_size,
 170                 size,
 171                 md5,
 172                 items
 173         ) values (?,?,?,?,?,?)
 174 });
 175
 176 #
 177 # This constant and the line of code below that uses it are borrowed
 178 # from Archive::Tar.  Thanks to Calle Dybedahl and Stephen Zander.
 179 # See www.cpan.org.
 180 #
 181 # Archive::Tar is Copyright 1997 Calle Dybedahl. All rights reserved.
 182 #                 Copyright 1998 Stephen Zander. All rights reserved.
 183 #
 184 my $tar_pack_header
 185     = 'a100 a8 a8 a8 a12 a12 A8 a1 a100 a6 a2 a32 a32 a8 a8 a155 x12';
 186 my $tar_header_length = 512;
 187
 188 my $BufSize    = $opts{w} || 1048576;     # 1MB or 2^20
 189 my $WriteBuf   = "";
 190 my $WriteBufSz = ($opts{b} || 20) * $tar_header_length;
 191
 192 my(%UidCache, %GidCache);
 193 my(%HardLinkExtraFiles, @HardLinks);
 194
 195 #
 196 # Write out all the requested files/directories
 197 #
 198
 199 my $max_file_size = $Conf{'MaxArchiveFileSize'} || die "problem with MaxArchiveFileSize parametar";
 200 $max_file_size *= 1024;
 201
 202 my $tar_dir = $Conf{InstallDir}.'/'.$Conf{GzipTempDir};
 203 die "problem with $tar_dir, check GzipTempDir in configuration\n" unless (-d $tar_dir && -w $tar_dir);
 204
 205 my $tar_file = BackupPC::SearchLib::getGzipName($Host, $ShareName, $Num) || die "can't getGzipName($Host, $ShareName, $Num)";
 206
 207 my $tar_path = $tar_dir . '/' . $tar_file . '.tmp';
 208 $tar_path =~ s#//#/#g;
 209
 210 my $sth = $dbh->prepare(qq{
 211         SELECT
 212                 backups.id
 213         FROM backups
 214                 JOIN shares on shares.id = shareid
 215                 JOIN hosts on hosts.id = shares.hostid
 216         WHERE hosts.name = ? and shares.name = ? and backups.num = ?
 217 });
 218 $sth->execute($Host, $ShareName, $Num);
 219 my ($backup_id) = $sth->fetchrow_array;
 220 $sth->finish;
 221
 222 print STDERR "backup_id: $backup_id working dir: $tar_dir, max uncompressed size $max_file_size bytes, tar $tar_file\n" if ($opts{d});
 223
 224
 225 my $fh;
 226 my $part = 0;
 227 my $no_files = 0;
 228 my $items_in_part = 0;
 229
 230 sub new_tar_part {
 231         my $arg = {@_};
 232
 233         if ($fh) {
 234                 return if ($current_tar_size == 0);
 235
 236                 print STDERR "# closing part $part\n" if ($opts{d});
 237
 238                 #
 239                 # Finish with two null 512 byte headers,
 240                 # and then round out a full block.
 241                 #
 242                 my $data = "\0" x ($tar_header_length * 2);
 243                 TarWrite($fh, \$data);
 244                 TarWrite($fh, undef);
 245
 246                 close($fh) || die "can't close archive part $part: $!";
 247
 248                 my $file = $tar_path . '/' . $part;
 249
 250                 my $md5 = read_file( $file . '.md5' ) || die "can't read md5sum file ${file}.md5";
 251                 $md5 =~ s/\s.*$//;
 252
 253                 my $size = (stat( $file . '.tar.gz' ))[7] || die "can't stat ${file}.tar.gz";
 254
 255                 $sth_backup_parts->execute(
 256                         $backup_id,
 257                         $part,
 258                         $current_tar_size,
 259                         $size,
 260                         $md5,
 261                         $items_in_part,
 262                 );
 263
 264                 $total_increment_size += int( ( $size + 1023 ) / 1024 ) * 1024;
 265
 266                 if ($arg->{close}) {
 267                         print STDERR "# close last part\n" if ($opts{d});
 268                         $sth_inc_size->execute(
 269                                 $total_increment_size,
 270                                 $part,
 271                                 $backup_id
 272                         );
 273                         return;
 274                 }
 275
 276         }
 277
 278         $part++;
 279
 280         # if this is first part, create directory
 281
 282         if ($part == 1) {
 283                 if (-d $tar_path) {
 284                         print STDERR "# deleting existing $tar_path\n" if ($opts{d});
 285                         rmtree($tar_path);
 286                 }
 287                 mkdir($tar_path) || die "can't create directory $tar_path: $!";
 288
 289                 sub abort_cleanup {
 290                         print STDERR "ABORTED: cleanup temp dir";
 291                         rmtree($tar_path);
 292                         $dbh->rollback;
 293                         exit 1;
 294                 }
 295
 296                 $SIG{'INT'}  = \&abort_cleanup;
 297                 $SIG{'QUIT'} = \&abort_cleanup;
 298                 $SIG{'__DIE__'} = \&abort_cleanup;
 299
 300         }
 301
 302         my $file = $tar_path . '/' . $part;
 303
 304         #
 305         # create comprex pipe which will pass output through gzip
 306         # for compression, create file on disk using tee
 307         # and pipe same output to md5sum to create checksum
 308         #
 309
 310         my $cmd = '| ' . $bin->{'gzip'}   . ' ' . $Conf{GzipLevel} .      ' ' .
 311                   '| ' . $bin->{'tee'}    . ' ' . $file . '.tar.gz' . ' ' .
 312                   '| ' . $bin->{'md5sum'} . ' - > ' . $file . '.md5';
 313
 314         print STDERR "## $cmd\n" if ($opts{d});
 315
 316         open($fh, $cmd) or die "can't open $cmd: $!";
 317         binmode($fh);
 318
 319         $current_tar_size = 0;
 320         $items_in_part = 0;
 321 }
 322
 323 new_tar_part();
 324
 325 if (seedCache($Host, $ShareName, $Num)) {
 326         archiveWrite($fh, '/');
 327         archiveWriteHardLinks($fh);
 328 } else {
 329         print STDERR "NOTE: no files found for $Host:$ShareName, increment $Num\n" if ($opts{v});
 330         $no_files = 1;
 331 }
 332
 333 new_tar_part( close => 1 );
 334
 335 # remove temporary files if there are no files
 336 if ($no_files) {
 337         rmtree($tar_path);
 338 } elsif ($part == 1) {
 339         warn "FIXME: if there is only one part move to parent directory and rename";
 340 }
 341
 342 #
 343 # print out totals if requested
 344 #
 345 if ( $opts{t} ) {
 346     print STDERR "Done: $FileCnt files, $ByteCnt bytes, $DirCnt dirs,",
 347                  " $SpecialCnt specials, $ErrorCnt errors\n";
 348 }
 349 if ( $ErrorCnt && !$FileCnt && !$DirCnt ) {
 350     #
 351     # Got errors, with no files or directories; exit with non-zero
 352     # status
 353     #
 354     die "got errors or no files\n";
 355 }
 356
 357 $sth_inc_size->finish;
 358 $sth_backup_parts->finish;
 359
 360 $dbh->commit || die "can't commit changes to database";
 361 $dbh->disconnect();
 362
 363 exit;
 364
 365 ###########################################################################
 366 # Subroutines
 367 ###########################################################################
 368
 369 sub archiveWrite
 370 {
 371     my($fh, $dir, $tarPathOverride) = @_;
 372
 373     if ( $dir =~ m{(^|/)\.\.(/|$)} ) {
 374         print(STDERR "$0: bad directory '$dir'\n");
 375         $ErrorCnt++;
 376         return;
 377     }
 378     $dir = "/" if ( $dir eq "." );
 379     #print(STDERR "calling find with $Num, $ShareName, $dir\n");
 380
 381     if ( $view->find($Num, $ShareName, $dir, 0, \&TarWriteFile,
 382                 $fh, $tarPathOverride) < 0 ) {
 383         print(STDERR "$0: bad share or directory '$ShareName/$dir'\n");
 384         $ErrorCnt++;
 385         return;
 386     }
 387 }
 388
 389 #
 390 # Write out any hardlinks (if any)
 391 #
 392 sub archiveWriteHardLinks
 393 {
 394     my $fh = @_;
 395     foreach my $hdr ( @HardLinks ) {
 396         $hdr->{size} = 0;
 397         if ( defined($PathRemove)
 398               && substr($hdr->{linkname}, 0, length($PathRemove)+1)
 399                         eq ".$PathRemove" ) {
 400             substr($hdr->{linkname}, 0, length($PathRemove)+1) = ".$PathAdd";
 401         }
 402         TarWriteFileInfo($fh, $hdr);
 403     }
 404     @HardLinks = ();
 405     %HardLinkExtraFiles = ();
 406 }
 407
 408 sub UidLookup
 409 {
 410     my($uid) = @_;
 411
 412     $UidCache{$uid} = (getpwuid($uid))[0] if ( !exists($UidCache{$uid}) );
 413     return $UidCache{$uid};
 414 }
 415
 416 sub GidLookup
 417 {
 418     my($gid) = @_;
 419
 420     $GidCache{$gid} = (getgrgid($gid))[0] if ( !exists($GidCache{$gid}) );
 421     return $GidCache{$gid};
 422 }
 423
 424 sub TarWrite
 425 {
 426     my($fh, $dataRef) = @_;
 427
 428
 429     if ( !defined($dataRef) ) {
 430         #
 431         # do flush by padding to a full $WriteBufSz
 432         #
 433         my $data = "\0" x ($WriteBufSz - length($WriteBuf));
 434         $dataRef = \$data;
 435     }
 436
 437     # poor man's tell :-)
 438     $current_tar_size += length($$dataRef);
 439
 440     if ( length($WriteBuf) + length($$dataRef) < $WriteBufSz ) {
 441         #
 442         # just buffer and return
 443         #
 444         $WriteBuf .= $$dataRef;
 445         return;
 446     }
 447     my $done = $WriteBufSz - length($WriteBuf);
 448     if ( syswrite($fh, $WriteBuf . substr($$dataRef, 0, $done))
 449                                 != $WriteBufSz ) {
 450         die "Unable to write to output file ($!)\n";
 451     }
 452     while ( $done + $WriteBufSz <= length($$dataRef) ) {
 453         if ( syswrite($fh, substr($$dataRef, $done, $WriteBufSz))
 454                             != $WriteBufSz ) {
 455             die "Unable to write to output file ($!)\n";
 456         }
 457         $done += $WriteBufSz;
 458     }
 459     $WriteBuf = substr($$dataRef, $done);
 460 }
 461
 462 sub TarWritePad
 463 {
 464     my($fh, $size) = @_;
 465
 466     if ( $size % $tar_header_length ) {
 467         my $data = "\0" x ($tar_header_length - ($size % $tar_header_length));
 468         TarWrite($fh, \$data);
 469     }
 470 }
 471
 472 sub TarWriteHeader
 473 {
 474     my($fh, $hdr) = @_;
 475
 476     $hdr->{uname} = UidLookup($hdr->{uid}) if ( !defined($hdr->{uname}) );
 477     $hdr->{gname} = GidLookup($hdr->{gid}) if ( !defined($hdr->{gname}) );
 478     my $devmajor = defined($hdr->{devmajor}) ? sprintf("%07o", $hdr->{devmajor})
 479                                              : "";
 480     my $devminor = defined($hdr->{devminor}) ? sprintf("%07o", $hdr->{devminor})
 481                                              : "";
 482     my $sizeStr;
 483     if ( $hdr->{size} >= 2 * 65536 * 65536 ) {
 484         #
 485         # GNU extension for files >= 8GB: send size in big-endian binary
 486         #
 487         $sizeStr = pack("c4 N N", 0x80, 0, 0, 0,
 488                                   $hdr->{size} / (65536 * 65536),
 489                                   $hdr->{size} % (65536 * 65536));
 490     } elsif ( $hdr->{size} >= 1 * 65536 * 65536 ) {
 491         #
 492         # sprintf octal only handles up to 2^32 - 1
 493         #
 494         $sizeStr = sprintf("%03o", $hdr->{size} / (1 << 24))
 495                  . sprintf("%08o", $hdr->{size} % (1 << 24));
 496     } else {
 497         $sizeStr = sprintf("%011o", $hdr->{size});
 498     }
 499     my $data = pack($tar_pack_header,
 500                      substr($hdr->{name}, 0, 99),
 501                      sprintf("%07o", $hdr->{mode}),
 502                      sprintf("%07o", $hdr->{uid}),
 503                      sprintf("%07o", $hdr->{gid}),
 504                      $sizeStr,
 505                      sprintf("%011o", $hdr->{mtime}),
 506                      "",        #checksum field - space padded by pack("A8")
 507                      $hdr->{type},
 508                      substr($hdr->{linkname}, 0, 99),
 509                      $hdr->{magic} || 'ustar ',
 510                      $hdr->{version} || ' ',
 511                      $hdr->{uname},
 512                      $hdr->{gname},
 513                      $devmajor,
 514                      $devminor,
 515                      ""         # prefix is empty
 516                  );
 517     substr($data, 148, 7) = sprintf("%06o\0", unpack("%16C*",$data));
 518     TarWrite($fh, \$data);
 519 }
 520
 521 sub TarWriteFileInfo
 522 {
 523     my($fh, $hdr) = @_;
 524
 525     #
 526     # Handle long link names (symbolic links)
 527     #
 528     if ( length($hdr->{linkname}) > 99 ) {
 529         my %h;
 530         my $data = $hdr->{linkname} . "\0";
 531         $h{name} = "././\@LongLink";
 532         $h{type} = "K";
 533         $h{size} = length($data);
 534         TarWriteHeader($fh, \%h);
 535         TarWrite($fh, \$data);
 536         TarWritePad($fh, length($data));
 537     }
 538     #
 539     # Handle long file names
 540     #
 541     if ( length($hdr->{name}) > 99 ) {
 542         my %h;
 543         my $data = $hdr->{name} . "\0";
 544         $h{name} = "././\@LongLink";
 545         $h{type} = "L";
 546         $h{size} = length($data);
 547         TarWriteHeader($fh, \%h);
 548         TarWrite($fh, \$data);
 549         TarWritePad($fh, length($data));
 550     }
 551     TarWriteHeader($fh, $hdr);
 552 }
 553
 554 #
 555 # seed cache of files in this increment
 556 #
 557 sub seedCache($$$) {
 558         my ($host, $share, $dumpNo) = @_;
 559
 560         print STDERR curr_time(), "getting files for $host:$share increment $dumpNo..." if ($opts{v});
 561         my $sql = q{
 562                 SELECT path,size
 563                 FROM files
 564                         JOIN shares on shares.id = shareid
 565                         JOIN hosts on hosts.id = shares.hostid
 566                 WHERE hosts.name = ? and shares.name = ? and backupnum = ?
 567         };
 568
 569         my $sth = $dbh->prepare($sql);
 570         $sth->execute($host, $share, $dumpNo);
 571         my $count = $sth->rows;
 572         print STDERR " found $count items\n" if ($opts{v});
 573         while (my $row = $sth->fetchrow_arrayref) {
 574 #print STDERR "+ ", $row->[0],"\n";
 575                 $in_backup_increment->{ $row->[0] } = $row->[1];
 576         }
 577
 578         $sth->finish();
 579
 580         return $count;
 581 }
 582
 583 #
 584 # calculate overhad for one file in tar
 585 #
 586 sub tar_overhead($) {
 587         my $name = shift || '';
 588
 589         # header, padding of file and two null blocks at end
 590         my $len = 4 * $tar_header_length;
 591
 592         # if filename is longer than 99 chars subtract blocks for
 593         # long filename
 594         if ( length($name) > 99 ) {
 595                 $len += int( ( length($name) + $tar_header_length ) / $tar_header_length ) * $tar_header_length;
 596         }
 597
 598         return $len;
 599 }
 600
 601 my $Attr;
 602 my $AttrDir;
 603
 604 sub TarWriteFile
 605 {
 606     my($hdr, $fh, $tarPathOverride) = @_;
 607
 608     my $tarPath = $hdr->{relPath};
 609     $tarPath = $tarPathOverride if ( defined($tarPathOverride) );
 610
 611     $tarPath =~ s{//+}{/}g;
 612
 613     #print STDERR "? $tarPath\n" if ($opts{d});
 614     my $size = $in_backup_increment->{$tarPath};
 615     return unless (defined($size));
 616
 617     # is this file too large to fit into MaxArchiveFileSize?
 618
 619     if ( ($current_tar_size + tar_overhead($tarPath) + $size) > $max_file_size ) {
 620         print STDERR "# tar file $current_tar_size + $tar_header_length + $size > $max_file_size, splitting\n" if ($opts{d});
 621         new_tar_part();
 622     }
 623
 624     #print STDERR "A $tarPath [$size] tell: $current_tar_size\n" if ($opts{d});
 625     $items_in_part++;
 626
 627     if ( defined($PathRemove)
 628             && substr($tarPath, 0, length($PathRemove)) eq $PathRemove ) {
 629         substr($tarPath, 0, length($PathRemove)) = $PathAdd;
 630     }
 631     $tarPath = "./" . $tarPath if ( $tarPath !~ /^\.\// );
 632     $tarPath =~ s{//+}{/}g;
 633     $hdr->{name} = $tarPath;
 634
 635     if ( $hdr->{type} == BPC_FTYPE_DIR ) {
 636         #
 637         # Directory: just write the header
 638         #
 639         $hdr->{name} .= "/" if ( $hdr->{name} !~ m{/$} );
 640         TarWriteFileInfo($fh, $hdr);
 641         $DirCnt++;
 642     } elsif ( $hdr->{type} == BPC_FTYPE_FILE ) {
 643         #
 644         # Regular file: write the header and file
 645         #
 646         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
 647         if ( !defined($f) ) {
 648             print(STDERR "Unable to open file $hdr->{fullPath}\n");
 649             $ErrorCnt++;
 650             return;
 651         }
 652         # do we need to split file?
 653         if ($hdr->{size} < $max_file_size) {
 654                 TarWriteFileInfo($fh, $hdr);
 655                 my($data, $size);
 656                 while ( $f->read(\$data, $BufSize) > 0 ) {
 657                     TarWrite($fh, \$data);
 658                     $size += length($data);
 659                 }
 660                 $f->close;
 661                 TarWritePad($fh, $size);
 662                 $FileCnt++;
 663                 $ByteCnt += $size;
 664         } else {
 665                 my $full_size = $hdr->{size};
 666                 my $orig_name = $hdr->{name};
 667                 my $max_part_size = $max_file_size - tar_overhead($hdr->{name});
 668
 669                 my $parts = int(($full_size + $max_part_size - 1) / $max_part_size);
 670                 print STDERR "# splitting $orig_name [$full_size bytes] into $parts parts\n" if ($opts{d});
 671                 foreach my $subpart ( 1 .. $parts ) {
 672                         new_tar_part();
 673                         if ($subpart < $parts) {
 674                                 $hdr->{size} = $max_part_size;
 675                         } else {
 676                                 $hdr->{size} = $full_size % $max_part_size;
 677                         }
 678                         $hdr->{name} = $orig_name . '/' . $subpart;
 679                         print STDERR "## creating part $subpart ",$hdr->{name}, " [", $hdr->{size}," bytes]\n";
 680
 681                         TarWriteFileInfo($fh, $hdr);
 682                         my($data, $size);
 683 if (0) {
 684                         for ( 1 .. int($hdr->{size} / $BufSize) ) {
 685                                 my $r_size = $f->read(\$data, $BufSize);
 686                                 die "expected $BufSize bytes read, got $r_size bytes!" if ($r_size != $BufSize);
 687                                 TarWrite($fh, \$data);
 688                                 $size += length($data);
 689                         }
 690 }
 691                         my $size_left = $hdr->{size} % $BufSize;
 692                         my $r_size = $f->read(\$data, $size_left);
 693                         die "expected $size_left bytes last read, got $r_size bytes!" if ($r_size != $size_left);
 694
 695                         TarWrite($fh, \$data);
 696                         $size += length($data);
 697                         TarWritePad($fh, $size);
 698
 699                         $items_in_part++;
 700                 }
 701                 $f->close;
 702                 $FileCnt++;
 703                 $ByteCnt += $full_size;
 704                 new_tar_part();
 705         }
 706     } elsif ( $hdr->{type} == BPC_FTYPE_HARDLINK ) {
 707         #
 708         # Hardlink file: either write a hardlink or the complete file
 709         # depending upon whether the linked-to file will be written
 710         # to the archive.
 711         #
 712         # Start by reading the contents of the link.
 713         #
 714         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
 715         if ( !defined($f) ) {
 716             print(STDERR "Unable to open file $hdr->{fullPath}\n");
 717             $ErrorCnt++;
 718             return;
 719         }
 720         my $data;
 721         while ( $f->read(\$data, $BufSize) > 0 ) {
 722             $hdr->{linkname} .= $data;
 723         }
 724         $f->close;
 725         my $done = 0;
 726         my $name = $hdr->{linkname};
 727         $name =~ s{^\./}{/};
 728         if ( $HardLinkExtraFiles{$name} ) {
 729             #
 730             # Target file will be or was written, so just remember
 731             # the hardlink so we can dump it later.
 732             #
 733             push(@HardLinks, $hdr);
 734             $SpecialCnt++;
 735         } else {
 736             #
 737             # Have to dump the original file.  Just call the top-level
 738             # routine, so that we save the hassle of dealing with
 739             # mangling, merging and attributes.
 740             #
 741             $HardLinkExtraFiles{$hdr->{linkname}} = 1;
 742             archiveWrite($fh, $hdr->{linkname}, $hdr->{name});
 743         }
 744     } elsif ( $hdr->{type} == BPC_FTYPE_SYMLINK ) {
 745         #
 746         # Symbolic link: read the symbolic link contents into the header
 747         # and write the header.
 748         #
 749         my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0, $hdr->{compress});
 750         if ( !defined($f) ) {
 751             print(STDERR "Unable to open symlink file $hdr->{fullPath}\n");
 752             $ErrorCnt++;
 753             return;
 754         }
 755         my $data;
 756         while ( $f->read(\$data, $BufSize) > 0 ) {
 757             $hdr->{linkname} .= $data;
 758         }
 759         $f->close;
 760         $hdr->{size} = 0;
 761         TarWriteFileInfo($fh, $hdr);
 762         $SpecialCnt++;
 763     } elsif ( $hdr->{type} == BPC_FTYPE_CHARDEV
 764            || $hdr->{type} == BPC_FTYPE_BLOCKDEV
 765            || $hdr->{type} == BPC_FTYPE_FIFO ) {
 766         #
 767         # Special files: for char and block special we read the
 768         # major and minor numbers from a plain file.
 769         #
 770         if ( $hdr->{type} != BPC_FTYPE_FIFO ) {
 771             my $f = BackupPC::FileZIO->open($hdr->{fullPath}, 0,
 772                                                 $hdr->{compress});
 773             my $data;
 774             if ( !defined($f) || $f->read(\$data, $BufSize) < 0 ) {
 775                 print(STDERR "Unable to open/read char/block special file"
 776                            . " $hdr->{fullPath}\n");
 777                 $f->close if ( defined($f) );
 778                 $ErrorCnt++;
 779                 return;
 780             }
 781             $f->close;
 782             if ( $data =~ /(\d+),(\d+)/ ) {
 783                 $hdr->{devmajor} = $1;
 784                 $hdr->{devminor} = $2;
 785             }
 786         }
 787         $hdr->{size} = 0;
 788         TarWriteFileInfo($fh, $hdr);
 789         $SpecialCnt++;
 790     } else {
 791         print(STDERR "Got unknown type $hdr->{type} for $hdr->{name}\n");
 792         $ErrorCnt++;
 793     }
 794 }
 795
 796 my $t_fmt = '%Y-%m-%d %H:%M:%S';
 797 sub curr_time {
 798         return strftime($t_fmt,localtime());
 799 }