examples/loopback.pl

   1 #!/usr/bin/perl -w
   2 use strict;
   3
   4 use blib;
   5 use Fuse;
   6 use IO::File;
   7 use POSIX qw(ENOENT ENOSYS EEXIST EPERM O_RDONLY O_RDWR O_APPEND O_CREAT);
   8 use Fcntl qw(S_ISBLK S_ISCHR S_ISFIFO SEEK_SET S_ISREG S_ISFIFO S_IMODE);
   9 my $can_syscall = eval {
  10         require 'syscall.ph'; # for SYS_mknod and SYS_lchown
  11 };
  12 if (!$can_syscall && open my $fh, '<', '/usr/include/sys/syscall.h') {
  13         my %sys = do { local $/ = undef;
  14                         <$fh> =~ m/\#define \s+ (\w+) \s+ (\d+)/gxms;
  15         };
  16         close $fh;
  17         if ($sys{SYS_mknod} && $sys{SYS_lchown}) {
  18                 *SYS_mknod  = sub { $sys{SYS_mknod}  };
  19                 *SYS_lchown = sub { $sys{SYS_lchown} };
  20                 $can_syscall = 1;
  21         }
  22 }
  23
  24 sub fixup { return "/tmp/fusetest-" . $ENV{LOGNAME} . shift }
  25
  26 sub x_getattr {
  27         my ($file) = fixup(shift);
  28         my (@list) = lstat($file);
  29         return -$! unless @list;
  30         return @list;
  31 }
  32
  33 sub x_getdir {
  34         my ($dirname) = fixup(shift);
  35         unless(opendir(DIRHANDLE,$dirname)) {
  36                 return -ENOENT();
  37         }
  38         my (@files) = readdir(DIRHANDLE);
  39         closedir(DIRHANDLE);
  40         return (@files, 0);
  41 }
  42
  43 sub x_open {
  44         my ($file) = fixup(shift);
  45         my ($mode) = shift;
  46         return -$! unless sysopen(FILE,$file,$mode);
  47         close(FILE);
  48         return 0;
  49 }
  50
  51 sub x_read {
  52         my ($file,$bufsize,$off) = @_;
  53         my ($rv) = -ENOSYS();
  54         my ($handle) = new IO::File;
  55         return -ENOENT() unless -e ($file = fixup($file));
  56         my ($fsize) = -s $file;
  57         return -ENOSYS() unless open($handle,$file);
  58         if(seek($handle,$off,SEEK_SET)) {
  59                 read($handle,$rv,$bufsize);
  60         }
  61         return $rv;
  62 }
  63
  64 sub x_write {
  65         my ($file,$buf,$off) = @_;
  66         my ($rv);
  67         return -ENOENT() unless -e ($file = fixup($file));
  68         my ($fsize) = -s $file;
  69         return -ENOSYS() unless open(FILE,'+<',$file);
  70         if($rv = seek(FILE,$off,SEEK_SET)) {
  71                 $rv = print(FILE $buf);
  72         }
  73         $rv = -ENOSYS() unless $rv;
  74         close(FILE);
  75         return length($buf);
  76 }
  77
  78 sub err { return (-shift || -$!) }
  79
  80 sub x_readlink { return readlink(fixup(shift));         }
  81 sub x_unlink   { return unlink(fixup(shift)) ? 0 : -$!; }
  82
  83 sub x_symlink { print "symlink\n"; return symlink(shift,fixup(shift)) ? 0 : -$!; }
  84
  85 sub x_rename {
  86         my ($old) = fixup(shift);
  87         my ($new) = fixup(shift);
  88         my ($err) = rename($old,$new) ? 0 : -ENOENT();
  89         return $err;
  90 }
  91 sub x_link { return link(fixup(shift),fixup(shift)) ? 0 : -$! }
  92 sub x_chown {
  93         return -ENOSYS() if ! $can_syscall;
  94         my ($fn) = fixup(shift);
  95         print "nonexistent $fn\n" unless -e $fn;
  96         my ($uid,$gid) = @_;
  97         # perl's chown() does not chown symlinks, it chowns the symlink's
  98         # target.  it fails when the link's target doesn't exist, because
  99         # the stat64() syscall fails.
 100         # this causes error messages when unpacking symlinks in tarballs.
 101         my ($err) = syscall(&SYS_lchown,$fn,$uid,$gid,$fn) ? -$! : 0;
 102         return $err;
 103 }
 104 sub x_chmod {
 105         my ($fn) = fixup(shift);
 106         my ($mode) = shift;
 107         my ($err) = chmod($mode,$fn) ? 0 : -$!;
 108         return $err;
 109 }
 110 sub x_truncate { return truncate(fixup(shift),shift) ? 0 : -$! ; }
 111 sub x_utime { return utime($_[1],$_[2],fixup($_[0])) ? 0:-$!; }
 112
 113 sub x_mkdir { my ($name, $perm) = @_; return 0 if mkdir(fixup($name),$perm); return -$!; }
 114 sub x_rmdir { return 0 if rmdir fixup(shift); return -$!; }
 115
 116 sub x_mknod {
 117         return -ENOSYS() if ! $can_syscall;
 118         # since this is called for ALL files, not just devices, I'll do some checks
 119         # and possibly run the real mknod command.
 120         my ($file, $modes, $dev) = @_;
 121         $file = fixup($file);
 122         undef $!;
 123         if ($^O eq 'freebsd' || $^O eq 'darwin' || $^O eq 'netbsd') {
 124                 if (S_ISREG($modes)) {
 125                         open(FILE, '>', $file) || return -$!;
 126                         print FILE "";
 127                         close(FILE);
 128                         return 0;
 129                 } elsif (S_ISFIFO($modes)) {
 130                         my ($rv) = POSIX::mkfifo($file, S_IMODE($modes));
 131                         return $rv ? 0 : -POSIX::errno();
 132                 }
 133         }
 134         syscall(&SYS_mknod,$file,$modes,$dev);
 135         return -$!;
 136 }
 137
 138 # kludge
 139 sub x_statfs {return 255,1000000,500000,1000000,500000,4096}
 140 my ($mountpoint) = "";
 141 $mountpoint = shift(@ARGV) if @ARGV;
 142 Fuse::main(
 143         mountpoint=>$mountpoint,
 144         getattr =>"main::x_getattr",
 145         readlink=>"main::x_readlink",
 146         getdir  =>"main::x_getdir",
 147         mknod   =>"main::x_mknod",
 148         mkdir   =>"main::x_mkdir",
 149         unlink  =>"main::x_unlink",
 150         rmdir   =>"main::x_rmdir",
 151         symlink =>"main::x_symlink",
 152         rename  =>"main::x_rename",
 153         link    =>"main::x_link",
 154         chmod   =>"main::x_chmod",
 155         chown   =>"main::x_chown",
 156         truncate=>"main::x_truncate",
 157         utime   =>"main::x_utime",
 158         open    =>"main::x_open",
 159         read    =>"main::x_read",
 160         write   =>"main::x_write",
 161         statfs  =>"main::x_statfs",
 162         threaded=>0,
 163         debug => 1,
 164 );