package WebPac;

use base 'CGI::Application';
use strict;

use HTML::Pager;
use HTML::FillInForm;
use SWISH;
use Text::Iconv;
use DBI;
use Config::IniFiles;
use Text::Unaccent;

use lib '..';
use index_DBI;
use back2html;


# read global.conf configuration
my $cfg_global = new Config::IniFiles( -file => '../global.conf' ) || die "can't open 'global.conf'";

# configuration options from global.conf
my $TEMPLATE_PATH = $cfg_global->val('webpac', 'template_html') || die "need template_html in global.conf, section webpac";
my $CHARSET = $cfg_global->val('webpac', 'charset') || 'ISO-8859-1';
my $SWISH = $cfg_global->val('webpac', 'swish') || '/usr/bin/swish-e';
my $INDEX = $cfg_global->val('webpac', 'index') || die "need index in global.conf, section webpac";
my $MAX_HITS = $cfg_global->val('webpac', 'max_hits') || 0;
my $ON_PAGE =$cfg_global->val('webpac', 'on_page') || 10;
my $MIN_WILDCARD =$cfg_global->val('webpac', 'min_wildcard') || 1;


Text::Iconv->raise_error(0);     # Conversion errors raise exceptions

my $from_utf8 = Text::Iconv->new('UTF8', $CHARSET);


sub setup {
	my $self = shift;
	$self->tmpl_path($TEMPLATE_PATH);
	$self->run_modes(
		'search' => 'show_search_form',
		'results' => 'show_results_list',
#		'user' => 'show_user_detail',
		'index' => 'show_index',
	);
	$self->start_mode('search');
	$self->mode_param('rm');

	$self->header_props(-charset=>$CHARSET);
}

sub show_search_form {
	my $self = shift;

	# Get the CGI.pm query object
	my $q = $self->query();

	my $tmpl = $self->load_tmpl('search.html');
	my $html = $tmpl->output;

	my $fif = new HTML::FillInForm;

	return $fif->fill(scalarref => \$html, fobject => $q,
		target => 'search');
}
 
