makeDist

   1 #!/bin/perl
   2 #
   3 # makeDist: Build a BackupPC distribution
   4 #
   5 # DESCRIPTION
   6 #
   7 #   This script should be run with no arguments to build a
   8 #   distribution.  The $Version and $ReleaseDate should be
   9 #   edited below to specify the version name and the release
  10 #   date.  The distribution is createede in the sub-directory
  11 #   dist.  The dsitribution is in the file name:
  12 #
  13 #           dist/BackupPC-$Version.tar.gz.
  14 #
  15 #   Often the language files are not up to date, and makeDist
  16 #   exits after complaining about the lang files being inconsistent.
  17 #   Use the -l option to turn off that behavior.
  18 #
  19 # AUTHOR
  20 #   Craig Barratt <cbarratt@users.sourceforge.net>
  21 #
  22 # COPYRIGHT
  23 #   Copyright (C) 2001-2007  Craig Barratt
  24 #
  25 #   This program is free software; you can redistribute it and/or modify
  26 #   it under the terms of the GNU General Public License as published by
  27 #   the Free Software Foundation; either version 2 of the License, or
  28 #   (at your option) any later version.
  29 #
  30 #   This program is distributed in the hope that it will be useful,
  31 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  32 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  33 #   GNU General Public License for more details.
  34 #
  35 #   You should have received a copy of the GNU General Public License
  36 #   along with this program; if not, write to the Free Software
  37 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  38 #
  39 #========================================================================
  40 #
  41
  42 use strict;
  43 use File::Path;
  44 use File::Copy;
  45 use Getopt::Std;
  46 use lib "./lib";
  47 use BackupPC::Lib;
  48 use BackupPC::Config::Meta qw(:all);
  49
  50 my $bpc;
  51 die("BackupPC::Lib->new failed\n")
  52         if ( !($bpc = BackupPC::Lib->new(".", ".", "./conf", 1)) );
  53
  54 umask(0022);
  55
  56 my $Version     = "3.1.0";
  57 my $ReleaseDate = "15 Apr 2007";
  58 my $DistDir     = "dist/BackupPC-$Version";
  59
  60 my @PerlSrc = qw(
  61     bin/BackupPC
  62     bin/BackupPC_archive
  63     bin/BackupPC_archiveHost
  64     bin/BackupPC_attribPrint
  65     bin/BackupPC_dump
  66     bin/BackupPC_fixupBackupSummary
  67     bin/BackupPC_link
  68     bin/BackupPC_nightly
  69     bin/BackupPC_restore
  70     bin/BackupPC_sendEmail
  71     bin/BackupPC_serverMesg
  72     bin/BackupPC_trashClean
  73     bin/BackupPC_tarExtract
  74     bin/BackupPC_tarCreate
  75     bin/BackupPC_tarPCCopy
  76     bin/BackupPC_compressPool
  77     bin/BackupPC_zipCreate
  78     bin/BackupPC_zcat
  79     lib/BackupPC/Attrib.pm
  80     lib/BackupPC/Config.pm
  81     lib/BackupPC/FileZIO.pm
  82     lib/BackupPC/Lib.pm
  83     lib/BackupPC/PoolWrite.pm
  84     lib/BackupPC/Storage.pm
  85     lib/BackupPC/View.pm
  86     lib/BackupPC/CGI/AdminOptions.pm
  87     lib/BackupPC/CGI/Archive.pm
  88     lib/BackupPC/CGI/ArchiveInfo.pm
  89     lib/BackupPC/CGI/Browse.pm
  90     lib/BackupPC/CGI/DirHistory.pm
  91     lib/BackupPC/CGI/EditConfig.pm
  92     lib/BackupPC/CGI/EmailSummary.pm
  93     lib/BackupPC/CGI/GeneralInfo.pm
  94     lib/BackupPC/CGI/HostInfo.pm
  95     lib/BackupPC/CGI/Lib.pm
  96     lib/BackupPC/CGI/LOGlist.pm
  97     lib/BackupPC/CGI/Queue.pm
  98     lib/BackupPC/CGI/ReloadServer.pm
  99     lib/BackupPC/CGI/RestoreFile.pm
 100     lib/BackupPC/CGI/RestoreInfo.pm
 101     lib/BackupPC/CGI/Restore.pm
 102     lib/BackupPC/CGI/RSS.pm
 103     lib/BackupPC/CGI/StartServer.pm
 104     lib/BackupPC/CGI/StartStopBackup.pm
 105     lib/BackupPC/CGI/StopServer.pm
 106     lib/BackupPC/CGI/Summary.pm
 107     lib/BackupPC/CGI/View.pm
 108     lib/BackupPC/Config/Meta.pm
 109     lib/BackupPC/Lang/de.pm
 110     lib/BackupPC/Lang/en.pm
 111     lib/BackupPC/Lang/es.pm
 112     lib/BackupPC/Lang/fr.pm
 113     lib/BackupPC/Lang/it.pm
 114     lib/BackupPC/Lang/nl.pm
 115     lib/BackupPC/Lang/pt_br.pm
 116     lib/BackupPC/Storage/Text.pm
 117     lib/BackupPC/Xfer/Archive.pm
 118     lib/BackupPC/Xfer/BackupPCd.pm
 119     lib/BackupPC/Xfer/Smb.pm
 120     lib/BackupPC/Xfer/Tar.pm
 121     lib/BackupPC/Xfer/Rsync.pm
 122     lib/BackupPC/Xfer/RsyncDigest.pm
 123     lib/BackupPC/Xfer/RsyncFileIO.pm
 124     lib/BackupPC/Zip/FileMember.pm
 125     cgi-bin/BackupPC_Admin
 126 );
 127
 128 my %opts;
 129 if ( !getopts("l", \%opts) || @ARGV != 0 ) {
 130     print("usage: $0 [-l]\n");
 131     exit(1);
 132 }
 133
 134 #
 135 # Check config parameters
 136 #
 137 my $ConfVars = {};
 138 my $errCnt;
 139
 140 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
 141
 142 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
 143
 144 $errCnt += CheckMetaDataVsConfig($ConfVars, "lib/BackupPC/Config/Meta.pm");
 145
 146 $errCnt += CheckEditorVsConfig($ConfVars, "lib/BackupPC/CGI/EditConfig.pm");
 147
 148 #
 149 # These config parameters are not used in the code, so ignore them.
 150 #
 151 $ConfVars->{BackupPCUser} = 2;
 152 $ConfVars->{CgiDir}       = 2;
 153 $ConfVars->{TopDir}       = 2;
 154 $ConfVars->{LogDir}       = 2;
 155 $ConfVars->{ConfDir}      = 2;
 156 $ConfVars->{InstallDir}   = 2;
 157 $ConfVars->{CgiImageDir}  = 2;
 158
 159 #
 160 # These config parameters are used in the code to be backward compatible,
 161 # but are not present in the current config file, so ignore them.
 162 #
 163 $ConfVars->{BlackoutHourBegin} = 2;
 164 $ConfVars->{BlackoutHourEnd}   = 2;
 165 $ConfVars->{BlackoutWeekDays}  = 2;
 166 $ConfVars->{RsyncLogLevel}     = 2;
 167
 168 foreach my $file ( @PerlSrc ) {
 169     $errCnt += CheckConfigParams($file, $ConfVars, 1);
 170 }
 171 if ( !$opts{l} ) {
 172     $errCnt += CheckLangUsage();
 173     $errCnt += CheckLangTags();
 174 }
 175 if ( $errCnt ) {
 176     print("Exiting because of errors\n");
 177     exit(1)
 178 }
 179
 180 $errCnt = 0;
 181 foreach my $var ( sort(keys(%$ConfVars) ) ) {
 182     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
 183     printf("Unused config parameter $var\n");
 184     $errCnt++;
 185 }
 186 if ( $errCnt ) {
 187     print("Exiting because of errors\n");
 188     exit(1)
 189 }
 190
 191 rmtree($DistDir, 0, 0);
 192 mkpath($DistDir, 0, 0777);
 193
 194 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin
 195                      lib/BackupPC/CGI
 196                      lib/BackupPC/Config
 197                      lib/BackupPC/Lang
 198                      lib/BackupPC/Storage
 199                      lib/BackupPC/Xfer
 200                      lib/BackupPC/Zip
 201                 ) ) {
 202     mkpath("$DistDir/$dir", 0, 0777);
 203 }
 204
 205 my %ConfName;
 206 my $ConfPod = config2pod();
 207 rmtree("doc", 0, 0);
 208 mkpath("doc", 0, 0777);
 209 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
 210
 211 use Pod::Html;
 212 pod2html("doc/BackupPC.pod",
 213         "--backlink=Back to Top",
 214         "--header",
 215         "--title=BackupPC",
 216         "--outfile=doc/BackupPC.html");
 217
 218 foreach my $file ( (@PerlSrc,
 219             <images/*.gif>,
 220             <images/*.png>,
 221             qw(
 222                 conf/config.pl
 223                 conf/hosts
 224                 conf/BackupPC_stnd.css
 225                 conf/BackupPC_stnd_orig.css
 226                 conf/sorttable.js
 227                 init.d/README
 228                 init.d/src/debian-backuppc
 229                 init.d/src/freebsd-backuppc
 230                 init.d/src/gentoo-backuppc
 231                 init.d/src/gentoo-backuppc.conf
 232                 init.d/src/linux-backuppc
 233                 init.d/src/slackware-backuppc
 234                 init.d/src/solaris-backuppc
 235                 init.d/src/suse-backuppc
 236                 doc/BackupPC.pod
 237                 doc/BackupPC.html
 238                 README
 239                 LICENSE
 240                 ChangeLog
 241                 configure.pl
 242         )) ) {
 243     InstallFile("$file", "$DistDir/$file");
 244 }
 245 rmtree("doc", 0, 0);
 246 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
 247 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
 248 unlink("pod2htmd.x~~");
 249 unlink("pod2htmi.x~~");
 250 unlink("pod2htmd.tmp");
 251 unlink("pod2htmi.tmp");
 252
 253 ###########################################################################
 254 # Subroutines
 255 ###########################################################################
 256
 257 sub InstallFile
 258 {
 259     my($file, $dest) = @_;
 260
 261     unlink($dest) if ( -d $dest );
 262     if ( $file =~ /\.gif/ || $file =~ /\.png/ ) {
 263         die("can't copy($file, $dest)\n") unless copy($file, $dest);
 264     } else {
 265         open(FILE, $file)   || die("can't open $file for reading\n");
 266         open(OUT, ">$dest") || die("can't open $dest for writing\n");
 267         binmode(FILE);
 268         binmode(OUT);
 269         while ( <FILE> ) {
 270             s/^([#*\s]+)Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/$1Version __VERSION__, released __RELEASEDATE__./;
 271             s/__VERSION__/$Version/g;
 272             s/__RELEASEDATE__/$ReleaseDate/g;
 273             if ( $file =~ /BackupPC\.html$/ ) {
 274                 #
 275                 # fixup for conf links
 276                 #
 277                 if ( !/A NAME="item_(%|_)conf/i ) {
 278                     s/\$Conf{([^}]*)}/
 279                         defined($ConfName{$1})
 280                             ? "\L<a href=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
 281                             : "\$Conf{$1}"/eg;
 282                 }
 283                 s/^<DD>/<DD><P>/;
 284                 s/^<li><\/li>/<li>/;
 285             }
 286             if ( /__CONFIGPOD__/ ) {
 287                 print OUT $ConfPod;
 288             } elsif ( /^use lib ".*BackupPC\/lib";/
 289                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
 290                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
 291             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$topDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
 292                 print OUT "$1'__TOPDIR__'$2\n";
 293             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$installDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
 294                 print OUT "$1'__INSTALLDIR__'$2\n";
 295             } elsif ( $file =~ /Lib.pm/ && /^(\s*my \$useFHS\s*=\s*)\d;/ ) {
 296                 print OUT "${1}0;\n";
 297             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
 298                 print OUT "$1'$Version',\n";
 299             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_BIN_LIST__/ ) {
 300                 print OUT "        ", join("\n        ", grep(/^bin\//, @PerlSrc)), "\n";
 301             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_LIB_LIST__/ ) {
 302                 print OUT "        ", join("\n        ", grep(/^lib\//, @PerlSrc)), "\n";
 303             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
 304                 print OUT "$1'__INSTALLDIR__/lib';\n";
 305             } else {
 306                 print OUT;
 307             }
 308         }
 309         close(FILE);
 310         close(OUT);
 311     }
 312     if ( -x $file ) {
 313         chmod(0555, $dest);
 314     } else {
 315         chmod(0444, $dest);
 316     }
 317 }
 318
 319 sub config2pod
 320 {
 321     open(C, "conf/config.pl") || die("can't open conf/config.pl");
 322     binmode(C);
 323     my($str, $out, $getHdr, @conf);
 324     my $first = 1;
 325     while ( <C> ) {
 326         chomp;
 327         s/ +$//;
 328         if ( /^#########################/ ) {
 329             if ( $getHdr ) {
 330                 $str =~ s/\n.*//sg;
 331                 $out .= "=back\n\n" if ( !$first );
 332                 $out .= "=head2 $str\n\n=over 4\n\n";
 333                 $str = "";
 334                 $first = 0;
 335             }
 336             $getHdr = !$getHdr;
 337             next;
 338         }
 339         if ( /^#/ ) {
 340             s/# ?//;
 341             next if ( $str eq "" && /^$/ );
 342             $str .= $_ . "\n";
 343             $str .= "\n" if ( $str =~ /examples?:\n$/i );
 344         } elsif ( /^\$Conf{([^}]*)/ ) {
 345             my $var = $1;
 346             s/  +/ /g;
 347             s/;\s*#.*/;/;
 348             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
 349                 s/([^;])\s*$/$1 .../;
 350             }
 351             push(@conf, $_);
 352             my $text = "_conf_${var}_";
 353             $text =~ s{[\W\s]}{_}g;
 354             $ConfName{$var} = "item_$text";
 355         } elsif ( /^$/ ) {
 356             if ( $str ne "" && @conf ) {
 357                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
 358                 $out .= $str;
 359                 $out .= "\n" if ( $str !~ /\n$/ );
 360             }
 361             $str = "";
 362             @conf = ();
 363         }
 364     }
 365     if ( $str ne "" && @conf ) {
 366         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
 367         $out .= $str;
 368         $out .= "\n" if ( $str !~ /\n$/ );
 369     }
 370     $out .= "=back\n\n" if ( !$first );
 371     return $out;
 372 }
 373
 374 sub CheckConfigParams
 375 {
 376     my($file, $vars, $check) = @_;
 377     my $errors;
 378
 379     open(F, $file) || die("can't open $file\n");
 380     binmode(F);
 381     if ( $check ) {
 382         while ( <F> ) {
 383             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
 384                     print("Unexpected Conf var $2 in $file\n");
 385                     $errors++;
 386                 } else {
 387                     $vars->{$2}++;
 388                 }/eg;
 389             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
 390                     print("Unexpected Conf var $1 in $file\n");
 391                     $errors++;
 392                 } else {
 393                     $vars->{$1}++;
 394                 }/eg;
 395             s/UserCommandRun\("([^"]*)"/if ( !defined($vars->{$1}) ) {
 396                     print("Unexpected Conf var $1 in $file\n");
 397                     $errors++;
 398                 } else {
 399                     $vars->{$1}++;
 400                 }/eg;
 401         }
 402     } else {
 403         while ( <F> ) {
 404             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
 405             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
 406         }
 407     }
 408     close(F);
 409     return $errors;
 410 }
 411
 412 sub CheckMetaDataVsConfig
 413 {
 414     my($confVars, $file) = @_;
 415     my $done = {};
 416     my $errors;
 417
 418     #
 419     # Check that the meta file mentions all the config
 420     # parameters
 421     #
 422     open(F, $file) || die("can't open $file");
 423
 424     while ( <F> ) {
 425         next if ( !/^\s{4}(\w+)\s+=>/ );
 426         if ( $confVars->{$1} ) {
 427             $done->{$1} = 1;
 428             next;
 429         }
 430         next if ( $1 eq "Hosts" );
 431         print("$file has $1 but missing from conf/config.pl\n");
 432         $errors++;
 433     }
 434     close(F);
 435     foreach my $v ( keys(%$confVars) ) {
 436         next if ( $done->{$v} );
 437         print("$file missing $v from conf/config.pl\n");
 438         $errors++;
 439     }
 440
 441     #
 442     # Do extra checks that the CgiUserConfigEdit hash in the Meta
 443     # file matches the config file
 444     #
 445     foreach my $p ( keys(%{$ConfigMeta{CgiUserConfigEdit}{child}}) ) {
 446         if ( !defined($bpc->{Conf}{CgiUserConfigEdit}{$p}) ) {
 447             print("lib/BackupPC/Config/Meta.pm has $p in CgiUserConfigEdit,"
 448                 . " but conf/config.pl CgiUserConfigEdit does not\n");
 449             $errors++;
 450         }
 451     }
 452     foreach my $p ( keys(%{$bpc->{Conf}{CgiUserConfigEdit}}) ) {
 453         if ( !defined($ConfigMeta{CgiUserConfigEdit}{child}{$p}) ) {
 454             print("conf/config.pl CgiUserConfigEdit has $p, but"
 455                 . " lib/BackupPC/Config/Meta.pm does not\n");
 456             $errors++;
 457         }
 458     }
 459     return $errors;
 460 }
 461
 462 sub CheckEditorVsConfig
 463 {
 464     my($confVars, $file) = @_;
 465     my $done = {};
 466     my $errors;
 467
 468     #
 469     # Check that the config editor file mentions all the config
 470     # parameters
 471     #
 472     open(F, $file) || die("can't open $file");
 473
 474     while ( <F> ) {
 475         next if ( !/name\s*=>\s*"(\w+)"/ );
 476         if ( $confVars->{$1} ) {
 477             $done->{$1} = 1;
 478             next;
 479         }
 480         next if ( $1 eq "Hosts" );
 481         print("$file has $1 but missing from conf/config.pl\n");
 482         $errors++;
 483     }
 484     close(F);
 485     foreach my $v ( keys(%$confVars) ) {
 486         next if ( $done->{$v} );
 487         print("$file missing $v from conf/config.pl\n");
 488         $errors++;
 489     }
 490     return $errors;
 491 }
 492
 493 #
 494 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
 495 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
 496 # we didn't miss any translations in any of the languages.
 497 #
 498 sub CheckLangUsage
 499 {
 500     my $errors;
 501     my $vars = {};
 502
 503     foreach my $file ( (
 504                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
 505                 <lib/BackupPC/CGI/*pm>,
 506                 <lib/BackupPC/Lang/en.pm>,
 507             ) ) {
 508         open(F, $file) || die("can't open $file");
 509         binmode(F);
 510         while ( <F> ) {
 511             next if ( /^\s*#/ );
 512             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
 513             s/(text|comment)\s*=>\s*"(CfgEdit_.*)"/$vars->{$2} = 1;/eg;
 514         }
 515         close(F);
 516     }
 517
 518     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
 519         my $done = {};
 520         open(F, $f) || die("can't open $f\n");
 521         binmode(F);
 522         while ( <F> ) {
 523             s/#.*//g;
 524             s/\$Lang{([^}]*)}/
 525                     my $var = $1;
 526                     next if ( $var =~ m{^(Reason_|Status_|backupType_|Disabled_)} );
 527                     next if ( $var eq "Documentation" );
 528                     if ( !defined($vars->{$var}) ) {
 529                         print("Unexpected Lang var $var in $f\n");
 530                         $errors++;
 531                     } else {
 532                         $done->{$var} = 1;
 533                     }/eg;
 534         }
 535         close(F);
 536         foreach my $v ( keys(%$vars) ) {
 537             #
 538             # skip "variables" with "$", since they are like expressions
 539             #
 540             next if ( $v =~ /\$/ );
 541             if ( !defined($done->{$v}) ) {
 542                 print("Lang var $v missing from $f\n");
 543                 $errors++;
 544             }
 545         }
 546     }
 547     return $errors;
 548 }
 549
 550 #
 551 # Pedantically check that all the html tags in each language file
 552 # match.
 553 #
 554 sub CheckLangTags
 555 {
 556     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
 557     my($errors);
 558
 559     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm nl.pm pt_br.pm) ) {
 560         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
 561         foreach my $v1 ( @$en ) {
 562             my $v2 = shift(@$d);
 563             if ( $v1->{var} ne $v2->{var} ) {
 564                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
 565                 exit;
 566             }
 567             my $t1 = LangTextStrip($v1->{val});
 568             my $t2 = LangTextStrip($v2->{val});
 569             if ( $t1 ne $t2 ) {
 570                 my $i;
 571                 for ( $i = 0 ; $i < length($t1) ; $i++ ) {
 572                     last if ( substr($t1, 0, $i) ne substr($t2, 0, $i) );
 573                 }
 574                 print("$v1->{var}: ($i) got en.pm $t1\nvs $lang $t2\n\n");
 575                 $errors++;
 576             }
 577         }
 578     }
 579     return $errors;
 580 }
 581
 582 sub LangTextStrip
 583 {
 584     my($t) = @_;
 585
 586     $t = "" if ( $t !~ /<.*>/ );
 587     $t =~ s/^[^<]*</</s;
 588     $t =~ s/([}>])[^<]*</$1</g;
 589     $t =~ s/>[^<]*$/>/;
 590     $t =~ s/(value=)"[^"]*"/$1""/sg;
 591     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
 592     $t =~ s/ENG[\s\n]*//sg;
 593     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
 594     return $t;
 595 }
 596
 597 sub LangParse
 598 {
 599     my($file) = @_;
 600     open(C, $file) || die("can't open $file");
 601     binmode(C);
 602     my($out, @lang, $var);
 603     my $comment = 1;
 604     my $allVars = {};
 605     my $endLine = undef;
 606     while ( <C> ) {
 607         if ( /^#/ && !defined($endLine) ) {
 608             if ( $comment ) {
 609                 $out .= $_;
 610             } else {
 611                 if ( $out ne "" ) {
 612                     $allVars->{$var} = @lang if ( defined($var) );
 613                     push(@lang, {
 614                         text => $out,
 615                         var => $var,
 616                     });
 617                 }
 618                 $var = undef;
 619                 $comment = 1;
 620                 $out = $_;
 621             }
 622         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
 623             $comment = 0;
 624             if ( defined($var) ) {
 625                 $allVars->{$var} = @lang if ( defined($var) );
 626                 push(@lang, {
 627                     text => $out,
 628                     var => $var,
 629                 });
 630                 $out = $_;
 631             } else {
 632                 $out .= $_;
 633             }
 634             $var = $1;
 635             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
 636             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
 637         } else {
 638             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
 639             $out .= $_;
 640         }
 641     }
 642     if ( $out ne "" ) {
 643         $allVars->{$var} = @lang if ( defined($var) );
 644         push(@lang, {
 645             text => $out,
 646             var  => $var,
 647         });
 648     }
 649     close(C);
 650     foreach my $v ( @lang ) {
 651         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
 652             $v->{val} = $1;
 653         }
 654     }
 655     return (\@lang, $allVars);
 656 }