lib/RFID/Biblio/Reader.pm

   1 package RFID::Biblio::Reader;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Data::Dump qw(dump);
   7 use Time::HiRes;
   8 use lib 'lib';
   9 use RFID::Biblio;
  10
  11 =head1 NAME
  12
  13 RFID::Biblio::Reader - simple way to write RFID applications in perl
  14
  15 =head1 DESCRIPTION
  16
  17 This module will probe all available readers and use calls from
  18 L<RFID::Biblio::Reader::API> to invoke correct reader.
  19
  20 =head1 FUNCTIONS
  21
  22 =head2 new
  23
  24   my $rfid = RFID::Biblio::Reader->new( 'optional reader filter' );
  25
  26 =cut
  27
  28 sub new {
  29         my ( $class, $filter ) = @_;
  30         my $self = {};
  31         bless $self, $class;
  32         $self->{_readers} = [ $self->_available( $filter ) ];
  33         return $self;
  34 }
  35
  36 =head2 tags
  37
  38   my @visible = $rfid->tags(
  39                 enter => sub { my $tag = shift; },
  40                 leave => sub { my $tag = shift; },
  41   );
  42
  43 =cut
  44
  45 sub tags {
  46         my $self = shift;
  47         my $triggers = {@_};
  48
  49         $self->{_tags} ||= {};
  50         $self->{_tags}->{$_}->{time} = 0 foreach keys %{$self->{_tags}};
  51         my $t = time;
  52
  53         foreach my $rfid ( @{ $self->{_readers} } ) {
  54                 warn "# inventory on $rfid";
  55                 my @tags = $rfid->inventory;
  56
  57                 foreach my $tag ( @tags ) {
  58
  59                         if ( ! exists $self->{_tags}->{$tag} ) {
  60                                 eval {
  61                                         my $blocks = $rfid->read_blocks($tag);
  62                                         $self->{_tags}->{$tag}->{blocks} = $blocks->{$tag} || die "no $tag in ",dump($blocks);
  63                                         my $afi = $rfid->read_afi($tag);
  64                                         $self->{_tags}->{$tag}->{afi} = $afi;
  65
  66                                 };
  67                                 if ( $@ ) {
  68                                         warn "ERROR reading $tag: $@\n";
  69                                         $self->_invalidate_tag( $tag );
  70                                         next;
  71                                 }
  72
  73                                 $triggers->{enter}->( $tag ) if $triggers->{enter};
  74                         }
  75
  76                         $self->{_tags}->{$tag}->{time} = $t;
  77
  78                 }
  79
  80                 foreach my $tag ( grep { $self->{_tags}->{$_}->{time} == 0 } keys %{ $self->{_tags} } ) {
  81                         $triggers->{leave}->( $tag ) if $triggers->{leave};
  82                         $self->_invalidate_tag( $tag );
  83                 }
  84
  85         }
  86
  87         warn "## _tags ",dump( $self->{_tags} );
  88
  89         return grep { $self->{_tags}->{$_}->{time} } keys %{ $self->{_tags} };
  90 }
  91
  92 =head2 blocks
  93
  94   my $blocks_arrayref = $rfid->blocks( $tag );
  95
  96 =head2 afi
  97
  98   my $afi = $rfid->afi( $tag );
  99
 100 =cut
 101
 102 sub blocks { $_[0]->{_tags}->{$_[1]}->{ 'blocks' } || die "no blocks for $_[1]"; };
 103 sub afi    { $_[0]->{_tags}->{$_[1]}->{ 'afi'    } || die "no afi for $_[1]"; };
 104
 105 =head1 PRIVATE
 106
 107 =head2 _invalidate_tag
 108
 109   $rfid->_invalidate_tag( $tag );
 110
 111 =cut
 112
 113 sub _invalidate_tag {
 114         my ( $self, $tag ) = @_;
 115         my @caller = caller(0);
 116         warn "## _invalidate_tag caller $caller[0] $caller[1] +$caller[2]\n";
 117         my $old = delete $self->{_tags}->{$tag};
 118         warn "# _invalidate_tag $tag ", dump($old);
 119 }
 120
 121 =head2 _available
 122
 123 Probe each RFID reader supported and returns succefull ones
 124
 125   my $rfid_readers = RFID::Biblio::Reader->_available( $regex_filter );
 126
 127 =cut
 128
 129 my @readers = ( '3M810', 'CPRM02', 'librfid' );
 130
 131 sub _available {
 132         my ( $self, $filter ) = @_;
 133
 134         $filter = '' unless defined $filter;
 135
 136         warn "# filter: $filter";
 137
 138         my @rfid;
 139
 140         foreach my $reader ( @readers ) {
 141                 next if $filter && $reader !~ /$filter/i;
 142                 my $module = "RFID::Biblio::Reader::$reader";
 143                 eval "use $module";
 144                 die $@ if $@;
 145                 if ( my $rfid = $module->new ) {
 146                         push @rfid, $rfid;
 147                         warn "# added $module\n";
 148                 } else {
 149                         warn "# ignored $module\n";
 150                 }
 151         }
 152
 153         die "no readers found" unless @rfid;
 154
 155         return @rfid;
 156 }
 157
 158 =head1 AUTOLOAD
 159
 160 On any other function calls, we just marshall to all readers
 161
 162 =cut
 163
 164 # we don't want DESTROY to fallback into AUTOLOAD
 165 sub DESTROY {}
 166
 167 our $AUTOLOAD;
 168 sub AUTOLOAD {
 169         my $self = shift;
 170         my $command = $AUTOLOAD;
 171         $command =~ s/.*://;
 172
 173         my @out;
 174
 175         foreach my $r ( @{ $self->{_readers} } ) {
 176                 push @out, $r->$command(@_);
 177         }
 178
 179         $self->_invalidate_tag( $_[0] ) if $command =~ m/write/;
 180
 181         return @out;
 182 }
 183
 184 1
 185 __END__
 186
 187 =head1 SEE ALSO
 188
 189 =head2 RFID reader implementations
 190
 191 L<RFID::Biblio::Reader::3M810>
 192
 193 L<RFID::Biblio::Reader::CPRM02>
 194
 195 L<RFID::Biblio::Reader::librfid>
 196