lib/MojoFacets/Data.pm

   1 package MojoFacets::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'Mojolicious::Controller';
   7
   8 use Data::Dump qw(dump);
   9 use File::Slurp;
  10 use Encode;
  11 use locale;
  12 use File::Find;
  13 use Storable;
  14 use Time::HiRes qw(time);
  15 use File::Path qw(mkpath);
  16
  17 use MojoFacets::Import::File;
  18 use MojoFacets::Import::HTMLTable;
  19
  20 our $loaded;
  21 our $filters;
  22
  23 sub index {
  24         my $self = shift;
  25
  26         my $data_dir = $self->app->home->rel_dir('data');
  27         die "no data dir $data_dir" unless -d $data_dir;
  28
  29         my @files;
  30         my $changes;
  31         find( sub {
  32                 my $file = $File::Find::name;
  33                 if ( -f $file && $file =~ m/\.(js(on)?|txt)$/ ) {
  34                         $file =~ s/$data_dir\/*//;
  35                         push @files, $file;
  36                 } elsif ( -f $file && $file =~ m/([^\/]+)\.changes\/(\d+\.\d+.+)/ ) {
  37                         push @{ $changes->{$1} }, $2
  38                 } elsif ( -d $file && $file =~ m/\.html$/ ) {
  39                         $file =~ s/$data_dir\/*//;
  40                         push @files, $file;
  41                 } else {
  42                         warn "IGNORE: $file\n";
  43                 }
  44         }, $data_dir);
  45
  46         @files = sort { lc $a cmp lc $b } @files;
  47         my $size;
  48         $size->{$_} = -s "$data_dir/$_" foreach @files;
  49
  50         $self->render(
  51                 files => [ @files ],
  52                 size => $size,
  53                 loaded => $loaded,
  54                 filters => $filters,
  55                 dump_path => { map { $_ => $self->_dump_path($_) } @files },
  56                 changes => $changes,
  57         );
  58 }
  59
  60 sub _dump_path {
  61         my ( $self, $name ) = @_;
  62         my $dir = $self->app->home->rel_dir('data');
  63         $name =~ s/^$dir//;
  64         $name =~ s/\/+/_/g;
  65         return '/tmp/mojo_facets.' . $name . '.storable';
  66 }
  67
  68 sub _save {
  69         my ( $self, $path ) = @_;
  70
  71         my $dump_path = $self->_dump_path( $path );
  72         my $first_load = ! -e $dump_path;
  73         warn "save loaded to $dump_path";
  74         my $info = $loaded->{$path};
  75         store $info, $dump_path;
  76
  77         if ( $first_load ) {
  78                 my $mtime = $loaded->{$path}->{mtime};
  79                 utime $mtime, $mtime, $dump_path;
  80                 warn "sync time to $path at $mtime\n";
  81         }
  82
  83         warn $dump_path, ' ', -s $dump_path, " bytes\n";
  84         return $dump_path;
  85 }
  86
  87
  88 sub __stats {
  89
  90         my $stats;
  91
  92         my $nr_items = $#{ $_[0] } + 1;
  93
  94         warn "__stats $nr_items\n";
  95
  96         foreach my $e ( @{ $_[0] } ) {
  97                 foreach my $n ( keys %$e ) {
  98                         $stats->{$n}->{count}++;
  99                         my @v;
 100                         if ( ref $e->{$n} eq 'ARRAY' ) {
 101                                 $stats->{$n}->{array} += $#{ $e->{$n} } + 1;
 102                                 @v = @{ $e->{$n} };
 103                         } else {
 104                                 @v = ( $e->{$n} );
 105                         }
 106
 107                         foreach my $x ( @v ) {
 108                                 $stats->{$n}->{numeric}++
 109                                         if $x =~ m/^[-+]?([0-9]*\.[0-9]+|[0-9]+)$/;
 110                                 $stats->{$n}->{empty}++
 111                                         if length $x == 0; # faster than $x =~ m/^\s*$/;
 112                         }
 113
 114                 }
 115         }
 116
 117         foreach my $n ( keys %$stats ) {
 118                 my $s = $stats->{$n};
 119                 next unless defined $s->{array};
 120                 if ( $s->{array} == $s->{count} ) {
 121                         delete $s->{array};
 122                         if ( $s->{count} == $nr_items ) {
 123                                 warn "check $n for uniqeness\n";
 124                                 my $unique;
 125                                 foreach my $e ( @{ $_[0] } ) {
 126                                         if ( ++$unique->{ $e->{$n}->[0] } == 2 ) {
 127                                                 $unique = 0;
 128                                                 last;
 129                                         }
 130                                 }
 131                                 if ( $unique ) {
 132                                         $stats->{$n}->{unique} = 1;
 133                                         #warn "# $n unique ",dump( $unique );
 134                                 }
 135                         }
 136                 }
 137         }
 138
 139         warn "# __stats ",dump($stats);
 140
 141         return $stats;
 142 }
 143
 144 sub _param_or_session {
 145         $_[0]->param( $_[1] ) || $_[0]->session( $_[1] )
 146 }
 147
 148 sub stats {
 149         my $self = shift;
 150         my $path = $self->_param_or_session('path');
 151         warn "stats $path\n";
 152         delete $loaded->{$path}->{stats};
 153         $self->redirect_to( '/data/columns' );
 154 }
 155
 156
 157 sub _load_path {
 158         my ( $self, $path ) = @_;
 159
 160         my $full_path = $self->app->home->rel_file( 'data/' . $path );
 161         die "$full_path $!" unless -r $full_path;
 162
 163         my $dump_path = $self->_dump_path( $path );
 164
 165         if ( defined $loaded->{$path}->{data} ) {
 166                 my $mtime = (stat($full_path))[9];
 167                 return if $loaded->{$path}->{mtime} == $mtime;
 168                 warn "reload $full_path, modified ", time() - $mtime, " seconds ago\n";
 169         } elsif ( -e $dump_path ) {
 170                 warn "dump_path $dump_path ", -s $dump_path, " bytes loading...\n";
 171                 my $info = retrieve $dump_path;
 172                 $loaded->{ $path } = $info;
 173                 return;
 174         }
 175
 176         my $data;
 177         if ( -f $full_path ) {
 178                 $data = MojoFacets::Import::File->new( full_path => $full_path, path => $path )->data;
 179         } elsif ( -d $full_path && $full_path =~ m/.html/ ) {
 180                 $data = MojoFacets::Import::HTMLTable->new( dir => $full_path )->data;
 181         } else {
 182                 die "can't load $full_path";
 183         }
 184
 185         my @header;
 186
 187         if ( defined $data->{header} ) {
 188                 if ( ref $data->{header} eq 'ARRAY' ) {
 189                         @header = @{ $data->{header} };
 190                 } else {
 191                         warn "header not array ", dump( $data->{header} );
 192                 }
 193         }
 194
 195         my $stats = __stats( $data->{items} );
 196
 197         @header =
 198                 sort { $stats->{$b}->{count} <=> $stats->{$a}->{count} }
 199                 grep { defined $stats->{$_}->{count} } keys %$stats
 200                 unless @header;
 201
 202         my $info = {
 203                 header => [ @header ],
 204                 stats  => $stats,
 205                 full_path => $full_path,
 206                 size => -s $full_path,
 207                 mtime => (stat($full_path))[9],
 208                 data => $data,
 209         };
 210
 211         $loaded->{ $path } = $info;
 212         $self->_save( $path );
 213
 214 }
 215
 216
 217 sub load {
 218         my $self = shift;
 219
 220         my @paths = $self->param('paths');
 221         warn "# paths ", dump @paths;
 222         $self->_load_path( $_ ) foreach @paths;
 223
 224         my $path = $self->param('path') || $self->redirect_to( '/data/index' );
 225         warn "# path $path\n";
 226         $self->_load_path( $path );
 227
 228         $self->session( 'path' => $path );
 229
 230         my $redirect_to = '/data/items';
 231
 232         $self->session( 'header' => $loaded->{$path}->{header} );
 233         if ( ! defined $loaded->{$path}->{columns} ) {
 234                 my $columns_path = $self->_permanent_path( 'columns' );
 235                 if ( -e $columns_path ) {
 236                         my @columns = map { s/[\r\n]+$//; $_ } read_file $columns_path;
 237                         $loaded->{$path}->{columns} = [ @columns ];
 238                         warn "# columns_path $columns_path ",dump(@columns);
 239                 } else {
 240                         $loaded->{$path}->{columns} = $loaded->{$path}->{header}
 241                 }
 242
 243                 $redirect_to = '/data/columns';
 244         }
 245         $self->session( 'columns' => $loaded->{$path}->{columns} );
 246         $self->session( 'order'   => $loaded->{$path}->{columns}->[0] );
 247         $self->redirect_to( $redirect_to );
 248 }
 249
 250
 251 sub _loaded {
 252         my ( $self, $name ) = @_;
 253         my $path = $self->session('path') || $self->param('path');
 254         $self->redirect_to('/data/index') unless $path;
 255
 256         if ( defined $loaded->{$path}->{modified} && $loaded->{$path}->{modified} > 1 ) {
 257                 my $caller = (caller(1))[3];
 258                 if ( $caller =~ m/::edit/ ) {
 259                         warn "rebuild stats for $path ignored caller $caller\n";
 260                 } else {
 261                         warn "rebuild stats for $path FORCED by modified caller $caller\n";
 262                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 263                         $loaded->{$path}->{modified} = 1;
 264                 }
 265         }
 266
 267         if ( ! defined $loaded->{$path}->{$name} ) {
 268                 warn "$path $name isn't loaded\n";
 269                 $self->_load_path( $path );
 270                 if ( ! defined $loaded->{$path}->{stats} ) {
 271                         warn "rebuild stats for $path\n";
 272                         $loaded->{$path}->{stats} = __stats( $loaded->{$path}->{data}->{items} );
 273                 }
 274                 if ( ! defined $loaded->{$path}->{$name} ) {
 275                         warn "MISSING $name for $path\n";
 276                         $self->redirect_to('/data/index')
 277                 }
 278         }
 279
 280         $self->session( 'modified' => $loaded->{$path}->{modified} );
 281
 282         return $loaded->{$path}->{$name};
 283 }
 284
 285
 286 sub _checked {
 287         my $self = shift;
 288         my $checked;
 289         $checked->{$_}++ foreach @_;
 290 #       warn "# _checked ",dump($checked);
 291         return $checked;
 292 }
 293
 294 sub _permanent_path {
 295         my $self = shift;
 296         my $path = $self->_param_or_session('path');
 297         $self->app->home->rel_dir('data') . '/' . join('.', $path, @_);
 298 }
 299
 300 sub _export_path {
 301         my $self = shift;
 302         my $path = $self->_param_or_session('path');
 303         if ( ! $path ) {
 304                 warn "no path in param or session";
 305                 return;
 306         }
 307         my $dir = $self->app->home->rel_dir('public') . "/export/$path";
 308         mkpath $dir unless -e $dir;
 309         $dir . '/' . join('.', @_);
 310 }
 311
 312 sub columns {
 313     my $self = shift;
 314
 315         if ( $self->param('columns') ) {
 316                 my @columns = $self->_param_array('columns');
 317                 write_file( $self->_permanent_path( 'columns' ), map { "$_\n" } @columns );
 318                 $self->redirect_to('/data/items');
 319         }
 320
 321         my $stats = $self->_loaded( 'stats' );
 322
 323         my @columns;
 324         @columns = grep { defined $stats->{$_}->{count} } @{ $self->session('columns') } if $self->session('columns');
 325
 326         foreach my $c ( @{ $self->session( 'header' ) } ) {
 327                 push @columns, $c unless grep { /^\Q$c\E$/ } @columns;
 328         }
 329
 330     $self->render(
 331                 message => 'Select columns to display',
 332                 stats => $stats,
 333                 columns => \@columns,
 334                 checked => $self->_checked( $self->_param_array('columns') ),
 335         );
 336 }
 337
 338 sub _param_array {
 339     my ($self,$name) = @_;
 340
 341         my @array = $self->param($name);
 342         my $path  = $self->session('path');
 343
 344         if ( @array ) {
 345                 $self->session($name => [ @array ]);
 346                 $loaded->{$path}->{$name} = [ @array ];
 347         } elsif ( my $session = $self->session($name) ) {
 348                 if ( ref $session eq 'ARRAY' ) {
 349                         @array = @$session;
 350                 } else {
 351                         die "$name not array ",dump($session);
 352                 }
 353         }
 354         #warn "# $name ",dump @array;
 355         return @array;
 356 }
 357
 358 sub _param_scalar {
 359     my ($self,$name,$default) = @_;
 360
 361         my $scalar = $self->param($name);
 362
 363         if ( defined $scalar ) {
 364                 $self->session($name => $scalar);
 365         } else {
 366                 $scalar = $self->session($name);
 367         }
 368
 369         if ( ! defined $scalar ) {
 370                 $scalar = $default;
 371                 die "no default for $name" unless defined $scalar;
 372                 $self->session($name => $scalar);
 373         }
 374
 375         warn "# _param_scalar $name ",dump $scalar;
 376         return $scalar;
 377 }
 378
 379 sub filter {
 380         my $self = shift;
 381
 382         my $name = $self->param('filter_name') || die "name?";
 383         my @vals = $self->param('filter_vals');
 384
 385         $self->_remove_filter( $name );
 386         if ( @vals ) {
 387                 $self->_filter_on_data( $name, @vals );
 388                 if ( my $permanent = $self->param('_permanent') ) {
 389                         my $permanent_path = $self->_export_path( 'filter', $name, $permanent );
 390                         write_file $permanent_path, map { "$_\n" } @vals;
 391                         warn "permanent filter $permanent_path ", -s $permanent_path;
 392                 }
 393         }
 394
 395         $self->session( 'offset' => 0 );
 396
 397         $self->redirect_to('/data/items');
 398 }
 399
 400 sub _filter_on_data {
 401         my ( $self, $name, @vals ) = @_;
 402
 403         my $path = $self->session('path');
 404
 405         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 406                 warn "filter $name not found in data set";
 407                 return;
 408         }
 409
 410         $filters->{$name} = [ @vals ];
 411         warn "_filter_on_data $name ", $#vals + 1, " values on $path\n";
 412
 413         my $filter_hash;
 414         $filter_hash->{$_}++ foreach @vals;
 415
 416         #warn "# filter_hash ",dump( $filter_hash );
 417
 418         my $items = $self->_loaded('data')->{items};
 419
 420         my $include_missing = defined $filter_hash->{_missing};
 421         my $filtered_items;
 422
 423         foreach my $i ( 0 .. $#$items ) {
 424
 425                 if ( defined $items->[$i]->{$name} ) {
 426                         foreach my $v ( @{ $items->[$i]->{$name} } ) {
 427                                 if ( defined $filter_hash->{ $v } ) {
 428                                         $filtered_items->{$i}++;
 429                                 }
 430                         }
 431                 } elsif ( $include_missing ) {
 432                         $filtered_items->{$i}++;
 433                 }
 434         }
 435
 436         #warn "# filter $name ",dump($filtered_items);
 437
 438         $loaded->{$path}->{filters}->{$name} = $filtered_items;
 439         warn "filter $name with ", scalar keys %$filtered_items, " items created\n";
 440 }
 441
 442 sub _data_items {
 443         my ( $self, $all ) = @_;
 444         my $data = $self->_loaded( 'data' );
 445
 446         return @{ $data->{items} } if $all == 1;
 447
 448         my $filters = $self->_current_filters;
 449         my $filter_value;
 450         foreach my $f ( keys %$filters ) {
 451                 foreach my $n ( @{ $filters->{$f} } ) {
 452                         $filter_value->{$f}->{$n} = 1;
 453                 }
 454         }
 455         my @items = @{ $data->{items} };
 456         @items = grep {
 457                 my $i = $_;
 458                 my $pass = 1;
 459                 foreach my $n ( keys %$filter_value ) {
 460                         if ( ! exists $i->{$n} ) {
 461                                 if ( defined $filter_value->{$n}->{_missing} ) {
 462                                         $pass = 1;
 463                                         next;
 464                                 } else {
 465                                         $pass = 0;
 466                                         last;
 467                                 }
 468                         }
 469                         # and match any of values in element
 470                         my $have_values = 0;
 471                         foreach my $v ( @{ $i->{$n} } ) { # FIXME not array?
 472                                 $have_values ||= 1 if defined $filter_value->{$n}->{$v};
 473                         }
 474                         if ( ! $have_values ) {
 475                                 $pass = 0;
 476                                 last;
 477                         }
 478                 }
 479                 $pass;
 480         } @items if $filter_value;
 481         return @items;
 482 }
 483
 484
 485 sub _current_filters {
 486         my $self = shift;
 487         my $current_filters;
 488         $current_filters->{ $_ } = $filters->{ $_ }
 489                 foreach (
 490                         grep { defined $filters->{ $_ } }
 491                         @{ $self->_loaded('header') }
 492                 );
 493         #warn "# current_filters ",dump($current_filters);
 494         return $current_filters;
 495 }
 496
 497 sub _data_sorted_by {
 498         my ( $self, $order ) = @_;
 499
 500         my $path = $self->session('path');
 501
 502         warn "_data_sorted_by $order from $path";
 503
 504         if ( defined $loaded->{$path}->{sorted}->{$order} ) {
 505                 return $loaded->{$path}->{sorted}->{$order};
 506         }
 507
 508         my $data = $self->_loaded( 'data' );
 509         my $numeric = $self->_is_numeric($order);
 510         my $missing = $numeric ? 0 : '';
 511         no warnings qw(numeric);
 512         my $nr = 0;
 513         my @sorted = map {
 514                 $_->[0]
 515         } sort {
 516                 if ( $numeric ) {
 517                         $a->[1] <=> $b->[1]
 518                 } else {
 519                         $a->[1] cmp $b->[1]
 520                 }
 521         } map {
 522                 [ $nr++, exists $_->{$order} ? join('', @{$_->{$order}}) : $missing ]
 523         } grep { ref $_->{$order} eq 'ARRAY' } @{ $data->{items} }
 524         ;
 525
 526         warn "sorted: $order numeric: $numeric items: ", $#sorted + 1, "\n";
 527         #warn "# sorted ",dump( @sorted );
 528
 529         $loaded->{$path}->{sorted}->{$order} = [ @sorted ];
 530 }
 531
 532
 533 sub items {
 534         my $self = shift;
 535
 536         if ( my $show = $self->param('id') ) {
 537                 $self->param('show', $show);
 538                 warn "show $show\n";
 539         }
 540
 541         my $path = $self->session('path');
 542
 543         my @columns = $self->_param_array('columns');
 544         $self->redirect_to('/data/columns') unless @columns;
 545         my $order   = $self->_param_scalar('order', $columns[0]);
 546         my $sort    = $self->_param_scalar('sort', 'a');
 547         my $offset  = $self->_param_scalar('offset', 0);
 548         my $limit   = $self->_param_scalar('limit', 20);
 549         $self->_param_scalar('show', 'table');
 550
 551         # fix offset when changing limit
 552         $offset = int( $offset / $limit ) * $limit;
 553
 554         my $sorted = $self->_data_sorted_by( $order );
 555
 556         my @filter_names;
 557         if ( $filters ) {
 558                 foreach my $name ( keys %$filters ) {
 559                         if ( ! defined $loaded->{$path}->{stats}->{ $name } ) {
 560                                 warn "skip filter $name not found in $path\n";
 561                                 next;
 562                         }
 563                         push @filter_names, $name;
 564                 }
 565                 warn "filter_names ",dump( @filter_names );
 566                 foreach my $name ( @filter_names ) {
 567                         next if ref $loaded->{$path}->{filters}->{$name} eq 'ARRAY';
 568                         $self->_filter_on_data( $name, @{ $filters->{$name} } );
 569                 }
 570         }
 571
 572         my $all_filters = join(' ',sort @filter_names,'order:',$order);
 573
 574 #       warn "# all_filters $all_filters ", dump( $loaded->{$path}->{filtered}->{$all_filters} );
 575
 576         if ( ! defined $loaded->{$path}->{filtered}->{$all_filters} ) {
 577
 578                 my $path_filters = $loaded->{$path}->{filters};
 579
 580                 warn "create combined filter for $all_filters\n";
 581
 582                 my @filtered;
 583                 foreach my $i ( 0 .. $#$sorted ) {
 584                         my $pos = $sorted->[$i];
 585
 586                         if ( $#filter_names == -1 ) {
 587                                 push @filtered, $pos;
 588                                 next;
 589                         }
 590
 591                         my $skip = 0;
 592                         foreach ( @filter_names ) {
 593                                 $skip ||= 1 if ! defined $path_filters->{$_}->{$pos};
 594                         }
 595                         next if $skip;
 596
 597                         push @filtered, $pos;
 598                 }
 599
 600                 $loaded->{$path}->{filtered}->{$all_filters} = [ @filtered ];
 601         }
 602
 603         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 604                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 605
 606         warn "all_filters $all_filters produced ", $#$filtered + 1, " items\n" if $filtered;
 607
 608         my $data = $self->_loaded('data');
 609
 610         my $code = $self->_param_scalar('code','');
 611         $code =~ s{\n+$}{}s;
 612
 613         my $commit = $self->param('commit');
 614         my $test = $self->param('test');
 615
 616         if ( $code && ( $test || $commit ) ) {
 617                 # XXX find columns used in code snippet and show them to user
 618                 foreach my $column ( $code =~ m/\$rec->{(.+?)}/g ) {
 619                         if ( $column =~ s/^(['"])// ) {
 620                                 $column =~ s/$1$//;
 621                         }
 622                         next if grep { /$column/ } @columns;
 623                         unshift @columns, $column;
 624                         if ( $commit ) {
 625                                 $self->session('columns', [ @columns ]);
 626                                 $loaded->{$path}->{columns} = [ @columns ];
 627                         }
 628                 }
 629         }
 630
 631         if ( $commit ) {
 632                 warn "# commit on ", $#$filtered + 1, " items:\n$code\n";
 633                 foreach ( 0 .. $#$filtered ) {
 634                         my $i = $filtered->[$_];
 635                         my $rec = $data->{items}->[$i];
 636                         eval $code;
 637                 }
 638         }
 639
 640         my $sorted_items;
 641         my $from_end = $sort eq 'd' ? $#$filtered : 0;
 642         foreach ( 0 .. $limit ) {
 643                 my $i = $_ + $offset;
 644                 last unless defined $filtered->[$i];
 645                 $i = $from_end - $i if $from_end;
 646                 my $id = $filtered->[$i];
 647                 my $rec = $data->{items}->[ $id ];
 648                 $rec->{_row_id} ||= $id;
 649                 if ( $code && $test ) {
 650                         $rec = Storable::dclone $rec;
 651                         eval $code;
 652                         if ( $@ ) {
 653                                 warn "ERROR evaling\n$code\n$@";
 654                                 $self->stash('eval_error', $@) if $@;
 655                         } else {
 656                                 warn "EVAL ",dump($rec);
 657                         }
 658                 }
 659                 push @$sorted_items, $rec;
 660         }
 661
 662         warn "# sorted_items ", $#$sorted_items + 1, " offset $offset limit $limit order $sort";
 663
 664         $self->render(
 665                 order => $order,
 666                 offset => $offset,
 667                 limit => $limit,
 668                 sorted => $sorted_items,
 669                 columns => [ @columns ],
 670                 rows => $#$filtered + 1,
 671                 numeric => { map { $_, $self->_is_numeric($_) } @columns },
 672                 filters => $self->_current_filters,
 673                 code => $code,
 674         );
 675
 676 }
 677
 678
 679 sub order {
 680         my $self = shift;
 681         $self->session('order', $self->param('order'));
 682         $self->session('sort', $self->param('sort'));
 683         $self->redirect_to('/data/items');
 684 }
 685
 686 sub _is_numeric {
 687         my ( $self, $name ) = @_;
 688
 689         my $stats = $self->_loaded( 'stats' );
 690
 691         # sort facet numerically if more >50% elements are numeric
 692         my $count = $stats->{$name}->{count};
 693         $count   -= $stats->{$name}->{empty} if defined $stats->{$name}->{empty};
 694         defined $stats->{$name}->{numeric} &&
 695                 $stats->{$name}->{numeric} > $count / 2;
 696 }
 697
 698 sub _remove_filter {
 699         my ($self,$name) = @_;
 700         warn "_remove_filter $name\n";
 701
 702         my $path = $self->session('path');
 703
 704         delete $filters->{$name};
 705         delete $loaded->{$path}->{filters}->{$name};
 706         warn "filters left: ", keys %{ $loaded->{$path}->{filters} };
 707
 708         foreach (
 709                         grep { /\b$name\b/ }
 710                         keys %{ $loaded->{$path}->{filtered} }
 711         ) {
 712                 delete $loaded->{$path}->{filtered}->{$_};
 713                 warn "remove filtered cache $_";
 714         }
 715 }
 716
 717 sub facet {
 718         my $self = shift;
 719
 720         my $path = $self->session('path') || $self->redirect_to( '/data/index' );
 721
 722         if ( my $name = $self->param('remove') ) {
 723                 $self->_remove_filter( $name );
 724                 $self->redirect_to( '/data/items' );
 725         }
 726
 727         my $facet;
 728         my $name = $self->param('name') || die "no name";
 729
 730         my $all = $self->_param_scalar('all', 1);
 731         my $data = $self->_loaded('data');
 732
 733         my $filters = $self->_current_filters;
 734         my $all_filters = join(' ',sort keys %$filters,'order:',$self->session('order'));
 735         my $filtered = $loaded->{$path}->{filtered}->{$all_filters}
 736                 if defined $loaded->{$path}->{filtered}->{$all_filters};
 737
 738         if ( ! $filtered || $all ) {
 739                 $filtered = [ 0 .. $#{ $data->{items} } ];
 740                 warn "filter all values\n";
 741         } else {
 742                 warn "filter using $all_filters\n";
 743         }
 744
 745         foreach my $i ( @$filtered ) {
 746                 my $item = $data->{items}->[$i];
 747                 if ( ! exists $item->{$name} ) {
 748                         $facet->{ _missing }++;
 749                 } elsif ( ref $item->{$name} eq 'ARRAY' ) {
 750                         $facet->{$_}++ foreach @{ $item->{$name} };
 751                 } else {
 752                         $facet->{ $item->{$name} }++;
 753                 }
 754         }
 755
 756 #       warn "# facet $name ",dump $facet;
 757
 758         my $checked;
 759         my @facet_names =
 760                   $all                      ? keys %$facet
 761                 : defined $filters->{$name} ? @{ $filters->{$name} }
 762                 : keys %$facet;
 763
 764         $checked = $self->_checked( @{ $filters->{$name} } ) if defined $filters->{$name};
 765
 766         my $numeric = $self->_is_numeric($name);
 767
 768         my $sort = $self->param('sort');
 769         # sort numeric facets with more than 5 values ascending
 770         $sort ||= $numeric && $#facet_names > 4 ? 'a' : 'c';
 771
 772         @facet_names = sort {
 773                 my $result;
 774                 if ( $sort eq 'a' ) {
 775                         $result = $numeric ? $a <=> $b : lc $a cmp lc $b;
 776                 } elsif ( $sort eq 'd' ) {
 777                         $result = $numeric ? $b <=> $a : lc $b cmp lc $a;
 778                 } elsif ( $sort eq 'c' ) {
 779                         $result = ( $facet->{$b} || -1 ) <=> ( $facet->{$a} || -1 )
 780                 } else {
 781                         warn "unknown sort: $sort";
 782                         $result = $a cmp $b;
 783                 }
 784                 $result = $a cmp $b unless defined $result; # FIXME cludge for numeric facets with invalid data
 785                 $result;
 786         } @facet_names;
 787
 788         $self->render( name => $name, facet => $facet, checked => $checked,
 789                 facet_names => \@facet_names, sort => $sort, numeric => $numeric,
 790         );
 791 }
 792
 793
 794 sub __invalidate_path_column {
 795         my ( $path, $name ) = @_;
 796
 797         if ( defined $loaded->{$path}->{sorted}->{$name} ) {
 798                 delete $loaded->{$path}->{sorted}->{$name};
 799                 warn "# invalidate $path sorted $name\n";
 800         }
 801
 802         foreach ( grep { m/$name/ } keys %{ $loaded->{$path}->{filtered} } ) {
 803                 delete $loaded->{$path}->{filtered}->{$_};
 804                 warn "# invalidate $path filtered $_\n";
 805         }
 806 }
 807
 808 sub __path_modified {
 809         my ( $path, $value ) = @_;
 810         $value = 1 unless defined $value;
 811
 812         $loaded->{$path}->{modified}  = $value;
 813
 814         warn "# __path_modified $path $value\n";
 815 }
 816
 817 sub edit {
 818         my $self = shift;
 819         my $new_content = $self->param('new_content');
 820         $new_content  ||= $self->param('content'); # backward compatibility with old actions
 821
 822         my $i = $self->param('_row_id');
 823         die "invalid _row_id ",dump($i) unless $i =~ m/^\d+$/;
 824         my $path = $self->param('path') || die "no path";
 825         my $name = $self->param('name') || die "no name";
 826         my $status = 200; # 200 = OK, 201 = Created
 827
 828         my $data = $self->_loaded('data');
 829
 830         if ( defined $loaded->{$path}->{data}->{items}->[$i] ) {
 831                 $new_content =~ s/^\s+//s;
 832                 $new_content =~ s/\s+$//s;
 833                 my $v;
 834                 if ( $new_content =~ /\xB6/ ) { # para
 835                         $v = [ split(/\s*\xB6\s*/, $new_content) ];
 836                 } else {
 837                         $v = [ $new_content ];
 838                 }
 839
 840                 my $old = dump $loaded->{$path}->{data}->{items}->[$i]->{$name};
 841                 my $new = dump $v;
 842                 if ( $old ne $new
 843                         && ! ( $old eq 'undef' && length($new_content) == 0 ) # new value empty, previous undef
 844                 ) {
 845                         my $change = {
 846                                 path => $path,
 847                                 column => $name,
 848                                 pos => $i,
 849                                 old => $loaded->{$path}->{data}->{items}->[$i]->{$name},
 850                                 new => $v,
 851                                 time => $self->param('time') || time(),
 852                                 user => $self->param('user') || $ENV{'LOGNAME'},
 853                                 unique => {
 854                                         map { $_ => $loaded->{$path}->{data}->{items}->[$i]->{$_}->[0] }
 855                                         grep { defined $loaded->{$path}->{stats}->{$_}->{unique} }
 856                                         keys %{ $loaded->{$path}->{stats} }
 857                                 },
 858                         };
 859                         my $change_path = $self->_permanent_path( 'changes' );
 860                         mkdir $change_path unless -d $change_path;
 861                         $change_path .= '/' . $change->{time};
 862                         store $change, $change_path;
 863                         utime $change->{time}, $change->{time}, $change_path;
 864                         warn "# $change_path ", dump($change);
 865
 866                         warn "# change $path $i $old -> $new\n";
 867                         $loaded->{$path}->{data}->{items}->[$i]->{$name} = $v;
 868
 869                         __invalidate_path_column( $path, $name );
 870
 871                         $status = 201; # created
 872                         # modified = 2 -- force rebuild of stats
 873                         __path_modified( $path, 2 );
 874
 875                         $new_content = join("\xB6",@$v);
 876
 877                 } else {
 878                         warn "# unchanged $path $i $old\n";
 879                         $status = 304;
 880                 }
 881         } else {
 882                 $new_content = "$path $i $name doesn't exist\n";
 883                 $status = 404;
 884         }
 885
 886         warn "# edit $status ", dump $new_content;
 887
 888         $self->render(
 889                 status => $status,
 890                 new_content => scalar $new_content,
 891         );
 892 }
 893
 894
 895 sub save {
 896         my $self = shift;
 897         my $path = $self->_param_or_session('path');
 898         my $dump_path = $self->_save( $path );
 899         __path_modified( $path, 0 );
 900
 901         $self->redirect_to( '/data/items' );
 902 }
 903
 904 sub export {
 905         my $self = shift;
 906
 907         if ( my $import = $self->param('import') ) {
 908
 909                 if ( $import =~ m{/filter\.(.+?)\..+} ) {
 910                         my $name = $1;
 911                         my @vals = map { chomp; $_ }
 912                                 read_file $self->app->home->rel_dir('public') . "/export/$import";
 913                         $self->_remove_filter( $name );
 914                         $self->_filter_on_data( $name, @vals );
 915                         $self->session( 'offset' => 0 );
 916                         $self->redirect_to('/data/items');
 917                 } else {
 918                         warn "UNKNOWN IMPORT $import";
 919                 }
 920         }
 921
 922         $self->render( export => [
 923                 glob( $self->_export_path . '*' )
 924         ] );
 925 }
 926
 927 sub __loaded_paths {
 928         return
 929                 grep { defined $loaded->{$_}->{data} }
 930                 keys %$loaded;
 931 }
 932
 933 1;