git.rot13.org Git - pxelator/blob - lib/PXElator/httpd.pm

   1 package httpd;
   2
   3 use warnings;
   4 use strict;
   5 use autodie;
   6
   7 =head1 httpd
   8
   9 Start with:
  10
  11   perl -Ilib/PXElator -Mhttpd -e httpd::start
  12
  13 =cut
  14
  15 use Data::Dump qw/dump/;
  16 use Carp qw/confess/;
  17 use File::Slurp;
  18 #use JSON;
  19 use IO::Socket::INET;
  20 use Regexp::Common qw/net/;
  21
  22 our $title;
  23
  24 sub html_start {
  25 qq{
  26 <html>
  27 <head>
  28 <title>$title</title>
  29 </head>
  30 <body>
  31 }}
  32
  33 sub html_end {
  34 qq{
  35 </body>
  36 </html>
  37 }}
  38
  39 sub menu {
  40 qq{
  41 <div style="font-size: 80%; color: #888">
  42 <a href=/>home</a>
  43 <a href=/server>server</a>
  44 <a href=/brctl>brctl</a>
  45 <a href=/ip>ip</a>
  46 <a href=/nmap>nmap</a>
  47 <a href=/client>client</a>
  48 </div>
  49
  50 }}
  51
  52 our $port = 7777;
  53
  54 use server;
  55 our $debug = server::debug;
  56 our $url = "http://$server::ip:$port";
  57
  58 use html;
  59 our $static_pids;
  60 use progress_bar;
  61 use config;
  62 use client;
  63 use log;
  64 use x11;
  65 use amt;
  66 use boolean;
  67 use daemons;
  68
  69 use kvm;
  70 use browser;
  71 use network;
  72 use ip;
  73 use wireshark;
  74 use syslogd;
  75 use nmap;
  76 use ping;
  77 use wol;
  78
  79 use CouchDB;
  80
  81 sub static {
  82         my ($client,$path) = @_;
  83
  84         my $full = "$server::base_dir/tftp/$path";
  85
  86         return if ! -f $full;
  87
  88         if ( my $pid = fork ) {
  89                 # parent
  90                 close($client);
  91                 $static_pids->{$pid} = $path;
  92                 return 1;
  93         }
  94
  95         my $type = 'application/octet-stream';
  96         $type = 'text/html' if $path =~ m{\.htm};
  97         $type = 'application/javascript' if $path =~ m{\.js};
  98         $type = 'text/plain' if $path =~ m{\.txt};
  99
 100         my $size = -s $full || return;
 101
 102         print $client "HTTP/1.0 200 OK\r\nContent-Type: $type\r\nContent-Length: $size\r\nConnection: close\r\n\r\n";
 103
 104         open(my $fh, $full);
 105
 106         my $block = 1400; # try not to fragment packages (pxelinux seems to have problems with it)
 107         my $buff;
 108         my $pos = 0;
 109
 110         CouchDB::audit( 'static', { pid => $$, path => $path, type => $type, size => $size, block => $block, peerhost => $client->peerhost });
 111
 112         progress_bar::start;
 113
 114         while( my $len = read $fh, $buff, $block ) {
 115                 print $client $buff;
 116                 $client->flush;
 117                 $pos += $len;
 118                 progress_bar::tick( $path, $pos, $size );
 119         }
 120         close($fh);
 121         close($client);
 122
 123         print STDERR "\n";
 124
 125         exit(0);
 126 }
 127
 128 sub ok {
 129         qq|HTTP/1.0 200 OK\r\nContent-Type: text/html\r\nConnection: close\r\n\r\n| . html_start() . menu()
 130 }
 131
 132 sub redirect {
 133         my $to = shift;
 134         $to ||= $url;
 135         qq|HTTP/1.1 302 Found\r\nContent-type: text/html\r\nLocation: $to\r\n\r\n|
 136 }
 137
 138 sub get_request {
 139         my ( $client, $path, $param ) = @_;
 140
 141         server->refresh;
 142
 143         CouchDB::audit( 'request', { path => $path, param => $param, peerhost => $client->peerhost } );
 144
 145         $title = $path;
 146
 147         if ( my $found = static( $client,$path ) ) {
 148                 warn "static $found" if $debug;
 149         } elsif ( $path eq '/' ) {
 150
 151                 my @rows;
 152
 153                 my $debug_proc = '';
 154
 155 warn "XXX pids = ", dump( $daemons::pids );
 156
 157                 foreach my $name ( sort keys %$daemons::pids ) {
 158                         my $pid = $daemons::pids->{$name}; # || next;
 159
 160                         my $html;
 161
 162                         my $proc = "/proc/$pid/status";
 163
 164                         if ( -e $proc ) {
 165                                 $html .= qq|<a href=/start_stop/$name>$pid</a>|;
 166                                 if ( $debug ) {
 167                                         $html .= qq| <a name=$pid href=#proc-$pid>?</a>| if $name->can('start');
 168
 169                                         $debug_proc
 170                                                 .= qq|<a name=proc-$pid href=#$pid>$proc</a><pre style="font-size: 10%">|
 171                                                 .  read_file($proc)
 172                                                 .  qq|</pre>|
 173                                                 ;
 174                                 }
 175
 176                                 my $class = $name;
 177                                 $class =~ s{\.\d+$}{};
 178
 179                                 if ( $class->can('fork_if_active') ) {
 180                                         $html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $class->fork_if_active;
 181                                 }
 182
 183                                 if ( $class->can('actions') ) {
 184                                         $html .= qq| <a href=/action/$name/$_>$_</a>| foreach $class->actions;
 185                                 }
 186                         } else {
 187                                 if ( $pid =~ m{^\d+$} ) {
 188                                         $html .= qq|$pid exited |
 189                                 } else {
 190                                         $html .= qq|$pid |;
 191                                 }
 192                                 $html .= qq|<a href=/start_stop/$name>restart</a>| if $pid || $name->can('start');
 193                                 if ( $name->can('fork_actions') ) {
 194                                         $html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $name->fork_actions;
 195                                 }
 196                         }
 197
 198                         die "no html generated" unless $html;
 199
 200                         push @rows, ( $name => $html );
 201                 }
 202
 203                 my $below_table = '';
 204
 205                 warn 'static_pids: ', dump( $static_pids ) if $debug;
 206                 foreach my $pid ( keys %$static_pids ) {
 207                         my $path = $static_pids->{$pid};
 208                         if ( -d "/proc/$pid" ) {
 209                                 push @rows, ( $path => qq|<a href=/kill/static/$pid>$pid</a>| );
 210                         } elsif ( $param->{clean_completed_downloads} ) {
 211                                 delete $static_pids->{$pid}
 212                         } else {
 213                                 push @rows, ( $path => "$pid competed" );
 214                                 $below_table = qq|<a href="/?clean_completed_downloads=1">clean completed downloads</a>|;
 215                         }
 216                 }
 217
 218                 print $client ok
 219                         , html::table( 2, @rows )
 220                         , $below_table
 221                         , html::tabs( log::mac_changes )
 222                         , $debug_proc
 223                         ;
 224
 225         } elsif ( $path =~ m{^/server} ) {
 226                 print $client ok
 227                         , html::table( 2,
 228                                 'debug' => qq|<a href=/our/debug/| . boolean::toggle($debug) . qq|>$debug</a>|,
 229                                  map {
 230                                         ( $_, html::tt eval '$server::'.$_ )
 231                                  } ( 'ip', 'netmask', 'ip_from', 'ip_to', 'domain_name', 'base_dir', 'conf' )
 232                         )
 233                         ;
 234         } elsif ( $path =~ m!^/client(?:/$RE{net}{IPv4}{-keep})?! ) {
 235                 my $ip = $1;
 236                 $title = $ip;
 237
 238                 if ( $param->{action} eq 'remove' ) {
 239                         client::remove( $param->{change_ip} );
 240                         print $client redirect("$url/client");
 241                         return;
 242                 } elsif ( $param->{action} eq 'change' ) {
 243                         if ( my $new_ip = client::change_ip( $ip, $param->{change_ip} ) ) {
 244                                 print $client redirect("$url/client#$new_ip");
 245                                 return;
 246                         }
 247                 }
 248
 249                 if ( ! $ip ) {
 250                         my $peer_ip = $client->peerhost;
 251
 252                         my $netmask  = ip::to_int $server::netmask;
 253                         my $network  = ip::to_int($server::ip) & $netmask;
 254                         my $from_int = $network | $server::ip_from;
 255                         my $to_int   = $network | $server::ip_to;
 256                         my $ip_int   = ip::to_int $peer_ip;
 257
 258                         # show edit for clients in our dhcp range
 259                         if ( $ip_int >= $from_int && $ip_int <= $to_int ) {
 260                                 $ip = $peer_ip;
 261                         }
 262                 }
 263
 264                 if ( $ip && $ip ne $server::ip ) {
 265
 266                         my @editable = ( qw/hostname config homepage/ );
 267
 268                         client::conf( $ip, $_ => $param->{$_} ) foreach @editable;
 269
 270                         my $conf = client::all_conf( $ip );
 271                         my $config = delete $conf->{config};
 272
 273                         my $nmap = qq|<a href=/nmap?scan=$ip>nmap</a>|;
 274                         my @table = (
 275                                 'ping' => ping::host($ip)
 276                                         ? qq|<span style="color:green">up</span> $nmap|
 277                                         : qq|<span style="color: red">down</span> <a href=/wol/$ip>wol</a> $nmap|
 278                                         ,
 279                                 'ip' => qq|<input type=text name=change_ip value="$ip" onChange="document.getElementById('old_ip').style.display = '';"><span id=old_ip style="display: none; color: #888;">old: $ip<span>|,
 280                                 'mac' => format::mac( delete $conf->{mac}, 'html' ),
 281                                 'hostname' => qq|<input type=text name=hostname value="| . delete($conf->{hostname}) . qq|">|,
 282                                 'config' => html::select( 'config', $config, config::available ),
 283                                 html::conf( $ip, $conf, 'edit', @editable )
 284                         );
 285
 286                         print $client ok
 287                                 , qq|<form method=get>|
 288                                 , html::table( 2, @table ),
 289                                 , qq|
 290                                         <input type=submit name=action value=change>
 291                                         <input type=submit name=action value=remove style="color: red">
 292                                         </form>|
 293                                 ;
 294
 295                         if ( $config ) {
 296                                 if ( my $for_ip = config::for_ip( $ip ) ) {
 297                                         print $client qq|<h2>config::for_ip</h2>| . html::pre( $for_ip );
 298                                 }
 299                         }
 300
 301                         if ( $conf->{amt} ) {
 302                                 print $client qq|<h2>amt network</h2>|, html::pre_dump( amt::network( $ip ) );
 303                                 print $client qq|<h2>amt log</h2>|, html::pre_dump( amt::log( $ip ) );
 304                         }
 305
 306                 } else {
 307
 308                         my @ping;
 309                         if ( my $host = $param->{ping_target} ) {
 310                                 @ping = ( $host );
 311                         } elsif ( $param->{ping} ) {
 312                                 @ping = client::all_ips;
 313                         }
 314
 315                         my $ping = ping::fping( @ping ) if @ping;
 316                         my $arp = client::arp_mac_dev;
 317
 318                         print $client ok
 319                                 , qq|<h2>Clients on $server::ip</h2>|
 320                                 , html::table( -5,
 321                                         'ip', 'mac', 'dev', 'hostname', 'conf',
 322                                         map {
 323                                                 my $ip = $_;
 324                                                 my $conf = client::all_conf( $ip );
 325                                                 my $mac = delete $conf->{mac} || '';
 326                                                 my $style;
 327                                                 $style
 328                                                         = 'style="color:'
 329                                                         . ( $ping->{$ip} ? 'green' : 'red' )
 330                                                         . '"'
 331                                                         if $ping;
 332                                                 $style ||= '';
 333                                                 (
 334                                                         qq|<a $style name=$ip target=$ip href=/client/$ip>$ip</a>|
 335                                                         , format::mac( $mac => 'html' )
 336                                                         , $arp->{$mac}
 337                                                         , delete $conf->{hostname}
 338                                                         , html::conf( $ip, $conf, 'inline' )
 339                                                 )
 340                                         } client::all_ips
 341                                 )
 342                                 ;
 343                         print $client qq|
 344                                 <form method=get>
 345                                 <input type=text   name=ping_target   size=15>
 346                                 <input type=submit name=ping value=ping>
 347                                 </form>
 348                         |;
 349                 }
 350         } elsif ( $path =~ m{^/brctl} ) {
 351                 print $client ok, html::table( -4,
 352                         map {
 353                                 my @c = split(/\t+/,$_,4);
 354                                 if ( $#c == 1 ) {
 355                                         ( '', '', '', $c[1] )
 356                                 } else {
 357                                         @c
 358                                 }
 359                         } split(/\n/, `brctl show`)
 360                 );
 361         } elsif ( $path =~ m{^/ip/?(\w+)?} ) {
 362                 print $client ok
 363                         , join("\n", map { qq|<a href=/ip/$_>$_</a>| } ( qw/link addr route neigh ntable tunnel maddr mroute xfrm/ ))
 364                         , ip::html( $1 )
 365                         ;
 366         } elsif ( $path =~ m{^/nmap} ) {
 367                 if ( my $scan = $param->{scan} ) {
 368                         nmap::scan( $scan );
 369                         print $client redirect("$url/client#$scan");
 370                 } else {
 371                         print $client ok, qq|
 372                                 <form method=get>
 373                                 <input type=text name=scan>
 374                                 <input type=submit value=scan>
 375                                 </form>
 376                         |;
 377                 }
 378         } elsif ( $path =~ m{^/wol/(\S+)} ) {
 379                 print $client redirect( "$url/client/$1" ), wol::power_on($1);
 380         } elsif ( $path =~ m!^/amt/(\w+)/$RE{net}{IPv4}{-keep}! ) {
 381                 my ( $run, $ip ) = ( $1, $2 );
 382                 print $client redirect( "$url/client/$ip" ), amt::RemoteControl( $ip, $run );
 383         } elsif ( $path =~ m{^/our/(\w+)/(\S+)} ) {
 384                 eval 'our $' . $1 . ' = ' . $2;
 385                 warn $@ if $@;
 386                 print $client redirect($url), qq|<big>$1 = $2</big><br>Location: <a href="$url">$url</a>|;
 387                 server::debug( $debug ) if $1 eq 'debug';
 388         } elsif ( $path =~ m{^/start_stop/(\S+)} ) {
 389                 print $client redirect, daemons::start_stop($1,$param);
 390         } elsif ( $path =~ m{^/action/([^/]+)/(.+)} ) {
 391                 $1->$2();
 392                 print $client redirect;
 393         } elsif ( $path =~ m{^/kill/static/(\d+)} ) {
 394                 print $client redirect;
 395                 kill 1, $1 || kill 9, $2 && warn "killed $1";
 396         } else {
 397                 print $client "HTTP/1.0 404 $path\r\nConnection: close\r\nContent-type: text/html\r\n\r\n<big>404 $path</big>";
 398                 warn "404 $path";
 399         }
 400
 401 }
 402
 403 sub start {
 404
 405         warn 'network ', network::setup();
 406
 407         daemons::start_stop 'browser', { url => $url };
 408         daemons::start_stop $_ foreach ( qw/dhcpd tftpd dnsd syslogd/ );
 409 #       daemons::start_stop 'kvm' unless $ENV{DEV}; # skip kvm statup when running on real device
 410
 411         my $server = IO::Socket::INET->new(
 412                         Proto     => 'tcp',
 413                         LocalAddr => $server::ip,
 414                         LocalPort => $httpd::port,
 415                         Listen    => SOMAXCONN,
 416                         Reuse     => 1
 417         ) || die "can't start server on $url: $!";
 418
 419         print "url $url\n";
 420
 421         syslogd::install_local;
 422
 423         while (1) {
 424                 my $client = $server->accept() || next; # ALARM trickle us
 425                 my $request = <$client>;
 426
 427                 warn "request $request\n" if $debug;
 428
 429                 if ($request =~ m{^GET (/.*) HTTP/1.[01]}) {
 430                         my $path = $1;
 431                         $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/ge;
 432                         my $param;
 433                         if ( $path =~ s{\?(.+)}{} ) {
 434                                 foreach my $p ( split(/[&;]/, $1) ) {
 435                                         my ($n,$v) = split(/=/, $p, 2);
 436                                         $param->{$n} = $v;
 437                                 }
 438                                 warn "param: ",dump( $param ) if $debug;
 439                         }
 440                         get_request $client, $path, $param;
 441                 } else {
 442                         print $client "HTTP/1.0 500 No method\r\nConnection: close\r\nContent-type: text/plain\r\n\r\n500 $request";
 443                         warn "500 $request";
 444                 }
 445
 446                 print $client menu() . html_end() if $client->connected;
 447
 448         }
 449
 450         die "server died";
 451 }
 452
 453 warn "loaded";
 454
 455 1;