lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 our $loaded;
  16
  17 sub index {
  18         my $self = shift;
  19
  20         my $path = $self->app->home->rel_dir('data');
  21         die "no data dir $path" unless -d $path;
  22
  23         my @files;
  24         find( sub {
  25                 my $file = $File::Find::name;
  26                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  27                         $file =~ s/$path\/*//;
  28                         push @files, $file;
  29                 } else {
  30                         warn "IGNORE: $file\n";
  31                 }
  32         }, $path);
  33
  34         @files = sort { lc $a cmp lc $b } @files;
  35         my $size;
  36         $size->{$_} = -s "$path/$_" foreach @files;
  37
  38         $self->render(
  39                 files => [ @files ],
  40                 size => $size,
  41                 loaded => $loaded,
  42         );
  43 }
  44
  45 sub _load_path {
  46         my ( $self, $path ) = @_;
  47
  48         return if defined $loaded->{$path}->{data};
  49
  50         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  51         die "$full_path $!" unless -r $full_path;
  52
  53         # we could use Mojo::JSON here, but it's too slow
  54 #       $data = from_json read_file $path;
  55         my $data = read_file $full_path;
  56         warn "# data snippet: ", substr($data,0,200);
  57         my @header;
  58         if ( $path =~ m/\.js/ ) {
  59                 Encode::_utf8_on($data);
  60                 $data = from_json $data;
  61         } elsif ( $path =~ m/\.txt/ ) {
  62                 my @lines = split(/\r?\n/, $data);
  63                 $data = { items => [] };
  64
  65                 my $header_line = shift @lines;
  66                 my $multiline = $header_line =~ s/\^//g;
  67                 @header = split(/\|/, $header_line );
  68                 warn "# header ", dump( @header );
  69                 while ( my $line = shift @lines ) {
  70                         $line =~ s/\^//g;
  71                         chomp $line;
  72                         my @v = split(/\|/, $line);
  73                         while ( @lines && $#v < $#header ) {
  74                                 $line = $lines[0];
  75                                 $line =~ s/\^//g;
  76                                 chomp $line;
  77                                 my @more_v = split(/\|/, $line);
  78                                 if ( $#v + $#more_v > $#header ) {
  79                                         warn "short line: ",dump( @v );
  80                                         last;
  81                                 }
  82                                 shift @lines;
  83                                 $v[ $#v ] .= shift @more_v;
  84                                 push @v, @more_v if @more_v;
  85
  86                                 if ( $#v > $#header ) {
  87                                         die "# splice $#header ", dump( @v );
  88                                         @v = splice @v, 0, $#header;
  89                                 }
  90                         }
  91                         my $item;
  92                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  93                         push @{ $data->{items} }, $item;
  94                 }
  95         } else {
  96                 warn "file format unknown $path";
  97         }
  98
  99         my $stats;
 100
 101         foreach my $e ( @{ $data->{items} } ) {
 102                 foreach my $n ( keys %$e ) {
 103                         $stats->{$n}->{count}++;
 104                         if ( ref $e->{$n} eq 'ARRAY' ) {
 105
 106                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 107
 108                                 foreach my $x ( @{$e->{$n}} ) {
 109                                         $stats->{$n}->{numeric}++
 110                                                 if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 111                                 }
 112
 113                         } else {
 114                                 $stats->{$n}->{numeric}++
 115                                         if $e->{$n} =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 116                         }
 117                 }
 118         }
 119
 120         foreach my $n ( keys %$stats ) {
 121                 next unless defined $stats->{$n}->{array};
 122                 delete $stats->{$n}->{array}
 123                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 124         }
 125
 126         @header =
 127                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 128                 grep { defined $stats->{$_}->{count} } keys %$stats
 129                 unless @header;
 130
 131         warn dump($stats);
 132
 133         $loaded->{ $path } = {
 134                 header => [ @header ],
 135                 stats  => $stats,
 136                 full_path => $full_path,
 137                 size => -s $full_path,
 138                 data => $data,
 139         };
 140
 141 }
 142
 143
 144 sub load {
 145         my $self = shift;
 146
 147         my @paths = $self->param('paths');
 148         warn "# paths ", dump @paths;
 149         $self->_load_path( $_ ) foreach @paths;
 150
 151         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 152         warn "# path $path\n";
 153         $self->session('path' => $path);
 154         $self->_load_path( $path );
 155
 156         $self->session( 'header' => $loaded->{$path}->{header} );
 157         $self->session( 'columns' => $loaded->{$path}->{header} );
 158
 159         $self->session( 'filters' => {} );
 160
 161         $self->redirect_to( '/data/columns' );
 162 }
 163
 164
 165 sub _loaded {
 166         my ( $self, $name ) = @_;
 167         my $path = $self->session('path');
 168         die "$path $name doesn't exist in loaded ",dump( $loaded )
 169                 unless defined $loaded->{$path}->{$name};
 170         return $loaded->{$path}->{$name};
 171 }
 172
 173
 174
 175
 176 sub columns {
 177     my $self = shift;
 178
 179         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 180
 181         my @columns;
 182         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 183
 184         foreach my $c ( @{ $self->session( 'header' ) } ) {
 185                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 186         }
 187
 188     $self->render(
 189                 message => 'Select columns to display',
 190                 stats => $stats,
 191                 columns => \@columns,
 192                 checked => $self->_checked( $self->_perm_array('columns') ),
 193         );
 194 }
 195
 196 sub _perm_array {
 197     my ($self,$name) = @_;
 198
 199         my @array = $self->param($name);
 200
 201         if ( @array ) {
 202                 $self->session($name => [ @array ]);
 203         } elsif ( my $session = $self->session($name) ) {
 204                 if ( ref $session eq 'ARRAY' ) {
 205                         @array = @$session;
 206                 } else {
 207                         die "$name not array ",dump($session);
 208                 }
 209         }
 210         warn "# $name ",dump @array;
 211         return @array;
 212 }
 213
 214 sub _perm_scalar {
 215     my ($self,$name,$default) = @_;
 216
 217         my $scalar = $self->param($name);
 218
 219         if ( defined $scalar ) {
 220                 $self->session($name => $scalar);
 221         } else {
 222                 $scalar = $self->session($name);
 223         }
 224
 225         if ( ! defined $scalar ) {
 226                 $scalar = $default;
 227                 die "no default for $name" unless defined $scalar;
 228                 $self->session($name => $scalar);
 229         }
 230
 231         warn "# $name ",dump $scalar;
 232         return $scalar;
 233 }
 234
 235 sub filter {
 236         my $self = shift;
 237
 238         my $name = $self->param('filter_name') || die "name?";
 239         my @vals = $self->param('filter_vals');
 240
 241         warn "# filter $name vals ",dump(@vals);
 242
 243         my $filters = $self->session('filters');
 244         if ( @vals ) {
 245                 $filters->{$name} = [ @vals ];
 246         } else {
 247                 delete $filters->{$name};
 248         }
 249         $self->session( 'filters' => $filters );
 250
 251         warn "# filters ",dump($self->session('filters'));
 252
 253         $self->session( 'offset' => 0 );
 254
 255         $self->redirect_to('/data/items');
 256 }
 257
 258 sub _filter_item {
 259         my ( $self, $filters, $i ) = @_;
 260         my $pass = 1;
 261         foreach my $n ( keys %$filters ) {
 262                 my @filter_values = @{ $filters->{$n} };
 263                 my $include_missing = grep { /^_missing/ } @filter_values;
 264                 if ( ! exists $i->{$n} ) {
 265                         if ( $include_missing ) {
 266                                 $pass = 1;
 267                                 next;
 268                         } else {
 269                                 $pass = 0;
 270                                 last;
 271                         }
 272                 }
 273                 # and match any of values in element
 274                 my $have_values = 0;
 275                 foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 276                         $have_values ||= 1 if grep { m/^\Q$v\E$/ } @filter_values;
 277                 }
 278                 if ( ! $have_values ) {
 279                         $pass = 0;
 280                         last;
 281                 }
 282         }
 283         return $pass;
 284 }
 285
 286 sub _data_items {
 287         my $self = shift;
 288         my $filters = $self->session('filters');
 289         my $data = $self->_loaded( 'data' );
 290         grep {
 291                 $filters ? $self->_filter_item( $filters, $_ ) : 1;
 292         } @{ $data->{items} };
 293 }
 294
 295 sub items {
 296     my $self = shift;
 297
 298         $self->redirect_to('/data/index') unless defined $loaded->{ $self->session('path') };
 299
 300         my @columns = $self->_perm_array('columns');
 301         $self->redirect_to('/data/columns') unless @columns;
 302         my $order   = $self->_perm_scalar('order', $columns[0]);
 303         my $sort    = $self->_perm_scalar('sort', 'a');
 304         my $offset  = $self->_perm_scalar('offset', 0);
 305         my $limit   = $self->_perm_scalar('limit', 20);
 306         $self->_perm_scalar('show', 'table');
 307
 308         # fix offset when changing limit
 309         $offset = int( $offset / $limit ) * $limit;
 310
 311         # FIXME - multi-level sort
 312         my $numeric = $self->_is_numeric($order);
 313         my $missing = $numeric ? 0 : '';
 314         no warnings qw(numeric);
 315         my @sorted = sort {
 316                 my $v1 = exists $a->{$order} ? join('', @{$a->{$order}}) : $missing;
 317                 my $v2 = exists $b->{$order} ? join('', @{$b->{$order}}) : $missing;
 318                 ($v1,$v2) = ($v2,$v1) if $sort eq 'd';
 319                 $numeric ? $v1 <=> $v2 : $v1 cmp $v2 ;
 320         } $self->_data_items;
 321
 322 #       warn "# sorted ", dump @sorted;
 323
 324         my $rows = $#sorted + 1;
 325
 326         $self->render(
 327                 order => $order,
 328                 offset => $offset,
 329                 limit => $limit,
 330                 sorted => [ splice @sorted, $offset, $limit ],
 331                 columns => [ @columns ],
 332                 rows => $rows,
 333                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 334         );
 335
 336 }
 337
 338
 339 sub order {
 340         my $self = shift;
 341         $self->session('order', $self->param('order'));
 342         $self->session('sort', $self->param('sort'));
 343         $self->redirect_to('/data/items');
 344 }
 345
 346 sub _is_numeric {
 347         my ( $self, $name ) = @_;
 348
 349         my $stats = $self->_loaded( 'stats' );
 350
 351         # sort facet numerically if more >50% elements are numeric
 352         defined $stats->{$name}->{numeric} &&
 353                 $stats->{$name}->{numeric} > $stats->{$name}->{count} / 2;
 354 }
 355
 356 sub facet {
 357         my $self = shift;
 358
 359         if ( my $remove = $self->param('remove') ) {
 360                 my $f = $self->session('filters');
 361                 delete $f->{$remove};
 362                 $self->session( 'filters' => $f );
 363                 $self->redirect_to( '/data/items' );
 364         }
 365
 366         my $facet;
 367         my $name = $self->param('name') || die "no name";
 368
 369         foreach my $i ( $self->_data_items ) {
 370                 if ( ! exists $i->{$name} ) {
 371                         $facet->{ _missing }++;
 372                 } elsif ( ref $i->{$name} eq 'ARRAY' ) {
 373                         $facet->{$_}++ foreach @{ $i->{$name} };
 374                 } else {
 375                         $facet->{ $i->{$name} }++;
 376                 }
 377         }
 378
 379 #       warn "# facet $name ",dump $facet;
 380
 381         my $checked;
 382         if ( my $f = $self->session('filters') ) {
 383                 if ( defined $f->{$name} ) {
 384                         $checked = $self->_checked( @{ $f->{$name} } );
 385                 }
 386         }
 387
 388         my $sort = $self->param('sort') || 'c';
 389
 390         # sort facet numerically if more >50% elements are numeric
 391         my $numeric = $self->_is_numeric($name);
 392
 393         my @facet_names = sort {
 394                 if ( $sort =~ m/a/i ) {
 395                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 396                 } elsif ( $sort =~ m/d/i ) {
 397                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 398                 } elsif ( $sort =~ m/c/i ) {
 399                         $facet->{$b} <=> $facet->{$a};
 400                 } else {
 401                         warn "unknown sort: $sort";
 402                         $a cmp $b;
 403                 }
 404         } keys %$facet;
 405
 406         $self->render( name => $name, facet => $facet, checked => $checked,
 407                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 408         );
 409 }
 410
 411 sub _checked {
 412         my $self = shift;
 413         my $checked;
 414         $checked->{$_}++ foreach @_;
 415         warn "# _checked ",dump($checked);
 416         return $checked;
 417 }
 418
 419 1;