git.rot13.org Git - koha-bibliografija/blob - html.pl

   1 #!/usr/bin/perl
   2
   3 # LC_COLLATE=hr_HR.utf8 KOHA_CONF=/etc/koha/sites/ffzg/koha-conf.xml ./html.pl
   4
   5 use warnings;
   6 use strict;
   7
   8 use DBI;
   9 use Data::Dump qw(dump);
  10 use autodie;
  11 use locale;
  12 use Text::Unaccent;
  13 use Carp qw(confess);
  14 use utf8;
  15 use JSON;
  16 use POSIX qw(strftime);
  17 use Storable;
  18
  19 use lib '/srv/koha_ffzg';
  20 use C4::Context;
  21 use XML::LibXML;
  22 use XML::LibXSLT;
  23
  24 my $dbh = C4::Context->dbh;
  25
  26 sub debug {
  27         my ($title, $data) = @_;
  28         print "# $title ",dump($data), $/ if $ENV{DEBUG};
  29 }
  30
  31 my $xslfilename = 'compact.xsl';
  32
  33 my $azvo_group_title = {
  34 'znanstveno nastavni' => qr/(profes|docent|znanstveni savjetnik|znanstveni suradnik)/i,
  35 'lektori i predavači' => qr/(lektor|predavač)/i,
  36 'asistenti i novaci' => qr/(asistent|novak)/i,
  37 };
  38
  39 my $department_groups = {
  40 'AAB_humanističke'             => qr/(anglistiku|arheologiju|antropologiju|filozofiju|fonetiku|germanistiku|hungarologiju|indologiju|slavenske|filologiju|komparativnu|kroatistiku|lingvistiku|povijest|romanistiku|talijanistiku)/i,
  41 'AAC_društvene'                        => qr/(informacijske|pedagogiju|psihologiju|sociologiju)/i,
  42 };
  43
  44 my $auth_header;
  45 my $auth_department;
  46 my $auth_group;
  47 my @authors;
  48 my $department_in_sum;
  49 my $department_in_group;
  50
  51 my $skip;
  52
  53 my $sth_auth = $dbh->prepare(q{
  54 select
  55         authid,
  56         ExtractValue(marcxml,'//datafield[@tag="100"]/subfield[@code="a"]') as full_name,
  57         ExtractValue(marcxml,'//datafield[@tag="680"]/subfield[@code="a"]') as department,
  58         ExtractValue(marcxml,'//datafield[@tag="680"]/subfield[@code="i"]') as academic_title
  59 from auth_header
  60 });
  61
  62 $sth_auth->execute();
  63 while( my $row = $sth_auth->fetchrow_hashref ) {
  64         if ( $row->{department} !~ m/Filozofski fakultet u Zagrebu/ ) {
  65                 push @{ $skip->{nije_ffzg} }, $row;
  66                 next;
  67         }
  68         $auth_header->{ $row->{authid} } = $row->{full_name};
  69         $row->{department} =~ s/, Filozofski fakultet u Zagrebu.*$//;
  70         $row->{department} =~ s/^.+\.\s*//;
  71         $row->{department} =~ s/\s+$//s;
  72         my $group;
  73         foreach my $title ( keys %$azvo_group_title ) {
  74                 if ( $row->{academic_title} =~ $azvo_group_title->{$title} ) {
  75                         $group = $title;
  76                         last;
  77                 }
  78         }
  79         if ( $group ) {
  80                 $row->{academic_group} = $group;
  81                 $auth_group->{ $row->{authid} } = $group;
  82                 $skip->{group_stat}->{$group}++;
  83         } else {
  84                 push @{ $skip->{no_academic_group} }, $row;
  85         }
  86
  87 #       warn "# ", dump( $row );
  88         push @{ $auth_department->{ $row->{department} } }, $row->{authid};
  89         push @authors, $row;
  90         $department_in_sum->{ $row->{department} }++;
  91         foreach my $name ( keys %$department_groups ) {
  92                 my $regex = $department_groups->{$name};
  93                 if ( $row->{department} =~ $regex ) {
  94                         $department_in_group->{ $row->{department} } = $name;
  95                         last;
  96                 }
  97         }
  98 }
  99
 100 debug 'department_in_group' => $department_in_group;
 101
 102 foreach my $department ( keys %$department_in_sum ) {
 103         $department_in_sum->{$department} = 0 unless $department =~ m/(centar|croaticum|katedra|odsjek)/i;
 104 }
 105
 106 debug 'auth_department' => $auth_department;
 107 store $auth_department, '/dev/shm/auth_department.storable';
 108 debug 'auth_group' => $auth_group;
 109 debug 'department_in_sum' => $department_in_sum;
 110
 111
 112 my $authors;
 113 my $marcxml;
 114
 115 my $sth_select_authors  = $dbh->prepare(q{
 116 select
 117         biblionumber,
 118         itemtype,
 119         marcxml
 120 from biblioitems
 121 where
 122         agerestriction > 0
 123 });
 124
 125 =for sql
 126 --      ExtractValue(marcxml,'//datafield[@tag="100"]/subfield[@code="9"]') as first_author,
 127 --      ExtractValue(marcxml,'//datafield[@tag="700"]/subfield[@code="9"]') as other_authors,
 128 --      ExtractValue(marcxml,'//datafield[@tag="942"]/subfield[@code="t"]') as category,
 129
 130 --      and SUBSTR(ExtractValue(marcxml,'//controlfield[@tag="008"]'),8,4) between 2008 and 2013
 131 -- order by SUBSTR(ExtractValue(marcxml,'//controlfield[@tag="008"]'),8,4) desc
 132 =cut
 133
 134 my $biblio_year;
 135 my $biblio_full_name;
 136 my $type_stats;
 137
 138 my $parser = XML::LibXML->new();
 139 $parser->recover_silently(0); # don't die when you find &, >, etc
 140 my $style_doc = $parser->parse_file($xslfilename);
 141 my $xslt = XML::LibXSLT->new();
 142 my $parsed = $xslt->parse_stylesheet($style_doc);
 143
 144 my $biblio_html;
 145 my $biblio_parsed;
 146 my $biblio_data;
 147 my $biblio_author_external;
 148
 149 open(my $xml_fh, '>', '/tmp/bibliografija.xml') if $ENV{XML};
 150
 151 sub biblioitem_html {
 152         my ($biblionumber, $parse_only) = @_;
 153
 154         return $biblio_html->{$biblionumber} if exists $biblio_html->{$biblionumber} && ! $parse_only;
 155
 156         my $xmlrecord = $marcxml->{$biblionumber} || confess "missing $biblionumber marcxml";
 157
 158         print $xml_fh $xmlrecord if $ENV{XML};
 159
 160         my $source = eval { $parser->parse_string($xmlrecord) };
 161         if ( $@ ) {
 162 #               warn "SKIP $biblionumber corrupt XML";
 163                 push @{ $skip->{XML_corrupt} }, $biblionumber;
 164                 return;
 165         }
 166
 167         if ( $parse_only ) {
 168                 $biblio_parsed->{$biblionumber} = $source;
 169                 return $source;
 170         }
 171
 172         my $transformed = $parsed->transform($source);
 173         $biblio_html->{$biblionumber} = $parsed->output_string( $transformed );
 174
 175         delete $biblio_parsed->{$biblionumber};
 176
 177         return $biblio_html->{$biblionumber};
 178 }
 179
 180 $sth_select_authors->execute();
 181 while( my $row = $sth_select_authors->fetchrow_hashref ) {
 182 #       warn dump($row),$/;
 183
 184         my $biblio;
 185
 186         $marcxml->{ $row->{biblionumber} } = $row->{marcxml};
 187
 188         my $doc = biblioitem_html( $row->{biblionumber}, 1 );
 189         if ( ! $doc ) {
 190 #               warn "ERROR can't parse MARCXML ", $row->{biblionumber}, " ", $row->{marcxml}, "\n";
 191                 next;
 192         }
 193
 194         my $root = $doc->documentElement;
 195 =for leader
 196         my @leaders = $root->getElementsByLocalName('leader');
 197         if (@leaders) {
 198                 my $leader = $leaders[0]->textContent;
 199                 warn "leader $leader\n";
 200         }
 201 =cut
 202
 203         my $extract = {
 204                 '008' => undef,
 205                 '100' => '(9|a)',
 206                 '245' => 'a',
 207                 '680' => 'i',
 208                 '700' => '(9|4|a)',
 209                 '942' => '(t|r|v)'
 210         };
 211
 212         my $data;
 213
 214         foreach my $elt ($root->getChildrenByLocalName('*')) {
 215                 my $tag = $elt->getAttribute('tag');
 216                 next if ! $tag;
 217                 next unless exists $extract->{ $tag };
 218
 219         if ($elt->localname eq 'controlfield') {
 220                         if ( $tag eq '008' ) {
 221                                 my $content = $elt->textContent;
 222                                 my $year = substr($content, 7, 4 );
 223                                 if ( $year !~ m/^\d+$/ ) {
 224                                         $year = 0;
 225                                         push @{ $skip->{invalid_year} }, $row->{biblionumber};
 226                                 }
 227                                 $biblio_year->{ $row->{biblionumber} } = $data->{year} = $year;
 228                                 $data->{'008'} = $content;
 229                         }
 230                         next;
 231         } elsif ($elt->localname eq 'datafield') {
 232                         my $sf_data;
 233             foreach my $sfelt ($elt->getChildrenByLocalName('subfield')) {
 234                 my $sf = $sfelt->getAttribute('code');
 235                                 next unless $sf =~ m/$extract->{$tag}/;
 236                                 if ( exists $sf_data->{$sf} ) {
 237                                         $sf_data->{$sf} .= " " . $sfelt->textContent();
 238                                 } else {
 239                                         $sf_data->{$sf} = $sfelt->textContent();
 240                                 }
 241                         }
 242                         push @{ $data->{$tag} }, $sf_data if $sf_data;
 243                 }
 244         }
 245
 246         if ( ! defined $data->{year} ) {
 247                 warn "MISSING year in ", $row->{biblionumber};
 248 =for remove-year-limit
 249         } elsif ( $data->{year} < 2008 ) {
 250                 push @{ $skip->{year_lt_2008} }, $row->{biblionumber};
 251                 next;
 252         } elsif ( $data->{year} > 2013 ) {
 253                 push @{ $skip->{year_gt_2013} }, $row->{biblionumber};
 254                 next;
 255 =cut
 256         }
 257
 258 #       warn "# ", $row->{biblionumber}, " data ",dump($data);
 259
 260         my $category = $data->{942}->[0]->{'t'};
 261         if ( ! $category ) {
 262 #               warn "# SKIP ", $row->{biblionumber}, " no category in ", dump($data);
 263                 push @{ $skip->{no_category} }, $row->{biblionumber};
 264                 next;
 265         }
 266
 267         my $have_100 = 1;
 268
 269         if ( exists $data->{100} ) {
 270                         my @first_author =
 271                                 map { $_->{'9'} }
 272                                 grep {
 273                                         if ( ! exists $_->{9} ) {
 274                                                 $biblio_author_external->{ $row->{biblionumber} }++;
 275                                                 0;
 276                                         } elsif ( exists $auth_header->{ $_->{9} } ) {
 277                                                 1; # from FFZXG
 278                                         } else {
 279                                                 0;
 280                                         }
 281                                 }
 282                                 @{ $data->{100} };
 283                         foreach my $authid ( @first_author ) {
 284                                 push @{ $authors->{$authid}->{aut}->{ $category } }, $row->{biblionumber};
 285                         }
 286                         $biblio_full_name->{ $row->{biblionumber} } = $data->{100}->[0]->{a};
 287         } else {
 288                 $have_100 = 0;
 289         }
 290
 291         $biblio_full_name->{ $row->{biblionumber} } ||= $data->{245}->[0]->{a};
 292
 293         my $have_edt;
 294
 295         if ( exists $data->{700} ) {
 296                         my @other_authors =
 297                                 grep {
 298                                         if ( ! exists $_->{9} ) {
 299                                                 $biblio_author_external->{ $row->{biblionumber} }++;
 300                                                 0;
 301                                         } elsif ( exists $auth_header->{ $_->{9} } ) {
 302                                                 1; # from FFZXG
 303                                         } else {
 304                                                 0;
 305                                         }
 306                                 }
 307                                 @{ $data->{700} };
 308                         foreach my $auth ( @other_authors ) {
 309                                 my $authid = $auth->{9} || next;
 310                                 my $type   = $auth->{4} || next; #die "no 4 in ",dump($data);
 311
 312                                 $type_stats->{$type}++;
 313
 314                                 if ( $type =~ m/(edt|trl|com|ctb)/ ) {
 315                                         push @{ $authors->{$authid}->{sec}->{ $category } }, $row->{biblionumber};
 316                                         push @{ $authors->{$authid}->{$1}->{ $category } }, $row->{biblionumber};
 317                                 } elsif ( $type =~ m/aut/ ) {
 318                                         if ( ! $have_100 ) {
 319                                                 $have_edt = grep { exists $_->{4} && $_->{4} =~ m/edt/ } @{ $data->{700} } if ! defined $have_edt;
 320                                                 if ( $have_edt ) {
 321                                                         $skip->{ have_700_edt }->{ $row->{biblionumber} }++;
 322                                                 } else {
 323                                                         push @{ $authors->{$authid}->{aut}->{ $category } }, $row->{biblionumber};
 324                                                 }
 325                                         } else {
 326                                                 push @{ $authors->{$authid}->{aut}->{ $category } }, $row->{biblionumber};
 327                                         }
 328                                 } else {
 329 #                                       warn "# SKIP ", $row->{biblionumber}, ' no 700$4 in ', dump($data);
 330                                         $skip->{ 'no_700$4' }->{ $row->{biblionumber} }++;
 331                                 }
 332                         }
 333                         delete $data->{700};
 334         }
 335
 336         $biblio_data->{ $row->{biblionumber} } = $data;
 337
 338 }
 339
 340 debug 'authors' => $authors;
 341 store $authors, '/dev/shm/authors.storable';
 342 debug 'type_stats' => $type_stats;
 343 debug 'skip' => $skip;
 344 debug 'biblio_year' => $biblio_year;
 345 debug 'biblio_full_name' => $biblio_full_name;
 346 debug 'biblio_data' => $biblio_data;
 347 debug 'biblio_author_external' => $biblio_author_external;
 348
 349 my $category_label;
 350 my $sth_categories = $dbh->prepare(q{
 351 select authorised_value, lib from authorised_values where category = 'BIBCAT'
 352 });
 353 $sth_categories->execute();
 354 while( my $row = $sth_categories->fetchrow_hashref ) {
 355         $category_label->{ $row->{authorised_value} } = $row->{lib};
 356
 357 }
 358 debug 'category_label' => $category_label;
 359
 360 sub html_title {
 361         return qq|<html>
 362 <head>
 363 <meta charset="UTF-8">
 364 <title>|, join(" ", @_), qq|</title>
 365 <link href="style.css" type="text/css" rel="stylesheet" />
 366 <script src="//code.jquery.com/jquery-1.11.2.js"></script>
 367 </head>
 368 <body>
 369 |;
 370 }
 371
 372 sub html_end {
 373         return
 374                 qq|<small style="color:gray">Zadnji puta osvježeno: |,
 375                 strftime("%Y-%m-%d %H:%M:%S\n", localtime()),
 376                 qq|</body>\n</html>\n|;
 377 }
 378
 379 mkdir 'html' unless -d 'html';
 380
 381 open(my $index, '>:encoding(utf-8)', 'html/index.new');
 382 print $index html_title('Bibliografija Filozofskog fakulteta');
 383
 384 my $first_letter = '';
 385
 386 debug 'authors' => \@authors;
 387
 388 sub li_biblio {
 389         my ($biblionumber) = @_;
 390         return qq|<li class="y|, $biblio_year->{$biblionumber}, qq|">|,
 391                 qq|<a href="https://koha.ffzg.hr/cgi-bin/koha/opac-detail.pl?biblionumber=$biblionumber">$biblionumber</a>|,
 392                 biblioitem_html($biblionumber),
 393                 qq|<a href="https://koha.ffzg.hr:8443/cgi-bin/koha/cataloguing/addbiblio.pl?biblionumber=$biblionumber">edit</a>|,
 394                 qq|</li>\n|;
 395 }
 396
 397 sub unique_biblionumber {
 398         my @v = @_;
 399         my $u;
 400         $u->{$_}++ foreach @v;
 401         return sort {
 402                 $biblio_year->{$b} <=> $biblio_year->{$a} ||
 403                 $biblio_full_name->{$a} cmp $biblio_full_name->{$b} ||
 404                 $a <=> $b
 405         } keys %$u;
 406 }
 407
 408 sub author_html {
 409         my ( $fh, $authid, $type, $label ) = @_;
 410
 411         return unless exists $authors->{$authid}->{$type};
 412
 413         print $fh qq|<h2>$label</h2>\n|;
 414
 415         foreach my $category ( sort keys %{ $authors->{$authid}->{$type} } ) {
 416                 my $label = $category_label->{$category} || 'Bez kategorije';
 417                 print $fh qq|<a name="$type-$category"><h3>$label</h3></a>\n<ol>\n|;
 418                 foreach my $biblionumber ( unique_biblionumber @{ $authors->{$authid}->{$type}->{$category} } ) {
 419                         print $fh li_biblio( $biblionumber );
 420                 }
 421                 print $fh qq|</ol>\n|;
 422         }
 423 }
 424
 425
 426 sub count_author_years {
 427         my $years = shift;
 428         my ($authid) = @_;
 429         foreach my $type ( keys %{ $authors->{$authid} } ) {
 430                 foreach my $category ( keys %{ $authors->{$authid}->{$type} } ) {
 431                         foreach my $biblionumber ( @{ $authors->{$authid}->{$type}->{$category} } ) {
 432                                 $years->{ $biblio_year->{ $biblionumber } }->{ $type . '-' . $category }++;
 433                         }
 434                 }
 435         }
 436         return $years;
 437 }
 438
 439 sub html_year_selection {
 440         my $fh = shift;
 441         my @authids = @_;
 442
 443         print $fh qq|<span id="years">Godine:\n|;
 444         my $type_cat_count = {};
 445         my $years;
 446
 447         foreach my $authid ( @authids ) {
 448                 $years = count_author_years( $years, $authid );
 449         }
 450
 451         foreach my $year ( sort { $b <=> $a } keys %$years ) {
 452                 print $fh qq|<label><input name="year_selection" value="$year" type=checkbox onClick="toggle_year($year, this)" checked="checked">$year</label>&nbsp;\n|;
 453                 foreach my $type_cat ( keys %{ $years->{$year} } ) {
 454                         $type_cat_count->{ $type_cat } += $years->{$year}->{$type_cat};
 455                 }
 456         }
 457
 458         print $fh qq|
 459 <input type=button value="all" onClick="all_years(1)">
 460 <input type=button value="none" onClick="all_years(0)">
 461         |;
 462
 463         print $fh qq|</span>|;
 464
 465         print $fh q|
 466 <script>
 467
 468 var years = |, encode_json($years), q|;
 469
 470 var type_cat_count = |, encode_json($type_cat_count), q|;
 471
 472 function year_show(year) {
 473         $('.y'+year).show();
 474         console.debug('show', year);
 475         for(var type_cat in years[year]) {
 476                 if ( ( type_cat_count[ type_cat ] += years[year][type_cat] ) == years[year][type_cat]) {
 477                         $('a[name="'+type_cat+'"]').show();
 478                         console.debug(type_cat, 'show');
 479                 }
 480         }
 481 }
 482
 483 function year_hide(year) {
 484         $('.y'+year).hide();
 485         console.debug('hide', year);
 486         for(var type_cat in years[year]) {
 487                 if ( ( type_cat_count[ type_cat ] -= years[year][type_cat] ) == 0 ) {
 488                         $('a[name="'+type_cat+'"]').hide();
 489                         console.debug(type_cat, 'hide');
 490                 }
 491         }
 492 }
 493
 494 function toggle_year(year, el) {
 495         if ( el.checked ) {
 496                 year_show(year);
 497         } else {
 498                 year_hide(year);
 499         }
 500 }
 501
 502 function all_years( turn_on ) {
 503         $('input[name=year_selection]').each( function(i,el) {
 504                 if ( turn_on ) {
 505                         if ( ! el.checked ) {
 506                                 el.checked = true;
 507                                 year_show( el.value );
 508                         }
 509                 } else {
 510                         if ( el.checked ) {
 511                                 el.checked = false;
 512                                 year_hide( el.value );
 513                         }
 514                 }
 515         } );
 516 }
 517
 518 $(document).ready( function() {
 519         console.info('ready');
 520
 521         $('input[name=year_selection]').each( function(i, el) {
 522                 var year = el.value;
 523                 console.debug( 'on load', year, el.checked );
 524                 if (! el.checked) year_hide(year);
 525         });
 526
 527 });
 528 </script>
 529         |;
 530 }
 531
 532 foreach my $row ( sort { $a->{full_name} cmp $b->{full_name} } @authors ) {
 533
 534         my $first = substr( $row->{full_name}, 0, 1 );
 535         if ( $first ne $first_letter ) {
 536                 print $index qq{</ul>\n} if $first_letter;
 537                 $first_letter = $first;
 538                 print $index qq{<h1>$first</h1>\n<ul>\n};
 539         }
 540         print $index qq{<li><a href="}, $row->{authid}, qq{.html">}, $row->{full_name}, "</a></li>\n";
 541
 542         my $path = "html/$row->{authid}";
 543         open(my $fh, '>:encoding(utf-8)', "$path.new");
 544         print $fh html_title($row->{full_name}, "bibliografija");
 545         print $fh qq|<h1>$row->{full_name} - bibliografija</h1>\n|;
 546
 547         html_year_selection $fh => $row->{authid};
 548
 549         author_html( $fh, $row->{authid}, 'aut' => 'Primarno autorstvo' );
 550         author_html( $fh, $row->{authid}, 'sec' => 'Uredništva, prijevodi, kritička izdanja' );
 551
 552         print $fh html_end;
 553         close($fh);
 554         rename "$path.new", "$path.html";
 555
 556 }
 557
 558 print $index html_end;
 559 close($index);
 560 rename 'html/index.new', 'html/index.html';
 561
 562 debug 'auth_header' => $auth_header;
 563
 564
 565 my $department_category_author;
 566 foreach my $department ( sort keys %$auth_department ) {
 567         foreach my $authid ( sort @{ $auth_department->{$department} } ) {
 568                 my   @categories = keys %{ $authors->{$authid}->{aut} };
 569                 push @categories,  keys %{ $authors->{$authid}->{sec} };
 570                 foreach my $category ( sort @categories ) {
 571                         push @{ $department_category_author->{$department}->{$category} }, $authid;
 572                         push @{ $department_category_author->{'AAA_ukupno'}->{$category} }, $authid if $department_in_sum->{$department};
 573                         if ( my $group = $department_in_group->{ $department } ) {
 574                                 push @{ $department_category_author->{$group}->{$category} }, $authid;
 575                         } else {
 576                                 $skip->{'department_not_in_group'}->{ $department }++;
 577                         }
 578                 }
 579         }
 580 }
 581
 582 debug 'department_category_author' => $department_category_author;
 583
 584
 585 sub department_html {
 586         my ( $fh, $department, $type, $label ) = @_;
 587
 588         print $fh qq|<h2>$label</h2>\n|;
 589
 590         foreach my $category ( sort keys %{ $department_category_author->{$department} } ) {
 591
 592                 my @authids = @{ $department_category_author->{$department}->{$category} };
 593                 next unless @authids;
 594
 595                 my @biblionumber = unique_biblionumber map { @{ $authors->{$_}->{$type}->{$category} } } grep { exists $authors->{$_}->{$type}->{$category} } @authids;
 596
 597                 next unless @biblionumber;
 598
 599                 my $label = $category_label->{$category} || 'Bez kategorije';
 600                 print $fh qq|<a name="$type-$category"><h3>$label</h3></a>\n<ol>\n|;
 601
 602                 print $fh li_biblio( $_ ) foreach @biblionumber;
 603
 604                 print $fh qq|</ol>|;
 605         }
 606
 607 }
 608
 609
 610 mkdir 'html/departments' unless -d 'html/departments';
 611
 612 open(my $dep_fh, '>:encoding(utf-8)', 'html/departments/index.new');
 613 print $dep_fh html_title('Odsjeci Filozofskog fakulteta u Zagrebu'), qq|<ul>\n|;
 614 foreach my $department ( sort keys %$department_category_author ) {
 615         my $dep = $department || 'Nema odsjeka';
 616         my $dep_file = unac_string('utf-8',$dep);
 617         print $dep_fh qq|<li><a href="$dep_file.html">$dep</a></li>\n|;
 618         open(my $fh, '>:encoding(utf-8)', "html/departments/$dep_file.new");
 619
 620         print $fh html_title($department . ' bibliografija');
 621         print $fh qq|<h1>$department bibliografija</h1>\n|;
 622
 623         my @authids;
 624         foreach my $category ( sort keys %{ $department_category_author->{$department} } ) {
 625                 push @authids, @{ $department_category_author->{$department}->{$category} };
 626         }
 627         html_year_selection $fh => @authids;
 628
 629         department_html( $fh, $department, 'aut', 'Primarno autorstvo' );
 630
 631         department_html( $fh, $department, 'sec', 'Sekundarno autorstvo' );
 632
 633         print $fh html_end;
 634         close($fh);
 635         rename "html/departments/$dep_file.new", "html/departments/$dep_file.html";
 636 }
 637 print $dep_fh qq|</ul>\n|, html_end;
 638 close($dep_fh);
 639 rename 'html/departments/index.new', 'html/departments/index.html';
 640
 641 my $azvo_stat_biblio;
 642
 643 foreach my $department ( sort keys %$department_category_author ) {
 644         foreach my $category ( sort keys %{ $department_category_author->{$department} } ) {
 645                 foreach my $authid ( @{ $department_category_author->{$department}->{$category} } ) {
 646                         my $group = $auth_group->{$authid};
 647                         if ( ! $group ) {
 648                                 push @{ $skip->{no_auth_group} }, $authid;
 649                                 next;
 650                         }
 651                         foreach my $type ( keys %{ $authors->{$authid} } ) {
 652                                 next unless exists $authors->{$authid}->{$type}->{$category};
 653                                 push @{ $azvo_stat_biblio->{ $department }->{ $category }->{ $type }->{$group} },  @{ $authors->{$authid}->{$type}->{$category} };
 654                                 push @{ $azvo_stat_biblio->{ $department }->{ $category }->{ $type }->{''} },  @{ $authors->{$authid}->{$type}->{$category} };
 655                         }
 656                 }
 657                 foreach my $type ( keys %{ $azvo_stat_biblio->{ $department }->{ $category } } ) {
 658                         foreach my $group ( keys %{ $azvo_stat_biblio->{ $department }->{ $category }->{ $type } } ) {
 659                                 my @biblios = unique_biblionumber @{ $azvo_stat_biblio->{ $department }->{ $category }->{ $type }->{ $group } };
 660                                 $azvo_stat_biblio->{ $department }->{ $category }->{ $type }->{ $group } = [ @biblios ];
 661                         }
 662                 }
 663         }
 664 }
 665
 666 debug 'azvo_stat_biblio' => $azvo_stat_biblio;
 667
 668 my @report_lines;
 669 my @report_labels;
 670
 671 my $label;
 672 my $sub_labels;
 673 open(my $report, '<:encoding(utf-8)', 'AZVO.txt');
 674 while( <$report> ) {
 675         chomp;
 676         if ( /^([^\t]+)\t+(.+)/ ) {
 677                 $label = $1;
 678                 push @report_labels, $label;
 679                 my $type = [ map { m/\s+/ ? [ split(/\s+/,$_) ] : [ $_, 'aut' ] } split (/\s*\+\s*/, $2) ];
 680                 push @report_lines, [ $label, @$type ];
 681         } elsif ( /^\t+([^\t]+):\t+(\d+)(\w*)\t*(.*)$/ ) {
 682                 push @{ $sub_labels->{$label} }, [ $1, $2, $3, $4 ];
 683                 my $sub_label = $1;
 684                 pop (@report_labels) if ( $report_labels[ $#report_labels ] =~ m/^$label$/ ); # remove partial name
 685                 push @report_labels, $label . $sub_label;
 686         } else {
 687                 die "ERROR: [$_]\n";
 688         }
 689 }
 690
 691 debug 'report_lines', \@report_lines;
 692 debug 'sub_labels', $sub_labels;
 693 debug 'report_labels', \@report_labels;
 694
 695 my @departments = ( sort { lc($a) cmp lc($b) } keys %$azvo_stat_biblio );
 696
 697 debug 'departments' => \@departments;
 698
 699 my $department2col;
 700 $department2col->{ $departments[$_] } = $_ foreach ( 0 .. $#departments );
 701 my $label2row;
 702 $label2row->{ $report_labels[$_] } = $_ foreach ( 0 .. $#report_labels );
 703
 704 my $table;
 705
 706 sub table_count {
 707         my $label = shift @_;
 708         my $department = shift @_;
 709         my $group = shift @_;
 710         my @biblionumbers = @_;
 711         my $unique;
 712         $unique->{$_}++ foreach @biblionumbers;
 713         my @bibs = keys %$unique;
 714         $table->{ffzg}->{$group}->[ $label2row->{ $label } ]->[ $department2col->{$department} ] = scalar @bibs;
 715         $table->{external}->{$group}->[ $label2row->{ $label } ]->[ $department2col->{$department} ] = scalar grep { $biblio_author_external->{$_} } @bibs;
 716 }
 717
 718 foreach my $group ( '', keys %$azvo_group_title ) {
 719
 720 foreach my $department ( @departments ) {
 721         foreach my $line ( @report_lines ) {
 722                 my $label = $line->[0];
 723                 my @biblionumbers;
 724                 foreach ( 1 .. $#$line ) {
 725                         my ( $category, $type ) = @{ $line->[ $_ ] };
 726                         my $b = $azvo_stat_biblio->{ $department }->{$category}->{$type}->{$group};
 727                         push @biblionumbers, @$b if $b;
 728                 }
 729                 if ( $sub_labels->{$label} ) {
 730                         my $sub_stats;
 731                         foreach my $biblionumber ( @biblionumbers ) {
 732                                 my $data = $biblio_data->{$biblionumber} || die "can't find biblionumber $biblionumber";
 733                                 foreach my $sub_label ( @{ $sub_labels->{$label} } ) {
 734                                         my ( $sub_label, $field, $sf, $regex ) = @$sub_label;
 735                                         if ( ! $regex ) {
 736                                                 push @{ $sub_stats->{ $sub_label } }, $biblionumber;
 737                                                 last;
 738                                         }
 739                                         if ( $field < 100 ) {
 740                                                 if ( $data->{$field} =~ m/$regex/ ) {
 741                                                         push @{ $sub_stats->{ $sub_label } }, $biblionumber;
 742                                                         last;
 743                                                 }
 744                                         } else {
 745                                                 if ( exists $data->{$field}->[0]->{$sf} && $data->{$field}->[0]->{$sf} =~ m/$regex/ ) {
 746                                                         push @{ $sub_stats->{ $sub_label } }, $biblionumber;
 747                                                         last;
 748                                                 }
 749                                         }
 750                                 }
 751                         }
 752                         foreach my $sub_label ( keys %$sub_stats ) {
 753                                 my $full_label = $label . $sub_label;
 754                                 table_count $full_label, $department, $group, @{ $sub_stats->{$sub_label} };
 755                         }
 756                 } else {
 757                         table_count $label, $department, $group, @biblionumbers;
 758                 }
 759         }
 760 }
 761
 762 } # group
 763
 764 debug 'table', $table;
 765
 766 open(my $fh, '>:encoding(utf-8)', 'html/azvo.new');
 767 open(my $fh2, '>:encoding(utf-8)', 'html/azvo2.new');
 768
 769 sub print_fh {
 770         print $fh @_;
 771         print $fh2 @_;
 772 }
 773
 774 print $fh html_title('AZVO tablica - FFZG');
 775 print $fh2 html_title('AZVO tablica - kolaboracija sa FFZG');
 776
 777 foreach my $group ( keys %{ $table->{ffzg} } ) {
 778
 779                 print_fh "<h1>$group</h1>" if $group;
 780
 781                 print_fh "<table border=1>\n";
 782                 print_fh "<tr><th></th>";
 783                 print_fh "<th>$_</th>" foreach @departments;
 784                 print_fh "</tr>\n";
 785
 786                 foreach my $row ( 0 .. $#{ $table->{ffzg}->{$group} } ) {
 787                         print_fh "<tr><th>", $report_labels[$row], "</th>\n";
 788                         foreach ( 0 .. $#departments ) {
 789                                 print_fh "<td>";
 790                                 print $fh $table->{ffzg}->{$group}->[ $row ]->[ $_ ] || '';
 791                                 print $fh2 $table->{external}->{$group}->[ $row ]->[ $_ ] || '';
 792                                 print_fh "</td>\n"
 793                         }
 794                         print_fh "</tr>\n";
 795                 }
 796
 797                 print_fh "</table>\n";
 798
 799 } # group
 800
 801 print_fh html_end;
 802 close($fh);
 803 close($fh2);
 804 rename 'html/azvo.new', 'html/azvo.html';
 805 rename 'html/azvo2.new', 'html/azvo2.html';
 806