lib/BackupPC/Xfer/Rsync.pm

   1 #============================================================= -*-perl-*-
   2 #
   3 # BackupPC::Xfer::Rsync package
   4 #
   5 # DESCRIPTION
   6 #
   7 #   This library defines a BackupPC::Xfer::Rsync class for managing
   8 #   the rsync-based transport of backup data from the client.
   9 #
  10 # AUTHOR
  11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  12 #
  13 # COPYRIGHT
  14 #   Copyright (C) 2002-2003  Craig Barratt
  15 #
  16 #   This program is free software; you can redistribute it and/or modify
  17 #   it under the terms of the GNU General Public License as published by
  18 #   the Free Software Foundation; either version 2 of the License, or
  19 #   (at your option) any later version.
  20 #
  21 #   This program is distributed in the hope that it will be useful,
  22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 #   GNU General Public License for more details.
  25 #
  26 #   You should have received a copy of the GNU General Public License
  27 #   along with this program; if not, write to the Free Software
  28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  29 #
  30 #========================================================================
  31 #
  32 # Version 2.1.0_CVS, released 8 Feb 2004.
  33 #
  34 # See http://backuppc.sourceforge.net.
  35 #
  36 #========================================================================
  37
  38 package BackupPC::Xfer::Rsync;
  39
  40 use strict;
  41 use BackupPC::View;
  42 use BackupPC::Xfer::RsyncFileIO;
  43
  44 use vars qw( $RsyncLibOK $RsyncLibErr );
  45
  46 BEGIN {
  47     eval "use File::RsyncP;";
  48     if ( $@ ) {
  49         #
  50         # Rsync module doesn't exist.
  51         #
  52         $RsyncLibOK = 0;
  53         $RsyncLibErr = "File::RsyncP module doesn't exist";
  54     } else {
  55         if ( $File::RsyncP::VERSION < 0.44 ) {
  56             $RsyncLibOK = 0;
  57             $RsyncLibErr = "File::RsyncP module version too old: need 0.44";
  58         } else {
  59             $RsyncLibOK = 1;
  60         }
  61     }
  62 };
  63
  64 sub new
  65 {
  66     my($class, $bpc, $args) = @_;
  67
  68     return if ( !$RsyncLibOK );
  69     $args ||= {};
  70     my $t = bless {
  71         bpc       => $bpc,
  72         conf      => { $bpc->Conf },
  73         host      => "",
  74         hostIP    => "",
  75         shareName => "",
  76         badFiles  => [],
  77
  78         #
  79         # Various stats
  80         #
  81         byteCnt         => 0,
  82         fileCnt         => 0,
  83         xferErrCnt      => 0,
  84         xferBadShareCnt => 0,
  85         xferBadFileCnt  => 0,
  86         xferOK          => 0,
  87
  88         #
  89         # User's args
  90         #
  91         %$args,
  92     }, $class;
  93
  94     return $t;
  95 }
  96
  97 sub args
  98 {
  99     my($t, $args) = @_;
 100
 101     foreach my $arg ( keys(%$args) ) {
 102         $t->{$arg} = $args->{$arg};
 103     }
 104 }
 105
 106 sub useTar
 107 {
 108     return 0;
 109 }
 110
 111 sub start
 112 {
 113     my($t) = @_;
 114     my $bpc = $t->{bpc};
 115     my $conf = $t->{conf};
 116     my(@fileList, $rsyncClientCmd, $rsyncArgs, $logMsg,
 117        $incrDate, $argList, $fioArgs);
 118
 119     #
 120     # We add a slash to the share name we pass to rsync
 121     #
 122     ($t->{shareNameSlash} = "$t->{shareName}/") =~ s{//+$}{/};
 123
 124     if ( $t->{type} eq "restore" ) {
 125         $rsyncClientCmd = $conf->{RsyncClientRestoreCmd};
 126         $rsyncArgs = $conf->{RsyncRestoreArgs};
 127         my $remoteDir = "$t->{shareName}/$t->{pathHdrDest}";
 128         $remoteDir    =~ s{//+}{/}g;
 129         $argList = ['--server', @$rsyncArgs, '.', $remoteDir];
 130         $fioArgs = {
 131             client   => $t->{bkupSrcHost},
 132             share    => $t->{bkupSrcShare},
 133             viewNum  => $t->{bkupSrcNum},
 134             fileList => $t->{fileList},
 135         };
 136         $logMsg = "restore started below directory $t->{shareName}"
 137                 . " to host $t->{host}";
 138     } else {
 139         #
 140         # Turn $conf->{BackupFilesOnly} and $conf->{BackupFilesExclude}
 141         # into a hash of arrays of files.
 142         #
 143         $conf->{RsyncShareName} = [ $conf->{RsyncShareName} ]
 144                         unless ref($conf->{RsyncShareName}) eq "ARRAY";
 145         foreach my $param qw(BackupFilesOnly BackupFilesExclude) {
 146             next if ( !defined($conf->{$param}) );
 147             if ( ref($conf->{$param}) eq "ARRAY" ) {
 148                 $conf->{$param} = {
 149                         $conf->{RsyncShareName}[0] => $conf->{$param}
 150                 };
 151             } elsif ( ref($conf->{$param}) eq "HASH" ) {
 152                 # do nothing
 153             } else {
 154                 $conf->{$param} = {
 155                         $conf->{RsyncShareName}[0] => [ $conf->{$param} ]
 156                 };
 157             }
 158         }
 159         if ( defined($conf->{BackupFilesOnly}{$t->{shareName}}) ) {
 160             my(@inc, @exc, %incDone, %excDone);
 161             foreach my $file ( @{$conf->{BackupFilesOnly}{$t->{shareName}}} ) {
 162                 #
 163                 # If the user wants to just include /home/craig, then
 164                 # we need to do create include/exclude pairs at
 165                 # each level:
 166                 #     --include /home --exclude /*
 167                 #     --include /home/craig --exclude /home/*
 168                 #
 169                 # It's more complex if the user wants to include multiple
 170                 # deep paths.  For example, if they want /home/craig and
 171                 # /var/log, then we need this mouthfull:
 172                 #     --include /home --include /var --exclude /*
 173                 #     --include /home/craig --exclude /home/*
 174                 #     --include /var/log --exclude /var/*
 175                 #
 176                 # To make this easier we do all the includes first and all
 177                 # of the excludes at the end (hopefully they commute).
 178                 #
 179                 $file =~ s{/$}{};
 180                 $file = "/$file";
 181                 $file =~ s{//+}{/}g;
 182                 if ( $file eq "/" ) {
 183                     #
 184                     # This is a special case: if the user specifies
 185                     # "/" then just include it and don't exclude "/*".
 186                     #
 187                     push(@inc, $file) if ( !$incDone{$file} );
 188                     next;
 189                 }
 190                 my $f = "";
 191                 while ( $file =~ m{^/([^/]*)(.*)} ) {
 192                     my $elt = $1;
 193                     $file = $2;
 194                     if ( $file eq "/" ) {
 195                         #
 196                         # preserve a tailing slash
 197                         #
 198                         $file = "";
 199                         $elt = "$elt/";
 200                     }
 201                     push(@exc, "$f/*") if ( !$excDone{"$f/*"} );
 202                     $excDone{"$f/*"} = 1;
 203                     $f = "$f/$elt";
 204                     push(@inc, $f) if ( !$incDone{$f} );
 205                     $incDone{$f} = 1;
 206                 }
 207             }
 208             foreach my $file ( @inc ) {
 209                 push(@fileList, "--include=$file");
 210             }
 211             foreach my $file ( @exc ) {
 212                 push(@fileList, "--exclude=$file");
 213             }
 214         }
 215         if ( defined($conf->{BackupFilesExclude}{$t->{shareName}}) ) {
 216             foreach my $file ( @{$conf->{BackupFilesExclude}{$t->{shareName}}} )
 217             {
 218                 #
 219                 # just append additional exclude lists onto the end
 220                 #
 221                 push(@fileList, "--exclude=$file");
 222             }
 223         }
 224         if ( $t->{type} eq "full" ) {
 225             $logMsg = "full backup started for directory $t->{shareName}";
 226         } else {
 227             $incrDate = $bpc->timeStamp($t->{lastFull} - 3600, 1);
 228             $logMsg = "incr backup started back to $incrDate for directory"
 229                     . " $t->{shareName}";
 230         }
 231
 232         #
 233         # A full dump is implemented with --ignore-times: this causes all
 234         # files to be checksummed, even if the attributes are the same.
 235         # That way all the file contents are checked, but you get all
 236         # the efficiencies of rsync: only files deltas need to be
 237         # transferred, even though it is a full dump.
 238         #
 239         $rsyncArgs = $conf->{RsyncArgs};
 240         $rsyncArgs = [@$rsyncArgs, @fileList] if ( @fileList );
 241         $rsyncArgs = [@$rsyncArgs, "--ignore-times"]
 242                                     if ( $t->{type} eq "full" );
 243         $rsyncClientCmd = $conf->{RsyncClientCmd};
 244         $argList = ['--server', '--sender', @$rsyncArgs,
 245                               '.', $t->{shareNameSlash}];
 246         $fioArgs = {
 247             client     => $t->{client},
 248             share      => $t->{shareName},
 249             viewNum    => $t->{lastFullBkupNum},
 250             partialNum => $t->{partialNum},
 251         };
 252     }
 253
 254     #
 255     # Merge variables into $rsyncClientCmd
 256     #
 257     my $args = {
 258         host      => $t->{host},
 259         hostIP    => $t->{hostIP},
 260         client    => $t->{client},
 261         shareName => $t->{shareName},
 262         shareNameSlash => $t->{shareNameSlash},
 263         rsyncPath => $conf->{RsyncClientPath},
 264         sshPath   => $conf->{SshPath},
 265         argList   => $argList,
 266     };
 267     $rsyncClientCmd = $bpc->cmdVarSubstitute($rsyncClientCmd, $args);
 268
 269     #
 270     # Create the Rsync object, and tell it to use our own File::RsyncP::FileIO
 271     # module, which handles all the special BackupPC file storage
 272     # (compression, mangling, hardlinks, special files, attributes etc).
 273     #
 274     $t->{rsyncClientCmd} = $rsyncClientCmd;
 275     $t->{rs} = File::RsyncP->new({
 276         logLevel     => $conf->{RsyncLogLevel},
 277         rsyncCmd     => sub {
 278                             $bpc->verbose(0);
 279                             $bpc->cmdExecOrEval($rsyncClientCmd, $args);
 280                         },
 281         rsyncCmdType => "full",
 282         rsyncArgs    => $rsyncArgs,
 283         timeout      => $conf->{ClientTimeout},
 284         logHandler   => sub {
 285                             my($str) = @_;
 286                             $str .= "\n";
 287                             $t->{XferLOG}->write(\$str);
 288                         },
 289         pidHandler   => sub {
 290                             $t->{pidHandler}(@_);
 291                         },
 292         fio          => BackupPC::Xfer::RsyncFileIO->new({
 293                             xfer       => $t,
 294                             bpc        => $t->{bpc},
 295                             conf       => $t->{conf},
 296                             backups    => $t->{backups},
 297                             logLevel   => $conf->{RsyncLogLevel},
 298                             logHandler => sub {
 299                                               my($str) = @_;
 300                                               $str .= "\n";
 301                                               $t->{XferLOG}->write(\$str);
 302                                           },
 303                             %$fioArgs,
 304                       }),
 305     });
 306
 307     delete($t->{_errStr});
 308
 309     return $logMsg;
 310 }
 311
 312 sub run
 313 {
 314     my($t) = @_;
 315     my $rs = $t->{rs};
 316     my $conf = $t->{conf};
 317     my($remoteSend, $remoteDir, $remoteDirDaemon);
 318
 319     alarm($conf->{ClientTimeout});
 320     if ( $t->{type} eq "restore" ) {
 321         $remoteSend       = 0;
 322         ($remoteDir       = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 323         ($remoteDirDaemon = "$t->{shareName}/$t->{pathHdrDest}") =~ s{//+}{/}g;
 324         $remoteDirDaemon  = $t->{shareNameSlash}
 325                                 if ( $t->{pathHdrDest} eq ""
 326                                               || $t->{pathHdrDest} eq "/" );
 327     } else {
 328         $remoteSend      = 1;
 329         $remoteDir       = $t->{shareNameSlash};
 330         $remoteDirDaemon = ".";
 331     }
 332     if ( $t->{XferMethod} eq "rsync" ) {
 333         #
 334         # Run rsync command
 335         #
 336         my $str = "Running: "
 337                 . $t->{bpc}->execCmd2ShellCmd(@{$t->{rsyncClientCmd}})
 338                 . "\n";
 339         $t->{XferLOG}->write(\$str);
 340         $rs->remoteStart($remoteSend, $remoteDir);
 341     } else {
 342         #
 343         # Connect to the rsync server
 344         #
 345         if ( defined(my $err = $rs->serverConnect($t->{hostIP},
 346                                              $conf->{RsyncdClientPort})) ) {
 347             $t->{hostError} = $err;
 348             my $str = "Error connecting to rsync daemon at $t->{hostIP}"
 349                     . ":$conf->{RsyncdClientPort}: $err\n";
 350             $t->{XferLOG}->write(\$str);
 351             return;
 352         }
 353         #
 354         # Pass module name, and follow it with a slash if it already
 355         # contains a slash; otherwise just keep the plain module name.
 356         #
 357         my $module = $t->{shareName};
 358         $module = $t->{shareNameSlash} if ( $module =~ /\// );
 359         if ( defined(my $err = $rs->serverService($module,
 360                                              $conf->{RsyncdUserName},
 361                                              $conf->{RsyncdPasswd},
 362                                              $conf->{RsyncdAuthRequired})) ) {
 363             my $str = "Error connecting to module $module at $t->{hostIP}"
 364                     . ":$conf->{RsyncdClientPort}: $err\n";
 365             $t->{XferLOG}->write(\$str);
 366             $t->{hostError} = $err;
 367             return;
 368         }
 369         $rs->serverStart($remoteSend, $remoteDirDaemon);
 370     }
 371     my $error = $rs->go($t->{shareNameSlash});
 372     $rs->serverClose();
 373
 374     #
 375     # TODO: generate sensible stats
 376     #
 377     # $rs->{stats}{totalWritten}
 378     # $rs->{stats}{totalSize}
 379     #
 380     my $stats = $rs->statsFinal;
 381     if ( !defined($error) && defined($stats) ) {
 382         $t->{xferOK} = 1;
 383     } else {
 384         $t->{xferOK} = 0;
 385     }
 386     $t->{xferErrCnt} = $stats->{remoteErrCnt}
 387                      + $stats->{childStats}{errorCnt}
 388                      + $stats->{parentStats}{errorCnt};
 389     $t->{byteCnt}    = $stats->{childStats}{TotalFileSize}
 390                      + $stats->{parentStats}{TotalFileSize};
 391     $t->{fileCnt}    = $stats->{childStats}{TotalFileCnt}
 392                      + $stats->{parentStats}{TotalFileCnt};
 393     my $str = "Done: $t->{fileCnt} files, $t->{byteCnt} bytes\n";
 394     $t->{XferLOG}->write(\$str);
 395     #
 396     # TODO: get error count, and call fio to get stats...
 397     #
 398     $t->{hostError} = $error if ( defined($error) );
 399
 400     if ( $t->{type} eq "restore" ) {
 401         return (
 402             $t->{fileCnt},
 403             $t->{byteCnt},
 404             0,
 405             0
 406         );
 407     } else {
 408         return (
 409             0,
 410             $stats->{childStats}{ExistFileCnt}
 411                 + $stats->{parentStats}{ExistFileCnt},
 412             $stats->{childStats}{ExistFileSize}
 413                 + $stats->{parentStats}{ExistFileSize},
 414             $stats->{childStats}{ExistFileCompSize}
 415                 + $stats->{parentStats}{ExistFileCompSize},
 416             $stats->{childStats}{TotalFileCnt}
 417                 + $stats->{parentStats}{TotalFileCnt},
 418             $stats->{childStats}{TotalFileSize}
 419                 + $stats->{parentStats}{TotalFileSize},
 420         );
 421     }
 422 }
 423
 424 sub setSelectMask
 425 {
 426     my($t, $FDreadRef) = @_;
 427 }
 428
 429 sub errStr
 430 {
 431     my($t) = @_;
 432
 433     return $RsyncLibErr if ( !defined($t) || ref($t) ne "HASH" );
 434     return $t->{_errStr};
 435 }
 436
 437 sub xferPid
 438 {
 439     my($t) = @_;
 440
 441     return ();
 442 }
 443
 444 sub logMsg
 445 {
 446     my($t, $msg) = @_;
 447
 448     push(@{$t->{_logMsg}}, $msg);
 449 }
 450
 451 sub logMsgGet
 452 {
 453     my($t) = @_;
 454
 455     return shift(@{$t->{_logMsg}});
 456 }
 457
 458 #
 459 # Returns a hash ref giving various status information about
 460 # the transfer.
 461 #
 462 sub getStats
 463 {
 464     my($t) = @_;
 465
 466     return { map { $_ => $t->{$_} }
 467             qw(byteCnt fileCnt xferErrCnt xferBadShareCnt xferBadFileCnt
 468                xferOK hostAbort hostError lastOutputLine)
 469     };
 470 }
 471
 472 sub getBadFiles
 473 {
 474     my($t) = @_;
 475
 476     return @{$t->{badFiles}};
 477 }
 478
 479 1;