catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # $Header$
   6 #
   7 # Copyright 2006 LibLime
   8 #
   9 # This file is part of Koha
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along with
  21 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  22 # Suite 330, Boston, MA  02111-1307 USA
  23
  24 =head1 NAME
  25
  26 search - a search script for finding records in a Koha system (Version 3)
  27
  28 =head1 OVERVIEW
  29
  30 This script utilizes a new search API for Koha 3. It is designed to be
  31 simple to use and configure, yet capable of performing feats like stemming,
  32 field weighting, relevance ranking, support for multiple  query language
  33 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  34 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  35 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  36
  37 The API as represented in this script is mostly sound, even if the individual
  38 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  39 free to disagree :-)
  40
  41 I will attempt to describe what is happening at each part of this script.
  42 -- Joshua Ferraro <jmf AT liblime DOT com>
  43
  44 =head2 INTRO
  45
  46 This script performs two functions:
  47
  48 =over
  49
  50 =item 1. interacts with Koha to retrieve and display the results of a search
  51
  52 =item 2. loads the advanced search page
  53
  54 =back
  55
  56 These two functions share many of the same variables and modules, so the first
  57 task is to load what they have in common and determine which template to use.
  58 Once determined, proceed to only load the variables and procedures necessary
  59 for that function.
  60
  61 =head2 LOADING ADVANCED SEARCH PAGE
  62
  63 This is fairly straightforward, and I won't go into detail ;-)
  64
  65 =head2 PERFORMING A SEARCH
  66
  67 If we're performing a search, this script  performs three primary
  68 operations:
  69
  70 =over
  71
  72 =item 1. builds query strings (yes, plural)
  73
  74 =item 2. perform the search and return the results array
  75
  76 =item 3. build the HTML for output to the template
  77
  78 =back
  79
  80 There are several additional secondary functions performed that I will
  81 not cover in detail.
  82
  83 =head3 1. Building Query Strings
  84
  85 There are several types of queries needed in the process of search and retrieve:
  86
  87 =over
  88
  89 =item 1 $query - the fully-built query passed to zebra
  90
  91 This is the most complex query that needs to be built. The original design goal
  92 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  93 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  94 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  95 I'll try to flesh out this section to better explain.
  96
  97 This query incorporates query profiles that aren't compatible with most non-Zebra
  98 Z39.50 targets to acomplish the field weighting and relevance ranking.
  99
 100 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 101 stemming, etc., suitable to pass off to other search targets
 102
 103 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 104 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 105
 106 =item 3 $query_cgi - passed to the template / saved for future refinements of
 107 the query (by user)
 108
 109 This is a simple string that completely expresses the query as a CGI string that
 110 can be used for future refinements of the query or as a part of a history feature.
 111
 112 =item 4 $query_desc - Human search description - what the user sees in search
 113 feedback area
 114
 115 This is a simple string that is human readable. It will contain '=', ',', etc.
 116
 117 =back
 118
 119 =head3 2. Perform the Search
 120
 121 This section takes the query strings and performs searches on the named servers,
 122 including the Koha Zebra server, stores the results in a deeply nested object,
 123 builds 'faceted results', and returns these objects.
 124
 125 =head3 3. Build HTML
 126
 127 The final major section of this script takes the objects collected thusfar and
 128 builds the HTML for output to the template and user.
 129
 130 =head3 Additional Notes
 131
 132 Not yet completed...
 133
 134 =cut
 135
 136 use strict;            # always use
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth;
 146 use C4::Search;
 147 use C4::Languages qw(getAllLanguages);
 148 use C4::Koha;
 149 use POSIX qw(ceil floor);
 150 use C4::Branch; # GetBranches
 151
 152 # create a new CGI object
 153 # FIXME: no_undef_params needs to be tested
 154 use CGI qw('-no_undef_params');
 155 my $cgi = new CGI;
 156
 157 my ($template,$borrowernumber,$cookie);
 158
 159 # decide which template to use
 160 my $template_name;
 161 my $template_type;
 162 my @params = $cgi->param("limit");
 163 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 164     $template_name = 'catalogue/results.tmpl';
 165 }
 166 else {
 167     $template_name = 'catalogue/advsearch.tmpl';
 168     $template_type = 'advsearch';
 169 }
 170 # load the template
 171 ($template, $borrowernumber, $cookie) = get_template_and_user({
 172     template_name => $template_name,
 173     query => $cgi,
 174     type => "intranet",
 175     authnotrequired => 0,
 176     flagsrequired   => { catalogue => 1 },
 177     }
 178 );
 179 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 180     $template->param('UNIMARC' => 1);
 181 }
 182
 183 ## URI Re-Writing
 184 # Deprecated, but preserved because it's interesting :-)
 185 # The same thing can be accomplished with mod_rewrite in
 186 # a more elegant way
 187 #
 188 #my $rewrite_flag;
 189 #my $uri = $cgi->url(-base => 1);
 190 #my $relative_url = $cgi->url(-relative=>1);
 191 #$uri.="/".$relative_url."?";
 192 #warn "URI:$uri";
 193 #my @cgi_params_list = $cgi->param();
 194 #my $url_params = $cgi->Vars;
 195 #
 196 #for my $each_param_set (@cgi_params_list) {
 197 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 198 #}
 199 #warn "New URI:$uri";
 200 # Only re-write a URI if there are params or if it already hasn't been re-written
 201 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 202 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 203 #                            -cookie => $cookie);
 204 #    exit;
 205 #}
 206
 207 # load the branches
 208 my $branches = GetBranches();
 209 my @branch_loop;
 210
 211 for my $branch_hash (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 212     push @branch_loop, {value => "$branch_hash" , branchname => $branches->{$branch_hash}->{'branchname'}, };
 213 }
 214
 215 my $categories = GetBranchCategories(undef,'searchdomain');
 216
 217 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 218
 219 # load the Type stuff
 220 # load the Type stuff
 221 my $itemtypes = GetItemTypes;
 222 # the index parameter is different for item-level itemtypes
 223 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 224 my @itemtypesloop;
 225 my $selected=1;
 226 my $cnt;
 227 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes");
 228
 229 if (!$advanced_search_types or $advanced_search_types eq 'itemtypes') {                                                                 foreach my $thisitemtype ( sort {$itemtypes->{$a}->{'description'} cmp $itemtypes->{$b}->{'description'} } keys %$itemtypes ) {
 230     my %row =(  number=>$cnt++,
 231                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 232                 ccl => $itype_or_itemtype,
 233                 code => $thisitemtype,
 234                 selected => $selected,
 235                 description => $itemtypes->{$thisitemtype}->{'description'},
 236                 count5 => $cnt % 4,
 237             );
 238         $selected = 0 if ($selected) ;
 239         push @itemtypesloop, \%row;
 240     }
 241     $template->param(itemtypeloop => \@itemtypesloop);
 242 } else {
 243     my $advsearchtypes = GetAuthorisedValues($advanced_search_types);
 244     for my $thisitemtype (@$advsearchtypes) {
 245         my %row =(
 246                 number=>$cnt++,
 247                 imageurl=> getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 248                 ccl => $advanced_search_types,
 249                 code => $thisitemtype->{authorised_value},
 250                 selected => $selected,
 251                 description => $thisitemtype->{'lib'},
 252                 count5 => $cnt % 4,
 253             );
 254         push @itemtypesloop, \%row;
 255     }
 256     $template->param(itemtypeloop => \@itemtypesloop);
 257 }
 258
 259 # The following should only be loaded if we're bringing up the advanced search template
 260 if ( $template_type eq 'advsearch' ) {
 261
 262     # load the servers (used for searching -- to do federated searching, etc.)
 263     my $primary_servers_loop;# = displayPrimaryServers();
 264     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 265
 266     my $secondary_servers_loop;# = displaySecondaryServers();
 267     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 268
 269     # determine what to display next to the search boxes (ie, boolean option
 270     # shouldn't appear on the first one, scan indexes should, adding a new
 271     # box should only appear on the last, etc.
 272     my @search_boxes_array;
 273     my $search_boxes_count = C4::Context->preference("OPACAdvSearchInputCount") | 3; # FIXME: should be a syspref
 274     for (my $i=1;$i<=$search_boxes_count;$i++) {
 275         # if it's the first one, don't display boolean option, but show scan indexes
 276         if ($i==1) {
 277             push @search_boxes_array,
 278                 {
 279                 scan_index => 1,
 280                 };
 281
 282         }
 283         # if it's the last one, show the 'add field' box
 284         elsif ($i==$search_boxes_count) {
 285             push @search_boxes_array,
 286                 {
 287                 boolean => 1,
 288                 add_field => 1,
 289                 };
 290         }
 291         else {
 292             push @search_boxes_array,
 293                 {
 294                 boolean => 1,
 295                 };
 296         }
 297
 298     }
 299     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 300                       search_boxes_loop => \@search_boxes_array);
 301
 302     # load the language limits (for search)
 303     my $languages_limit_loop = getAllLanguages();
 304     $template->param(search_languages_loop => $languages_limit_loop,);
 305
 306     # use the global setting by default
 307     if ( C4::Context->preference("expandedSearchOption") == 1) {
 308         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 309     }
 310     # but let the user override it
 311     if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 312         $template->param( expanded_options => $cgi->param('expanded_options'));
 313     }
 314
 315     output_html_with_http_headers $cgi, $cookie, $template->output;
 316     exit;
 317 }
 318
 319 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 320
 321 # Fetch the paramater list as a hash in scalar context:
 322 #  * returns paramater list as tied hash ref
 323 #  * we can edit the values by changing the key
 324 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 325 my $params = $cgi->Vars;
 326
 327 # Params that can have more than one value
 328 # sort by is used to sort the query
 329 # in theory can have more than one but generally there's just one
 330 my @sort_by;
 331 my $default_sort_by = C4::Context->preference('defaultSortField')."_".C4::Context->preference('defaultSortOrder')
 332     if (C4::Context->preference('defaultSortField') && C4::Context->preference('defaultSortOrder'));
 333
 334 @sort_by = split("\0",$params->{'sort_by'}) if $params->{'sort_by'};
 335 $sort_by[0] = $default_sort_by unless $sort_by[0];
 336 foreach my $sort (@sort_by) {
 337     $template->param($sort => 1);
 338 }
 339 $template->param('sort_by' => $sort_by[0]);
 340
 341 # Use the servers defined, or just search our local catalog(default)
 342 my @servers;
 343 @servers = split("\0",$params->{'server'}) if $params->{'server'};
 344 unless (@servers) {
 345     #FIXME: this should be handled using Context.pm
 346     @servers = ("biblioserver");
 347     # @servers = C4::Context->config("biblioserver");
 348 }
 349 # operators include boolean and proximity operators and are used
 350 # to evaluate multiple operands
 351 my @operators;
 352 @operators = split("\0",$params->{'op'}) if $params->{'op'};
 353
 354 # indexes are query qualifiers, like 'title', 'author', etc. They
 355 # can be single or multiple parameters separated by comma: kw,right-Truncation
 356 my @indexes;
 357 @indexes = split("\0",$params->{'idx'});
 358
 359 # if a simple index (only one)  display the index used in the top search box
 360 if ($indexes[0] && !$indexes[1]) {
 361     $template->param("ms_".$indexes[0] => 1);}
 362
 363
 364 # an operand can be a single term, a phrase, or a complete ccl query
 365 my @operands;
 366 @operands = split("\0",$params->{'q'}) if $params->{'q'};
 367
 368 # limits are use to limit to results to a pre-defined category such as branch or language
 369 my @limits;
 370 @limits = split("\0",$params->{'limit'}) if $params->{'limit'};
 371
 372 if($params->{'multibranchlimit'}) {
 373 push @limits, join(" or ", map { "branch: $_ "}  @{GetBranchesInCategory($params->{'multibranchlimit'})}) ;
 374 }
 375
 376 my $available;
 377 foreach my $limit(@limits) {
 378     if ($limit =~/available/) {
 379         $available = 1;
 380     }
 381 }
 382 $template->param(available => $available);
 383
 384 # append year limits if they exist
 385 my $limit_yr;
 386 my $limit_yr_value;
 387 if ($params->{'limit-yr'}) {
 388     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 389         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 390         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 391         $limit_yr_value = "$yr1-$yr2";
 392     }
 393     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 394         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 395         $limit_yr_value = $params->{'limit-yr'};
 396     }
 397     push @limits,$limit_yr;
 398     #FIXME: Should return a error to the user, incorect date format specified
 399 }
 400
 401 # Params that can only have one value
 402 my $scan = $params->{'scan'};
 403 my $count = C4::Context->preference('numSearchResults') || 20;
 404 my $results_per_page = $params->{'count'} || $count;
 405 my $offset = $params->{'offset'} || 0;
 406 my $page = $cgi->param('page') || 1;
 407 #my $offset = ($page-1)*$results_per_page;
 408 my $hits;
 409 my $expanded_facet = $params->{'expand'};
 410
 411 # Define some global variables
 412 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 413
 414 my @results;
 415
 416 ## I. BUILD THE QUERY
 417 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by,$scan);
 418
 419 ## parse the query_cgi string and put it into a form suitable for <input>s
 420 my @query_inputs;
 421 my $scan_index_to_use;
 422
 423 for my $this_cgi ( split('&',$query_cgi) ) {
 424     next unless $this_cgi;
 425     $this_cgi =~ m/(.*=)(.*)/;
 426     my $input_name = $1;
 427     my $input_value = $2;
 428     $input_name =~ s/=$//;
 429     push @query_inputs, { input_name => $input_name, input_value => $input_value };
 430         if ($input_name eq 'idx') {
 431         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 432         }
 433 }
 434 $template->param ( QUERY_INPUTS => \@query_inputs,
 435                    scan_index_to_use => $scan_index_to_use );
 436
 437 ## parse the limit_cgi string and put it into a form suitable for <input>s
 438 my @limit_inputs;
 439 for my $this_cgi ( split('&',$limit_cgi) ) {
 440     next unless $this_cgi;
 441     # handle special case limit-yr
 442     if ($this_cgi =~ /yr,st-numeric/) {
 443         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 444         next;
 445     }
 446     $this_cgi =~ m/(.*=)(.*)/;
 447     my $input_name = $1;
 448     my $input_value = $2;
 449     $input_name =~ s/=$//;
 450     push @limit_inputs, { input_name => $input_name, input_value => $input_value };
 451 }
 452 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 453
 454 ## II. DO THE SEARCH AND GET THE RESULTS
 455 my $total; # the total results for the whole set
 456 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 457 my @results_array;
 458 my $results_hashref;
 459
 460 if (C4::Context->preference('NoZebra')) {
 461     $query=~s/yr(:|=)\s*([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 462     $simple_query=~s/yr\s*(:|=)([\d]{1,4})-([\d]{1,4})/(yr>=$2 and yr<=$3)/g;
 463     warn $query;
 464     eval {
 465         ($error, $results_hashref, $facets) = NZgetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 466     };
 467 } else {
 468     eval {
 469         ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 470     };
 471 }
 472 if ($@ || $error) {
 473     $template->param(query_error => $error.$@);
 474
 475     output_html_with_http_headers $cgi, $cookie, $template->output;
 476     exit;
 477 }
 478
 479 # FIXME: This belongs in tools/ not in the primary search results page
 480 my $op=$cgi->param("operation");
 481 if ($op eq "bulkedit"){
 482     my ($countchanged,$listunchanged)=
 483     ModBiblios($results_hashref->{'biblioserver'}->{"RECORDS"},
 484                       $params->{"tagsubfield"},
 485                       $params->{"inputvalue"},
 486                       $params->{"targetvalue"},
 487                       $params->{"test"}
 488                       );
 489     $template->param(bulkeditresults=>1,
 490                       tagsubfield=>$params->{"tagsubfield"},
 491                       inputvalue=>$params->{"inputvalue"},
 492                       targetvalue=>$params->{"targetvalue"},
 493                       countchanged=>$countchanged,
 494                       countunchanged=>scalar(@$listunchanged),
 495                       listunchanged=>$listunchanged);
 496
 497     if (C4::Context->userenv->{'flags'}==1 ||(C4::Context->userenv->{'flags'} & ( 2**9 ) )){
 498     #Edit Catalogue Permissions
 499         my $editable_subfields = GetManagedTagSubfields();
 500         # change '--' to '&mdash;' to avoid escaping issues
 501         for (my $i = 0; $i <= $#{$editable_subfields}; $i++) {
 502             $editable_subfields->[$i]->{subfielddesc} =~ s/--/&mdash;/g;
 503             $editable_subfields->[$i]->{tagdesc} =~ s/--/&mdash;/g;
 504         }
 505         $template->param(bulkedit => 1);
 506         $template->param(tagsubfields=>$editable_subfields);
 507     }
 508 }
 509
 510 # At this point, each server has given us a result set
 511 # now we build that set for template display
 512 my @sup_results_array;
 513 for (my $i=0;$i<@servers;$i++) {
 514     my $server = $servers[$i];
 515     if ($server =~/biblioserver/) { # this is the local bibliographic server
 516         $hits = $results_hashref->{$server}->{"hits"};
 517         my $page = $cgi->param('page') || 0;
 518         my @newresults = searchResults( $query_desc,$hits,$results_per_page,$offset,$scan,@{$results_hashref->{$server}->{"RECORDS"}});
 519         $total = $total + $results_hashref->{$server}->{"hits"};
 520         ## If there's just one result, redirect to the detail page
 521         if ($total == 1) {
 522             my $biblionumber=@newresults[0]->{biblionumber};
 523             if (C4::Context->preference('IntranetBiblioDefaultView') eq 'isbd') {
 524                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 525             } elsif  (C4::Context->preference('IntranetBiblioDefaultView') eq 'marc') {
 526                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 527             } else {
 528                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 529             }
 530             exit;
 531         }
 532         if ($hits) {
 533             $template->param(total => $hits);
 534             my $limit_cgi_not_availablity = $limit_cgi;
 535             $limit_cgi_not_availablity =~ s/&limit=available//g;
 536             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 537             $template->param(limit_cgi => $limit_cgi);
 538             $template->param(query_cgi => $query_cgi);
 539             $template->param(query_desc => $query_desc);
 540             $template->param(limit_desc => $limit_desc);
 541             if ($query_desc || $limit_desc) {
 542                 $template->param(searchdesc => 1);
 543             }
 544             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 545             $template->param(results_per_page =>  $results_per_page);
 546             $template->param(SEARCH_RESULTS => \@newresults);
 547
 548             ## FIXME: add a global function for this, it's better than the current global one
 549             ## Build the page numbers on the bottom of the page
 550             my @page_numbers;
 551             # total number of pages there will be
 552             my $pages = ceil($hits / $results_per_page);
 553             # default page number
 554             my $current_page_number = 1;
 555             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 556             my $previous_page_offset = $offset - $results_per_page unless ($offset - $results_per_page <0);
 557             my $next_page_offset = $offset + $results_per_page;
 558             # If we're within the first 10 pages, keep it simple
 559             #warn "current page:".$current_page_number;
 560             if ($current_page_number < 10) {
 561                 # just show the first 10 pages
 562                 # Loop through the pages
 563                 my $pages_to_show = 10;
 564                 $pages_to_show = $pages if $pages<10;
 565                 for (my $i=1; $i<=$pages_to_show;$i++) {
 566                     # the offset for this page
 567                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 568                     # the page number for this page
 569                     my $this_page_number = $i;
 570                     # it should only be highlighted if it's the current page
 571                     my $highlight = 1 if ($this_page_number == $current_page_number);
 572                     # put it in the array
 573                     push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 574
 575                 }
 576
 577             }
 578             # now, show twenty pages, with the current one smack in the middle
 579             else {
 580                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 581                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 582                     my $this_page_number = $i-9;
 583                     my $highlight = 1 if ($this_page_number == $current_page_number);
 584                     if ($this_page_number <= $pages) {
 585                         push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 586                     }
 587                 }
 588
 589             }
 590             # FIXME: no previous_page_offset when pages < 2
 591             $template->param(   PAGE_NUMBERS => \@page_numbers,
 592                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 593             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 594         }
 595         # no hits
 596         else {
 597             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 598         }
 599     } # end of the if local
 600
 601     # asynchronously search the authority server
 602     elsif ($server =~/authorityserver/) { # this is the local authority server
 603         my @inner_sup_results_array;
 604         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 605             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 606             # warn "Authority Found: ".$marc_record_object->as_formatted();
 607             push @inner_sup_results_array, {
 608                 'title' => $marc_record_object->field(100)->subfield('a'),
 609                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 610             };
 611         }
 612         my $servername = $server;
 613         push @sup_results_array, {  servername => $servername,
 614                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 615     }
 616     # FIXME: can add support for other targets as needed here
 617     $template->param(           outer_sup_results_loop => \@sup_results_array);
 618 } #/end of the for loop
 619 #$template->param(FEDERATED_RESULTS => \@results_array);
 620
 621
 622 $template->param(
 623             #classlist => $classlist,
 624             total => $total,
 625             opacfacets => 1,
 626             facets_loop => $facets,
 627             scan => $scan,
 628             search_error => $error,
 629 );
 630
 631 if ($query_desc || $limit_desc) {
 632     $template->param(searchdesc => 1);
 633 }
 634
 635 ## Now let's find out if we have any supplemental data to show the user
 636 #  and in the meantime, save the current query for statistical purposes, etc.
 637 my $koha_spsuggest; # a flag to tell if we've got suggestions coming from Koha
 638 my @koha_spsuggest; # place we store the suggestions to be returned to the template as LOOP
 639 my $phrases = $query_desc;
 640 my $ipaddress;
 641
 642 if ( C4::Context->preference("kohaspsuggest") ) {
 643         my ($suggest_host, $suggest_dbname, $suggest_user, $suggest_pwd) = split(':', C4::Context->preference("kohaspsuggest"));
 644         eval {
 645             my $koha_spsuggest_dbh;
 646             # FIXME: this needs to be moved to Context.pm
 647             eval {
 648                 $koha_spsuggest_dbh=DBI->connect("DBI:mysql:$suggest_dbname:$suggest_host","$suggest_user","$suggest_pwd");
 649             };
 650             if ($@) {
 651                 warn "can't connect to spsuggest db";
 652             }
 653             else {
 654                 my $koha_spsuggest_insert = "INSERT INTO phrase_log(phr_phrase,phr_resultcount,phr_ip) VALUES(?,?,?)";
 655                 my $koha_spsuggest_query = "SELECT display FROM distincts WHERE strcmp(soundex(suggestion), soundex(?)) = 0 order by soundex(suggestion) limit 0,5";
 656                 my $koha_spsuggest_sth = $koha_spsuggest_dbh->prepare($koha_spsuggest_query);
 657                 $koha_spsuggest_sth->execute($phrases);
 658                 while (my $spsuggestion = $koha_spsuggest_sth->fetchrow_array) {
 659                     $spsuggestion =~ s/(:|\/)//g;
 660                     my %line;
 661                     $line{spsuggestion} = $spsuggestion;
 662                     push @koha_spsuggest,\%line;
 663                     $koha_spsuggest = 1;
 664                 }
 665
 666                 # Now save the current query
 667                 $koha_spsuggest_sth=$koha_spsuggest_dbh->prepare($koha_spsuggest_insert);
 668                 #$koha_spsuggest_sth->execute($phrases,$results_per_page,$ipaddress);
 669                 $koha_spsuggest_sth->finish;
 670
 671                 $template->param( koha_spsuggest => $koha_spsuggest ) unless $hits;
 672                 $template->param( SPELL_SUGGEST => \@koha_spsuggest,
 673                 );
 674             }
 675     };
 676     if ($@) {
 677             warn "Kohaspsuggest failure:".$@;
 678     }
 679 }
 680
 681 # VI. BUILD THE TEMPLATE
 682 output_html_with_http_headers $cgi, $cookie, $template->output;