lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 sub index {
  16         my $self = shift;
  17
  18         my $path = $self->app->home->rel_dir('data');
  19         die "no data dir $path" unless -d $path;
  20
  21         my @files;
  22         find( sub {
  23                 my $file = $File::Find::name;
  24                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  25                         $file =~ s/$path\/*//;
  26                         push @files, $file;
  27                 } else {
  28                         warn "IGNORE: $file\n";
  29                 }
  30         }, $path);
  31
  32         $self->render( files => [ @files ] );
  33 }
  34
  35 our $data;
  36 our $stats;
  37
  38 sub load {
  39         my $self = shift;
  40
  41         my $path = $self->app->home->rel_file( 'data/' . $self->param('path') );
  42         die "$path $!" unless -r $path;
  43
  44         $self->session('path' => $self->param('path'));
  45
  46         # we could use Mojo::JSON here, but it's too slow
  47 #       $data = from_json read_file $path;
  48         $data = read_file $path;
  49         Encode::_utf8_on($data);
  50         warn "# data snippet: ", substr($data,0,200);
  51         if ( $path =~ m/\.js/ ) {
  52                 $data = from_json $data;
  53         } elsif ( $path =~ m/\.txt/ ) {
  54                 my @lines = split(/\n/, $data);
  55                 $data = { items => [] };
  56
  57                 my @header = split(/\|/, shift @lines);
  58                 warn "# header ", dump( @header );
  59                 $self->session( 'header' => [ @header ] );
  60                 foreach my $line ( @lines ) {
  61                         my @v = split(/\|/, $line);
  62                         my $item;
  63                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  64                         push @{ $data->{items} }, $item;
  65                 }
  66         } else {
  67                 warn "file format unknown $path";
  68         }
  69
  70         $stats = {};
  71
  72         foreach my $e ( @{ $data->{items} } ) {
  73                 foreach my $n ( keys %$e ) {
  74                         $stats->{$n}->{count}++;
  75                         if ( ref $e->{$n} eq 'ARRAY' ) {
  76
  77                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
  78
  79                                 foreach my $x ( @{$e->{$n}} ) {
  80                                         $stats->{$n}->{numeric}++
  81                                                 if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  82                                 }
  83
  84                         } else {
  85                                 $stats->{$n}->{numeric}++
  86                                         if $e->{$n} =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
  87                         }
  88                 }
  89         }
  90
  91         foreach my $n ( keys %$stats ) {
  92                 next unless defined $stats->{$n}->{array};
  93                 delete $stats->{$n}->{array}
  94                         if $stats->{$n}->{array} == $stats->{$n}->{count};
  95         }
  96
  97         $self->session( 'header' => [
  98                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
  99                 grep { defined $stats->{$_}->{count} } keys %$stats
 100         ] ) unless $self->session( 'header' );
 101
 102         warn dump($stats);
 103
 104         $self->redirect_to( '/data/columns' );
 105 }
 106
 107
 108 sub columns {
 109     my $self = shift;
 110
 111         $self->redirect_to( '/data/index' ) unless $self->session('header');
 112
 113         my @columns;
 114         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 115
 116         foreach my $c ( @{ $self->session( 'header' ) } ) {
 117                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 118         }
 119
 120     $self->render(
 121                 message => 'Select columns to display',
 122                 stats => $stats,
 123                 columns => \@columns,
 124                 checked => $self->_checked( $self->_perm_array('columns') ),
 125         );
 126 }
 127
 128 sub _perm_array {
 129     my ($self,$name) = @_;
 130
 131         my @array = $self->param($name);
 132
 133         if ( @array ) {
 134                 $self->session($name => [ @array ]);
 135         } elsif ( my $session = $self->session($name) ) {
 136                 if ( ref $session eq 'ARRAY' ) {
 137                         @array = @$session;
 138                 } else {
 139                         die "$name not array ",dump($session);
 140                 }
 141         }
 142         warn "# $name ",dump @array;
 143         return @array;
 144 }
 145
 146 sub _perm_scalar {
 147     my ($self,$name,$default) = @_;
 148
 149         my $scalar = $self->param($name);
 150
 151         if ( defined $scalar ) {
 152                 $self->session($name => $scalar);
 153         } else {
 154                 $scalar = $self->session($name);
 155         }
 156
 157         if ( ! defined $scalar ) {
 158                 $scalar = $default;
 159                 die "no default for $name" unless defined $scalar;
 160                 $self->session($name => $scalar);
 161         }
 162
 163         warn "# $name ",dump $scalar;
 164         return $scalar;
 165 }
 166
 167 sub filter {
 168         my $self = shift;
 169
 170         my $name = $self->param('filter_name') || die "name?";
 171         my @vals = $self->param('filter_vals');
 172
 173         warn "# filter $name vals ",dump(@vals);
 174
 175         my $filters = $self->session('filters');
 176         if ( @vals ) {
 177                 $filters->{$name} = [ @vals ];
 178         } else {
 179                 delete $filters->{$name};
 180         }
 181         $self->session( 'filters' => $filters );
 182
 183         warn "# filters ",dump($self->session('filters'));
 184
 185         $self->session( 'offset' => 0 );
 186
 187         $self->redirect_to('/data/items');
 188 }
 189
 190 sub _filter_item {
 191         my ( $self, $filters, $i ) = @_;
 192         my $pass = 1;
 193         foreach my $n ( keys %$filters ) {
 194                 my @filter_values = @{ $filters->{$n} };
 195                 my $include_missing = grep { /^_missing/ } @filter_values;
 196                 if ( ! exists $i->{$n} ) {
 197                         if ( $include_missing ) {
 198                                 $pass = 1;
 199                                 next;
 200                         } else {
 201                                 $pass = 0;
 202                                 last;
 203                         }
 204                 }
 205                 # and match any of values in element
 206                 my $have_values = 0;
 207                 foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 208                         $have_values ||= 1 if grep { m/^\Q$v\E$/ } @filter_values;
 209                 }
 210                 if ( ! $have_values ) {
 211                         $pass = 0;
 212                         last;
 213                 }
 214         }
 215         return $pass;
 216 }
 217
 218 sub _data_items {
 219         my $self = shift;
 220         my $filters = $self->session('filters');
 221         grep {
 222                 $filters ? $self->_filter_item( $filters, $_ ) : 1;
 223         } @{ $data->{items} };
 224 }
 225
 226 sub items {
 227     my $self = shift;
 228
 229         $self->redirect_to('/data/index') unless $data->{items};
 230
 231         my @columns = $self->_perm_array('columns');
 232         $self->redirect_to('/data/columns') unless @columns;
 233         my $order   = $self->_perm_scalar('order', $columns[0]);
 234         my $sort    = $self->_perm_scalar('sort', 'a');
 235         my $offset  = $self->_perm_scalar('offset', 0);
 236         my $limit   = $self->_perm_scalar('limit', 20);
 237         $self->_perm_scalar('show', 'table');
 238
 239         # fix offset when changing limit
 240         $offset = int( $offset / $limit ) * $limit;
 241
 242         # FIXME - multi-level sort
 243         my $numeric = $self->_is_numeric($order);
 244         my $missing = $numeric ? 0 : '';
 245         no warnings qw(numeric);
 246         my @sorted = sort {
 247                 my $v1 = exists $a->{$order} ? join('', @{$a->{$order}}) : $missing;
 248                 my $v2 = exists $b->{$order} ? join('', @{$b->{$order}}) : $missing;
 249                 ($v1,$v2) = ($v2,$v1) if $sort eq 'd';
 250                 $numeric ? $v1 <=> $v2 : $v1 cmp $v2 ;
 251         } $self->_data_items;
 252
 253 #       warn "# sorted ", dump @sorted;
 254
 255         my $rows = $#sorted + 1;
 256
 257         $self->render(
 258                 order => $order,
 259                 offset => $offset,
 260                 limit => $limit,
 261                 sorted => [ splice @sorted, $offset, $limit ],
 262                 columns => [ @columns ],
 263                 rows => $rows,
 264                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 265         );
 266
 267 }
 268
 269
 270 sub order {
 271         my $self = shift;
 272         $self->session('order', $self->param('order'));
 273         $self->session('sort', $self->param('sort'));
 274         $self->redirect_to('/data/items');
 275 }
 276
 277 sub _is_numeric {
 278         my ( $self, $name ) = @_;
 279
 280         # sort facet numerically if more >50% elements are numeric
 281         defined $stats->{$name}->{numeric} &&
 282                 $stats->{$name}->{numeric} > $stats->{$name}->{count} / 2;
 283 }
 284
 285 sub facet {
 286         my $self = shift;
 287
 288         if ( my $remove = $self->param('remove') ) {
 289                 my $f = $self->session('filters');
 290                 delete $f->{$remove};
 291                 $self->session( 'filters' => $f );
 292                 $self->redirect_to( '/data/items' );
 293         }
 294
 295         my $facet;
 296         my $name = $self->param('name') || die "no name";
 297
 298         foreach my $i ( $self->_data_items ) {
 299                 if ( ! exists $i->{$name} ) {
 300                         $facet->{ _missing }++;
 301                 } elsif ( ref $i->{$name} eq 'ARRAY' ) {
 302                         $facet->{$_}++ foreach @{ $i->{$name} };
 303                 } else {
 304                         $facet->{ $i->{$name} }++;
 305                 }
 306         }
 307
 308 #       warn "# facet $name ",dump $facet;
 309
 310         my $checked;
 311         if ( my $f = $self->session('filters') ) {
 312                 if ( defined $f->{$name} ) {
 313                         $checked = $self->_checked( @{ $f->{$name} } );
 314                 }
 315         }
 316
 317         my $sort = $self->param('sort') || 'c';
 318
 319         # sort facet numerically if more >50% elements are numeric
 320         my $numeric = $self->_is_numeric($name);
 321
 322         my @facet_names = sort {
 323                 if ( $sort =~ m/a/i ) {
 324                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 325                 } elsif ( $sort =~ m/d/i ) {
 326                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 327                 } elsif ( $sort =~ m/c/i ) {
 328                         $facet->{$b} <=> $facet->{$a};
 329                 } else {
 330                         warn "unknown sort: $sort";
 331                         $a cmp $b;
 332                 }
 333         } keys %$facet;
 334
 335         $self->render( name => $name, facet => $facet, checked => $checked,
 336                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 337         );
 338 }
 339
 340 sub _checked {
 341         my $self = shift;
 342         my $checked;
 343         $checked->{$_}++ foreach @_;
 344         warn "# _checked ",dump($checked);
 345         return $checked;
 346 }
 347
 348 1;