lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 our $loaded;
  16 our $filters;
  17
  18 sub index {
  19         my $self = shift;
  20
  21         my $path = $self->app->home->rel_dir('data');
  22         die "no data dir $path" unless -d $path;
  23
  24         my @files;
  25         find( sub {
  26                 my $file = $File::Find::name;
  27                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  28                         $file =~ s/$path\/*//;
  29                         push @files, $file;
  30                 } else {
  31                         warn "IGNORE: $file\n";
  32                 }
  33         }, $path);
  34
  35         @files = sort { lc $a cmp lc $b } @files;
  36         my $size;
  37         $size->{$_} = -s "$path/$_" foreach @files;
  38
  39         $self->render(
  40                 files => [ @files ],
  41                 size => $size,
  42                 loaded => $loaded,
  43                 filters => $filters,
  44         );
  45 }
  46
  47 sub _load_path {
  48         my ( $self, $path ) = @_;
  49
  50         return if defined $loaded->{$path}->{data};
  51
  52         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  53         die "$full_path $!" unless -r $full_path;
  54
  55         # we could use Mojo::JSON here, but it's too slow
  56 #       $data = from_json read_file $path;
  57         my $data = read_file $full_path;
  58         warn "# data snippet: ", substr($data,0,200);
  59         my @header;
  60         if ( $path =~ m/\.js/ ) {
  61                 Encode::_utf8_on($data);
  62                 $data = from_json $data;
  63         } elsif ( $path =~ m/\.txt/ ) {
  64                 my @lines = split(/\r?\n/, $data);
  65                 $data = { items => [] };
  66
  67                 my $header_line = shift @lines;
  68                 my $multiline = $header_line =~ s/\^//g;
  69                 @header = split(/\|/, $header_line );
  70                 warn "# header ", dump( @header );
  71                 while ( my $line = shift @lines ) {
  72                         $line =~ s/\^//g;
  73                         chomp $line;
  74                         my @v = split(/\|/, $line);
  75                         while ( @lines && $#v < $#header ) {
  76                                 $line = $lines[0];
  77                                 $line =~ s/\^//g;
  78                                 chomp $line;
  79                                 my @more_v = split(/\|/, $line);
  80                                 if ( $#v + $#more_v > $#header ) {
  81                                         warn "short line: ",dump( @v );
  82                                         last;
  83                                 }
  84                                 shift @lines;
  85                                 $v[ $#v ] .= shift @more_v if @more_v;
  86                                 push @v, @more_v if @more_v;
  87
  88                                 if ( $#v > $#header ) {
  89                                         die "# splice $#header ", dump( @v );
  90                                         @v = splice @v, 0, $#header;
  91                                 }
  92                         }
  93                         my $item;
  94                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  95                         push @{ $data->{items} }, $item;
  96                 }
  97         } else {
  98                 warn "file format unknown $path";
  99         }
 100
 101         my $stats;
 102
 103         foreach my $e ( @{ $data->{items} } ) {
 104                 foreach my $n ( keys %$e ) {
 105                         $stats->{$n}->{count}++;
 106                         my @v;
 107                         if ( ref $e->{$n} eq 'ARRAY' ) {
 108                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 109                                 @v = @{ $e->{$n} };
 110                         } else {
 111                                 @v = ( $e->{$n} );
 112                         }
 113
 114                         foreach my $x ( @v ) {
 115                                 $stats->{$n}->{numeric}++
 116                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 117                                 $stats->{$n}->{empty}++
 118                                         if $x =~ m/^\s*$/;
 119                         }
 120
 121                 }
 122         }
 123
 124         foreach my $n ( keys %$stats ) {
 125                 next unless defined $stats->{$n}->{array};
 126                 delete $stats->{$n}->{array}
 127                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 128         }
 129
 130         @header =
 131                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 132                 grep { defined $stats->{$_}->{count} } keys %$stats
 133                 unless @header;
 134
 135         warn dump($stats);
 136
 137         $loaded->{ $path } = {
 138                 header => [ @header ],
 139                 stats  => $stats,
 140                 full_path => $full_path,
 141                 size => -s $full_path,
 142                 data => $data,
 143         };
 144
 145 }
 146
 147
 148 sub load {
 149         my $self = shift;
 150
 151         my @paths = $self->param('paths');
 152         warn "# paths ", dump @paths;
 153         $self->_load_path( $_ ) foreach @paths;
 154
 155         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 156         warn "# path $path\n";
 157         $self->session('path' => $path);
 158         $self->_load_path( $path );
 159
 160         $self->session( 'header' => $loaded->{$path}->{header} );
 161         if ( ! defined $loaded->{$path}->{columns} ) {
 162                 $self->session( 'columns' => $loaded->{$path}->{header} );
 163                 $self->redirect_to( '/data/columns' );
 164         } else {
 165                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 166                 $self->redirect_to( '/data/items' );
 167         }
 168
 169 }
 170
 171
 172 sub _loaded {
 173         my ( $self, $name ) = @_;
 174         my $path = $self->session('path');
 175         die "$path $name doesn't exist in loaded ",dump( $loaded )
 176                 unless defined $loaded->{$path}->{$name};
 177         return $loaded->{$path}->{$name};
 178 }
 179
 180
 181 sub _checked {
 182         my $self = shift;
 183         my $checked;
 184         $checked->{$_}++ foreach @_;
 185 #       warn "# _checked ",dump($checked);
 186         return $checked;
 187 }
 188
 189
 190 sub columns {
 191     my $self = shift;
 192
 193         if ( $self->param('columns') ) {
 194                 $self->_perm_array('columns');
 195                 $self->redirect_to('/data/items');
 196         }
 197
 198         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 199
 200         my @columns;
 201         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 202
 203         foreach my $c ( @{ $self->session( 'header' ) } ) {
 204                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 205         }
 206
 207     $self->render(
 208                 message => 'Select columns to display',
 209                 stats => $stats,
 210                 columns => \@columns,
 211                 checked => $self->_checked( $self->_perm_array('columns') ),
 212         );
 213 }
 214
 215 sub _perm_array {
 216     my ($self,$name) = @_;
 217
 218         my @array = $self->param($name);
 219         my $path  = $self->session('path');
 220
 221         if ( @array ) {
 222                 $self->session($name => [ @array ]);
 223                 $loaded->{$path}->{$name} = [ @array ];
 224         } elsif ( my $session = $self->session($name) ) {
 225                 if ( ref $session eq 'ARRAY' ) {
 226                         @array = @$session;
 227                 } else {
 228                         die "$name not array ",dump($session);
 229                 }
 230         }
 231         warn "# $name ",dump @array;
 232         return @array;
 233 }
 234
 235 sub _perm_scalar {
 236     my ($self,$name,$default) = @_;
 237
 238         my $scalar = $self->param($name);
 239
 240         if ( defined $scalar ) {
 241                 $self->session($name => $scalar);
 242         } else {
 243                 $scalar = $self->session($name);
 244         }
 245
 246         if ( ! defined $scalar ) {
 247                 $scalar = $default;
 248                 die "no default for $name" unless defined $scalar;
 249                 $self->session($name => $scalar);
 250         }
 251
 252         warn "# _perm_scalar $name ",dump $scalar;
 253         return $scalar;
 254 }
 255
 256 sub filter {
 257         my $self = shift;
 258
 259         my $name = $self->param('filter_name') || die "name?";
 260         my @vals = $self->param('filter_vals');
 261
 262 #       warn "# filter $name vals ",dump(@vals);
 263
 264         my $path = $self->session('path');
 265
 266         if ( @vals ) {
 267                 $filters->{$name} = [ @vals ];
 268                 warn "# filter + $name $#vals\n";
 269
 270                 my $filter_hash;
 271                 $filter_hash->{$_}++ foreach @vals;
 272
 273                 warn "# filter_hash ",dump( $filter_hash );
 274
 275                 my $items = $self->_loaded('data')->{items};
 276
 277                 my $include_missing = defined $filter_hash->{_missing};
 278                 my $filtered_items;
 279
 280                 foreach my $i ( 0 .. $#$items ) {
 281
 282                         if ( defined $items->[$i]->{$name} ) {
 283                                 foreach my $v ( @{ $items->[$i]->{$name} } ) {
 284                                         if ( defined $filter_hash->{ $v } ) {
 285                                                 $filtered_items->{$i}++;
 286                                         }
 287                                 }
 288                         } elsif ( $include_missing ) {
 289                                 $filtered_items->{$i}++;
 290                         }
 291                 }
 292
 293                 warn "# filter $name ",dump($filtered_items);
 294
 295                 $loaded->{$path}->{filters}->{$name} = $filtered_items;
 296
 297         } else {
 298                 warn "# filter - $name\n";
 299                 delete $filters->{$name};
 300                 delete $loaded->{$path}->{filters}->{$name};
 301         }
 302
 303         warn "# filters ",dump($filters);
 304
 305         $self->session( 'offset' => 0 );
 306
 307         $self->redirect_to('/data/items');
 308 }
 309
 310
 311 sub _data_items {
 312         my ( $self, $all ) = @_;
 313         my $data = $self->_loaded( 'data' );
 314
 315         return @{ $data->{items} } if $all == 1;
 316
 317         my $filters = $self->_current_filters;
 318         my $filter_value;
 319         foreach my $f ( keys %$filters ) {
 320                 foreach my $n ( @{ $filters->{$f} } ) {
 321                         $filter_value->{$f}->{$n} = 1;
 322                 }
 323         }
 324         my @items = @{ $data->{items} };
 325         @items = grep {
 326                 my $i = $_;
 327                 my $pass = 1;
 328                 foreach my $n ( keys %$filter_value ) {
 329                         if ( ! exists $i->{$n} ) {
 330                                 if ( defined $filter_value->{$n}->{_missing} ) {
 331                                         $pass = 1;
 332                                         next;
 333                                 } else {
 334                                         $pass = 0;
 335                                         last;
 336                                 }
 337                         }
 338                         # and match any of values in element
 339                         my $have_values = 0;
 340                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 341                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 342                         }
 343                         if ( ! $have_values ) {
 344                                 $pass = 0;
 345                                 last;
 346                         }
 347                 }
 348                 $pass;
 349         } @items if $filter_value;
 350         return @items;
 351 }
 352
 353
 354 sub _current_filters {
 355         my $self = shift;
 356         my $current_filters;
 357         $current_filters->{ $_ } = $filters->{ $_ }
 358                 foreach (
 359                         grep { defined $filters->{ $_ } }
 360                         @{ $self->_loaded('header') }
 361                 );
 362         warn "# current_filters ",dump($current_filters);
 363         return $current_filters;
 364 }
 365
 366 sub _data_sorted_by {
 367         my ( $self, $order ) = @_;
 368
 369         my $path = $self->session('path');
 370
 371         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 372                 return $loaded->{$path}->{sorted}->{$order};
 373         }
 374
 375         my $data = $self->_loaded( 'data' );
 376         my $numeric = $self->_is_numeric($order);
 377         my $missing = $numeric ? 0 : '';
 378         no warnings qw(numeric);
 379         my $nr = 0;
 380         my @sorted = map {
 381                 $_->[0]
 382         } sort {
 383                 if ( $numeric ) {
 384                         $a->[1] <=> $b->[1]
 385                 } else {
 386                         $a->[1] cmp $b->[1]
 387                 }
 388         } map {
 389                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 390         } @{ $data->{items} }
 391         ;
 392
 393         warn "sorted $order"; # ,dump( @sorted );
 394
 395         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 396 }
 397
 398
 399 sub items {
 400         my $self = shift;
 401
 402         my $path = $self->session('path');
 403         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 404
 405         my @columns = $self->_perm_array('columns');
 406         $self->redirect_to('/data/columns') unless @columns;
 407         my $order   = $self->_perm_scalar('order', $columns[0]);
 408         my $sort    = $self->_perm_scalar('sort', 'a');
 409         my $offset  = $self->_perm_scalar('offset', 0);
 410         my $limit   = $self->_perm_scalar('limit', 20);
 411         $self->_perm_scalar('show', 'table');
 412
 413         # fix offset when changing limit
 414         $offset = int( $offset / $limit ) * $limit;
 415
 416         my $sorted = $self->_data_sorted_by( $order );
 417
 418         my $path_filters = $loaded->{$path}->{filters};
 419         my @filter_names = keys %$path_filters;
 420
 421         my @filtered;
 422         foreach my $i ( 0 .. $#$sorted ) {
 423                 my $pos = $sort eq 'd' ? $sorted->[$i] : $sorted->[ $#$sorted - $i ];
 424
 425                 my $skip = 0;
 426                 foreach ( @filter_names ) {
 427                         $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 428                 }
 429                 next if $skip;
 430
 431                 push @filtered, $pos;
 432         }
 433
 434         my $sorted_items;
 435         my $data = $self->_loaded('data');
 436         foreach ( $offset .. $offset + $limit ) {
 437                 last unless defined $filtered[$_];
 438                 push @$sorted_items, $data->{items}->[ $filtered[$_] ];
 439         }
 440
 441
 442 #       warn "# sorted ", dump $sorted;
 443
 444         $self->render(
 445                 order => $order,
 446                 offset => $offset,
 447                 limit => $limit,
 448                 sorted => $sorted_items,
 449                 columns => [ @columns ],
 450                 rows => $#filtered + 1,
 451                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 452                 filters => $self->_current_filters,
 453         );
 454
 455 }
 456
 457
 458 sub order {
 459         my $self = shift;
 460         $self->session('order', $self->param('order'));
 461         $self->session('sort', $self->param('sort'));
 462         $self->redirect_to('/data/items');
 463 }
 464
 465 sub _is_numeric {
 466         my ( $self, $name ) = @_;
 467
 468         my $stats = $self->_loaded( 'stats' );
 469
 470         # sort facet numerically if more >50% elements are numeric
 471         my $count = $stats->{$name}->{count};
 472         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 473         defined $stats->{$name}->{numeric} &&
 474                 $stats->{$name}->{numeric} > $count / 2;
 475 }
 476
 477 sub facet {
 478         my $self = shift;
 479
 480         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 481
 482         if ( my $remove = $self->param('remove') ) {
 483                 delete $filters->{$remove};
 484                 $self->redirect_to( '/data/items' );
 485         }
 486
 487         my $facet;
 488         my $name = $self->param('name') || die "no name";
 489
 490         my $all = $self->_perm_scalar('all', 1);
 491
 492         foreach my $i ( $self->_data_items($all) ) {
 493                 if ( ! exists $i->{$name} ) {
 494                         $facet->{ _missing }++;
 495                 } elsif ( ref $i->{$name} eq 'ARRAY' ) {
 496                         $facet->{$_}++ foreach @{ $i->{$name} };
 497                 } else {
 498                         $facet->{ $i->{$name} }++;
 499                 }
 500         }
 501
 502 #       warn "# facet $name ",dump $facet;
 503
 504         my $checked;
 505         my @facet_names =
 506                   $all                      ? keys %$facet
 507                 : defined $filters->{$name} ? @{ $filters->{$name} }
 508                 : keys %$facet;
 509
 510         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 511
 512         my $sort = $self->param('sort') || 'c';
 513
 514         # sort facet numerically if more >50% elements are numeric
 515         my $numeric = $self->_is_numeric($name);
 516
 517         @facet_names = sort {
 518                 if ( $sort =~ m/a/i ) {
 519                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 520                 } elsif ( $sort =~ m/d/i ) {
 521                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 522                 } elsif ( $sort =~ m/c/i ) {
 523                         $facet->{$b} <=> $facet->{$a};
 524                 } else {
 525                         warn "unknown sort: $sort";
 526                         $a cmp $b;
 527                 }
 528         } @facet_names;
 529
 530         $self->render( name => $name, facet => $facet, checked => $checked,
 531                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 532         );
 533 }
 534
 535 sub edit {
 536         my $self = shift;
 537         my $content = $self->param('content');
 538
 539         $self->render(
 540                 content => $content
 541         );
 542 }
 543
 544 1;