package WebPac;

use base 'CGI::Application';
use strict;

use HTML::Pager;
use HTML::FillInForm;
use SWISH;
use Text::Iconv;
use DBI;
use Config::IniFiles;
use Text::Unaccent;

use lib '..';
use index_DBI_cache;
use back2html;


# read global.conf configuration
my $cfg_global = new Config::IniFiles( -file => '../global.conf' ) || die "can't open 'global.conf'";

# configuration options from global.conf
my $TEMPLATE_PATH = $cfg_global->val('webpac', 'template_html') || die "need template_html in global.conf, section webpac";
my $CHARSET = $cfg_global->val('webpac', 'charset') || 'ISO-8859-1';
my $SWISH = $cfg_global->val('webpac', 'swish') || '/usr/bin/swish-e';
my $INDEX = $cfg_global->val('webpac', 'index') || die "need index in global.conf, section webpac";
my $MAX_HITS = $cfg_global->val('webpac', 'max_hits') || 0;
my $ON_PAGE =$cfg_global->val('webpac', 'on_page') || 10;
my $MIN_WILDCARD =$cfg_global->val('webpac', 'min_wildcard') || 1;
my $TEMPLATE =$cfg_global->val('webpac', 'template');
my $UNAC_FILTER =$cfg_global->val('global', 'unac_filter');
my $BASE_PATH =$cfg_global->val('webpac', 'base_path');

if ($UNAC_FILTER) {
	require $UNAC_FILTER;
}

Text::Iconv->raise_error(0);     # Conversion errors raise exceptions

my $from_utf8 = Text::Iconv->new('UTF8', $CHARSET);

# use path from cgi script to support templates in subdirs
sub url_ex {
	my $q = shift || die "suff2file needs CGI object!";
	my $tpl = shift || die "url_ex needs template name!";
	return suff2file($BASE_PATH, $q->url(-path => 1),$TEMPLATE_PATH,$tpl);
}

