opac/sco/sco-main.pl

   1 #!/usr/bin/perl
   2 #
   3 # This code has been modified by Trendsetters (originally from opac-user.pl)
   4 # This code has been modified by rch
   5 # Parts Copyright 2010-2011, ByWater Solutions (those related to username/password auth)
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 # We're going to authenticate a self-check user.  we'll add a flag to borrowers 'selfcheck'
  23 #
  24 # We're in a controlled environment; we trust the user.
  25 # So the selfcheck station will accept a patronid and issue items to that borrower.
  26 # FIXME: NOT really a controlled environment...  We're on the internet!
  27 #
  28 # The checkout permission comes form the CGI cookie/session of a staff user.
  29 # The patron is not really logging in here in the same way as they do on the
  30 # rest of the OPAC.  So don't confuse loggedinuser with the patron user.
  31 #
  32 # FIXME: inputfocus not really used in TMPL
  33
  34 use Modern::Perl;
  35
  36 use CGI qw ( -utf8 );
  37
  38 use C4::Auth qw(get_template_and_user checkpw);
  39 use C4::Koha;
  40 use C4::Circulation;
  41 use C4::Reserves;
  42 use C4::Output;
  43 use C4::Members;
  44 use C4::Biblio;
  45 use C4::Items;
  46 use Koha::DateUtils qw( dt_from_string );
  47 use Koha::Acquisition::Currencies;
  48 use Koha::Patrons;
  49 use Koha::Patron::Images;
  50 use Koha::Patron::Messages;
  51 use Koha::Token;
  52
  53 my $query = new CGI;
  54
  55 unless (C4::Context->preference('WebBasedSelfCheck')) {
  56     # redirect to OPAC home if self-check is not enabled
  57     print $query->redirect("/cgi-bin/koha/opac-main.pl");
  58     exit;
  59 }
  60
  61 if (C4::Context->preference('AutoSelfCheckAllowed'))
  62 {
  63     my $AutoSelfCheckID = C4::Context->preference('AutoSelfCheckID');
  64     my $AutoSelfCheckPass = C4::Context->preference('AutoSelfCheckPass');
  65     $query->param(-name=>'userid',-values=>[$AutoSelfCheckID]);
  66     $query->param(-name=>'password',-values=>[$AutoSelfCheckPass]);
  67     $query->param(-name=>'koha_login_context',-values=>['sco']);
  68 }
  69 $query->param(-name=>'sco_user_login',-values=>[1]);
  70
  71 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  72     {
  73         template_name   => "sco/sco-main.tt",
  74         authnotrequired => 0,
  75         flagsrequired   => { self_check => "self_checkout_module" },
  76         query           => $query,
  77         type            => "opac",
  78         debug           => 1,
  79     }
  80 );
  81
  82 # Get the self checkout timeout preference, or use 120 seconds as a default
  83 my $selfchecktimeout = 120000;
  84 if (C4::Context->preference('SelfCheckTimeout')) {
  85     $selfchecktimeout = C4::Context->preference('SelfCheckTimeout') * 1000;
  86 }
  87 $template->param( SelfCheckTimeout => $selfchecktimeout );
  88
  89 # Checks policy laid out by AllowSelfCheckReturns, defaults to 'on' if preference is undefined
  90 my $allowselfcheckreturns = 1;
  91 if (defined C4::Context->preference('AllowSelfCheckReturns')) {
  92     $allowselfcheckreturns = C4::Context->preference('AllowSelfCheckReturns');
  93 }
  94
  95 my $issuerid = $loggedinuser;
  96 my ($op, $patronid, $patronlogin, $patronpw, $barcode, $confirmed, $newissues) = (
  97     $query->param("op")         || '',
  98     $query->param("patronid")   || '',
  99     $query->param("patronlogin")|| '',
 100     $query->param("patronpw")   || '',
 101     $query->param("barcode")    || '',
 102     $query->param("confirmed")  || '',
 103     $query->param("newissues")  || '',
 104 );
 105 my @newissueslist = split /,/, $newissues;
 106 my $issuenoconfirm = 1; #don't need to confirm on issue.
 107 my $issuer   = Koha::Patrons->find( $issuerid )->unblessed;
 108 my $item     = GetItem(undef,$barcode);
 109 if (C4::Context->preference('SelfCheckoutByLogin') && !$patronid) {
 110     my $dbh = C4::Context->dbh;
 111     my $resval;
 112     ($resval, $patronid) = checkpw($dbh, $patronlogin, $patronpw);
 113 }
 114
 115 my ( $borrower, $patron );
 116 if ( $patronid ) {
 117     $patron = Koha::Patrons->find( { cardnumber => $patronid } );
 118     $borrower = $patron->unblessed if $patron;
 119 }
 120
 121 my $branch = $issuer->{branchcode};
 122 my $confirm_required = 0;
 123 my $return_only = 0;
 124 #warn "issuer cardnumber: " .   $issuer->{cardnumber};
 125 #warn "patron cardnumber: " . $borrower->{cardnumber};
 126 if ($op eq "logout") {
 127     $template->param( loggedout => 1 );
 128     $query->param( patronid => undef, patronlogin => undef, patronpw => undef );
 129 }
 130 elsif ( $op eq "returnbook" && $allowselfcheckreturns ) {
 131     my ($doreturn) = AddReturn( $barcode, $branch );
 132     $template->param( returned => $doreturn );
 133 }
 134 elsif ( $patron and $op eq "checkout" ) {
 135     my $impossible  = {};
 136     my $needconfirm = {};
 137     ( $impossible, $needconfirm ) = CanBookBeIssued(
 138         $patron,
 139         $barcode,
 140         undef,
 141         0,
 142         C4::Context->preference("AllowItemsOnHoldCheckoutSCO")
 143     );
 144     my $issue_error;
 145     if ( $confirm_required = scalar keys %$needconfirm ) {
 146         for my $error ( qw( UNKNOWN_BARCODE max_loans_allowed ISSUED_TO_ANOTHER NO_MORE_RENEWALS NOT_FOR_LOAN DEBT WTHDRAWN RESTRICTED RESERVED ITEMNOTSAMEBRANCH EXPIRED DEBARRED CARD_LOST GNA INVALID_DATE UNKNOWN_BARCODE TOO_MANY DEBT_GUARANTEES USERBLOCKEDOVERDUE PATRON_CANT PREVISSUE NOT_FOR_LOAN_FORCING ITEM_LOST) ) {
 147             if ( $needconfirm->{$error} ) {
 148                 $issue_error = $error;
 149                 $confirmed = 0;
 150                 last;
 151             }
 152         }
 153     }
 154
 155     #warn "confirm_required: " . $confirm_required ;
 156     if (scalar keys %$impossible) {
 157
 158         my $issue_error = (keys %$impossible)[0]; # FIXME This is wrong, we assume only one error and keys are not ordered
 159
 160         $template->param(
 161             impossible                => $issue_error,
 162             "circ_error_$issue_error" => 1,
 163             title                     => $item->{title},
 164             hide_main                 => 1,
 165         );
 166         if ($issue_error eq 'DEBT') {
 167             $template->param(DEBT => $impossible->{DEBT});
 168         }
 169         #warn "issue_error: " . $issue_error ;
 170         if ( $issue_error eq "NO_MORE_RENEWALS" ) {
 171             $return_only = 1;
 172             $template->param(
 173                 returnitem => 1,
 174                 barcode    => $barcode,
 175             );
 176         }
 177     } elsif ( $needconfirm->{RENEW_ISSUE} ) {
 178         if ($confirmed) {
 179             #warn "renewing";
 180             AddRenewal( $borrower->{borrowernumber}, $item->{itemnumber} );
 181             push @newissueslist, $barcode;
 182             $template->param( renewed => 1 );
 183         } else {
 184             #warn "renew confirmation";
 185             $template->param(
 186                 renew               => 1,
 187                 barcode             => $barcode,
 188                 confirm             => 1,
 189                 confirm_renew_issue => 1,
 190                 hide_main           => 1,
 191             );
 192         }
 193     } elsif ( $confirm_required && !$confirmed ) {
 194         #warn "failed confirmation";
 195         $template->param(
 196             impossible                => 1,
 197             "circ_error_$issue_error" => 1,
 198             hide_main                 => 1,
 199         );
 200         if ($issue_error eq 'DEBT') {
 201             $template->param(DEBT => $needconfirm->{DEBT});
 202         }
 203     } else {
 204         if ( $confirmed || $issuenoconfirm ) {    # we'll want to call getpatroninfo again to get updated issues.
 205             my ( $hold_existed, $item );
 206             if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
 207                 # There is no easy way to know if the patron has been charged for this item.
 208                 # So we check if a hold existed for this item before the check in
 209                 $item = Koha::Items->find({ barcode => $barcode });
 210                 $hold_existed = Koha::Holds->search(
 211                     {
 212                         -and => {
 213                             borrowernumber => $borrower->{borrowernumber},
 214                             -or            => {
 215                                 biblionumber => $item->biblionumber,
 216                                 itemnumber   => $item->itemnumber
 217                             }
 218                         }
 219                     }
 220                 )->count;
 221             }
 222
 223             AddIssue( $borrower, $barcode );
 224             push @newissueslist, $barcode;
 225
 226             if ( $hold_existed ) {
 227                 my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 228                 $template->param(
 229                     issued => 1,
 230                     # If the hold existed before the check in, let's confirm that the charge line exists
 231                     # Note that this should not be needed but since we do not have proper exception handling here we do it this way
 232                     patron_has_hold_fee => Koha::Account::Lines->search(
 233                         {
 234                             borrowernumber => $borrower->{borrowernumber},
 235                             accounttype    => 'Res',
 236                             description    => 'Reserve Charge - ' . $item->biblio->title,
 237                             date           => $dtf->format_date(dt_from_string)
 238                         }
 239                       )->count,
 240                 );
 241             }
 242         } else {
 243             $confirm_required = 1;
 244             #warn "issue confirmation";
 245             $template->param(
 246                 confirm    => "Issuing title: " . $item->{title},
 247                 barcode    => $barcode,
 248                 hide_main  => 1,
 249                 inputfocus => 'confirm',
 250             );
 251         }
 252     }
 253 } # $op
 254
 255 if ($borrower) {
 256 #   warn "issuer's  branchcode: " .   $issuer->{branchcode};
 257 #   warn   "user's  branchcode: " . $borrower->{branchcode};
 258     my $borrowername = sprintf "%s %s", ($borrower->{firstname} || ''), ($borrower->{surname} || '');
 259     my $pending_checkouts = $patron->pending_checkouts;
 260     my @checkouts;
 261     while ( my $c = $pending_checkouts->next ) {
 262         my $checkout = $c->unblessed_all_relateds;
 263         my ($can_be_renewed, $renew_error) = CanBookBeRenewed(
 264             $borrower->{borrowernumber},
 265             $checkout->{itemnumber},
 266         );
 267         $checkout->{can_be_renewed} = $can_be_renewed; # In the future this will be $checkout->can_be_renewed
 268         $checkout->{renew_error} = $renew_error;
 269         $checkout->{overdue} = $c->is_overdue;
 270         push @checkouts, $checkout;
 271     }
 272
 273     $template->param(
 274         validuser => 1,
 275         borrowername => $borrowername,
 276         issues_count => scalar(@checkouts),
 277         ISSUES => \@checkouts,
 278         newissues => join(',',@newissueslist),
 279         patronid => $patronid,
 280         patronlogin => $patronlogin,
 281         patronpw => $patronpw,
 282         noitemlinks => 1 ,
 283         borrowernumber => $borrower->{'borrowernumber'},
 284     );
 285
 286     my $patron_messages = Koha::Patron::Messages->search(
 287         {
 288             borrowernumber => $borrower->{'borrowernumber'},
 289             message_type => 'B',
 290         }
 291     );
 292     $template->param(
 293         patron_messages => $patron_messages,
 294         opacnote => $borrower->{opacnote},
 295     );
 296
 297     my $inputfocus = ($return_only      == 1) ? 'returnbook' :
 298                      ($confirm_required == 1) ? 'confirm'    : 'barcode' ;
 299     $template->param(
 300         inputfocus => $inputfocus,
 301         nofines => 1,
 302
 303     );
 304     if (C4::Context->preference('ShowPatronImageInWebBasedSelfCheck')) {
 305         my $patron_image = Koha::Patron::Images->find($borrower->{borrowernumber});
 306         $template->param(
 307             display_patron_image => 1,
 308             csrf_token           => Koha::Token->new->generate_csrf( { session_id => scalar $query->cookie('CGISESSID') . $borrower->{cardnumber}, id => $borrower->{userid}} ),
 309         ) if $patron_image;
 310     }
 311 } else {
 312     $template->param(
 313         patronid   => $patronid,
 314         nouser     => $patronid,
 315     );
 316 }
 317
 318 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };