#!/usr/bin/perl -w

use strict;
use OpenIsis;
use Getopt::Std;
use Data::Dumper;
use XML::Simple;
use Text::Unaccent 1.02;	# 1.01 won't compile on my platform,
use Text::Iconv;
use Config::IniFiles;
use Encode;

$|=1;

my $config_file = $0;
$config_file =~ s/\.pl$/.conf/;
die "FATAL: can't find configuration file '$config_file'" if (! -e $config_file);

my $config;

use index_DBI;	# there is no other, right now ;-)
my $index;

my %opts;

# usage:
# 	-d directory name
# 	-m multiple directories
# 	-q quiet
# 	-s run swish

getopts('d:m:qs', \%opts);

my $path;	# this is name of database

Text::Iconv->raise_error(1);     # Conversion errors raise exceptions

# this is encoding of all files on disk, including import_xml/*.xml file and
# filter/*.pm files! It will be used to store strings in perl internally!
my $codepage = 'ISO-8859-2';

my $utf2cp = Text::Iconv->new('UTF-8',$codepage);
# this function will convert data from XML files to local encoding
sub x {
	return $utf2cp->convert($_[0]);
}

# decode isis/excel or other import codepage
my $import2cp;

# outgoing xml must be in UTF-8
my $cp2utf = Text::Iconv->new($codepage,'UTF-8');

# mapping between data type and tag which specify
# format in XML file
my %type2tag = (
	'isis' => 'isis',
	'excel' => 'column'
);

sub data2xml {

	use xmlify;

	my $type = shift @_;
	my $row = shift @_;
	my $add_xml = shift @_;

	my $xml;

	use parse_format;

	my $html = "";		# html formatted display output

	my %field_usage;	# counter for usage of each field

	# sort subrouting using order="" attribute
	sub by_order {
		return 0 if (! $config->{indexer}->{$a}->{order});
		return 0 if (! $config->{indexer}->{$b}->{order});

		return $config->{indexer}->{$a}->{order} <=>
			$config->{indexer}->{$b}->{order} ;
	}

	foreach my $field (sort by_order keys %{$config->{indexer}}) {

		$field=x($field);

		$field_usage{$field}++;

		my $swish_data = "";
		my $display_data = "";
		my $line_delimiter;

		my ($swish,$display);

		my $tag = $type2tag{$type} || die "can't find which tag to use for type $type";
		foreach my $x (@{$config->{indexer}->{$field}->{$tag}}) {

			my $format = x($x->{content});
			my $delimiter = x($x->{delimiter}) || ' ';

			my $repeat_off = 0;		# repeatable offset

			my ($s,$d,$i) = (1,1,0);	# swish, display default
			$s = 0 if (lc($x->{type}) eq "display");
			$d = 0 if (lc($x->{type}) eq "swish");
			($s,$d,$i) = (0,0,1) if (lc($x->{type}) eq "index");

			# what will separate last line from this one?
			if ($display_data && $x->{append} && $x->{append} eq "1") {
				$line_delimiter = ' ';
			} elsif ($display_data) {
				$line_delimiter = '<br/>';
			}

			# init vars so that we go into while...
			($swish,$display) = (1,1);

			if ($swish || $display) {
				($swish,$display) = parse_format($type, $format,$row,$repeat_off++,$import2cp);
				# filter="name" ; filter this field through
				# filter/[name].pm
				my $filter = $x->{filter};
				if ($filter) {
					require "filter/".$filter.".pm";
				}
				# type="swish" ; field for swish
				if ($s && $swish) {
					if ($filter) {
						no strict 'refs';
						$swish_data .= join(" ",&$filter($swish));
					} else {
						$swish_data .= $swish;
					}
				}

				# type="display" ; field for display
				if ($d && $display) {
					if ($line_delimiter && $display_data) {
						$display_data .= $line_delimiter;
						undef $line_delimiter;
					}
					if ($filter) {
						no strict 'refs';
						$display_data .= join($delimiter,&$filter($display));
					} else {
						if ($display_data) {
							$display_data .= $delimiter.$display;
						} else {
							$display_data .= $display;
						}
					}
				}
						
				# type="index" ; insert into index
				if ($i && $display) {
					my $index_data = $display;
					if ($filter) {
						no strict 'refs';
						foreach my $d (&$filter($index_data)) {
							$index->insert($field, $d, $path);
						}
					} else {
						$index->insert($field, $index_data, $path);
					}
				}
			}
		}


		if ($display_data) {

			if ($field eq "headline") {
				$xml .= xmlify("headline", $display_data);
			} else {

				# find field name (signular, plural)
				my $field_name = "";
				if ($config->{indexer}->{$field}->{name_singular} && $field_usage{$field} == 1) {
					$field_name = $config->{indexer}->{$field}->{name_singular}."#-#";
				} elsif ($config->{indexer}->{$field}->{name_plural}) {
					$field_name = $config->{indexer}->{$field}->{name_plural}."#-#";
				} elsif ($config->{indexer}->{$field}->{name}) {
					$field_name = $config->{indexer}->{$field}->{name}."#-#";
				} else {
					print STDERR "WARNING: field '$field' doesn't have 'name' attribute!";
				}
				if ($field_name) {
					$html .= x($field_name);
				}
				$html .= $display_data."###\n";
			}
		}
		if ($swish_data) {
			# remove extra spaces
			$swish_data =~ s/ +/ /g;
			$swish_data =~ s/ +$//g;

			$xml .= xmlify($field."_swish", unac_string($codepage,$swish_data));
		}


	}

	# dump formatted output in <html>
	if ($html) {
		$xml .= xmlify("html",$html);
	}
	
	if ($xml) {
		$xml .= $add_xml if ($add_xml);
		return "<xml>\n$xml</xml>\n";
	} else {
		return;
	}
}

