t/01-Redis.t

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5
   6 use Test::More tests => 121;
   7 use Test::Exception;
   8 use Data::Dumper;
   9
  10 use lib 'lib';
  11
  12 BEGIN {
  13         use_ok( 'Redis' );
  14 }
  15
  16 ok( my $o = Redis->new(), 'new' );
  17
  18 ok( $o->ping, 'ping' );
  19
  20 ok( $o = Redis->new( server => 'localhost:6379' ), 'new with server' );
  21
  22 diag "Commands operating on string values";
  23
  24 ok( $o->set( foo => 'bar' ), 'set foo => bar' );
  25
  26 ok( ! $o->setnx( foo => 'bar' ), 'setnx foo => bar fails' );
  27
  28 cmp_ok( $o->get( 'foo' ), 'eq', 'bar', 'get foo = bar' );
  29
  30 ok( $o->set( foo => '' ), 'set foo => ""' );
  31
  32 cmp_ok( $o->get( 'foo' ), 'eq', '', 'get foo = ""' );
  33
  34 ok( $o->set( foo => 'baz' ), 'set foo => baz' );
  35
  36 cmp_ok( $o->get( 'foo' ), 'eq', 'baz', 'get foo = baz' );
  37
  38 my $euro = "\x{20ac}";
  39 ok( $o->set( utf8 => $euro ), 'set utf8' );
  40 cmp_ok( $o->get( 'utf8' ), 'eq', $euro, 'get utf8' );
  41
  42 ok( $o->set( 'test-undef' => 42 ), 'set test-undef' );
  43 ok( $o->exists( 'test-undef' ), 'exists undef' );
  44
  45 for my $size (10_000, 100_000, 500_000, 1_000_000, 2_500_000) {
  46   my $v = 'a' x $size;
  47   ok( $o->set('big_key', $v), "set with value size $size ok" );
  48   is( $o->get('big_key'), $v, "... and get was ok to" );
  49 }
  50
  51 $o->del('non-existant');
  52
  53 ok( ! $o->exists( 'non-existant' ), 'exists non-existant' );
  54 ok( ! $o->get( 'non-existant' ), 'get non-existant' );
  55
  56 ok( $o->set('key-next' => 0), 'key-next = 0' );
  57
  58 my $key_next = 3;
  59
  60 ok( $o->set('key-left' => $key_next), 'key-left' );
  61
  62 is_deeply( [ $o->mget( 'foo', 'key-next', 'key-left' ) ], [ 'baz', 0, 3 ], 'mget' );
  63
  64 my @keys;
  65
  66 foreach my $id ( 0 .. $key_next ) {
  67         my $key = 'key-' . $id;
  68         push @keys, $key;
  69         ok(     $o->set( $key => $id ),           "set $key" );
  70         ok(  $o->exists( $key       ),           "exists $key" );
  71         cmp_ok( $o->get( $key       ), 'eq', $id, "get $key" );
  72         cmp_ok( $o->incr( 'key-next' ), '==', $id + 1, 'incr' );
  73         cmp_ok( $o->decr( 'key-left' ), '==', $key_next - $id - 1, 'decr' );
  74 }
  75
  76 cmp_ok( $o->get( 'key-next' ), '==', $key_next + 1, 'key-next' );
  77
  78 ok( $o->set('test-incrby', 0), 'test-incrby' );
  79 ok( $o->set('test-decrby', 0), 'test-decry' );
  80 foreach ( 1 .. 3 ) {
  81         cmp_ok( $o->incrby('test-incrby', 3), '==', $_ * 3, 'incrby 3' );
  82         cmp_ok( $o->decrby('test-decrby', 7), '==', -( $_ * 7 ), 'decrby 7' );
  83 }
  84
  85 ok( $o->del( $_ ), "del $_" ) foreach map { "key-$_" } ( 'next', 'left' );
  86 ok( ! $o->del('non-existing' ), 'del non-existing' );
  87
  88 cmp_ok( $o->type('foo'), 'eq', 'string', 'type' );
  89
  90 cmp_ok( $o->keys('key-*'), '==', $key_next + 1, 'key-*' );
  91 is_deeply( [ $o->keys('key-*') ], [ @keys ], 'keys' );
  92
  93 ok( my $key = $o->randomkey, 'randomkey' );
  94
  95 ok( $o->rename( 'test-incrby', 'test-renamed' ), 'rename' );
  96 ok( $o->exists( 'test-renamed' ), 'exists test-renamed' );
  97
  98 eval { $o->rename( 'test-decrby', 'test-renamed', 1 ) };
  99 ok( $@, 'rename to existing key' );
 100
 101 ok( my $nr_keys = $o->dbsize, 'dbsize' );
 102
 103
 104 diag "Commands operating on lists";
 105
 106 my $list = 'test-list';
 107
 108 $o->del($list) && diag "cleanup $list from last run";
 109
 110 ok( $o->rpush( $list => "r$_" ), 'rpush' ) foreach ( 1 .. 3 );
 111
 112 ok( $o->lpush( $list => "l$_" ), 'lpush' ) foreach ( 1 .. 2 );
 113
 114 cmp_ok( $o->type($list), 'eq', 'list', 'type' );
 115 cmp_ok( $o->llen($list), '==', 5, 'llen' );
 116
 117 is_deeply( [ $o->lrange( $list, 0, 1 ) ], [ 'l2', 'l1' ], 'lrange' );
 118
 119 ok( $o->ltrim( $list, 1, 2 ), 'ltrim' );
 120 cmp_ok( $o->llen($list), '==', 2, 'llen after ltrim' );
 121
 122 cmp_ok( $o->lindex( $list, 0 ), 'eq', 'l1', 'lindex' );
 123 cmp_ok( $o->lindex( $list, 1 ), 'eq', 'r1', 'lindex' );
 124
 125 ok( $o->lset( $list, 0, 'foo' ), 'lset' );
 126 cmp_ok( $o->lindex( $list, 0 ), 'eq', 'foo', 'verified' );
 127
 128 ok( $o->lrem( $list, 1, 'foo' ), 'lrem' );
 129 cmp_ok( $o->llen( $list ), '==', 1, 'llen after lrem' );
 130
 131 cmp_ok( $o->lpop( $list ), 'eq', 'r1', 'lpop' );
 132
 133 ok( ! $o->rpop( $list ), 'rpop' );
 134
 135
 136 diag "Commands operating on sets";
 137
 138 my $set = 'test-set';
 139 $o->del($set);
 140
 141 ok( $o->sadd( $set, 'foo' ), 'sadd' );
 142 ok( ! $o->sadd( $set, 'foo' ), 'sadd' );
 143 cmp_ok( $o->scard( $set ), '==', 1, 'scard' );
 144 ok( $o->sismember( $set, 'foo' ), 'sismember' );
 145
 146 cmp_ok( $o->type( $set ), 'eq', 'set', 'type is set' );
 147
 148 ok( $o->srem( $set, 'foo' ), 'srem' );
 149 ok( ! $o->srem( $set, 'foo' ), 'srem again' );
 150 cmp_ok( $o->scard( $set ), '==', 0, 'scard' );
 151
 152 $o->sadd( 'test-set1', $_ ) foreach ( 'foo', 'bar', 'baz' );
 153 $o->sadd( 'test-set2', $_ ) foreach ( 'foo', 'baz', 'xxx' );
 154
 155 my $inter = [ 'foo', 'baz' ];
 156
 157 is_deeply( [ $o->sinter( 'test-set1', 'test-set2' ) ], $inter, 'siter' );
 158
 159 ok( $o->sinterstore( 'test-set-inter', 'test-set1', 'test-set2' ), 'sinterstore' );
 160
 161 cmp_ok( $o->scard( 'test-set-inter' ), '==', $#$inter + 1, 'cardinality of intersection' );
 162
 163
 164 diag "Multiple databases handling commands";
 165
 166 ok( $o->select( 1 ), 'select' );
 167 ok( $o->select( 0 ), 'select' );
 168
 169 ok( $o->move( 'foo', 1 ), 'move' );
 170 ok( ! $o->exists( 'foo' ), 'gone' );
 171
 172 ok( $o->select( 1 ), 'select' );
 173 ok( $o->exists( 'foo' ), 'exists' );
 174
 175 ok( $o->flushdb, 'flushdb' );
 176 cmp_ok( $o->dbsize, '==', 0, 'empty' );
 177
 178
 179 diag "Sorting";
 180
 181 ok( $o->lpush( 'test-sort', $_ ), "put $_" ) foreach ( 1 .. 4 );
 182 cmp_ok( $o->llen( 'test-sort' ), '==', 4, 'llen' );
 183
 184 is_deeply( [ $o->sort( 'test-sort' )      ], [ 1,2,3,4 ], 'sort' );
 185 is_deeply( [ $o->sort( 'test-sort', 'DESC' ) ], [ 4,3,2,1 ], 'sort DESC' );
 186
 187
 188 diag "Persistence control commands";
 189
 190 ok( $o->save, 'save' );
 191 ok( $o->bgsave, 'bgsave' );
 192 ok( $o->lastsave, 'lastsave' );
 193 #ok( $o->shutdown, 'shutdown' );
 194 diag "shutdown not tested";
 195
 196 diag "Remote server control commands";
 197
 198 ok( my $info = $o->info, 'info' );
 199 isa_ok( $info, 'HASH' );
 200 diag Dumper( $info );
 201
 202 diag "Connection handling";
 203
 204 ok( $o->quit, 'quit' );
 205
 206 throws_ok sub { Redis->new(server => '127.0.0.1:1') },
 207   qr/Could not connect to Redis server at 127[.]0[.]0[.]1:1:/,
 208   'Failed connection throws exception';