web_ui.pl

   1 #!/usr/bin/env perl
   2
   3 use Mojolicious::Lite;
   4 use Redis;
   5
   6 use lib '/srv/MojoX-Gearman/lib';
   7 use MojoX::Gearman;
   8
   9 use Data::Dump qw(dump);
  10
  11 plugin 'tag_helpers';
  12 # Documentation browser under "/perldoc" (this plugin requires Perl 5.10)
  13 plugin 'pod_renderer';
  14
  15 app->secret('apkpm');
  16
  17 get '/' => sub {
  18         my $self = shift;
  19         $self->render('index');
  20 };
  21
  22 get '/ping_http' => sub {
  23         my $self = shift;
  24         my $gearman = $self->client;
  25         my $pong = $gearman->post( "http://localhost:4780/ping" => { Connection => 'close' } => "some data" )->res->body;
  26         warn "ping = $pong";
  27         $self->render( 'ping', pong => $pong );
  28 };
  29
  30 my $gearman = MojoX::Gearman->new; #( ioloop => Mojo::IOLoop->singleton );
  31 $gearman->server( $ENV{GEARMAN} || 'localhost:4730' );
  32
  33 get '/ping_g' => sub {
  34         my $self = shift;
  35         my $pong = $gearman->req( 'SUBMIT_JOB', 'ping', '', "some data 2" );
  36         warn "ping = $pong";
  37         $self->render( 'ping', pong => $pong );
  38 };
  39
  40 sub _render_jsonp {
  41         my ( $self, $json ) = @_;
  42         #my $data = $self->render( json => $json, partial => 1 );
  43         my $data = $json;
  44         if ( my $callback = $self->param('callback') ) {
  45                 $data = "$callback($data)";
  46         }
  47         $self->render( data => $data, format => 'js' );
  48 }
  49
  50
  51 get '/g/:call/:args' => [ args => qr/.*/ ] => sub {
  52         my $self = shift;
  53         my $ret = $gearman->req( 'SUBMIT_JOB', $self->param('call'), '', $self->param('args') );
  54         warn $self->param('call'), " = ", dump($ret), "\n";
  55         die "no result for ", $self->param('call'), ' args: ', $self->param('args') unless defined $ret;
  56         _render_jsonp( $self, $ret );
  57 };
  58
  59 get '/_g/status' => sub {
  60         my $self = shift;
  61
  62         my $ret = $gearman->req( 'TEXT' => 'status' );
  63         warn "# status:\n$ret";
  64
  65         my @c = qw(function total running available);
  66
  67         my $status;
  68         foreach my $l ( split(/\n/,$ret) ) {
  69                 my @v = split(/\t/, $l);
  70                 my $h;
  71                 $h->{$c[$_]} = $v[$_] foreach 0 .. $#v;
  72                 push @$status, $h;
  73         }
  74         warn "## ", dump $status;
  75         _render_jsonp( $self, Mojo::JSON->new->encode({ status => $status }) );
  76 };
  77
  78 get '/gnuplot' => sub {
  79         my $self = shift;
  80
  81         my $sql = $self->param('sql') || die "sql required";
  82
  83         my $ret = $gearman->req( 'SUBMIT_JOB', 'Store_sql', '', $sql );
  84         die "no result for $sql" unless $ret;
  85
  86         $ret = Mojo::JSON->new->decode( $ret );
  87
  88         my $dir = $self->app->home->rel_dir('public');
  89
  90         my $name = $sql;
  91         $name =~ s/\W+//gs;
  92         $name .= '.png';
  93
  94 warn "# $sql -> $name";
  95
  96         mkdir "$dir/gnuplot" unless -e "$dir/gnuplot";
  97         my $png = "$dir/gnuplot/$name"; # FIXME
  98
  99         open(my $gnuplot, '|-', 'gnuplot') || die "gnuplot: $!";
 100         open($gnuplot, '>', '/tmp/gnuplot') if $self->param('debug');
 101
 102         my @c = @{ $ret->{columns} };
 103         warn "first column not timestamp" unless shift @c eq 'timestamp';
 104
 105         print $gnuplot qq|
 106 set terminal png
 107 set output '$png'
 108
 109 set xdata time
 110 set timefmt "%Y-%m-%d %H:%M:%S"
 111 set format x "%H%M%S"
 112
 113 plot '-' using 1:3 title "$c[0]"
 114 |;
 115         foreach my $row ( @{ $ret->{rows} } ) {
 116                 print $gnuplot join("\t", @$row),"\n";
 117         }
 118         print $gnuplot "e\n";
 119         close($gnuplot);
 120
 121         $self->render('gnuplot', sql => $sql, img => "/gnuplot/$name");
 122 };
 123
 124 get '/_redis' => sub {
 125         my $self = shift;
 126
 127         my $redis = Redis->new;
 128
 129         my $status;
 130         $status->{$_} = $redis->scard($_) foreach $redis->keys('poll.*');
 131
 132         warn "## ", dump $status;
 133         _render_jsonp( $self, Mojo::JSON->new->encode({ status => $status }) );
 134 };
 135
 136 app->start;
 137 __DATA__
 138
 139 @@ index.html.ep
 140 % layout 'default';
 141 % title 'Gearman demo';
 142
 143 <ul>
 144 <li><a href="/gearman.html#ping/127.0.0.1">Gearman</a> web interface
 145 <li><%= link_to 'CRM' => 'CRM.html' %> search with tabular output
 146 </ul>
 147
 148 Gnuplot graphs:
 149
 150 <ul>
 151 <li><a href="/gnuplot?sql=select timestamp,rtt from ping where ip << inet '10.17/16' order by timestamp desc limit 1000">ttl from 10.17 network</a>
 152 </ul>
 153
 154 Low-level API tests:
 155
 156 <%= link_to 'HTTP ping' => 'ping_http' %>
 157 <%= link_to 'Gearman ping' => 'ping_g' %>
 158
 159 @@ ping.html.ep
 160 % layout 'default';
 161 pong: <tt><%= $pong %>
 162
 163 @@ gnuplot.html.ep
 164 % layout 'default';
 165 <%= form_for gnuplot => begin %>
 166  <%= text_area 'sql', cols => 80 %>
 167  <%= submit_button %>
 168 <% end %>
 169 <img src="<%= $img %>">
 170
 171 @@ layouts/default.html.ep
 172 <!doctype html><html>
 173   <head><title><%= title %></title></head>
 174   <body><%= content %></body>
 175 </html>