git.rot13.org Git - pxelator/blob - lib/PXElator/httpd.pm

   1 package httpd;
   2
   3 use warnings;
   4 use strict;
   5 use autodie;
   6
   7 =head1 httpd
   8
   9 Start with:
  10
  11   perl -Ilib/PXElator -Mhttpd -e httpd::start
  12
  13 =cut
  14
  15 use Data::Dump qw/dump/;
  16 use Carp qw/confess/;
  17 use File::Slurp;
  18 #use JSON;
  19 use IO::Socket::INET;
  20 use Regexp::Common qw/net/;
  21
  22 sub menu {qq{
  23
  24 <div style="font-size: 80%; color: #888">
  25 <a href=/>home</a>
  26 <a href=/server>server</a>
  27 <a href=/brctl>brctl</a>
  28 <a href=/ip>ip</a>
  29 <a href=/client>client</a>
  30 </div>
  31
  32 }}
  33
  34 our $port = 7777;
  35
  36 use server;
  37 our $debug = server::debug;
  38 our $url = "http://$server::ip:$port";
  39
  40 use html;
  41 our $static_pids;
  42 use progress_bar;
  43 use config;
  44 use client;
  45 use log;
  46 use x11;
  47 use amt;
  48 use boolean;
  49 use daemons;
  50
  51 use kvm;
  52 use browser;
  53 use network;
  54 use ip;
  55 use wireshark;
  56 use syslogd;
  57
  58 use CouchDB;
  59
  60 sub static {
  61         my ($client,$path) = @_;
  62
  63         my $full = "$server::base_dir/tftp/$path";
  64
  65         return if ! -f $full;
  66
  67         if ( my $pid = fork ) {
  68                 # parent
  69                 close($client);
  70                 $static_pids->{$pid} = $path;
  71                 return 1;
  72         }
  73
  74         my $type = 'application/octet-stream';
  75         $type = 'text/html' if $path =~ m{\.htm};
  76         $type = 'application/javascript' if $path =~ m{\.js};
  77         $type = 'text/plain' if $path =~ m{\.txt};
  78
  79         my $size = -s $full || return;
  80
  81         print $client "HTTP/1.0 200 OK\r\nContent-Type: $type\r\nContent-Length: $size\r\nConnection: close\r\n\r\n";
  82
  83         open(my $fh, $full);
  84
  85         my $block = 1400; # try not to fragment packages (pxelinux seems to have problems with it)
  86         my $buff;
  87         my $pos = 0;
  88
  89         CouchDB::audit( 'static', { pid => $$, path => $path, type => $type, size => $size, block => $block, peerhost => $client->peerhost });
  90
  91         progress_bar::start;
  92
  93         while( my $len = read $fh, $buff, $block ) {
  94                 print $client $buff;
  95                 $client->flush;
  96                 $pos += $len;
  97                 progress_bar::tick( $path, $pos, $size );
  98         }
  99         close($fh);
 100         close($client);
 101
 102         print STDERR "\n";
 103
 104         exit(0);
 105 }
 106
 107 sub ok {
 108         qq|HTTP/1.0 200 OK\r\nContent-Type: text/html\r\nConnection: close\r\n\r\n| . menu()
 109 }
 110
 111 sub redirect {
 112         my $to = shift;
 113         $to ||= $url;
 114         qq|HTTP/1.1 302 Found\r\nContent-type: text/html\r\nLocation: $to\r\n\r\n|
 115 }
 116
 117 sub get_request {
 118         my ( $client, $path, $param ) = @_;
 119
 120         server->refresh;
 121
 122         CouchDB::audit( 'request', { path => $path, param => $param, peerhost => $client->peerhost } );
 123
 124         if ( my $found = static( $client,$path ) ) {
 125                 warn "static $found" if $debug;
 126         } elsif ( $path eq '/' ) {
 127
 128                 my @rows;
 129
 130                 my $debug_proc = '';
 131
 132 warn "XXX pids = ", dump( $daemons::pids );
 133
 134                 foreach my $name ( sort keys %$daemons::pids ) {
 135                         my $pid = $daemons::pids->{$name}; # || next;
 136
 137                         my $html;
 138
 139                         my $proc = "/proc/$pid/status";
 140
 141                         if ( -e $proc ) {
 142                                 $html .= qq|<a href=/start_stop/$name>$pid</a>|;
 143                                 if ( $debug ) {
 144                                         $html .= qq| <a name=$pid href=#proc-$pid>?</a>| if $name->can('start');
 145
 146                                         $debug_proc
 147                                                 .= qq|<a name=proc-$pid href=#$pid>$proc</a><pre style="font-size: 10%">|
 148                                                 .  read_file($proc)
 149                                                 .  qq|</pre>|
 150                                                 ;
 151                                 }
 152
 153                                 if ( $name->can('fork_if_active') ) {
 154                                         $html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $name->fork_if_active;
 155                                 }
 156
 157                                 if ( $name->can('actions') ) {
 158                                         $html .= qq| <a href=/action/$name/$_>$_</a>| foreach $name->actions;
 159                                 }
 160                         } else {
 161                                 if ( $pid =~ m{^\d+$} ) {
 162                                         $html .= qq|$pid exited |
 163                                 } else {
 164                                         $html .= qq|$pid |;
 165                                 }
 166                                 $html .= qq|<a href=/start_stop/$name>restart</a>| if $pid || $name->can('start');
 167                                 if ( $name->can('fork_actions') ) {
 168                                         $html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $name->fork_actions;
 169                                 }
 170                         }
 171
 172                         die "no html generated" unless $html;
 173
 174                         push @rows, ( $name => $html );
 175                 }
 176
 177                 my $below_table = '';
 178
 179                 warn 'static_pids: ', dump( $static_pids ) if $debug;
 180                 foreach my $pid ( keys %$static_pids ) {
 181                         my $path = $static_pids->{$pid};
 182                         if ( -d "/proc/$pid" ) {
 183                                 push @rows, ( $path => qq|<a href=/kill/static/$pid>$pid</a>| );
 184                         } elsif ( $param->{clean_completed_downloads} ) {
 185                                 delete $static_pids->{$pid}
 186                         } else {
 187                                 push @rows, ( $path => "$pid competed" );
 188                                 $below_table = qq|<a href="/?clean_completed_downloads=1">clean completed downloads</a>|;
 189                         }
 190                 }
 191
 192                 print $client ok
 193                         , html::table( 2, @rows )
 194                         , $below_table
 195                         , html::tabs( log::mac_changes )
 196                         , $debug_proc
 197                         ;
 198
 199         } elsif ( $path =~ m{^/server} ) {
 200                 print $client ok
 201                         , html::table( 2,
 202                                 'debug' => qq|<a href=/our/debug/| . boolean::toggle($debug) . qq|>$debug</a>|,
 203                                  map {
 204                                         ( $_, html::tt eval '$server::'.$_ )
 205                                  } ( 'ip', 'netmask', 'ip_from', 'ip_to', 'domain_name', 'base_dir', 'conf' )
 206                         )
 207                         ;
 208         } elsif ( $path =~ m!^/client(?:/$RE{net}{IPv4}{-keep})?! ) {
 209                 my $ip = $1 || $client->peerhost;
 210
 211                 if ( my $new_ip = $param->{change_ip} ) {
 212                         client::change_ip( $ip, $new_ip );
 213                         $ip = $new_ip;
 214                 }
 215
 216                 my $ip_short = (split(/\./, $ip, 4))[3];
 217
 218                 # if ( $ip ne $server::ip ) -- not flexible enough for tunnel endpoints
 219                 if ( $ip_short >= $server::ip_from && $ip_short <= $server::ip_to ) {
 220                         my $hostname = client::conf( $ip, 'hostname' => $param->{hostname} );
 221
 222                         my @table = (
 223                                 'ip' => qq|<input type=text name=change_ip value="$ip" onChange="document.getElementById('old_ip').style.display = '';"><span id=old_ip style="display: none; color: #888;">old: $ip<span>|,
 224                                 'hostname' => qq|<input type=text name=hostname value="$hostname">|,
 225                         );
 226
 227                         my $deploy;
 228
 229                         if ( my $mac = client::mac_from_ip( $ip ) ) {
 230                                 $deploy = client::conf( $ip, 'deploy' => $param->{deploy} );
 231                                 push @table, (
 232                                         'mac' => format::mac( $mac => 'html' ),
 233                                         'deploy' => html::select( 'deploy', $deploy, config::available )
 234                                 );
 235                                 if ( my $pxelinux = config::for_ip( $ip ) ) {
 236                                         $deploy = qq|<h2>PXElinux</h2>| . html::pre( $pxelinux );
 237                                 }
 238                         }
 239
 240                         print $client ok
 241                                 , qq|<form method=get>|
 242                                 , html::table( 2, @table ),
 243                                 , qq|<input type=submit value=change></form>|
 244                                 , $deploy
 245                                 ;
 246
 247                         if ( my $amt = client::conf( $ip, 'amt' ) ) {
 248                                 print $client qq|<h2>AMT</h2>|, amt::info( $amt, $ip );
 249                         }
 250                 } else {
 251
 252                         my $arp = {
 253                                 map {
 254                                         my @c = split(/\s+/,$_);
 255                                         if ( $#c == 5 ) {
 256                                                 ( uc $c[3] => [ $c[0] , $c[5] ] )
 257                                         } else {
 258                                         }
 259                                 } read_file('/proc/net/arp')
 260                         };
 261
 262                         warn "# arp ",dump( $arp );
 263
 264                         print $client ok
 265                                 , qq|<h2>Clients on $server::ip</h2>|
 266                                 , html::table( -6,
 267                                         'ip', 'mac', 'arp', 'hostname', 'deploy', 'conf',
 268                                         map {
 269                                                 my $ip = $_;
 270                                                 my $conf = client::all_conf( $ip );
 271                                                 my $mac = delete $conf->{mac} || '';
 272                                                 (
 273                                                         qq|<a href=/client/$ip>$ip</a>|
 274                                                         , format::mac( $mac => 'html' )
 275                                                         , ( $arp->{$mac} ? $arp->{$mac}->[1] : '' )
 276                                                         , delete $conf->{hostname}
 277                                                         , delete $conf->{deploy}
 278                                                         , html::pre_dump( $conf )
 279                                                 );
 280                                         }
 281                                         sort { ip::to_int($a) cmp ip::to_int($b) }
 282                                         map {
 283                                                 my $ip = $_;
 284                                                 $ip =~ s{^.+/ip/}{};
 285                                                 $ip;
 286                                         } glob("$server::conf/ip/*")
 287                                 )
 288                                 , qq|<h2>ARP</h2>|
 289                                 , html::table( -3, 'ip', 'mac', 'dev',
 290                                         map {
 291                                                 my $c = $arp->{$_};
 292                                                 ( $c->[0], format::mac( $_ => 'html' ), $c->[1] )
 293                                         } sort keys %$arp
 294                                 )
 295                                 ;
 296                 }
 297         } elsif ( $path =~ m{^/brctl} ) {
 298                 print $client ok
 299                         ,html::pre( `brctl show` )
 300                         ;
 301         } elsif ( $path =~ m{^/ip/?(\w+)?} ) {
 302                 print $client ok
 303                         , join("\n", map { qq|<a href=/ip/$_>$_</a>| } ( qw/link addr route neigh ntable tunnel maddr mroute xfrm/ ))
 304                         , ip::html( $1 )
 305                         ;
 306         } elsif ( $path =~ m{^/our/(\w+)/(\S+)} ) {
 307                 eval 'our $' . $1 . ' = ' . $2;
 308                 warn $@ if $@;
 309                 print $client redirect($url), qq|<big>$1 = $2</big><br>Location: <a href="$url">$url</a>|;
 310                 server::debug( $debug ) if $1 eq 'debug';
 311         } elsif ( $path =~ m{^/start_stop/(\S+)} ) {
 312                 print $client redirect, daemons::start_stop($1);
 313         } elsif ( $path =~ m{^/action/([^/]+)/(.+)} ) {
 314                 $1->$2();
 315                 print $client redirect;
 316         } elsif ( $path =~ m{^/kill/static/(\d+)} ) {
 317                 print $client redirect;
 318                 kill 1, $1 || kill 9, $2 && warn "killed $1";
 319         } else {
 320                 print $client "HTTP/1.0 404 $path\r\nConnection: close\r\nContent-type: text/html\r\n\r\n<big>404 $path</big>";
 321                 warn "404 $path";
 322         }
 323
 324 }
 325
 326 sub start {
 327
 328         warn 'network ', network::setup();
 329
 330         daemons::start_stop 'browser', $url;
 331         daemons::start_stop $_ foreach ( qw/dhcpd tftpd dnsd syslogd/ );
 332         daemons::start_stop 'kvm' unless $ENV{DEV}; # skip kvm statup when running on real device
 333
 334         my $server = IO::Socket::INET->new(
 335                         Proto     => 'tcp',
 336                         LocalAddr => $server::ip,
 337                         LocalPort => $httpd::port,
 338                         Listen    => SOMAXCONN,
 339                         Reuse     => 1
 340         ) || die "can't start server on $url: $!";
 341
 342         print "url $url\n";
 343
 344         while (1) {
 345                 my $client = $server->accept() || next; # ALARM trickle us
 346                 my $request = <$client>;
 347
 348                 warn "request $request\n" if $debug;
 349
 350                 if ($request =~ m{^GET (/.*) HTTP/1.[01]}) {
 351                         my $path = $1;
 352                         my $param;
 353                         if ( $path =~ s{\?(.+)}{} ) {
 354                                 foreach my $p ( split(/[&;]/, $1) ) {
 355                                         my ($n,$v) = split(/=/, $p, 2);
 356                                         $param->{$n} = $v;
 357                                 }
 358                                 warn "param: ",dump( $param ) if $debug;
 359                         }
 360                         get_request $client, $path, $param;
 361                 } else {
 362                         print $client "HTTP/1.0 500 No method\r\nConnection: close\r\nContent-type: text/plain\r\n\r\n500 $request";
 363                         warn "500 $request";
 364                 }
 365
 366                 print $client menu() if $client->connected;
 367
 368         }
 369
 370         die "server died";
 371 }
 372
 373 warn "loaded";
 374
 375 1;