sub suff2file($$$$) {
	my ($base_path, $p, $path, $tpl) = @_;

	return $tpl if (! $base_path);

	# strip everything to and including base path, leaving only
	# additional (virtual) path
	if ($p =~ s,^.*?$base_path,,) {
		$p =~ s,/*,,g;
		my ($name,$ext) = split(/\./,$tpl);
		$p = $name . $p . "." . $ext;
	} else {
		# if unable reset it!
		$p = $tpl;
	}

	if ( -e "$path/$p") {
		return $p;
	} else {
		return $tpl;
	}

}

sub setup {
	my $self = shift;
	$self->tmpl_path($TEMPLATE_PATH);
	$self->run_modes(
		'search' => 'show_search_form',
		'results' => 'show_results_list',
#		'user' => 'show_user_detail',
		'index' => 'show_index',
	);
	$self->start_mode('search');
	$self->mode_param('rm');

	$self->header_props(-charset=>$CHARSET);
}

sub in_template {
	my $q = shift || die "need CGI object!";
	my $html = shift || die "This page is left unintentionally blank";
	return $html if (! defined($TEMPLATE));

	my ($dir,$tpl);
	if ($TEMPLATE =~ m,^(.*?/*)([^/]+)$,) {
		($dir,$tpl) = ($1,$2);
	} else {
		die "can't parse TEMPLATE path";
	}

	my $master_tpl = suff2file($BASE_PATH, $q->url(-path => 1),$dir,$tpl);
	if (open(T, $master_tpl)) {
		my $template_html = join("\n",<T>);
		close(T);
		$template_html =~ s/##webpac##/$html/gsi;
		return $template_html;
	} else {
		return "Can't read template '$master_tpl'";
	}
}

sub show_search_form {
	my $self = shift;

	# Get the CGI.pm query object
	my $q = $self->query();

	my $tmpl = $self->load_tmpl(url_ex($q,'search.html'));
	my $html = $tmpl->output;

	my $fif = new HTML::FillInForm;

	return in_template($q,$fif->fill(scalarref => \$html, fobject => $q,
		target => 'search'));
}
 
sub show_results_list {
	my $self = shift;

	my $q = $self->query();

	my @swish_results;	# results from swish

	# load template for this page

	my @s_arr;	# all queries are located here

	my @path_arr = $q->param('path');
	my $full = $q->param('full');

	my @persist_vars = ( 'rm' ); 
	my @url_params = ( 'rm=results', 'show_full=1', 'last_PAGER_offset='.$q->param('PAGER_offset') || 0 );

	# support parametars "f" and "v" for start
	for(my $i = ""; $i <=30; $i++) {

		return show_index($self, $i) if ($q->param("f".$i."_index"));

		next if (! $q->param("v$i"));
		next if (! $q->param("f$i"));

		push @persist_vars, "f$i";
		push @persist_vars, "v$i";
		push @persist_vars, "e$i" if ($q->param("e$i"));

		push @url_params,"f$i=".$q->url_param("f$i");
		foreach my $v ($q->url_param("v$i")) {
			push @url_params,"v$i=$v";
		}
		push @url_params,"e$i=".$q->url_param("e$i");

		my $wc="*";	# swish wildcard
		$wc="" if ($i eq "");	# don't apply wildcard on field 0

		# re-write query from +/- to and/and not
		my @param_vals = $q->param("v$i");
		my @swish_q;
		my ($pre,$post,$exact) = ('','','');
		while (my $search = shift @param_vals) {
			my $s;
			# remove accents
			$search = unac_string($CHARSET,$search);
			while ($search =~ s/\s*("[^"]+")\s*/ /) {
				$s .= "$1 ";
			}
			$search =~ s/^\s+//;
			$search =~ s/\s+$//;

			# filed e[nr] is exact match bitmask
			# 1 = beginning, 2=end, 3=both
			$pre = '"xxbxx ' if ($q->param("e$i") & 1);
			$post = ' xxexx"' if ($q->param("e$i") & 2);
			# add qotes on other side
			if ($q->param("e$i")) {
				$pre = '"' if (! $pre);
				$post = '"' if (! $post);
				# what about wildcards?
				$wc = '';
				$wc = '*' if ($q->param("e$i") & 4);
				$exact = '_exact';
			}

			foreach (split(/\s+/,$search)) {
				if (m/^([+-])(\S+)/) {
					$s.= ($s) ? "and " : "";
					$s.="not " if ($1 eq "-");
					$s.=$2.$wc." ";
				} elsif (m/^\s*(and|or|not)\s*$/i) {
					$s.=$_." ";
				# don't add * to words with less than x chars
				} elsif (length($_) <= $MIN_WILDCARD) {
					$s.=$_." ";
				} else {
					$s.=$_.$wc." ";
				}
			}
			$s =~ s/\*+/*/g;
			$s = $pre.$s.$post if ($q->param("e$i"));
			push @swish_q,$s;
		}
		# FIXME default operator for multi-value fields is or. There is
		# no way to change it, except here for now. Is there need?
		push @s_arr, $q->param("f$i")."_swish".$exact."=(".join(" or ",@swish_q).")";
	}

	my $tmpl = $self->load_tmpl(url_ex($q,'results.html'), global_vars => 1);

	sub esc_html {
		my $html = shift;
		$html =~ s/</&lt;/g;
		$html =~ s/>/&gt;/g;
		return $html;
	}

	my $sort = 'swishrank';
	if ($q->param("sort")) {
		$sort = 'headline';
		push @persist_vars, "sort";
	}

	# call swish
	my $sh = SWISH->connect('Fork',
		prog     => $SWISH,
		indexes  => $INDEX,
		properties  => [qw/swishdocpath swishrank swishtitle headline html/],
		results  => sub {
			my ($sh,$hit) = @_;

			push @swish_results, {
				nr => ($#swish_results + 2),
				path => $hit->swishdocpath,
				headline => esc_html($from_utf8->convert($hit->headline)),
				html => back2html($from_utf8->convert($hit->html)),
				rank => $hit->swishrank };

		},
		#startnum => 0,
		maxhits => $MAX_HITS,
		sortorder => $sort,
	);

	die $SWISH::errstr unless $sh;
	# construct swish query
	my $sw_q = join(" and ",@s_arr);
	if (@path_arr && $q->param('show_full')) {
		$sw_q .= "and (swishdocpath=\"";
		$sw_q .= join("\" or swishdocpath=\"",@path_arr);
		$sw_q .= "\")";
		$tmpl->param('full',1);	# show full records
	} elsif ($q->param('show_full')) {
		# just show full path, no path defined
		$tmpl->param('full',1);
	} else {
		$tmpl->param('full',0);
	}

	my $hits = $sh->query($sw_q);

	$tmpl->param('hits',$hits);
	$tmpl->param('search',$sw_q);

	$tmpl->param('PAGER_offset',$q->param("PAGER_offset") || 0);
	$tmpl->param('last_PAGER_offset',$q->param("last_PAGER_offset") || 0);

	$tmpl->param('url_params',"?".join("&",@url_params));

	# create a Pager object
	my $pager = HTML::Pager->new(
		# required parameters
		query => $q,
		get_data_callback => sub {
			my ($offset, $rows) = @_;

			my @result;
			for (my $i=0; $i<$rows; $i++) {
				my $r = $swish_results[$offset+$i];
				if ($r && $tmpl->param('full')) {
					push @result, $r;
				} elsif ($r) {
					# if not full output, skip html
					delete $r->{html};
					push @result, $r;
				}
			}
			return \@result;
		},
		rows => $hits,
		page_size => $ON_PAGE,
		# some optional parameters
		persist_vars => [ @persist_vars ],
		#cell_space_color => '#000000',
		#cell_background_color => '#ffffff',
		#nav_background_color => '#dddddd',
		#javascript_presubmit => 'last_minute_javascript()',
		debug => 1,
		template => $tmpl,
	);

	my $html = $pager->output;

	return in_template($q,$html);
}
 
sub show_index {
	my $self = shift;
	my $i = shift;		# field number

	my $q = $self->query();

	my $field = $q->param("f$i");
	my $limit = $q->param("v$i");

	my $html;

	my $index = new index_DBI(
		$cfg_global->val('global', 'dbi_dbd'),
		$cfg_global->val('global', 'dbi_dsn'),
		$cfg_global->val('global', 'dbi_user'),
		$cfg_global->val('global', 'dbi_passwd') || ''
	);

	my $total = $index->count($field,$limit);
	if (! $total) {
		my $tmpl = $self->load_tmpl(url_ex($q,'no_index.html'));
		$tmpl->param('field',$field);
		$html = $tmpl->output;
		return $html;
	}

	my $tmpl = $self->load_tmpl(url_ex($q,'index_res.html'), global_vars => 1);
	$tmpl->param('field',$field);
	$tmpl->param('limit',$limit);
	$tmpl->param('total',$total);

# FIXME I should set offset and leave out limit from fetch!!
#	if (! $q->param("PAGER_offset") {
#		$q->param("Pager_offet)
#	}

	my $pager = HTML::Pager->new(
		query => $q,
		get_data_callback => sub {
			my ($offset, $rows) = @_;

			my @result = $index->fetch($field,$limit, $offset, $rows);
			return \@result;
		},
		rows => $total,
		page_size => $ON_PAGE,
		persist_vars => [
			'rm', 
			"f$i", "v$i", "f".$i."_index", 
			'offset',
			],
		debug => 1,
		template => $tmpl,
	);

	return in_template($q,$pager->output);
}

1;