##########################################################################

# read configuration for this script
my $cfg = new Config::IniFiles( -file => $config_file );

# read global.conf configuration
my $cfg_global = new Config::IniFiles( -file => 'global.conf' );

# open index
$index = new index_DBI(
		$cfg_global->val('global', 'dbi_dbd'),
		$cfg_global->val('global', 'dbi_dsn'),
		$cfg_global->val('global', 'dbi_user'),
		$cfg_global->val('global', 'dbi_passwd') || '',
	);

foreach my $database ($cfg->Sections) {

	my $type = lc($cfg -> val($database, 'type')) || die "$database doesn't have 'type' defined";
	my $add_xml = $cfg -> val($database, 'xml');	# optional

print STDERR "reading ./import_xml/$type.xml\n";

	$config=XMLin("./import_xml/$type.xml", forcearray => [ $type2tag{$type} ], forcecontent => 1);

	# output current progress indicator
	my $last_p = 0;
	sub progress {
		#return if (! $opts{q});	# FIXME
		my $current = shift;
		my $total = shift;
		my $p = int($current * 100 / $total);
		if ($p != $last_p) {
			printf STDERR ("%5d / %5d [%-51s] %-2d %% \r",$current,$total,"=" x ($p/2).">", $p );
			$last_p = $p;
		}
	}

	# now read database
print STDERR "using: $type...\n";

	if ($type eq "isis") {
		my $isis_db = $cfg -> val($database, 'isis_db') || die "$database doesn't have 'isis_db' defined!";

		$import2cp = Text::Iconv->new($config->{isis_codepage},$codepage);
		my $db = OpenIsis::open( $isis_db );

		my $max_rowid = OpenIsis::maxRowid( $db );

		print STDERR "Reading database: $isis_db [$max_rowid rows]\n";

		my $path = $database;

		for (my $row_id = 1; $row_id <= $max_rowid; $row_id++ ) {
			my $row = OpenIsis::read( $db, $row_id );
			if ($row && $row->{mfn}) {
	
				progress($row->{mfn}, $max_rowid);

				my $swishpath = $path."#".int($row->{mfn});

				if (my $xml = data2xml($type,$row,$add_xml)) {
					$xml = $cp2utf->convert($xml);
					use bytes;	# as opposed to chars
					print "Path-Name: $swishpath\n";
					print "Content-Length: ".(length($xml)+1)."\n";
					print "Document-Type: XML\n\n$xml\n";
				}
			}
		}
		print STDERR "\n";

	} elsif ($type eq "excel") {
		use Spreadsheet::ParseExcel;
		use Spreadsheet::ParseExcel::Utility qw(int2col);
		
		$import2cp = Text::Iconv->new($config->{excel_codepage},$codepage);
		my $excel_file = $cfg -> val($database, 'excel_file') || die "$database doesn't have 'excel_file' defined!";

		my $sheet = x($config->{sheet}) || die "no sheet in $type.xml";
		my $start_row = x($config->{start_row}) || die "no start_row in $type.xml";

		my $oBook = Spreadsheet::ParseExcel::Workbook->Parse($excel_file) || die "can't open Excel file '$excel_file'";

		my $sheet_nr = 0;
		foreach my $oWks (@{$oBook->{Worksheet}}) {
			#print STDERR "-- SHEET $sheet_nr:", $oWks->{Name}, "\n";
			last if ($oWks->{Name} eq $sheet);
			$sheet_nr++;
		}

		my $oWorksheet = $oBook->{Worksheet}[$sheet_nr];
	
		print STDERR "using sheet: ",$oWorksheet->{Name},"\n";
		defined ($oWorksheet) || die "can't find sheet '$sheet' in $excel_file";
		my $end_row = x($config->{end_row}) || $oWorksheet->{MaxRow};

		for(my $iR = $oWorksheet->{MinRow} ; defined $end_row && $iR <= $end_row ; $iR++) {
			my $row;
			for(my $iC = $oWorksheet->{MinCol} ; defined $oWorksheet->{MaxCol} && $iC <= $oWorksheet->{MaxCol} ; $iC++) {
				my $cell = $oWorksheet->{Cells}[$iR][$iC];
				if ($cell) {
					$row->{int2col($iC)} = $cell->Value;
				}
			}

			progress($iR, $end_row);

#			print "row[$iR/$end_row] ";
#			foreach (keys %{$row}) {
#				print "$_: ",$row->{$_},"\t";
#			}
#			print "\n";

			my $swishpath = $database."#".$iR;

			next if (! $row);

			if (my $xml = data2xml($type,$row,$add_xml)) {
				$xml = $cp2utf->convert($xml);
				use bytes;	# as opposed to chars
				print "Path-Name: $swishpath\n";
				print "Content-Length: ".(length($xml)+1)."\n";
				print "Document-Type: XML\n\n$xml\n";
			}
		}
	}
}

# call this to commit index
$index->close;

1;
__END__
##########################################################################

=head1 NAME

isis2xml.pl - read isis file and dump XML

=head1 DESCRIPTION

This command will read ISIS data file using OpenIsis perl module and
create XML file for usage with I<SWISH-E>
indexer. Dispite it's name, this script B<isn't general xml generator>
from isis files (isis allready has something like that). Output of this
script is tailor-made for SWISH-E.

=head1 AUTHOR

Dobrica Pavlinusic <dpavlin@rot13.org>

=head1 COPYRIGHT

GNU Public License (GPL) v2 or later

=head1 SEE ALSO

SWISH-E web site at http://www.swish-e.org

=cut
