lib/BackupPC/Xfer/Rsync.pm

   1 #============================================================= -*-perl-*-
   2 #
   3 # BackupPC::Xfer::Rsync package
   4 #
   5 # DESCRIPTION
   6 #
   7 #   This library defines a BackupPC::Xfer::Rsync class for managing
   8 #   the rsync-based transport of backup data from the client.
   9 #
  10 # AUTHOR
  11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  12 #
  13 # COPYRIGHT
  14 #   Copyright (C) 2002-2003  Craig Barratt
  15 #
  16 #   This program is free software; you can redistribute it and/or modify
  17 #   it under the terms of the GNU General Public License as published by
  18 #   the Free Software Foundation; either version 2 of the License, or
  19 #   (at your option) any later version.
  20 #
  21 #   This program is distributed in the hope that it will be useful,
  22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 #   GNU General Public License for more details.
  25 #
  26 #   You should have received a copy of the GNU General Public License
  27 #   along with this program; if not, write to the Free Software
  28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  29 #
  30 #========================================================================
  31 #
  32 # Version 2.1.0_CVS, released 3 Jul 2003.
  33 #
  34 # See http://backuppc.sourceforge.net.
  35 #
  36 #========================================================================
  37
  38 package BackupPC::Xfer::Rsync;
  39
  40 use strict;
  41 use BackupPC::View;
  42 use BackupPC::Xfer::RsyncFileIO;
  43
  44 use vars qw( $RsyncLibOK $RsyncLibErr );
  45
  46 BEGIN {
  47     eval "use File::RsyncP;";
  48     if ( $@ ) {
  49         #
  50         # Rsync module doesn't exist.
  51         #
  52         $RsyncLibOK = 0;
  53         $RsyncLibErr = "File::RsyncP module doesn't exist";
  54     } else {
  55         if ( $File::RsyncP::VERSION < 0.44 ) {
  56             $RsyncLibOK = 0;
  57             $RsyncLibErr = "File::RsyncP module version too old: need 0.44";
  58         } else {
  59             $RsyncLibOK = 1;
  60         }
  61     }
  62 };
  63
  64 sub new
  65 {
  66     my($class, $bpc, $args) = @_;
  67
  68     return if ( !$RsyncLibOK );
  69     $args ||= {};
  70     my $t = bless {
  71         bpc       => $bpc,
  72         conf      => { $bpc->Conf },
  73         host      => "",
  74         hostIP    => "",
  75         shareName => "",
  76         badFiles  => [],
  77
  78         #
  79         # Various stats
  80         #
  81         byteCnt         => 0,
  82         fileCnt         => 0,
  83         xferErrCnt      => 0,
  84         xferBadShareCnt => 0,
  85         xferBadFileCnt  => 0,
  86         xferOK          => 0,
  87
  88         #
  89         # User's args
  90         #
  91         %$args,
  92     }, $class;
  93
  94     return $t;
  95 }
  96
  97 sub args
  98 {
  99     my($t, $args) = @_;
 100
 101     foreach my $arg ( keys(%$args) ) {
 102         $t->{$arg} = $args->{$arg};
 103     }
 104 }
 105
 106 sub useTar
 107 {
 108     return 0;
 109 }
 110
 111 sub start
 112 {
 113     my($t) = @_;
 114     my $bpc = $t->{bpc};
 115     my $conf = $t->{conf};
 116     my(@fileList, $rsyncClientCmd, $rsyncArgs, $logMsg,
 117        $incrDate, $argList, $fioArgs);
 118
 119     #
 120     # We add a slash to the share name we pass to rsync
 121     #
 122     ($t->{shareNameSlash} = "$t->{shareName}/") =~ s{//+$}{/};
 123
 124     if ( $t->{type} eq "restore" ) {
 125         $rsyncClientCmd = $conf->{RsyncClientRestoreCmd};
 126         $rsyncArgs = $conf->{RsyncRestoreArgs};
 127         my $remoteDir = "$t->{shareName}/$t->{pathHdrDest}";
 128         $remoteDir    =~ s{//+}{/}g;
 129         $argList = ['--server', @$rsyncArgs, '.', $remoteDir];
 130         $fioArgs = {
 131             client   => $t->{bkupSrcHost},
 132             share    => $t->{bkupSrcShare},
 133             viewNum  => $t->{bkupSrcNum},
 134             fileList => $t->{fileList},
 135         };
 136         $logMsg = "restore started below directory $t->{shareName}"
 137                 . " to host $t->{host}";
 138     } else {
 139         #
 140         # Turn $conf->{BackupFilesOnly} and $conf->{BackupFilesExclude}
 141         # into a hash of arrays of files.
 142         #
 143         $conf->{RsyncShareName} = [ $conf->{RsyncShareName} ]
 144                         unless ref($conf->{RsyncShareName}) eq "ARRAY";
 145         foreach my $param qw(BackupFilesOnly BackupFilesExclude) {
 146             next if ( !defined($conf->{$param}) );
 147             if ( ref($conf->{$param}) eq "ARRAY" ) {
 148                 $conf->{$param} = {
 149                         $conf->{RsyncShareName}[0] => $conf->{$param}
 150                 };
 151             } elsif ( ref($conf->{$param}) eq "HASH" ) {
 152                 # do nothing
 153             } else {
 154                 $conf->{$param} = {
 155                         $conf->{RsyncShareName}[0] => [ $conf->{$param} ]
 156                 };
 157             }
 158         }
 159         if ( defined($conf->{BackupFilesOnly}{$t->{shareName}}) ) {
 160             my(@inc, @exc, %incDone, %excDone);
 161             foreach my $file ( @{$conf->{BackupFilesOnly}{$t->{shareName}}} ) {
 162                 #
 163                 # If the user wants to just include /home/craig, then
 164                 # we need to do create include/exclude pairs at
 165                 # each level:
 166                 #     --include /home --exclude /*
 167                 #     --include /home/craig --exclude /home/*
 168                 #
 169                 # It's more complex if the user wants to include multiple
 170                 # deep paths.  For example, if they want /home/craig and
 171                 # /var/log, then we need this mouthfull:
 172                 #     --include /home --include /var --exclude /*
 173                 #     --include /home/craig --exclude /home/*
 174                 #     --include /var/log --exclude /var/*
 175                 #
 176                 # To make this easier we do all the includes first and all
 177                 # of the excludes at the end (hopefully they commute).
 178                 #
 179                 $file =~ s{/$}{};
 180                 $file = "/$file";
 181                 $file =~ s{//+}{/}g;
 182                 if ( $file eq "/" ) {
 183                     #
 184                     # This is a special case: if the user specifies
 185                     # "/" then just include it and don't exclude "/*".
 186                     #
 187                     push(@inc, $file) if ( !$incDone{$file} );
 188                     next;
 189                 }
 190                 my $f = "";
 191                 while ( $file =~ m{^/([^/]*)(.*)} ) {
 192                     my $elt = $1;
 193                     $file = $2;
 194                     if ( $file eq "/" ) {
 195                         #
 196                         # preserve a tailing slash
 197                         #
 198                         $file = "";
 199                         $elt = "$elt/";
 200                     }
 201                     push(@exc, "$f/*") if ( !$excDone{"$f/*"} );
 202                     $excDone{"$f/*"} = 1;
 203                     $f = "$f/$elt";
 204                     push(@inc, $f) if ( !$incDone{$f} );
 205                     $incDone{$f} = 1;
 206                 }
 207             }
 208             foreach my $file ( @inc ) {
 209                 push(@fileList, "--include=$file");
 210             }
 211             foreach my $file ( @exc ) {
 212                 push(@fileList, "--exclude=$file");
 213             }
 214         }
 215         if ( defined($conf->{BackupFilesExclude}{$t->{shareName}}) ) {
 216             foreach my $file ( @{$conf->{BackupFilesExclude}{$t->{shareName}}} )
 217             {
 218                 #
 219                 # just append additional exclude lists onto the end
 220                 #
 221                 push(@fileList, "--exclude=$file");
 222             }
 223         }
 224         if ( $t->{type} eq "full" ) {
 225             $logMsg = "full backup started for directory $t->{shareName}";
 226         } else {
 227             $incrDate = $bpc->timeStamp($t->{lastFull} - 3600, 1);
 228             $logMsg = "incr backup started back to $incrDate for directory"
 229                     . " $t->{shareName}";
 230         }
 231
 232         #
 233         # A full dump is implemented with --ignore-times: this causes all
 234         # files to be checksummed, even if the attributes are the same.
 235         # That way all the file contents are checked, but you get all
 236         # the efficiencies of rsync: only files deltas need to be
 237         # transferred, even though it is a full dump.
 238         #
 239         $rsyncArgs = $conf->{RsyncArgs};
 240         $rsyncArgs = [@$rsyncArgs, @fileList] if ( @fileList );
 241         $rsyncArgs = [@$rsyncArgs, "--ignore-times"]
 242                                     if ( $t->{type} eq "full" );
 243         $rsyncClientCmd = $conf->{RsyncClientCmd};
 244         $argList = ['--server', '--sender', @$rsyncArgs,
 245                               '.', $t->{shareNameSlash}];
 246         $fioArgs = {
 247             client  => $t->{client},
 248             share   => $t->{shareName},
 249             viewNum => $t->{lastFullBkupNum},
 250         };
 251     }
 252
 253     #
 254     # Merge variables into $rsyncClientCmd
 255     #
 256     my $args = {
 257         host      => $t->{host},
 258         hostIP    => $t->{hostIP},
 259         client    => $t->{client},
 260         shareName => $t->{shareName},
 261         shareNameSlash => $t->{shareNameSlash},
 262         rsyncPath => $conf->{RsyncClientPath},
 263         sshPath   => $conf->{SshPath},
 264         argList   => $argList,
 265     };
 266     $rsyncClientCmd = $bpc->cmdVarSubstitute($rsyncClientCmd, $args);
 267
 268     #
 269     # Create the Rsync object, and tell it to use our own File::RsyncP::FileIO
 270     # module, which handles all the special BackupPC file storage
 271     # (compression, mangling, hardlinks, special files, attributes etc).
 272     #
 273     $t->{rsyncClientCmd} = $rsyncClientCmd;
 274     $t->{rs} = File::RsyncP->new({
 275         logLevel     => $conf->{RsyncLogLevel},
 276         rsyncCmd     => sub {
 277                             $bpc->verbose(0);
 278                             $bpc->cmdExecOrEval($rsyncClientCmd, $args);
 279                         },
 280         rsyncCmdType => "full",
 281         rsyncArgs    => $rsyncArgs,
 282         timeout      => $conf->{ClientTimeout},
 283         logHandler   => sub {
 284                             my($str) = @_;
 285                             $str .= "\n";
 286                             $t->{XferLOG}->write(\$str);
 287                         },
 288         pidHandler   => sub {
 289                             $t->{pidHandler}(@_);
 290                         },
 291         fio          => BackupPC::Xfer::RsyncFileIO->new({
 292                             xfer       => $t,
 293                             bpc        => $t->{bpc},
 294                             conf       => $t->{conf},
 295                             backups    => $t->{backups},
 296                             logLevel   => $conf->{RsyncLogLevel},
 297                             logHandler => sub {
 298                                               my($str) = @_;
 299                                               $str .= "\n";
 300                                               $t->{XferLOG}->write(\$str);
 301                                           },
 302                             %$fioArgs,
 303                       }),
 304     });
 305
 306     delete($t->{_errStr});
 307
 308     return $logMsg;
 309 }
 310
 311 sub run
 312 {
 313     my($t) = @_;
 314     my $rs = $t->{rs};
 315     my $conf = $t->{conf};
 316     my($remoteSend, $remoteDir, $remoteDirDaemon);
 317
 318     alarm($conf->{ClientTimeout});
 319     if ( $t->{type} eq "restore" ) {
 320         $remoteSend       = 0;
 321         ($remoteDir       = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 322         ($remoteDirDaemon = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 323         $remoteDirDaemon  = $t->{shareNameSlash}
 324                                 if ( $t->{pathHdrDest} eq ""
 325                                               || $t->{pathHdrDest} eq "/" );
 326     } else {
 327         $remoteSend      = 1;
 328         $remoteDir       = $t->{shareNameSlash};
 329         $remoteDirDaemon = ".";
 330     }
 331     if ( $t->{XferMethod} eq "rsync" ) {
 332         #
 333         # Run rsync command
 334         #
 335         my $str = "Running: "
 336                 . $t->{bpc}->execCmd2ShellCmd(@{$t->{rsyncClientCmd}})
 337                 . "\n";
 338         $t->{XferLOG}->write(\$str);
 339         $rs->remoteStart($remoteSend, $remoteDir);
 340     } else {
 341         #
 342         # Connect to the rsync server
 343         #
 344         if ( defined(my $err = $rs->serverConnect($t->{hostIP},
 345                                              $conf->{RsyncdClientPort})) ) {
 346             $t->{hostError} = $err;
 347             my $str = "Error connecting to rsync daemon at $t->{hostIP}"
 348                     . ":$conf->{RsyncdClientPort}: $err\n";
 349             $t->{XferLOG}->write(\$str);
 350             return;
 351         }
 352         #
 353         # Pass module name, and follow it with a slash if it already
 354         # contains a slash; otherwise just keep the plain module name.
 355         #
 356         my $module = $t->{shareName};
 357         $module = $t->{shareNameSlash} if ( $module =~ /\// );
 358         if ( defined(my $err = $rs->serverService($module,
 359                                              $conf->{RsyncdUserName},
 360                                              $conf->{RsyncdPasswd},
 361                                              $conf->{RsyncdAuthRequired})) ) {
 362             my $str = "Error connecting to module $module at $t->{hostIP}"
 363                     . ":$conf->{RsyncdClientPort}: $err\n";
 364             $t->{XferLOG}->write(\$str);
 365             $t->{hostError} = $err;
 366             return;
 367         }
 368         $rs->serverStart($remoteSend, $remoteDirDaemon);
 369     }
 370     my $error = $rs->go($t->{shareNameSlash});
 371     $rs->serverClose();
 372
 373     #
 374     # TODO: generate sensible stats
 375     #
 376     # $rs->{stats}{totalWritten}
 377     # $rs->{stats}{totalSize}
 378     #
 379     my $stats = $rs->statsFinal;
 380     if ( !defined($error) && defined($stats) ) {
 381         $t->{xferOK} = 1;
 382     } else {
 383         $t->{xferOK} = 0;
 384     }
 385     $t->{xferErrCnt} = $stats->{remoteErrCnt}
 386                      + $stats->{childStats}{errorCnt}
 387                      + $stats->{parentStats}{errorCnt};
 388     $t->{byteCnt}    = $stats->{childStats}{TotalFileSize}
 389                      + $stats->{parentStats}{TotalFileSize};
 390     $t->{fileCnt}    = $stats->{childStats}{TotalFileCnt}
 391                      + $stats->{parentStats}{TotalFileCnt};
 392     my $str = "Done: $t->{fileCnt} files, $t->{byteCnt} bytes\n";
 393     $t->{XferLOG}->write(\$str);
 394     #
 395     # TODO: get error count, and call fio to get stats...
 396     #
 397     $t->{hostError} = $error if ( defined($error) );
 398
 399     if ( $t->{type} eq "restore" ) {
 400         return (
 401             $t->{fileCnt},
 402             $t->{byteCnt},
 403             0,
 404             0
 405         );
 406     } else {
 407         return (
 408             0,
 409             $stats->{childStats}{ExistFileCnt}
 410                 + $stats->{parentStats}{ExistFileCnt},
 411             $stats->{childStats}{ExistFileSize}
 412                 + $stats->{parentStats}{ExistFileSize},
 413             $stats->{childStats}{ExistFileCompSize}
 414                 + $stats->{parentStats}{ExistFileCompSize},
 415             $stats->{childStats}{TotalFileCnt}
 416                 + $stats->{parentStats}{TotalFileCnt},
 417             $stats->{childStats}{TotalFileSize}
 418                 + $stats->{parentStats}{TotalFileSize},
 419         );
 420     }
 421 }
 422
 423 sub setSelectMask
 424 {
 425     my($t, $FDreadRef) = @_;
 426 }
 427
 428 sub errStr
 429 {
 430     my($t) = @_;
 431
 432     return $RsyncLibErr if ( !defined($t) || ref($t) ne "HASH" );
 433     return $t->{_errStr};
 434 }
 435
 436 sub xferPid
 437 {
 438     my($t) = @_;
 439
 440     return ();
 441 }
 442
 443 sub logMsg
 444 {
 445     my($t, $msg) = @_;
 446
 447     push(@{$t->{_logMsg}}, $msg);
 448 }
 449
 450 sub logMsgGet
 451 {
 452     my($t) = @_;
 453
 454     return shift(@{$t->{_logMsg}});
 455 }
 456
 457 #
 458 # Returns a hash ref giving various status information about
 459 # the transfer.
 460 #
 461 sub getStats
 462 {
 463     my($t) = @_;
 464
 465     return { map { $_ => $t->{$_} }
 466             qw(byteCnt fileCnt xferErrCnt xferBadShareCnt xferBadFileCnt
 467                xferOK hostAbort hostError lastOutputLine)
 468     };
 469 }
 470
 471 sub getBadFiles
 472 {
 473     my($t) = @_;
 474
 475     return @{$t->{badFiles}};
 476 }
 477
 478 1;