misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl -w
   2
   3 # Copyright 2008 Liblime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21 use warnings;
  22
  23 BEGIN {
  24
  25     # find Koha's Perl modules
  26     # test carefully before changing this
  27     use FindBin;
  28     eval { require "$FindBin::Bin/../kohalib.pl" };
  29 }
  30
  31 use C4::Context;
  32 use C4::Dates qw/format_date/;
  33 use C4::Debug;
  34 use C4::Letters;
  35
  36 use Getopt::Long;
  37 use Pod::Usage;
  38 use Text::CSV_XS;
  39
  40 =head1 NAME
  41
  42 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  43
  44 =head1 SYNOPSIS
  45
  46 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  47
  48  Options:
  49    -help                          brief help message
  50    -man                           full documentation
  51    -n                             No email will be sent
  52    -max          <days>           maximum days overdue to deal with
  53    -library      <branchname>     only deal with overdues from this library
  54    -csv          <filename>       populate CSV file
  55    -itemscontent <list of fields> item information in templates
  56
  57 =head1 OPTIONS
  58
  59 =over 8
  60
  61 =item B<-help>
  62
  63 Print a brief help message and exits.
  64
  65 =item B<-man>
  66
  67 Prints the manual page and exits.
  68
  69 =item B<-v>
  70
  71 Verbose. Without this flag set, only fatal errors are reported.
  72
  73 =item B<-n>
  74
  75 Do not send any email. Overdue notices that would have been sent to
  76 the patrons or to the admin are printed to standard out. CSV data (if
  77 the -csv flag is set) is written to standard out or to any csv
  78 filename given.
  79
  80 =item B<-max>
  81
  82 Items older than max days are assumed to be handled somewhere else,
  83 probably the F<longoverdues.pl> script. They are therefore ignored by
  84 this program. No notices are sent for them, and they are not added to
  85 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  86
  87 =item B<-library>
  88
  89 select overdues for one specific library. Use the value in the
  90 branches.branchcode table.
  91
  92 =item B<-csv>
  93
  94 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
  95 sent to standard out or to a filename if provided. Otherwise, only
  96 overdues that could not be emailed are sent in CSV format to the admin.
  97
  98 =item B<-itemscontent>
  99
 100 comma separated list of fields that get substituted into templates in
 101 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 102 defaults to issuedate,title,barcode,author
 103
 104 Other possible values come from fields in the biblios, items, and
 105 issues tables.
 106
 107 =item B<-t> | B<--triggered>
 108
 109 This option causes a notice to be generated if and only if
 110 an item is overdue by the number of days defined in a notice trigger.
 111
 112 By default, a notice is sent each time the script runs, which is suitable for
 113 less frequent run cron script, but requires syncing notice triggers with
 114 the  cron schedule to ensure proper behavior.
 115 Add the --triggered option for daily cron, at the risk of no notice
 116 being generated if the cron fails to run on time.
 117
 118 =item B<-list-all>
 119
 120 Default items.content lists only those items that fall in the
 121 range of the currently processing notice.
 122 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 123
 124 =back
 125
 126 =head1 DESCRIPTION
 127
 128 This script is designed to alert patrons and administrators of overdue
 129 items.
 130
 131 =head2 Configuration
 132
 133 This script pays attention to the overdue notice configuration
 134 performed in the "Overdue notice/status triggers" section of the
 135 "Tools" area of the staff interface to Koha. There, you can choose
 136 which letter templates are sent out after a configurable number of
 137 days to patrons of each library. More information about the use of this
 138 section of Koha is available in the Koha manual.
 139
 140 The templates used to craft the emails are defined in the "Tools:
 141 Notices" section of the staff interface to Koha.
 142
 143 =head2 Outgoing emails
 144
 145 Typically, messages are prepared for each patron with overdue
 146 items. Messages for whom there is no email address on file are
 147 collected and sent as attachments in a single email to each library
 148 administrator, or if that is not set, then to the email address in the
 149 C<KohaAdminEmailAddress> system preference.
 150
 151 These emails are staged in the outgoing message queue, as are messages
 152 produced by other features of Koha. This message queue must be
 153 processed regularly by the
 154 F<misc/cronjobs/process_message_queue.pl> program.
 155
 156 In the event that the C<-n> flag is passed to this program, no emails
 157 are sent. Instead, messages are sent on standard output from this
 158 program. They may be redirected to a file if desired.
 159
 160 =head2 Templates
 161
 162 Templates can contain variables enclosed in double angle brackets like
 163 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 164 specific to the overdue items or relevant patron. Available variables
 165 are:
 166
 167 =over
 168
 169 =item E<lt>E<lt>bibE<gt>E<gt>
 170
 171 the name of the library
 172
 173 =item E<lt>E<lt>items.contentE<gt>E<gt>
 174
 175 one line for each item, each line containing a tab separated list of
 176 title, author, barcode, issuedate
 177
 178 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 179
 180 any field from the borrowers table
 181
 182 =item E<lt>E<lt>branches.*E<gt>E<gt>
 183
 184 any field from the branches table
 185
 186 =back
 187
 188 =head2 CSV output
 189
 190 The C<-csv> command line option lets you specify a file to which
 191 overdues data should be output in CSV format.
 192
 193 With the C<-n> flag set, data about all overdues is written to the
 194 file. Without that flag, only information about overdues that were
 195 unable to be sent directly to the patrons will be written. In other
 196 words, this CSV file replaces the data that is typically sent to the
 197 administrator email address.
 198
 199 =head1 USAGE EXAMPLES
 200
 201 C<overdue_notices.pl> - In this most basic usage, with no command line
 202 arguments, all libraries are procesed individually, and notices are
 203 prepared for all patrons with overdue items for whom we have email
 204 addresses. Messages for those patrons for whom we have no email
 205 address are sent in a single attachment to the library administrator's
 206 email address, or to the address in the KohaAdminEmailAddress system
 207 preference.
 208
 209 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 210 populates F</tmp/overdues.csv> with information about all overdue
 211 items.
 212
 213 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 214 overdues in the last 2 weeks for the MAIN library.
 215
 216 =head1 SEE ALSO
 217
 218 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 219 messages to patrons in advance of thier items becoming due, or to
 220 alert them of items that have just become due.
 221
 222 =cut
 223
 224 # These variables are set by command line options.
 225 # They are initially set to default values.
 226 my $help    = 0;
 227 my $man     = 0;
 228 my $verbose = 0;
 229 my $nomail  = 0;
 230 my $MAX     = 90;
 231 my $mybranch;
 232 my $csvfilename;
 233 my $triggered = 0;
 234 my $listall = 0;
 235 my $itemscontent = join( ',', qw( issuedate title barcode author ) );
 236
 237 GetOptions(
 238     'help|?'         => \$help,
 239     'man'            => \$man,
 240     'v'              => \$verbose,
 241     'n'              => \$nomail,
 242     'max=s'          => \$MAX,
 243     'library=s'      => \$mybranch,
 244     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 245     'itemscontent=s' => \$itemscontent,
 246     'list-all'      => \$listall,
 247     't|triggered'             => \$triggered,
 248 ) or pod2usage(2);
 249 pod2usage(1) if $help;
 250 pod2usage( -verbose => 2 ) if $man;
 251
 252 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 253     warn qq(using "$csvfilename" as filename, that seems odd);
 254 }
 255
 256 my @branches    = C4::Overdues::GetBranchcodesWithOverdueRules();
 257 my $branchcount = scalar(@branches);
 258 if ($branchcount) {
 259     my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 260     $verbose and warn "Found $branchcount $branch_word with first message enabled: " . join( ', ', map { "'$_'" } @branches ), "\n";
 261 } else {
 262     die 'No branches with active overduerules';
 263 }
 264
 265 if ($mybranch) {
 266     $verbose and warn "Branch $mybranch selected\n";
 267     if ( scalar grep { $mybranch eq $_ } @branches ) {
 268         @branches = ($mybranch);
 269     } else {
 270         $verbose and warn "No active overduerules for branch '$mybranch'\n";
 271         ( scalar grep { '' eq $_ } @branches )
 272           or die "No active overduerules for DEFAULT either!";
 273         $verbose and warn "Falling back on default rules for $mybranch\n";
 274         @branches = ('');
 275     }
 276 }
 277
 278 # these are the fields that will be substituted into <<item.content>>
 279 my @item_content_fields = split( /,/, $itemscontent );
 280
 281 my $dbh = C4::Context->dbh();
 282 binmode( STDOUT, ":utf8" );
 283
 284 our $csv;       # the Text::CSV_XS object
 285 our $csv_fh;    # the filehandle to the CSV file.
 286 if ( defined $csvfilename ) {
 287     my $sep_char = C4::Context->preference('delimiter') || ',';
 288     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 289     if ( $csvfilename eq '' ) {
 290         $csv_fh = *STDOUT;
 291     } else {
 292         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 293     }
 294     if ( $csv->combine(qw(name surname address1 address2 zipcode city email itemcount itemsinfo)) ) {
 295         print $csv_fh $csv->string, "\n";
 296     } else {
 297         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 298     }
 299 }
 300
 301 foreach my $branchcode (@branches) {
 302     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 303     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 304     my @output_chunks;    # may be sent to mail or stdout or csv file.
 305
 306     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 307
 308     my $sth2 = $dbh->prepare( <<'END_SQL' );
 309 SELECT biblio.*, items.*, issues.*, TO_DAYS(NOW())-TO_DAYS(date_due) AS days_overdue
 310   FROM issues
 311   LEFT JOIN items USING(itemnumber)
 312   LEFT JOIN biblio USING(biblionumber)
 313   WHERE issues.borrowernumber = ?
 314     AND TO_DAYS(NOW())-TO_DAYS(date_due) BETWEEN ? and ?
 315 END_SQL
 316
 317     my $rqoverduerules = $dbh->prepare("SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ");
 318     $rqoverduerules->execute($branchcode);
 319
 320     # We get default rules is there is no rule for this branch
 321     if($rqoverduerules->rows == 0){
 322         $rqoverduerules = $dbh->prepare("SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ");
 323         $rqoverduerules->execute();
 324     }
 325
 326     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 327     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 328       PERIOD: foreach my $i ( 1 .. 3 ) {
 329             $verbose and warn "branch '$branchcode', pass $i\n";
 330             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 331             my $maxdays = (
 332                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 333                 ? $overdue_rules->{ "delay" . ( $i + 1 ) }
 334                 : ($MAX)
 335             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 336
 337             if ( !$overdue_rules->{"letter$i"} ) {
 338                 $verbose and warn "No letter$i code for branch '$branchcode'";
 339                 next PERIOD;
 340             }
 341
 342             # $letter->{'content'} is the text of the mail that is sent.
 343             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 344             # The following fields are available :
 345             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 346             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode>
 347
 348             my $borrower_sql = <<'END_SQL';
 349 SELECT COUNT(*), issues.borrowernumber, firstname, surname, address, address2, city, zipcode, email, MIN(date_due) as longest_issue
 350 FROM   issues
 351 LEFT JOIN borrowers USING (borrowernumber)
 352 LEFT JOIN categories ON (borrowers.categorycode=categories.categorycode)
 353 WHERE 1
 354 END_SQL
 355             my @borrower_parameters;
 356             if ($branchcode) {
 357                 $borrower_sql .= ' AND issues.branchcode=? ';
 358                 push @borrower_parameters, $branchcode;
 359             }
 360             if ( $overdue_rules->{categorycode} ) {
 361                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 362                 push @borrower_parameters, $overdue_rules->{categorycode};
 363             }
 364             $borrower_sql .= '  AND categories.overduenoticerequired=1
 365                                 GROUP BY issues.borrowernumber ';
 366             if($triggered) {
 367                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) = ?';
 368                 push @borrower_parameters, $mindays;
 369             } else {
 370                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) BETWEEN ? and ? ' ;
 371                 push @borrower_parameters, $mindays, $maxdays;
 372             }
 373
 374             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 375                 my $sth = $dbh->prepare($borrower_sql);
 376             $sth->execute(@borrower_parameters);
 377             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 378
 379             while( my ( $itemcount, $borrowernumber, $firstname, $lastname, $address1, $address2, $city, $postcode, $email ) = $sth->fetchrow ) {
 380                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has $itemcount items triggering level $i.";
 381
 382                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"} );
 383                 unless ($letter) {
 384                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 385
 386                     # might as well skip while PERIOD, no other borrowers are going to work.
 387                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 388                     next PERIOD;
 389                 }
 390
 391                 if ( $overdue_rules->{"debarred$i"} ) {
 392
 393                     #action taken is debarring
 394                     C4::Members::DebarMember($borrowernumber);
 395                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 396                 }
 397                 $sth2->execute( ($listall) ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ) );
 398                 my $itemcount = 0;
 399                 my $titles = "";
 400                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 401                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 402                     $titles .= join("\t", @item_info) . "\n";
 403                     $itemcount++;
 404                 }
 405                 $sth2->finish;
 406
 407                 $letter = parse_letter(
 408                     {   letter         => $letter,
 409                         borrowernumber => $borrowernumber,
 410                         branchcode     => $branchcode,
 411                         substitute     => {
 412                             bib             => $branch_details->{'branchname'},
 413                             'items.content' => $titles
 414                         }
 415                     }
 416                 );
 417
 418                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 419                 if (@misses) {
 420                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 421                 }
 422                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 423                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 424
 425                 if ($nomail) {
 426
 427                     push @output_chunks,
 428                       prepare_letter_for_printing(
 429                         {   letter         => $letter,
 430                             borrowernumber => $borrowernumber,
 431                             firstname      => $firstname,
 432                             lastname       => $lastname,
 433                             address1       => $address1,
 434                             address2       => $address2,
 435                             city           => $city,
 436                             postcode       => $postcode,
 437                             email          => $email,
 438                             itemcount      => $itemcount,
 439                             titles         => $titles,
 440                             outputformat   => defined $csvfilename ? 'csv' : '',
 441                         }
 442                       );
 443                 } else {
 444                     if ($email) {
 445                         C4::Letters::EnqueueLetter(
 446                             {   letter                 => $letter,
 447                                 borrowernumber         => $borrowernumber,
 448                                 message_transport_type => 'email',
 449                                 from_address           => $admin_email_address,
 450                             }
 451                         );
 452                     } else {
 453
 454                         # If we don't have an email address for this patron, send it to the admin to deal with.
 455                         push @output_chunks,
 456                           prepare_letter_for_printing(
 457                             {   letter         => $letter,
 458                                 borrowernumber => $borrowernumber,
 459                                 firstname      => $firstname,
 460                                 lastname       => $lastname,
 461                                 address1       => $address1,
 462                                 address2       => $address2,
 463                                 city           => $city,
 464                                 postcode       => $postcode,
 465                                 email          => $email,
 466                                 itemcount      => $itemcount,
 467                                 titles         => $titles,
 468                                 outputformat   => defined $csvfilename ? 'csv' : '',
 469                             }
 470                           );
 471                     }
 472                 }
 473             }
 474             $sth->finish;
 475         }
 476     }
 477
 478     if (@output_chunks) {
 479         if ($nomail) {
 480             if ( defined $csvfilename ) {
 481                 print $csv_fh @output_chunks;
 482             } else {
 483                 local $, = "\f";    # pagebreak
 484                 print @output_chunks;
 485             }
 486         } else {
 487             my $attachment = {
 488                 filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 489                 type => 'text/plain',
 490                 content => join( "\n", @output_chunks )
 491             };
 492
 493             my $letter = {
 494                 title   => 'Overdue Notices',
 495                 content => 'These messages were not sent directly to the patrons.',
 496             };
 497             C4::Letters::EnqueueLetter(
 498                 {   letter                 => $letter,
 499                     borrowernumber         => undef,
 500                     message_transport_type => 'email',
 501                     attachments            => [$attachment],
 502                     to_address             => $admin_email_address,
 503                 }
 504             );
 505         }
 506     }
 507
 508 }
 509 if ($csvfilename) {
 510
 511     # note that we're not testing on $csv_fh to prevent closing
 512     # STDOUT.
 513     close $csv_fh;
 514 }
 515
 516 =head1 INTERNAL METHODS
 517
 518 These methods are internal to the operation of overdue_notices.pl.
 519
 520 =head2 parse_letter
 521
 522 parses the letter template, replacing the placeholders with data
 523 specific to this patron, biblio, or item
 524
 525 named parameters:
 526   letter - required hashref
 527   borrowernumber - required integer
 528   substitute - optional hashref of other key/value pairs that should
 529     be substituted in the letter content
 530
 531 returns the C<letter> hashref, with the content updated to reflect the
 532 substituted keys and values.
 533
 534
 535 =cut
 536
 537 sub parse_letter {
 538     my $params = shift;
 539     foreach my $required (qw( letter borrowernumber )) {
 540         return unless exists $params->{$required};
 541     }
 542
 543     if ( $params->{'substitute'} ) {
 544         while ( my ( $key, $replacedby ) = each %{ $params->{'substitute'} } ) {
 545             my $replacefield = "<<$key>>";
 546
 547             $params->{'letter'}->{title}   =~ s/$replacefield/$replacedby/g;
 548             $params->{'letter'}->{content} =~ s/$replacefield/$replacedby/g;
 549         }
 550     }
 551
 552     C4::Letters::parseletter( $params->{'letter'}, 'borrowers', $params->{'borrowernumber'} );
 553
 554     if ( $params->{'branchcode'} ) {
 555         C4::Letters::parseletter( $params->{'letter'}, 'branches', $params->{'branchcode'} );
 556     }
 557
 558     if ( $params->{'biblionumber'} ) {
 559         C4::Letters::parseletter( $params->{'letter'}, 'biblio',      $params->{'biblionumber'} );
 560         C4::Letters::parseletter( $params->{'letter'}, 'biblioitems', $params->{'biblionumber'} );
 561     }
 562
 563     return $params->{'letter'};
 564 }
 565
 566 =head2 prepare_letter_for_printing
 567
 568 returns a string of text appropriate for printing in the event that an
 569 overdue notice will not be sent to the patron's email
 570 address. Depending on the desired output format, this may be a CSV
 571 string, or a human-readable representation of the notice.
 572
 573 required parameters:
 574   letter
 575   borrowernumber
 576
 577 optional parameters:
 578   outputformat
 579
 580 =cut
 581
 582 sub prepare_letter_for_printing {
 583     my $params = shift;
 584
 585     return unless ref $params eq 'HASH';
 586
 587     foreach my $required_parameter (qw( letter borrowernumber )) {
 588         return unless defined $params->{$required_parameter};
 589     }
 590
 591     my $return;
 592     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 593         if ($csv->combine(
 594                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 595                 $params->{'city'},      $params->{'email'},    $params->{'itemcount'}, $params->{'titles'}
 596             )
 597           ) {
 598             return $csv->string, "\n";
 599         } else {
 600             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 601         }
 602     } else {
 603         $return .= "$params->{'letter'}->{'content'}\n";
 604
 605         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 606     }
 607     return $return;
 608 }
 609