git.rot13.org Git - webpac2/blob - lib/WebPAC/Config.pm

   1 package WebPAC::Config;
   2
   3 use warnings;
   4 use strict;
   5
   6 use base qw/WebPAC::Common/;
   7
   8 use Data::Dump qw/dump/;
   9 use YAML qw/LoadFile/;
  10
  11 =head1 NAME
  12
  13 WebPAC::Config - handle WebPAC configuration file
  14
  15 =head1 VERSION
  16
  17 Version 0.01
  18
  19 =cut
  20
  21 our $VERSION = '0.01';
  22
  23 =head1 SYNOPSIS
  24
  25 FIXME
  26
  27 =head1 FUNCTIONS
  28
  29 =head2 new
  30
  31 Create new configuration object.
  32
  33   my $config = new WebPAC::Config(
  34         path => '/optional/path/to/config.yml'
  35   );
  36
  37 =cut
  38
  39 sub new {
  40         my $class = shift;
  41         my $self = {@_};
  42         bless($self, $class);
  43
  44         my $log = $self->_get_logger();
  45
  46         if (! $self->{path}) {
  47                 my $hostname = `hostname`;
  48                 chomp($hostname);
  49                 $hostname =~ s/\..+$//;
  50                 if (-e "conf/$hostname.yml") {
  51                         $self->{path} = "conf/$hostname.yml";
  52                         $log->info("using host configuration file: ", $self->{path});
  53                 }
  54         }
  55
  56         $self->{path} ||= 'conf/config.yml';
  57
  58         $self->{config} = LoadFile($self->{path}) ||
  59                 $log->logdie("can't open ",$self->{path}, ": $!");
  60
  61         $log->debug("config: ", dump( $self->{config} ));
  62
  63         $self ? return $self : return undef;
  64 }
  65
  66 =head2 databases
  67
  68 Return all databases in config
  69
  70   my $config_databases_hash = $config->databases;
  71   my @config_databases_names = $config->databases;
  72
  73 =cut
  74
  75 sub databases {
  76         my $self = shift;
  77         return unless ($self->{config});
  78         if (wantarray) {
  79                 return keys %{ $self->{config}->{databases} };
  80         } else {
  81                 return $self->{config}->{databases};
  82         }
  83 }
  84
  85 =head2 use_indexer
  86
  87 Which indexer are we using?
  88
  89   $config->use_indexer;
  90
  91 =cut
  92
  93 sub use_indexer {
  94         my $self = shift;
  95         my $default = 'hyperestraier';
  96         return unless ($self->{config});
  97         return $self->{config}->{use_indexer} || $default;
  98 }
  99
 100 =head2 get
 101
 102   $config->get('top-level_key');
 103
 104 =cut
 105
 106 sub get {
 107         my $self = shift;
 108         my $what = shift || return;
 109         return $self->{config}->{$what};
 110 }
 111
 112 =head2 webpac
 113
 114 Return C<< config -> webpac >> parts
 115
 116   my @supported_inputs = $config->webpac('inputs');
 117   my $inputs_hash = $config->webpac('inputs');
 118
 119 =cut
 120
 121 sub webpac {
 122         my $self = shift;
 123
 124         $self->_get_logger()->logdie("can't find config->webpac") unless defined( $self->{config}->{webpac} );
 125
 126         my $what = shift || return $self->{config}->{webpac};
 127
 128         if (wantarray && ref( $self->{config}->{webpac}->{$what} ) eq 'HASH') {
 129                 return keys %{ $self->{config}->{webpac}->{$what} };
 130         } else {
 131                 return $self->{config}->{webpac}->{$what};
 132         }
 133
 134 }
 135
 136 =head2 iterate_inputs
 137
 138   $config->iterate_inputs( sub {
 139         my $input = shift;
 140         # ... do something with input config hash
 141   } );
 142
 143 =cut
 144
 145 sub iterate_inputs {
 146         my $self = shift;
 147
 148         my $log = $self->_get_logger();
 149
 150         my $code_ref = shift;
 151         $log->logdie("called with CODE") unless ( ref($code_ref) eq 'CODE' );
 152
 153         while (my ($database, $db_config) = each %{ $self->{config}->{databases} }) {
 154                 my @inputs;
 155                 if (ref($db_config->{input}) eq 'ARRAY') {
 156                         @inputs = @{ $db_config->{input} };
 157                 } elsif ($db_config->{input}) {
 158                         push @inputs, $db_config->{input};
 159                 } else {
 160                         $log->info("database $database doesn't have inputs defined");
 161                 }
 162
 163                 foreach my $input (@inputs) {
 164                         $log->debug("iterating over input ", dump($input));
 165                         $code_ref->($input);
 166                 }
 167         }
 168
 169 }
 170
 171
 172 =head1 AUTHOR
 173
 174 Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>
 175
 176 =head1 COPYRIGHT & LICENSE
 177
 178 Copyright 2006 Dobrica Pavlinusic, All Rights Reserved.
 179
 180 This program is free software; you can redistribute it and/or modify it
 181 under the same terms as Perl itself.
 182
 183 =cut
 184
 185 1; # End of WebPAC::Config