lib/RFID/Biblio/Reader.pm

   1 package RFID::Biblio::Reader;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Data::Dump qw(dump);
   7 use Time::HiRes;
   8 use lib 'lib';
   9 use RFID::Biblio;
  10
  11 =head1 NAME
  12
  13 RFID::Biblio::Reader - simple way to write RFID applications in perl
  14
  15 =head1 DESCRIPTION
  16
  17 This module will probe all available readers and use calls from
  18 L<RFID::Biblio::Reader::API> to invoke correct reader.
  19
  20 =head1 FUNCTIONS
  21
  22 =head2 new
  23
  24   my $rfid = RFID::Biblio::Reader->new( 'optional reader filter' );
  25
  26 =cut
  27
  28 sub new {
  29         my ( $class, $filter ) = @_;
  30         my $self = {};
  31         bless $self, $class;
  32         $self->{_readers} = [ $self->_available( $filter ) ];
  33         return $self;
  34 }
  35
  36 =head2 tags
  37
  38   my @visible = $rfid->tags(
  39                 enter => sub {},
  40                 leave => sub {},
  41   );
  42
  43 =cut
  44
  45 sub tags {
  46         my $self = shift;
  47         my $triggers = {@_};
  48
  49         $self->{inventory} ||= {};
  50         $self->{inventory}->{$_} = 0 foreach keys %{$self->{inventory}};
  51         my $t = time;
  52
  53         foreach my $rfid ( @{ $self->{_readers} } ) {
  54                 warn "# inventory on $rfid";
  55                 my @tags = $rfid->inventory;
  56
  57                 foreach my $tag ( @tags ) {
  58
  59                         $self->{blocks}->{$tag} ||= $rfid->read_blocks( $tag )->{$tag};
  60                         $self->{afi}->{$tag}    ||= $rfid->read_afi( $tag );
  61
  62                         $triggers->{enter}->( $self, $tag ) if ! $self->{inventory}->{$tag} && $triggers->{enter};
  63                         $self->{inventory}->{$tag} = $t;
  64
  65                 }
  66
  67                 foreach my $tag ( grep { $self->{inventory}->{$_} == 0 } keys %{ $self->{inventory} } ) {
  68                         $triggers->{leave}->( $self, $tag ) if $triggers->{leave};
  69                 }
  70
  71         }
  72
  73         warn "## tags ",dump($self);
  74
  75         return grep { $self->{inventory}->{$_} } keys %{ $self->{inventory} };
  76 }
  77
  78 =head2 blocks
  79
  80   my $blocks_arrayref = $rfid->blocks( $tag );
  81
  82 =head2 afi
  83
  84   my $afi = $rfid->afi( $tag );
  85
  86 =cut
  87
  88 sub blocks { $_[0]->{ 'blocks' }->{$_[1]} || die "no blocks for $_[1]"; };
  89 sub afi    { $_[0]->{ 'afi'    }->{$_[1]} || die "no afi for $_[1]"; };
  90
  91 =head1 PRIVATE
  92
  93 =head2 _invalidate_tag
  94
  95   $rfid->_invalidate_tag( $tag );
  96
  97 =cut
  98
  99 sub _invalidate_tag {
 100         my ( $self, $tag ) = @_;
 101         delete $self->{'blocks'}->{$tag};
 102         delete $self->{'afi'}->{$tag};
 103         delete $self->{'inventory'}->{$tag};
 104         warn "# _invalidate_tag $tag";
 105 }
 106
 107 =head2 _available
 108
 109 Probe each RFID reader supported and returns succefull ones
 110
 111   my $rfid_readers = RFID::Biblio::Reader->_available( $regex_filter );
 112
 113 =cut
 114
 115 my @readers = ( '3M810', 'CPRM02', 'librfid' );
 116
 117 sub _available {
 118         my ( $self, $filter ) = @_;
 119
 120         $filter = '' unless defined $filter;
 121
 122         warn "# filter: $filter";
 123
 124         my @rfid;
 125
 126         foreach my $reader ( @readers ) {
 127                 next if $filter && $reader !~ /$filter/i;
 128                 my $module = "RFID::Biblio::Reader::$reader";
 129                 eval "use $module";
 130                 die $@ if $@;
 131                 if ( my $rfid = $module->new( device => '/dev/ttyUSB0' ) ) {
 132                         push @rfid, $rfid;
 133                         warn "# added $module\n";
 134                 } else {
 135                         warn "# ignored $module\n";
 136                 }
 137         }
 138
 139         die "no readers found" unless @rfid;
 140
 141         return @rfid;
 142 }
 143
 144 =head1 AUTOLOAD
 145
 146 On any other function calls, we just marshall to all readers
 147
 148 =cut
 149
 150 # we don't want DESTROY to fallback into AUTOLOAD
 151 sub DESTROY {}
 152
 153 our $AUTOLOAD;
 154 sub AUTOLOAD {
 155         my $self = shift;
 156         my $command = $AUTOLOAD;
 157         $command =~ s/.*://;
 158
 159         my @out;
 160
 161         foreach my $r ( @{ $self->{_readers} } ) {
 162                 push @out, $r->$command(@_);
 163         }
 164
 165         $self->_invalidate_tag( $_[0] ) if $command =~ m/write/;
 166
 167         return @out;
 168 }
 169
 170 1
 171 __END__
 172
 173 =head1 SEE ALSO
 174
 175 =head2 RFID reader implementations
 176
 177 L<RFID::Biblio::Reader::3M810>
 178
 179 L<RFID::Biblio::Reader::CPRM02>
 180
 181 L<RFID::Biblio::Reader::librfid>
 182