lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use JSON;
  11 use Encode;
  12 use locale;
  13 use File::Find;
  14
  15 our $loaded;
  16 our $filters;
  17
  18 sub index {
  19         my $self = shift;
  20
  21         my $path = $self->app->home->rel_dir('data');
  22         die "no data dir $path" unless -d $path;
  23
  24         my @files;
  25         find( sub {
  26                 my $file = $File::Find::name;
  27                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  28                         $file =~ s/$path\/*//;
  29                         push @files, $file;
  30                 } else {
  31                         warn "IGNORE: $file\n";
  32                 }
  33         }, $path);
  34
  35         @files = sort { lc $a cmp lc $b } @files;
  36         my $size;
  37         $size->{$_} = -s "$path/$_" foreach @files;
  38
  39         $self->render(
  40                 files => [ @files ],
  41                 size => $size,
  42                 loaded => $loaded,
  43                 filters => $filters,
  44         );
  45 }
  46
  47 sub _load_path {
  48         my ( $self, $path ) = @_;
  49
  50         return if defined $loaded->{$path}->{data};
  51
  52         my $full_path = $self->app->home->rel_file( 'data/' . $path );
  53         die "$full_path $!" unless -r $full_path;
  54
  55         # we could use Mojo::JSON here, but it's too slow
  56 #       $data = from_json read_file $path;
  57         my $data = read_file $full_path;
  58         warn "# data snippet: ", substr($data,0,200);
  59         my @header;
  60         if ( $path =~ m/\.js/ ) {
  61                 Encode::_utf8_on($data);
  62                 $data = from_json $data;
  63         } elsif ( $path =~ m/\.txt/ ) {
  64                 my @lines = split(/\r?\n/, $data);
  65                 $data = { items => [] };
  66
  67                 my $header_line = shift @lines;
  68                 my $multiline = $header_line =~ s/\^//g;
  69                 @header = split(/\|/, $header_line );
  70                 warn "# header ", dump( @header );
  71                 while ( my $line = shift @lines ) {
  72                         $line =~ s/\^//g;
  73                         chomp $line;
  74                         my @v = split(/\|/, $line);
  75                         while ( @lines && $#v < $#header ) {
  76                                 $line = $lines[0];
  77                                 $line =~ s/\^//g;
  78                                 chomp $line;
  79                                 my @more_v = split(/\|/, $line);
  80                                 if ( $#v + $#more_v > $#header ) {
  81                                         warn "short line: ",dump( @v );
  82                                         last;
  83                                 }
  84                                 shift @lines;
  85                                 $v[ $#v ] .= shift @more_v if @more_v;
  86                                 push @v, @more_v if @more_v;
  87
  88                                 if ( $#v > $#header ) {
  89                                         die "# splice $#header ", dump( @v );
  90                                         @v = splice @v, 0, $#header;
  91                                 }
  92                         }
  93                         my $item;
  94                         $item->{ $header[$_] || "f_$_" } = [ $v[$_] ] foreach ( 0 .. $#v );
  95                         push @{ $data->{items} }, $item;
  96                 }
  97         } else {
  98                 warn "file format unknown $path";
  99         }
 100
 101         my $stats;
 102
 103         foreach my $e ( @{ $data->{items} } ) {
 104                 foreach my $n ( keys %$e ) {
 105                         $stats->{$n}->{count}++;
 106                         my @v;
 107                         if ( ref $e->{$n} eq 'ARRAY' ) {
 108                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 109                                 @v = @{ $e->{$n} };
 110                         } else {
 111                                 @v = ( $e->{$n} );
 112                         }
 113
 114                         foreach my $x ( @v ) {
 115                                 $stats->{$n}->{numeric}++
 116                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 117                                 $stats->{$n}->{empty}++
 118                                         if $x =~ m/^\s*$/;
 119                         }
 120
 121                 }
 122         }
 123
 124         foreach my $n ( keys %$stats ) {
 125                 next unless defined $stats->{$n}->{array};
 126                 delete $stats->{$n}->{array}
 127                         if $stats->{$n}->{array} == $stats->{$n}->{count};
 128         }
 129
 130         @header =
 131                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 132                 grep { defined $stats->{$_}->{count} } keys %$stats
 133                 unless @header;
 134
 135         warn dump($stats);
 136
 137         $loaded->{ $path } = {
 138                 header => [ @header ],
 139                 stats  => $stats,
 140                 full_path => $full_path,
 141                 size => -s $full_path,
 142                 data => $data,
 143         };
 144
 145 }
 146
 147
 148 sub load {
 149         my $self = shift;
 150
 151         my @paths = $self->param('paths');
 152         warn "# paths ", dump @paths;
 153         $self->_load_path( $_ ) foreach @paths;
 154
 155         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 156         warn "# path $path\n";
 157         $self->session('path' => $path);
 158         $self->_load_path( $path );
 159
 160         $self->session( 'header' => $loaded->{$path}->{header} );
 161         if ( ! defined $loaded->{$path}->{columns} ) {
 162                 $self->session( 'columns' => $loaded->{$path}->{header} );
 163                 $self->redirect_to( '/data/columns' );
 164         } else {
 165                 $self->session( 'columns' => $loaded->{$path}->{columns} );
 166                 $self->redirect_to( '/data/items' );
 167         }
 168
 169 }
 170
 171
 172 sub _loaded {
 173         my ( $self, $name ) = @_;
 174         my $path = $self->session('path');
 175         die "$path $name doesn't exist in loaded ",dump( $loaded )
 176                 unless defined $loaded->{$path}->{$name};
 177         return $loaded->{$path}->{$name};
 178 }
 179
 180
 181 sub _checked {
 182         my $self = shift;
 183         my $checked;
 184         $checked->{$_}++ foreach @_;
 185         warn "# _checked ",dump($checked);
 186         return $checked;
 187 }
 188
 189
 190 sub columns {
 191     my $self = shift;
 192
 193         my $stats = $self->_loaded( 'stats' ); # || $self->redirect_to( '/data/index' );
 194
 195         my @columns;
 196         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 197
 198         foreach my $c ( @{ $self->session( 'header' ) } ) {
 199                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 200         }
 201
 202     $self->render(
 203                 message => 'Select columns to display',
 204                 stats => $stats,
 205                 columns => \@columns,
 206                 checked => $self->_checked( $self->_perm_array('columns') ),
 207         );
 208 }
 209
 210 sub _perm_array {
 211     my ($self,$name) = @_;
 212
 213         my @array = $self->param($name);
 214         my $path  = $self->session('path');
 215
 216         if ( @array ) {
 217                 $self->session($name => [ @array ]);
 218                 $loaded->{$path}->{$name} = [ @array ];
 219         } elsif ( my $session = $self->session($name) ) {
 220                 if ( ref $session eq 'ARRAY' ) {
 221                         @array = @$session;
 222                 } else {
 223                         die "$name not array ",dump($session);
 224                 }
 225         }
 226         warn "# $name ",dump @array;
 227         return @array;
 228 }
 229
 230 sub _perm_scalar {
 231     my ($self,$name,$default) = @_;
 232
 233         my $scalar = $self->param($name);
 234
 235         if ( defined $scalar ) {
 236                 $self->session($name => $scalar);
 237         } else {
 238                 $scalar = $self->session($name);
 239         }
 240
 241         if ( ! defined $scalar ) {
 242                 $scalar = $default;
 243                 die "no default for $name" unless defined $scalar;
 244                 $self->session($name => $scalar);
 245         }
 246
 247         warn "# $name ",dump $scalar;
 248         return $scalar;
 249 }
 250
 251 sub filter {
 252         my $self = shift;
 253
 254         my $name = $self->param('filter_name') || die "name?";
 255         my @vals = $self->param('filter_vals');
 256
 257         warn "# filter $name vals ",dump(@vals);
 258
 259         if ( @vals ) {
 260                 $filters->{$name} = [ @vals ];
 261                 warn "# filter + $name $#vals\n";
 262         } else {
 263                 warn "# filter - $name\n";
 264                 delete $filters->{$name};
 265         }
 266
 267         warn "# filters ",dump($filters);
 268
 269         $self->session( 'offset' => 0 );
 270
 271         $self->redirect_to('/data/items');
 272 }
 273
 274
 275 sub _data_items {
 276         my $self = shift;
 277         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 278         my $data = $self->_loaded( 'data' );
 279
 280         my $filters = $self->_current_filters;
 281         my $filter_value;
 282         foreach my $f ( keys %$filters ) {
 283                 foreach my $n ( @{ $filters->{$f} } ) {
 284                         $filter_value->{$f}->{$n} = 1;
 285                 }
 286         }
 287         my @items = @{ $data->{items} };
 288         @items = grep {
 289                 my $i = $_;
 290                 my $pass = 1;
 291                 foreach my $n ( keys %$filter_value ) {
 292                         if ( ! exists $i->{$n} ) {
 293                                 if ( defined $filter_value->{$n}->{_missing} ) {
 294                                         $pass = 1;
 295                                         next;
 296                                 } else {
 297                                         $pass = 0;
 298                                         last;
 299                                 }
 300                         }
 301                         # and match any of values in element
 302                         my $have_values = 0;
 303                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 304                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 305                         }
 306                         if ( ! $have_values ) {
 307                                 $pass = 0;
 308                                 last;
 309                         }
 310                 }
 311                 $pass;
 312         } @items if $filter_value;
 313         return @items;
 314 }
 315
 316
 317 sub _current_filters {
 318         my $self = shift;
 319         my $current_filters;
 320         $current_filters->{ $_ } = $filters->{ $_ }
 321                 foreach (
 322                         grep { defined $filters->{ $_ } }
 323                         @{ $self->_loaded('header') }
 324                 );
 325         warn "# current_filters ",dump($current_filters);
 326         return $current_filters;
 327 }
 328
 329
 330 sub items {
 331         my $self = shift;
 332
 333         my $path = $self->session('path');
 334         $self->redirect_to('/data/index') unless defined $loaded->{ $path };
 335
 336         my @columns = $self->_perm_array('columns');
 337         $self->redirect_to('/data/columns') unless @columns;
 338         my $order   = $self->_perm_scalar('order', $columns[0]);
 339         my $sort    = $self->_perm_scalar('sort', 'a');
 340         my $offset  = $self->_perm_scalar('offset', 0);
 341         my $limit   = $self->_perm_scalar('limit', 20);
 342         $self->_perm_scalar('show', 'table');
 343
 344         # fix offset when changing limit
 345         $offset = int( $offset / $limit ) * $limit;
 346
 347         # FIXME - multi-level sort
 348         my $numeric = $self->_is_numeric($order);
 349         my $missing = $numeric ? 0 : '';
 350         no warnings qw(numeric);
 351         my @sorted = sort {
 352                 my $v1 = exists $a->{$order} ? join('', @{$a->{$order}}) : $missing;
 353                 my $v2 = exists $b->{$order} ? join('', @{$b->{$order}}) : $missing;
 354                 ($v1,$v2) = ($v2,$v1) if $sort eq 'd';
 355                 $numeric ? $v1 <=> $v2 : $v1 cmp $v2 ;
 356         } $self->_data_items;
 357
 358 #       warn "# sorted ", dump @sorted;
 359
 360         my $rows = $#sorted + 1;
 361
 362         $self->render(
 363                 order => $order,
 364                 offset => $offset,
 365                 limit => $limit,
 366                 sorted => [ splice @sorted, $offset, $limit ],
 367                 columns => [ @columns ],
 368                 rows => $rows,
 369                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 370                 filters => $self->_current_filters,
 371         );
 372
 373 }
 374
 375
 376 sub order {
 377         my $self = shift;
 378         $self->session('order', $self->param('order'));
 379         $self->session('sort', $self->param('sort'));
 380         $self->redirect_to('/data/items');
 381 }
 382
 383 sub _is_numeric {
 384         my ( $self, $name ) = @_;
 385
 386         my $stats = $self->_loaded( 'stats' );
 387
 388         # sort facet numerically if more >50% elements are numeric
 389         my $count = $stats->{$name}->{count};
 390         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 391         defined $stats->{$name}->{numeric} &&
 392                 $stats->{$name}->{numeric} > $count / 2;
 393 }
 394
 395 sub facet {
 396         my $self = shift;
 397
 398         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 399
 400         if ( my $remove = $self->param('remove') ) {
 401                 delete $filters->{$remove};
 402                 $self->redirect_to( '/data/items' );
 403         }
 404
 405         my $facet;
 406         my $name = $self->param('name') || die "no name";
 407
 408         foreach my $i ( $self->_data_items ) {
 409                 if ( ! exists $i->{$name} ) {
 410                         $facet->{ _missing }++;
 411                 } elsif ( ref $i->{$name} eq 'ARRAY' ) {
 412                         $facet->{$_}++ foreach @{ $i->{$name} };
 413                 } else {
 414                         $facet->{ $i->{$name} }++;
 415                 }
 416         }
 417
 418 #       warn "# facet $name ",dump $facet;
 419
 420         my $checked;
 421         if ( defined $filters->{$name} ) {
 422                 $checked = $self->_checked( @{ $filters->{$name} } );
 423         }
 424
 425         my $sort = $self->param('sort') || 'c';
 426
 427         # sort facet numerically if more >50% elements are numeric
 428         my $numeric = $self->_is_numeric($name);
 429
 430         my @facet_names = sort {
 431                 if ( $sort =~ m/a/i ) {
 432                         $numeric ? $a <=> $b : lc $a cmp lc $b;
 433                 } elsif ( $sort =~ m/d/i ) {
 434                         $numeric ? $b <=> $a : lc $b cmp lc $a;
 435                 } elsif ( $sort =~ m/c/i ) {
 436                         $facet->{$b} <=> $facet->{$a};
 437                 } else {
 438                         warn "unknown sort: $sort";
 439                         $a cmp $b;
 440                 }
 441         } keys %$facet;
 442
 443         $self->render( name => $name, facet => $facet, checked => $checked,
 444                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 445         );
 446 }
 447
 448
 449 1;