makeDist

   1 #!/usr/bin/env perl
   2 #
   3 # makeDist: Build a BackupPC distribution
   4 #
   5 # DESCRIPTION
   6 #
   7 #   This script should be run with no arguments to build a
   8 #   distribution.  The $Version and $ReleaseDate should be
   9 #   edited below to specify the version name and the release
  10 #   date.  The distribution is createede in the sub-directory
  11 #   dist.  The dsitribution is in the file name:
  12 #
  13 #           dist/BackupPC-$Version.tar.gz.
  14 #
  15 #   Often the language files are not up to date, and makeDist
  16 #   exits after complaining about the lang files being inconsistent.
  17 #   Use the -nolangCheck option to turn off that behavior.
  18 #
  19 # AUTHOR
  20 #   Craig Barratt <cbarratt@users.sourceforge.net>
  21 #
  22 # COPYRIGHT
  23 #   Copyright (C) 2001-2009  Craig Barratt
  24 #
  25 #   This program is free software; you can redistribute it and/or modify
  26 #   it under the terms of the GNU General Public License as published by
  27 #   the Free Software Foundation; either version 2 of the License, or
  28 #   (at your option) any later version.
  29 #
  30 #   This program is distributed in the hope that it will be useful,
  31 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  32 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  33 #   GNU General Public License for more details.
  34 #
  35 #   You should have received a copy of the GNU General Public License
  36 #   along with this program; if not, write to the Free Software
  37 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  38 #
  39 #========================================================================
  40
  41 use strict;
  42 use File::Path;
  43 use File::Copy;
  44 use Getopt::Long;
  45 use Data::Dumper;
  46
  47 use lib "./lib";
  48 use BackupPC::Lib;
  49 use BackupPC::Config::Meta qw(:all);
  50
  51 my $bpc;
  52 die("BackupPC::Lib->new failed\n")
  53         if ( !($bpc = BackupPC::Lib->new(".", ".", "./conf", 1)) );
  54
  55 umask(0022);
  56
  57 my @PerlSrc = qw(
  58     bin/BackupPC
  59     bin/BackupPC_archive
  60     bin/BackupPC_archiveHost
  61     bin/BackupPC_archiveStart
  62     bin/BackupPC_attribPrint
  63     bin/BackupPC_dump
  64     bin/BackupPC_fixupBackupSummary
  65     bin/BackupPC_link
  66     bin/BackupPC_nightly
  67     bin/BackupPC_restore
  68     bin/BackupPC_sendEmail
  69     bin/BackupPC_serverMesg
  70     bin/BackupPC_trashClean
  71     bin/BackupPC_tarExtract
  72     bin/BackupPC_tarCreate
  73     bin/BackupPC_tarPCCopy
  74     bin/BackupPC_zipCreate
  75     bin/BackupPC_zcat
  76     lib/BackupPC/Attrib.pm
  77     lib/BackupPC/Config.pm
  78     lib/BackupPC/FileZIO.pm
  79     lib/BackupPC/Lib.pm
  80     lib/BackupPC/PoolWrite.pm
  81     lib/BackupPC/Storage.pm
  82     lib/BackupPC/View.pm
  83     lib/BackupPC/CGI/AdminOptions.pm
  84     lib/BackupPC/CGI/Archive.pm
  85     lib/BackupPC/CGI/ArchiveInfo.pm
  86     lib/BackupPC/CGI/Browse.pm
  87     lib/BackupPC/CGI/DirHistory.pm
  88     lib/BackupPC/CGI/EditConfig.pm
  89     lib/BackupPC/CGI/EmailSummary.pm
  90     lib/BackupPC/CGI/GeneralInfo.pm
  91     lib/BackupPC/CGI/HostInfo.pm
  92     lib/BackupPC/CGI/Lib.pm
  93     lib/BackupPC/CGI/LOGlist.pm
  94     lib/BackupPC/CGI/Queue.pm
  95     lib/BackupPC/CGI/ReloadServer.pm
  96     lib/BackupPC/CGI/RestoreFile.pm
  97     lib/BackupPC/CGI/RestoreInfo.pm
  98     lib/BackupPC/CGI/Restore.pm
  99     lib/BackupPC/CGI/RSS.pm
 100     lib/BackupPC/CGI/StartServer.pm
 101     lib/BackupPC/CGI/StartStopBackup.pm
 102     lib/BackupPC/CGI/StopServer.pm
 103     lib/BackupPC/CGI/Summary.pm
 104     lib/BackupPC/CGI/View.pm
 105     lib/BackupPC/Config/Meta.pm
 106     lib/BackupPC/Lang/de.pm
 107     lib/BackupPC/Lang/en.pm
 108     lib/BackupPC/Lang/es.pm
 109     lib/BackupPC/Lang/fr.pm
 110     lib/BackupPC/Lang/it.pm
 111     lib/BackupPC/Lang/nl.pm
 112     lib/BackupPC/Lang/pl.pm
 113     lib/BackupPC/Lang/pt_br.pm
 114     lib/BackupPC/Lang/zh_CN.pm
 115     lib/BackupPC/Storage/Text.pm
 116     lib/BackupPC/Xfer.pm
 117     lib/BackupPC/Xfer/Archive.pm
 118     lib/BackupPC/Xfer/Ftp.pm
 119     lib/BackupPC/Xfer/Protocol.pm
 120     lib/BackupPC/Xfer/Rsync.pm
 121     lib/BackupPC/Xfer/RsyncDigest.pm
 122     lib/BackupPC/Xfer/RsyncFileIO.pm
 123     lib/BackupPC/Xfer/Smb.pm
 124     lib/BackupPC/Xfer/Tar.pm
 125     lib/BackupPC/Zip/FileMember.pm
 126     lib/Net/FTP/AutoReconnect.pm
 127     lib/Net/FTP/RetrHandle.pm
 128     cgi-bin/BackupPC_Admin
 129 );
 130
 131 my %opts;
 132 $opts{langCheck}   = 1;
 133 $opts{syntaxCheck} = 1;
 134 if ( !GetOptions(
 135                  \%opts,
 136                  "langCheck!",
 137                  "syntaxCheck!",
 138                  "version=s",
 139                  "releasedate=s",
 140            ) || @ARGV != 0
 141              || !defined($opts{version})
 142         ) {
 143     print STDERR <<EOF;
 144 usage: $0 [--nolangCheck] [--nosyntaxCheck] [--releasedate 'DD MMM YYYY'] --version X.Y.Z
 145 EOF
 146     exit(1);
 147 }
 148
 149 my($sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst) = localtime();
 150 $year += 1900;
 151
 152 my @month_abbr  = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 153
 154 my $Version     = $opts{version} || "3.2.0";
 155 my $ReleaseDate = $opts{releasedate} || "$mday $month_abbr[$mon] $year";
 156 my $DistDir     = "dist/BackupPC-$Version";
 157
 158 #
 159 # Check config parameters
 160 #
 161 my $ConfVars = {};
 162 my $errCnt;
 163
 164 $errCnt += CheckConfigParams("conf/config.pl", $ConfVars, 0);
 165
 166 $errCnt += CheckConfigParams("doc-src/BackupPC.pod", $ConfVars, 1);
 167
 168 $errCnt += CheckMetaDataVsConfig($ConfVars, "lib/BackupPC/Config/Meta.pm");
 169
 170 $errCnt += CheckEditorVsConfig($ConfVars, "lib/BackupPC/CGI/EditConfig.pm");
 171
 172 #
 173 # These config parameters are not used in the code, so ignore them.
 174 #
 175 $ConfVars->{BackupPCUser} = 2;
 176 $ConfVars->{CgiDir}       = 2;
 177 $ConfVars->{TopDir}       = 2;
 178 $ConfVars->{LogDir}       = 2;
 179 $ConfVars->{ConfDir}      = 2;
 180 $ConfVars->{InstallDir}   = 2;
 181 $ConfVars->{CgiImageDir}  = 2;
 182 $ConfVars->{ClientCharsetLegacy}  = 2;      # actually used
 183
 184 #
 185 # These config parameters are used in the code to be backward compatible,
 186 # but are not present in the current config file, so ignore them.
 187 #
 188 $ConfVars->{BlackoutHourBegin} = 2;
 189 $ConfVars->{BlackoutHourEnd}   = 2;
 190 $ConfVars->{BlackoutWeekDays}  = 2;
 191 $ConfVars->{RsyncLogLevel}     = 2;
 192
 193 if ( $opts{syntaxCheck} ) {
 194     system("perl -Ilib -c conf/config.pl >& /dev/null")
 195             && die("$0: conf/config.pl contains a syntax error (or someone killed me)\n");
 196 }
 197 foreach my $file ( @PerlSrc ) {
 198     if ( $opts{syntaxCheck} ) {
 199         system("perl -Ilib -c $file >& /dev/null")
 200             && die("$0: $file contains a syntax error (or someone killed me)\n");
 201     }
 202     #
 203     # Skip checking of bundled libraries not explicitly part of
 204     # BackupPC
 205     #
 206     next if ( $file =~ m/lib\/Net\/FTP/ );
 207     $errCnt += CheckConfigParams($file, $ConfVars, 1);
 208 }
 209 if ( !$opts{langCheck} ) {
 210     $errCnt += CheckLangUsage();
 211     $errCnt += CheckLangTags();
 212 }
 213 if ( $errCnt ) {
 214     print("Exiting because of errors\n");
 215     exit(1)
 216 }
 217
 218 $errCnt = 0;
 219 foreach my $var ( sort(keys(%$ConfVars) ) ) {
 220     next if ( $ConfVars->{$var} >= 2 || $var =~ /^\$/ );
 221     printf("Unused config parameter $var\n");
 222     $errCnt++;
 223 }
 224 if ( $errCnt ) {
 225     print("Exiting because of errors\n");
 226     exit(1)
 227 }
 228
 229 rmtree($DistDir, 0, 0);
 230 mkpath($DistDir, 0, 0777);
 231
 232 foreach my $dir ( qw(bin doc conf images init.d/src cgi-bin httpd/src
 233                      lib/BackupPC/CGI
 234                      lib/BackupPC/Config
 235                      lib/BackupPC/Lang
 236                      lib/BackupPC/Storage
 237                      lib/BackupPC/Xfer
 238                      lib/BackupPC/Zip
 239                      lib/Net/FTP
 240                 ) ) {
 241     mkpath("$DistDir/$dir", 0, 0777);
 242 }
 243
 244 my %ConfName;
 245 my $ConfPod = config2pod();
 246 rmtree("doc", 0, 0);
 247 mkpath("doc", 0, 0777);
 248 InstallFile("doc-src/BackupPC.pod", "doc/BackupPC.pod");
 249
 250 use Pod::Html;
 251 pod2html("doc/BackupPC.pod",
 252         "--backlink=Back to Top",
 253         "--header",
 254         "--title=BackupPC",
 255         "--outfile=doc/BackupPC.html");
 256
 257 foreach my $file ( (@PerlSrc,
 258             <images/*.gif>,
 259             <images/*.png>,
 260             qw(
 261                 conf/config.pl
 262                 conf/hosts
 263                 conf/BackupPC_stnd.css
 264                 conf/BackupPC_stnd_orig.css
 265                 conf/sorttable.js
 266                 init.d/README
 267                 init.d/src/debian-backuppc
 268                 init.d/src/freebsd-backuppc
 269                 init.d/src/freebsd-backuppc2
 270                 init.d/src/gentoo-backuppc
 271                 init.d/src/gentoo-backuppc.conf
 272                 init.d/src/linux-backuppc
 273                 init.d/src/slackware-backuppc
 274                 init.d/src/solaris-backuppc
 275                 init.d/src/suse-backuppc
 276                 httpd/src/BackupPC.conf
 277                 doc/BackupPC.pod
 278                 doc/BackupPC.html
 279                 README
 280                 LICENSE
 281                 ChangeLog
 282                 configure.pl
 283         )) ) {
 284     InstallFile("$file", "$DistDir/$file");
 285 }
 286 rmtree("doc", 0, 0);
 287 system("cd dist ; tar zcf BackupPC-$Version.tar.gz BackupPC-$Version");
 288 print("Distribution written to dist/BackupPC-$Version.tar.gz\n");
 289 unlink("pod2htmd.x~~");
 290 unlink("pod2htmi.x~~");
 291 unlink("pod2htmd.tmp");
 292 unlink("pod2htmi.tmp");
 293
 294 ###########################################################################
 295 # Subroutines
 296 ###########################################################################
 297
 298 sub InstallFile
 299 {
 300     my($file, $dest) = @_;
 301
 302     unlink($dest) if ( -d $dest );
 303     if ( $file =~ /\.gif/ || $file =~ /\.png/ ) {
 304         die("can't copy($file, $dest)\n") unless copy($file, $dest);
 305     } else {
 306         open(FILE, $file)   || die("can't open $file for reading\n");
 307         open(OUT, ">$dest") || die("can't open $dest for writing\n");
 308         binmode(FILE);
 309         binmode(OUT);
 310         while ( <FILE> ) {
 311             s/^([#*\s]+)Version \d+\.\d+[\.\w]*, released \d+ \w+ \d{4}\.?/$1Version __VERSION__, released __RELEASEDATE__./;
 312             s/__VERSION__/$Version/g;
 313             s/__RELEASEDATE__/$ReleaseDate/g;
 314             if ( $file =~ /BackupPC\.html$/ ) {
 315                 #
 316                 # fixup for conf links
 317                 #
 318                 if ( !/A NAME="item_(%|_)conf/i ) {
 319                     s/\$Conf{([^}]*)}/
 320                         defined($ConfName{$1})
 321                             ? "\L<a href=\"#$ConfName{$1}\">\E\$Conf{$1}<\/A>"
 322                             : "\$Conf{$1}"/eg;
 323                 }
 324                 s/^<DD>/<DD><P>/;
 325                 s/^<li><\/li>/<li>/;
 326             }
 327             if ( /__CONFIGPOD__/ ) {
 328                 print OUT $ConfPod;
 329             } elsif ( /^use lib ".*BackupPC\/lib";/
 330                     || /^use lib "\/home\/pcbackup\/install\/lib";/ ) {
 331                 print OUT "use lib \"__INSTALLDIR__/lib\";\n";
 332             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$topDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
 333                 print OUT "$1'__TOPDIR__'$2\n";
 334             } elsif ( $file =~ /Lib.pm/ && /^(\s*\$installDir\s*=\s*)'.*'(\s*if\s.*)/ ) {
 335                 print OUT "$1'__INSTALLDIR__'$2\n";
 336             } elsif ( $file =~ /Lib.pm/ && /^(\s*ConfDir\s*=\>\s*\$confDir eq.*)'.*'(.*)/ ) {
 337                 print OUT "$1'__CONFDIR__'$2\n";
 338             } elsif ( $file =~ /Lib.pm/ && /^(\s*my \$useFHS\s*=\s*)\d;/ ) {
 339                 print OUT "${1}0;\n";
 340             } elsif ( $file =~ /Lib.pm/ && /(.*Version *=> .*)'[\w\d\.]+',/ ) {
 341                 print OUT "$1'$Version',\n";
 342             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_BIN_LIST__/ ) {
 343                 print OUT "        ", join("\n        ", grep(/^bin\//, @PerlSrc)), "\n";
 344             } elsif ( $file =~ /configure.pl/ && /__CONFIGURE_LIB_LIST__/ ) {
 345                 print OUT "        ", join("\n        ", grep(/^lib\//, @PerlSrc)), "\n";
 346             } elsif ( $file =~ /BackupPC_Admin/ && /(my *\$installDir *= *)'.*'/ ) {
 347                 print OUT "$1'__INSTALLDIR__/lib';\n";
 348             } else {
 349                 print OUT;
 350             }
 351         }
 352         close(FILE);
 353         close(OUT);
 354     }
 355     if ( -x $file ) {
 356         chmod(0555, $dest);
 357     } else {
 358         chmod(0444, $dest);
 359     }
 360 }
 361
 362 sub config2pod
 363 {
 364     open(C, "conf/config.pl") || die("can't open conf/config.pl");
 365     binmode(C);
 366     my($str, $out, $getHdr, @conf);
 367     my $first = 1;
 368     while ( <C> ) {
 369         chomp;
 370         s/ +$//;
 371         if ( /^#########################/ ) {
 372             if ( $getHdr ) {
 373                 $str =~ s/\n.*//sg;
 374                 $out .= "=back\n\n" if ( !$first );
 375                 $out .= "=head2 $str\n\n=over 4\n\n";
 376                 $str = "";
 377                 $first = 0;
 378             }
 379             $getHdr = !$getHdr;
 380             next;
 381         }
 382         if ( /^#/ ) {
 383             s/# ?//;
 384             next if ( $str eq "" && /^$/ );
 385             $str .= $_ . "\n";
 386             $str .= "\n" if ( $str =~ /examples?:\n$/i );
 387         } elsif ( /^\$Conf{([^}]*)/ ) {
 388             my $var = $1;
 389             s/  +/ /g;
 390             s/;\s*#.*/;/;
 391             if ( !s/\[$/[ ... ];/ && !s/<<'EOF'/.../ ) {
 392                 s/([^;])\s*$/$1 .../;
 393             }
 394             push(@conf, $_);
 395             my $text = "_conf_${var}_";
 396             $text =~ s{[\W\s]}{_}g;
 397             $ConfName{$var} = "item_$text";
 398         } elsif ( /^$/ ) {
 399             if ( $str ne "" && @conf ) {
 400                 $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
 401                 $out .= $str;
 402                 $out .= "\n" if ( $str !~ /\n$/ );
 403             }
 404             $str = "";
 405             @conf = ();
 406         }
 407     }
 408     if ( $str ne "" && @conf ) {
 409         $out .= "=item " . join("\n\n=item ", @conf) . "\n\n";
 410         $out .= $str;
 411         $out .= "\n" if ( $str !~ /\n$/ );
 412     }
 413     $out .= "=back\n\n" if ( !$first );
 414     return $out;
 415 }
 416
 417 sub CheckConfigParams
 418 {
 419     my($file, $vars, $check) = @_;
 420     my $errors;
 421
 422     open(F, $file) || die("can't open $file\n");
 423     binmode(F);
 424     if ( $check ) {
 425         while ( <F> ) {
 426             s/\$(self|bpc)->{Conf}{([^}\$]+)}/if ( !defined($vars->{$2}) ) {
 427                     print("Unexpected Conf var $2 in $file\n");
 428                     $errors++;
 429                 } else {
 430                     $vars->{$2}++;
 431                 }/eg;
 432             s/\$[Cc]onf(?:->)?{([^}\$]+)}/if ( !defined($vars->{$1}) ) {
 433                     print("Unexpected Conf var $1 in $file\n");
 434                     $errors++;
 435                 } else {
 436                     $vars->{$1}++;
 437                 }/eg;
 438             s/UserCommandRun\("([^"]*)"/if ( !defined($vars->{$1}) ) {
 439                     print("Unexpected Conf var $1 in $file\n");
 440                     $errors++;
 441                 } else {
 442                     $vars->{$1}++;
 443                 }/eg;
 444         }
 445     } else {
 446         while ( <F> ) {
 447             s/^[^#]*\$self->{Conf}{([^}]*)/$vars->{$1} = 1;/eg;
 448             s/^[^#]*\$Conf{([^}]*)/$vars->{$1} = 1;/eg;
 449         }
 450     }
 451     close(F);
 452     return $errors;
 453 }
 454
 455 sub CheckMetaDataVsConfig
 456 {
 457     my($confVars, $file) = @_;
 458     my $done = {};
 459     my $errors;
 460
 461     #
 462     # Check that the meta file mentions all the config
 463     # parameters
 464     #
 465     open(F, $file) || die("can't open $file");
 466
 467     while ( <F> ) {
 468         next if ( !/^\s{4}(\w+)\s+=>/ );
 469         if ( $confVars->{$1} ) {
 470             $done->{$1} = 1;
 471             next;
 472         }
 473         next if ( $1 eq "Hosts" );
 474         print("$file has $1 but missing from conf/config.pl\n");
 475         $errors++;
 476     }
 477     close(F);
 478     foreach my $v ( keys(%$confVars) ) {
 479         next if ( $done->{$v} );
 480         print("$file missing $v from conf/config.pl\n");
 481         $errors++;
 482     }
 483
 484     #
 485     # Do extra checks that the CgiUserConfigEdit hash in the Meta
 486     # file matches the config file
 487     #
 488     foreach my $p ( keys(%{$ConfigMeta{CgiUserConfigEdit}{child}}) ) {
 489         if ( !defined($bpc->{Conf}{CgiUserConfigEdit}{$p}) ) {
 490             print("lib/BackupPC/Config/Meta.pm has $p in CgiUserConfigEdit,"
 491                 . " but conf/config.pl CgiUserConfigEdit does not\n");
 492             $errors++;
 493         }
 494     }
 495     foreach my $p ( keys(%{$bpc->{Conf}{CgiUserConfigEdit}}) ) {
 496         if ( !defined($ConfigMeta{CgiUserConfigEdit}{child}{$p}) ) {
 497             print("conf/config.pl CgiUserConfigEdit has $p, but"
 498                 . " lib/BackupPC/Config/Meta.pm does not\n");
 499             $errors++;
 500         }
 501     }
 502     return $errors;
 503 }
 504
 505 sub CheckEditorVsConfig
 506 {
 507     my($confVars, $file) = @_;
 508     my $done = {};
 509     my $errors;
 510
 511     #
 512     # Check that the config editor file mentions all the config
 513     # parameters
 514     #
 515     open(F, $file) || die("can't open $file");
 516
 517     while ( <F> ) {
 518         next if ( !/name\s*=>\s*"(\w+)"/ );
 519         if ( $confVars->{$1} ) {
 520             $done->{$1} = 1;
 521             next;
 522         }
 523         next if ( $1 eq "Hosts" );
 524         print("$file has $1 but missing from conf/config.pl\n");
 525         $errors++;
 526     }
 527     close(F);
 528     foreach my $v ( keys(%$confVars) ) {
 529         next if ( $done->{$v} );
 530         print("$file missing $v from conf/config.pl\n");
 531         $errors++;
 532     }
 533     return $errors;
 534 }
 535
 536 #
 537 # Make sure that every lang variable in cgi-bin/BackupPC_Admin matches
 538 # the strings in each lib/BackupPC/Lang/*.pm file.  This makes sure
 539 # we didn't miss any translations in any of the languages.
 540 #
 541 sub CheckLangUsage
 542 {
 543     my $errors;
 544     my $vars = {};
 545
 546     foreach my $file ( (
 547                 qw(cgi-bin/BackupPC_Admin bin/BackupPC_sendEmail),
 548                 <lib/BackupPC/CGI/*pm>,
 549                 <lib/BackupPC/Lang/en.pm>,
 550             ) ) {
 551         open(F, $file) || die("can't open $file");
 552         binmode(F);
 553         while ( <F> ) {
 554             next if ( /^\s*#/ );
 555             s/\$Lang->{([^}]*)}/$vars->{$1} = 1;/eg;
 556             s/(text|comment)\s*=>\s*"(CfgEdit_.*)"/$vars->{$2} = 1;/eg;
 557         }
 558         close(F);
 559     }
 560
 561     foreach my $f ( <lib/BackupPC/Lang/*.pm> ) {
 562         my $done = {};
 563         open(F, $f) || die("can't open $f\n");
 564         binmode(F);
 565         while ( <F> ) {
 566             s/#.*//g;
 567             s/\$Lang{([^}]*)}/
 568                     my $var = $1;
 569                     next if ( $var =~ m{^(Reason_|Status_|backupType_|Disabled_)} );
 570                     next if ( $var eq "Documentation" );
 571                     if ( !defined($vars->{$var}) ) {
 572                         print("Unexpected Lang var $var in $f\n");
 573                         $errors++;
 574                     } else {
 575                         $done->{$var} = 1;
 576                     }/eg;
 577         }
 578         close(F);
 579         foreach my $v ( keys(%$vars) ) {
 580             #
 581             # skip "variables" with "$", since they are like expressions
 582             #
 583             next if ( $v =~ /\$/ );
 584             if ( !defined($done->{$v}) ) {
 585                 print("Lang var $v missing from $f\n");
 586                 $errors++;
 587             }
 588         }
 589     }
 590     return $errors;
 591 }
 592
 593 #
 594 # Pedantically check that all the html tags in each language file
 595 # match.
 596 #
 597 sub CheckLangTags
 598 {
 599     my($en, $enVars) = LangParse("lib/BackupPC/Lang/en.pm");
 600     my($errors);
 601
 602     foreach my $lang ( qw(fr.pm de.pm es.pm it.pm nl.pm pl.pm pt_br.pm zh_CN.pm) ) {
 603         my($d, $dVars) = LangParse("lib/BackupPC/Lang/$lang");
 604         foreach my $v1 ( @$en ) {
 605             my $v2 = shift(@$d);
 606             if ( $v1->{var} ne $v2->{var} ) {
 607                 print("Botch: got $lang var $v2->{var} vs en.pm $v1->{var}\n");
 608                 exit;
 609             }
 610             my $t1 = LangTextStrip($v1->{val});
 611             my $t2 = LangTextStrip($v2->{val});
 612             if ( $t1 ne $t2 ) {
 613                 my $i;
 614                 for ( $i = 0 ; $i < length($t1) ; $i++ ) {
 615                     last if ( substr($t1, 0, $i) ne substr($t2, 0, $i) );
 616                 }
 617                 print("$v1->{var}: ($i) got en.pm $t1\nvs $lang $t2\n\n");
 618                 $errors++;
 619             }
 620         }
 621     }
 622     return $errors;
 623 }
 624
 625 sub LangTextStrip
 626 {
 627     my($t) = @_;
 628
 629     $t = "" if ( $t !~ /<.*>/ );
 630     $t =~ s/^[^<]*</</s;
 631     $t =~ s/([}>])[^<]*</$1</g;
 632     $t =~ s/>[^<]*$/>/;
 633     $t =~ s/(value=)"[^"]*"/$1""/sg;
 634     $t =~ s/({h[12]\()"[^"]*"/$1""/g;
 635     $t =~ s/ENG[\s\n]*//sg;
 636     $t =~ s/^(<<EOF;\n)[^<]*/$1/g;
 637     return $t;
 638 }
 639
 640 sub LangParse
 641 {
 642     my($file) = @_;
 643     open(C, $file) || die("can't open $file");
 644     binmode(C);
 645     my($out, @lang, $var);
 646     my $comment = 1;
 647     my $allVars = {};
 648     my $endLine = undef;
 649     while ( <C> ) {
 650         if ( /^#/ && !defined($endLine) ) {
 651             if ( $comment ) {
 652                 $out .= $_;
 653             } else {
 654                 if ( $out ne "" ) {
 655                     $allVars->{$var} = @lang if ( defined($var) );
 656                     push(@lang, {
 657                         text => $out,
 658                         var => $var,
 659                     });
 660                 }
 661                 $var = undef;
 662                 $comment = 1;
 663                 $out = $_;
 664             }
 665         } elsif ( /^\s*\$Lang\{([^}]*)/ ) {
 666             $comment = 0;
 667             if ( defined($var) ) {
 668                 $allVars->{$var} = @lang if ( defined($var) );
 669                 push(@lang, {
 670                     text => $out,
 671                     var => $var,
 672                 });
 673                 $out = $_;
 674             } else {
 675                 $out .= $_;
 676             }
 677             $var = $1;
 678             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<(.*);/ );
 679             $endLine = $1 if ( /^\s*\$Lang\{[^}]*} *= *<<'(.*)';/ );
 680         } else {
 681             $endLine = undef if ( defined($endLine) && /^\Q$endLine[\n\r]*$/ );
 682             $out .= $_;
 683         }
 684     }
 685     if ( $out ne "" ) {
 686         $allVars->{$var} = @lang if ( defined($var) );
 687         push(@lang, {
 688             text => $out,
 689             var  => $var,
 690         });
 691     }
 692     close(C);
 693     foreach my $v ( @lang ) {
 694         if ( $v->{text} =~ /\$Lang{$v->{var}}\s*=\s*(.*)/s ) {
 695             $v->{val} = $1;
 696         }
 697     }
 698     return (\@lang, $allVars);
 699 }