sub show_results_list {
	my $self = shift;

	my $q = $self->query();

	my @swish_results;	# results from swish

	# load template for this page

	my @s_arr;	# all queries are located here

	my @path_arr = $q->param('path');
	my $full = $q->param('full');

	my @persist_vars = ( 'rm' ); 

	for(my $i = 1; $i <=30; $i++) {

		return show_index($self, $i) if ($q->param("f".$i."_index"));

		next if (! $q->param("v$i"));
		next if (! $q->param("f$i"));

		push @persist_vars, "f$i";
		push @persist_vars, "v$i";

		# re-write query from +/- to and/and not
		my @param_vals = $q->param("v$i");
		my @swish_q;
		while (my $search = shift @param_vals) {
			my $s;
			# remove accents
			$search = unac_string($CHARSET,$search);
			while ($search =~ s/\s*("[^"]+")\s*/ /) {
				$s .= "$1 ";
			}
			$search =~ s/^\s+//;
			$search =~ s/\s+$//;

			foreach (split(/\s+/,$search)) {
				if (m/^([+-])(\S+)/) {
					$s.= ($s) ? "and " : "";
					$s.="not " if ($1 eq "-");
					$s.="$2* ";
				} elsif (m/^\s*(and|or|not)\s*$/i) {
					$s.="$_ ";
				# don't add * to words with less than x chars
				} elsif (length($_) <= $MIN_WILDCARD) {
					$s.="$_ ";
				} else {
					$s.="$_* ";
				}
			}
			$s =~ s/\*+/*/g;
			push @swish_q,$s;
		}
		# FIXME default operator for multi-value fields is or. There is
		# no way to change it, except here for now. Is there need?
		push @s_arr, $q->param("f$i")."_swish=(".join(" or ",@swish_q).")";
	}

	my $tmpl = $self->load_tmpl('results.html');

	sub esc_html {
		my $html = shift;
		$html =~ s/</&lt;/g;
		$html =~ s/>/&gt;/g;
		return $html;
	}

	# call swish
	my $sh = SWISH->connect('Fork',
		prog     => $SWISH,
		indexes  => $INDEX,
		properties  => [qw/swishdocpath swishrank swishtitle headline html/],
		results  => sub {
			my ($sh,$hit) = @_;

			push @swish_results, {
				nr => ($#swish_results + 2),
				path => $hit->swishdocpath,
				headline => esc_html($from_utf8->convert($hit->headline)),
				html => back2html($from_utf8->convert($hit->html)),
				rank => $hit->swishrank };

		},
		#startnum => 0,
		maxhits => $MAX_HITS
	);

	die $SWISH::errstr unless $sh;
	# construct swish query
	my $sw_q = join(" and ",@s_arr);
	if (@path_arr && $q->param('show_full')) {
		$sw_q .= "and (swishdocpath=\"";
		$sw_q .= join("\" or swishdocpath=\"",@path_arr);
		$sw_q .= "\")";
		$tmpl->param('full',1);	# show full records
	} else {
		$tmpl->param('full',0);
	}

	my $hits = $sh->query($sw_q);

	$tmpl->param('hits',$hits);
	$tmpl->param('search',$sw_q);

	$tmpl->param('PAGER_offset',$q->param("PAGER_offset") || 0);
	$tmpl->param('last_PAGER_offset',$q->param("last_PAGER_offset") || 0);

	# create a Pager object
	my $pager = HTML::Pager->new(
		# required parameters
		query => $q,
		get_data_callback => sub {
			my ($offset, $rows) = @_;

			my @result;
			for (my $i=0; $i<$rows; $i++) {
				my $r = $swish_results[$offset+$i];
				if ($r && $tmpl->param('full')) {
					push @result, $r;
				} elsif ($r) {
					# if not full output, skip html
					delete $r->{html};
					push @result, $r;
				}
			}
			return \@result;
		},
		rows => $hits,
		page_size => $ON_PAGE,
		# some optional parameters
		persist_vars => [ @persist_vars ],
		#cell_space_color => '#000000',
		#cell_background_color => '#ffffff',
		#nav_background_color => '#dddddd',
		#javascript_presubmit => 'last_minute_javascript()',
		debug => 1,
		template => $tmpl,
	);

	my $html = $pager->output;

	return $html;
}
 
sub show_index {
	my $self = shift;
	my $i = shift;		# field number

	my $q = $self->query();

	my $field = $q->param("f$i");
	my $limit = $q->param("v$i");

	my $html;

	my $index = new index_DBI(
		$cfg_global->val('global', 'dbi_dbd'),
		$cfg_global->val('global', 'dbi_dsn'),
		$cfg_global->val('global', 'dbi_user'),
		$cfg_global->val('global', 'dbi_passwd') || ''
	);

	my $total = $index->check($field);
	if (! $total) {
		my $tmpl = $self->load_tmpl('no_index.html');
		$tmpl->param('field',$field);
		$html = $tmpl->output;
		return $html;
	}

	my $tmpl = $self->load_tmpl('index_res.html');
	$tmpl->param('field',$field);
	$tmpl->param('limit',$limit);
	$tmpl->param('total',$total);

# FIXME I should set offset and leave out limit from fetch!!
#	if (! $q->param("PAGER_offset") {
#		$q->param("Pager_offet)
#	}

	my $pager = HTML::Pager->new(
		query => $q,
		get_data_callback => sub {
			my ($offset, $rows) = @_;

			my @result = $index->fetch($field,'item',$limit, $offset, $rows);
			return \@result;
		},
		rows => $total,
		page_size => $ON_PAGE,
		persist_vars => [
			'rm', 
			"f$i", "v$i", "f".$i."_index", 
			'offset',
			],
		debug => 1,
		template => $tmpl,
	);

	return $pager->output;
}

1;
