git.rot13.org Git - pxelator/blob - lib/PXElator/httpd.pm

   1 package httpd;
   2
   3 use warnings;
   4 use strict;
   5 use autodie;
   6
   7 =head1 httpd
   8
   9 Start with:
  10
  11   perl -Ilib/PXElator -Mhttpd -e httpd::start
  12
  13 =cut
  14
  15 use Data::Dump qw/dump/;
  16 use Carp qw/confess/;
  17 use File::Slurp;
  18 #use JSON;
  19 use IO::Socket::INET;
  20 use Regexp::Common qw/net/;
  21
  22 our $title;
  23
  24 sub html_start {
  25 qq{
  26 <html>
  27 <head>
  28 <title>$title</title>
  29 </head>
  30 <body>
  31 }}
  32
  33 sub html_end {
  34 qq{
  35 </body>
  36 </html>
  37 }}
  38
  39 sub menu {
  40 qq{
  41 <div style="font-size: 80%; color: #888">
  42 <a href=/ target=/>home</a>
  43 <a href=/server target=server>server</a>
  44 <a href=/brctl target=brctl>brctl</a>
  45 <a href=/ip target=ip>ip</a>
  46 <a href=/nmap target=nmap>nmap</a>
  47 <a href=/client target=client>client</a>
  48 <a href=http://$server::ip:5984/_utils/ target=couchdb>couchdb</a>
  49 </div>
  50
  51 }}
  52
  53 our $port = 7777;
  54
  55 use server;
  56 our $debug = server::debug;
  57 our $url = "http://$server::ip:$port";
  58
  59 use html;
  60 our $static_pids;
  61 use progress_bar;
  62 use config;
  63 use client;
  64 use log;
  65 use x11;
  66 use amt;
  67 use boolean;
  68 use daemons;
  69
  70 use kvm;
  71 use browser;
  72 use network;
  73 use ip;
  74 use wireshark;
  75 use syslogd;
  76 use nmap;
  77 use ping;
  78 use wol;
  79
  80 use CouchDB;
  81
  82 sub static {
  83         my ($client,$path) = @_;
  84
  85         my $full = "$server::base_dir/tftp/$path";
  86
  87         return if ! -f $full;
  88
  89         return if $full =~ m{\.ico$};
  90
  91         if ( my $pid = fork ) {
  92                 # parent
  93                 close($client);
  94                 $static_pids->{$pid} = $path;
  95                 return 1;
  96         }
  97
  98         my $type = 'application/octet-stream';
  99         $type = 'text/html' if $path =~ m{\.htm};
 100         $type = 'application/javascript' if $path =~ m{\.js};
 101         $type = 'text/plain' if $path =~ m{\.txt};
 102
 103         my $size = -s $full || return;
 104
 105         print $client "HTTP/1.0 200 OK\r\nContent-Type: $type\r\nContent-Length: $size\r\nConnection: close\r\n\r\n";
 106
 107         open(my $fh, $full);
 108
 109         my $block = 1400; # try not to fragment packages (pxelinux seems to have problems with it)
 110         my $buff;
 111         my $pos = 0;
 112
 113         CouchDB::audit( 'static', { pid => $$, path => $path, type => $type, size => $size, block => $block, peerhost => $client->peerhost });
 114
 115         progress_bar::start;
 116
 117         while( my $len = read $fh, $buff, $block ) {
 118                 print $client $buff;
 119                 $client->flush;
 120                 $pos += $len;
 121                 progress_bar::tick( $path, $pos, $size );
 122         }
 123         close($fh);
 124         close($client);
 125
 126         print STDERR "\n";
 127
 128         exit(0);
 129 }
 130
 131 sub ok {
 132         qq|HTTP/1.0 200 OK\r\nContent-Type: text/html\r\nConnection: close\r\n\r\n| . html_start() . menu()
 133 }
 134
 135 sub redirect {
 136         my $to = shift;
 137         $to ||= $url;
 138         qq|HTTP/1.1 302 Found\r\nContent-type: text/html\r\nLocation: $to\r\n\r\n|
 139 }
 140
 141 sub get_request {
 142         my ( $client, $path, $param ) = @_;
 143
 144         server->refresh;
 145
 146         CouchDB::audit( 'request', { path => $path, param => $param, peerhost => $client->peerhost } );
 147
 148         $title = $path;
 149
 150         if ( my $found = static( $client,$path ) ) {
 151                 warn "static $found" if $debug;
 152         } elsif ( $path eq '/' ) {
 153
 154                 my @rows;
 155
 156                 my $debug_proc = '';
 157
 158 warn "XXX pids = ", dump( $daemons::pids );
 159
 160                 foreach my $name ( sort keys %$daemons::pids ) {
 161                         my $pid = $daemons::pids->{$name}; # || next;
 162
 163                         my $html;
 164
 165                         my $proc = "/proc/$pid/status";
 166
 167                         if ( -e $proc ) {
 168                                 $html .= qq|<a href=/start_stop/$name>$pid</a>|;
 169                                 if ( $debug ) {
 170                                         $html .= qq| <a name=$pid href=#proc-$pid>?</a>| if $name->can('start');
 171
 172                                         $debug_proc
 173                                                 .= qq|<a name=proc-$pid href=#$pid>$proc</a><pre style="font-size: 10%">|
 174                                                 .  read_file($proc)
 175                                                 .  qq|</pre>|
 176                                                 ;
 177                                 }
 178
 179                                 my $class = $name;
 180                                 $class =~ s{\.\d+$}{};
 181
 182                                 if ( $class->can('fork_if_active') ) {
 183                                         $html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $class->fork_if_active;
 184                                 }
 185
 186                                 if ( $class->can('actions') ) {
 187                                         $html .= qq| <a href=/action/$name/$_>$_</a>| foreach $class->actions;
 188                                 }
 189                         } else {
 190                                 if ( $pid =~ m{^\d+$} ) {
 191                                         $html .= qq|$pid exited |
 192                                 } else {
 193                                         $html .= qq|$pid |;
 194                                 }
 195                                 $html .= qq|<a href=/start_stop/$name>restart</a>| if $pid || $name->can('start');
 196                                 if ( $name->can('fork_actions') ) {
 197                                         $html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $name->fork_actions;
 198                                 }
 199                         }
 200
 201                         die "no html generated" unless $html;
 202
 203                         push @rows, ( $name => $html );
 204                 }
 205
 206                 my $below_table = '';
 207
 208                 warn 'static_pids: ', dump( $static_pids ) if $debug;
 209                 foreach my $pid ( keys %$static_pids ) {
 210                         my $path = $static_pids->{$pid};
 211                         if ( -d "/proc/$pid" ) {
 212                                 push @rows, ( $path => qq|<a href=/kill/static/$pid>$pid</a>| );
 213                         } elsif ( $param->{clean_completed_downloads} ) {
 214                                 delete $static_pids->{$pid}
 215                         } else {
 216                                 push @rows, ( $path => "$pid competed" );
 217                                 $below_table = qq|<a href="/?clean_completed_downloads=1">clean completed downloads</a>|;
 218                         }
 219                 }
 220
 221                 my $kvm = kvm::next_nr;
 222                 $kvm = qq|<div><a href=/start_stop/kvm?nr=$kvm>create new kvm $kvm</a></div>|;
 223
 224                 print $client ok
 225                         , html::table( 2, @rows )
 226                         , $below_table
 227                         , $kvm
 228                         , html::tabs( log::mac_changes )
 229                         , $debug_proc
 230                         ;
 231
 232         } elsif ( $path =~ m{^/server} ) {
 233                 foreach my $name ( keys %$param ) {
 234                         eval '$server::' . $name . '= $param->{$name}';
 235                 }
 236                 my @table = (
 237                           'debug' => qq|<a href=/our/debug/| . boolean::toggle($debug) . qq|>$debug</a>|,
 238                         , 'new_clients' => qq|<input type=text name=new_clients size=3 value="$server::new_clients">|
 239                 );
 240
 241                 foreach my $editable ( 'ip', 'netmask', 'ip_from', 'ip_to', 'domain' ) {
 242                         my $v = eval '$server::' . $editable;
 243                         push @table, ( $editable, qq|<input type=text name=$editable value="$v">| );
 244                 }
 245
 246                 foreach my $readonly ( 'base_dir', 'conf' ) {
 247                         my $v = eval '$server::' . $readonly;
 248                         push @table, ( $readonly, html::tt $v );
 249                 }
 250
 251                 print $client ok
 252                         , qq|<form method=get>|
 253                         , html::table( 2, @table )
 254                         , qq|
 255                                 <input type=submit name=action value=change>
 256                                 </form>
 257                         |
 258                         ;
 259
 260         } elsif ( $path =~ m!^/client(?:/$RE{net}{IPv4}{-keep})?! ) {
 261                 my $ip = $1;
 262                 $title = $ip if $ip;
 263
 264                 if ( $param->{action} eq 'remove' ) {
 265                         client::remove( $param->{change_ip} );
 266                         print $client redirect("$url/client");
 267                         return;
 268                 } elsif ( $param->{action} eq 'change' ) {
 269                         if ( my $new_ip = client::change_ip( $ip, $param->{change_ip} ) ) {
 270                                 print $client redirect("$url/client#$new_ip");
 271                                 return;
 272                         }
 273                 }
 274
 275                 if ( ! $ip ) {
 276                         my $peer_ip = $client->peerhost;
 277
 278                         my $netmask  = ip::to_int $server::netmask;
 279                         my $network  = ip::to_int($server::ip) & $netmask;
 280                         my $from_int = $network | $server::ip_from;
 281                         my $to_int   = $network | $server::ip_to;
 282                         my $ip_int   = ip::to_int $peer_ip;
 283
 284                         # show edit for clients in our dhcp range
 285                         if ( $ip_int >= $from_int && $ip_int <= $to_int ) {
 286                                 $ip = $peer_ip;
 287                         }
 288                 }
 289
 290                 if ( $ip && $ip ne $server::ip ) {
 291
 292                         my @editable = ( qw/hostname config homepage/ );
 293
 294                         client::conf( $ip, $_ => $param->{$_} ) foreach @editable;
 295
 296                         my $conf = client::all_conf( $ip );
 297                         my $config = delete $conf->{config};
 298
 299                         my $nmap = qq|<a href=/nmap?scan=$ip>nmap</a>|;
 300                         my @table = (
 301                                 'ping' => ping::host($ip)
 302                                         ? qq|<span style="color:green">up</span> $nmap|
 303                                         : qq|<span style="color: red">down</span> <a href=/wol/$ip>wol</a> $nmap|
 304                                         ,
 305                                 'ip' => qq|<input type=text name=change_ip value="$ip" onChange="document.getElementById('old_ip').style.display = '';"><span id=old_ip style="display: none; color: #888;">old: $ip<span>|,
 306                                 'mac' => format::mac( delete $conf->{mac}, 'html' ),
 307                                 'hostname' => qq|<input type=text name=hostname value="| . delete($conf->{hostname}) . qq|">|,
 308                                 'config' => html::select( 'config', $config, config::available ),
 309                                 html::conf( $ip, $conf, 'edit', @editable )
 310                         );
 311
 312                         print $client ok
 313                                 , qq|<form method=get>|
 314                                 , html::table( 2, @table ),
 315                                 , qq|
 316                                         <input type=submit name=action value=change>
 317                                         <input type=submit name=action value=remove style="color: red">
 318                                         </form>|
 319                                 ;
 320
 321                         if ( $config ) {
 322                                 if ( my $for_ip = config::for_ip( $ip ) ) {
 323                                         print $client qq|<h2>config::for_ip</h2>| . html::pre( $for_ip );
 324                                 }
 325                         }
 326
 327                         if ( $conf->{amt} ) {
 328                                 print $client qq|<h2>amt network</h2>|, html::pre_dump( amt::network( $ip ) );
 329                                 print $client qq|<h2>amt log</h2>|, html::pre_dump( amt::log( $ip ) );
 330                         }
 331
 332                 } else {
 333
 334                         my @ping;
 335                         if ( my $host = $param->{ping_target} ) {
 336                                 @ping = ( $host );
 337                         } elsif ( $param->{ping} ) {
 338                                 @ping = client::all_ips;
 339                         }
 340
 341                         my $ping = ping::fping( @ping ) if @ping;
 342                         my $arp = client::arp_mac_dev;
 343
 344                         print $client ok
 345                                 , qq|<h2>Clients on $server::ip</h2>|
 346                                 , html::table( -5,
 347                                         'ip', 'mac', 'dev', 'hostname', 'conf',
 348                                         map {
 349                                                 my $ip = $_;
 350                                                 my $conf = client::all_conf( $ip );
 351                                                 my $mac = delete $conf->{mac} || '';
 352                                                 my $style;
 353                                                 $style
 354                                                         = 'style="color:'
 355                                                         . ( $ping->{$ip} ? 'green' : 'red' )
 356                                                         . '"'
 357                                                         if $ping;
 358                                                 $style ||= '';
 359                                                 my $ip_text = qq|<tt>$ip</tt>|;
 360                                                 $ip_text = qq|<tt><b>$ip</b></tt>| if ip::in_dhcp_range($ip);
 361                                                 (
 362                                                         qq|<a $style name=$ip target=$ip href=/client/$ip>$ip_text</a>|
 363                                                         , format::mac( $mac => 'html' )
 364                                                         , $arp->{$mac}
 365                                                         , delete $conf->{hostname}
 366                                                         , html::conf( $ip, $conf, 'inline' )
 367                                                 )
 368                                         } client::all_ips
 369                                 )
 370                                 ;
 371                         print $client qq|
 372                                 <form method=get>
 373                                 <input type=text   name=ping_target   size=15>
 374                                 <input type=submit name=ping value=ping>
 375                                 </form>
 376                         |;
 377                 }
 378
 379
 380         } elsif ( $path =~ m{^/brctl} ) {
 381
 382                 system 'brctl addif virtual ' . $param->{addif} if $param->{addif};
 383                 system 'brctl delif virtual ' . $param->{delif} if $param->{delif};
 384
 385                 my $in_virtual;
 386
 387                 my @table =
 388                         map {
 389                                 my @c = split(/\t+/,$_,4);
 390                                 if ( $#c == 1 ) {
 391                                         $in_virtual->{ $c[1] }++;
 392                                         @c = ( '', '', '', $c[1] );
 393                                 } else {
 394                                         $in_virtual->{ $c[3] }++;
 395                                 }
 396                                 if ( $c[3] =~ m{\d$} ) {
 397                                         $c[3] = qq|<input type=submit name=delif value=$c[3] style="color:red" title="remove $c[3] from bridge">|;
 398                                 }
 399                                 @c
 400                         } split(/\n/, `brctl show`)
 401                 ;
 402
 403                 my @add_ifs = grep { ! $in_virtual->{$_} && $_ ne 'virtual' } ip::devices_up;
 404
 405                 push @table, ( '', '', '', html::select( 'addif', @add_ifs ) . qq|<input type=submit value=add></form>| );
 406
 407                 print $client ok
 408                         , qq|<form>|
 409                         , html::table( -4, @table )
 410                         , qq|</form>|
 411                         ;
 412
 413
 414         } elsif ( $path =~ m{^/ip/?(\w+)?} ) {
 415                 print $client ok
 416                         , join("\n", map { qq|<a href=/ip/$_>$_</a>| } ( qw/link addr route neigh ntable tunnel maddr mroute xfrm/ ))
 417                         , ip::html( $1 )
 418                         ;
 419         } elsif ( $path =~ m{^/nmap} ) {
 420                 if ( my $scan = $param->{scan} ) {
 421                         nmap::scan( $scan );
 422                         print $client redirect("$url/client#$scan");
 423                 } else {
 424                         print $client ok, qq|
 425                                 <form method=get>
 426                                 <input type=text name=scan>
 427                                 <input type=submit value=scan>
 428                                 </form>
 429                         |;
 430                 }
 431         } elsif ( $path =~ m{^/wol/(\S+)} ) {
 432                 print $client redirect( "$url/client/$1" ), wol::power_on($1);
 433         } elsif ( $path =~ m!^/amt/(\w+)/$RE{net}{IPv4}{-keep}! ) {
 434                 my ( $run, $ip ) = ( $1, $2 );
 435                 print $client redirect( "$url/client/$ip" ), amt::RemoteControl( $ip, $run );
 436         } elsif ( $path =~ m{^/our/(\w+)/(\S+)} ) {
 437                 eval 'our $' . $1 . ' = ' . $2;
 438                 warn $@ if $@;
 439                 print $client redirect($url), qq|<big>$1 = $2</big><br>Location: <a href="$url">$url</a>|;
 440                 server::debug( $debug ) if $1 eq 'debug';
 441         } elsif ( $path =~ m{^/start_stop/(\S+)} ) {
 442                 print $client redirect, daemons::start_stop($1,$param);
 443         } elsif ( $path =~ m{^/action/([^/]+)/(.+)} ) {
 444                 my ( $package, $method ) = ( $1, $2 );
 445                 $ENV{nr} = $1 if $package =~ s{\.(\d+)$}{};
 446                 $package->$method();
 447                 print $client redirect;
 448         } elsif ( $path =~ m{^/kill/static/(\d+)} ) {
 449                 print $client redirect;
 450                 kill 1, $1 || kill 9, $2 && warn "killed $1";
 451         } else {
 452                 print $client "HTTP/1.0 404 $path\r\nConnection: close\r\nContent-type: text/html\r\n\r\n<big>404 $path</big>";
 453                 warn "404 $path";
 454         }
 455
 456 }
 457
 458 sub start {
 459
 460         warn 'network ', network::setup();
 461
 462         daemons::start_stop 'browser', { url => $url };
 463         daemons::start_stop $_ foreach ( qw/dhcpd tftpd dnsd syslogd/ );
 464 #       daemons::start_stop 'kvm' unless $ENV{DEV}; # skip kvm statup when running on real device
 465
 466         my $server = IO::Socket::INET->new(
 467                         Proto     => 'tcp',
 468 #                       LocalAddr => $server::ip,
 469                         LocalPort => $httpd::port,
 470                         Listen    => SOMAXCONN,
 471                         Reuse     => 1
 472         ) || die "can't start server on $url: $!";
 473
 474         print "url $url\n";
 475
 476         syslogd::install_local;
 477         client::rebuild_mac_links;
 478
 479         while (1) {
 480                 my $client = $server->accept() || next; # ALARM trickle us
 481                 my $request = <$client>;
 482
 483                 my $headers;
 484
 485                 while ( my $header = <$client> ) {
 486                         chomp $header;
 487                         last if $header =~ m{^\s*$};
 488                         my ( $n, $v ) = split(/:\s*/, $header);
 489                         $headers->{ lc $n } = $v;
 490                 }
 491
 492                 if ( my $host = $headers->{host} ) {
 493                         $url = 'http://' . $host;
 494                         $url .= ":$port" unless $url =~ m{:\d+$};
 495                 }
 496
 497                 warn "## $url ## $request", dump( $headers ) if $debug;
 498
 499                 if ($request =~ m{^GET (/.*) HTTP/1.[01]}) {
 500                         my $path = $1;
 501                         $path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/ge;
 502                         my $param;
 503                         if ( $path =~ s{\?(.+)}{} ) {
 504                                 foreach my $p ( split(/[&;]/, $1) ) {
 505                                         my ($n,$v) = split(/=/, $p, 2);
 506                                         $param->{$n} = $v;
 507                                 }
 508                                 warn "param: ",dump( $param ) if $debug;
 509                         }
 510                         get_request $client, $path, $param;
 511                 } else {
 512                         print $client "HTTP/1.0 500 No method\r\nConnection: close\r\nContent-type: text/plain\r\n\r\n500 $request";
 513                         warn "500 $request";
 514                 }
 515
 516                 print $client menu() . html_end() if $client->connected;
 517
 518         }
 519
 520         die "server died";
 521 }
 522
 523 warn "loaded";
 524
 525 1;