#!/usr/bin/perl -w

use strict;
use OpenIsis;
use Getopt::Std;
use Data::Dumper;
use XML::Simple;
use Text::Unaccent 1.02;	# 1.01 won't compile on my platform,
use Text::Iconv;
use Config::IniFiles;
use Encode;

$|=1;

my $config_file = $0;
$config_file =~ s/\.pl$/.conf/;
die "FATAL: can't find configuration file '$config_file'" if (! -e $config_file);

my $config;

use index_DBI;	# there is no other, right now ;-)

my $index = new index_DBI();	# open index

my %opts;

# usage:
# 	-d directory name
# 	-m multiple directories
# 	-q quiet
# 	-s run swish

getopts('d:m:qs', \%opts);

my $path;	# this is name of database

Text::Iconv->raise_error(1);     # Conversion errors raise exceptions

# this is encoding of all files on disk, including import_xml/*.xml file and
# filter/*.pm files! It will be used to store strings in perl internally!
my $codepage = 'ISO-8859-2';

my $utf2cp = Text::Iconv->new('UTF-8',$codepage);
# this function will convert data from XML files to local encoding
sub x {
	return $utf2cp->convert($_[0]);
}

# decode isis import codepage
my $isis2cp;

# outgoing xml must be in UTF-8
my $cp2utf = Text::Iconv->new($codepage,'UTF-8');

sub isis2xml {

	use xmlify;

	my $row = shift @_;
	my $add_xml = shift @_;

	my $xml;

	use parse_format;

	my $html = "";		# html formatted display output

	my %field_usage;	# counter for usage of each field

	# sort subrouting using order="" attribute
	sub by_order {
		return 0 if (! $config->{indexer}->{$a}->{order});
		return 0 if (! $config->{indexer}->{$b}->{order});

		return $config->{indexer}->{$a}->{order} <=>
			$config->{indexer}->{$b}->{order} ;
	}

	foreach my $field (sort by_order keys %{$config->{indexer}}) {

		$field=x($field);

		$field_usage{$field}++;

		my $swish_data = "";
		my $display_data = "";
		my $line_delimiter;

		my ($swish,$display);

		foreach my $x (@{$config->{indexer}->{$field}->{isis}}) {

			my $format = x($x->{content});
			my $delimiter = x($x->{delimiter}) || ' ';

			my $isis_i = 0;		# isis repeatable offset

			my ($s,$d,$i) = (1,1,0);	# swish, display default
			$s = 0 if (lc($x->{type}) eq "display");
			$d = 0 if (lc($x->{type}) eq "swish");
			($s,$d,$i) = (0,0,1) if (lc($x->{type}) eq "index");

			# what will separate last line from this one?
			if ($display_data && $x->{append} && $x->{append} eq "1") {
				$line_delimiter = ' ';
			} elsif ($display_data) {
				$line_delimiter = '<br/>';
			}

			# init vars so that we go into while...
			($swish,$display) = (1,1);

			while ($swish || $display) {
				($swish,$display) = parse_format($format,$row,$isis_i++,$isis2cp);

				# filter="name" ; filter this field through
				# filter/[name].pm
				my $filter = $x->{filter};
				if ($filter) {
					require "filter/".$filter.".pm";
				}
				# type="swish" ; field for swish
				if ($s && $swish) {
					if ($filter) {
						no strict 'refs';
						$swish_data .= join(" ",&$filter($swish));
					} else {
						$swish_data .= $swish;
					}
				}

				# type="display" ; field for display
				if ($d && $display) {
					if ($line_delimiter && $display_data) {
						$display_data .= $line_delimiter;
						undef $line_delimiter;
					}
					if ($filter) {
						no strict 'refs';
						$display_data .= join($delimiter,&$filter($display));
					} else {
						if ($display_data) {
							$display_data .= $delimiter.$display;
						} else {
							$display_data .= $display;
						}
					}
				}
						
				# type="index" ; insert into index
				if ($i && $display) {
					my $index_data = $display;
					if ($filter) {
						no strict 'refs';
						foreach my $d (&$filter($index_data)) {
							$index->insert($field, $d, $path);
						}
					} else {
						$index->insert($field, $index_data, $path);
					}
				}
			}
		}


		if ($display_data) {

			if ($field eq "headline") {
				$xml .= xmlify("headline", $display_data);
			} else {

				# find field name (signular, plural)
				my $field_name = "";
				if ($config->{indexer}->{$field}->{name_singular} && $field_usage{$field} == 1) {
					$field_name = $config->{indexer}->{$field}->{name_singular}."#-#";
				} elsif ($config->{indexer}->{$field}->{name_plural}) {
					$field_name = $config->{indexer}->{$field}->{name_plural}."#-#";
				} elsif ($config->{indexer}->{$field}->{name}) {
					$field_name = $config->{indexer}->{$field}->{name}."#-#";
				} else {
					print STDERR "WARNING: field '$field' doesn't have 'name' attribute!";
				}
				if ($field_name) {
					$html .= x($field_name);
				}
				$html .= $display_data."###\n";
			}
		}
		if ($swish_data) {
			# remove extra spaces
			$swish_data =~ s/ +/ /g;
			$swish_data =~ s/ +$//g;

			$xml .= xmlify($field."_swish", unac_string($codepage,$swish_data));
		}


	}

	# dump formatted output in <html>
	if ($html) {
		$xml .= xmlify("html",$html);
	}
	
	if ($xml) {
		$xml .= $add_xml if ($add_xml);
		return "<xml>\n$xml</xml>\n";
	} else {
		return;
	}
}

##########################################################################

my $cfg = new Config::IniFiles( -file => $config_file );

foreach my $database ($cfg->Sections) {

	my $isis_db = $cfg -> val($database, 'isis_db') || die "$database doesn't have 'isis_db' defined!";
	my $type = $cfg -> val($database, 'type') || die "$database doesn't have 'type' defined";
	my $add_xml = $cfg -> val($database, 'xml');	# optional

	$config=XMLin("./import_xml/$type.xml", forcearray => [ 'isis' ], forcecontent => 1);

	$isis2cp = Text::Iconv->new($config->{isis_codepage},$codepage);

	my $db = OpenIsis::open( $isis_db );
	if (0) {
#	# FIX
#	if (! $db ) {
		print STDERR "WARNING: can't open '$isis_db'\n";
		next ;
	}

	my $max_rowid = OpenIsis::maxRowid( $db );

	print STDERR "Reading database: $isis_db [$max_rowid rows]\n";

	my $path = $database;			# was $isis_db

	my $last_p = 0;

#	{ my $row_id = 4514;
# FIX
	for (my $row_id = 1; $row_id <= $max_rowid; $row_id++ ) {
		my $row = OpenIsis::read( $db, $row_id );
		if ($row && $row->{mfn}) {
			# output current process indicator
			my $p = int($row->{mfn} * 100 / $max_rowid);
			if ($p != $last_p) {
				printf STDERR ("%5d / %5d [%-51s] %-2d %% \r",$row->{mfn},$max_rowid,"=" x ($p/2).">", $p ) if (! $opts{q});
				$last_p = $p;
			}

			my $swishpath = $path."#".int($row->{mfn});

			if (my $xml = $cp2utf->convert(isis2xml($row,$add_xml."<path>$swishpath</path>"))) {
				use bytes;	# as opposed to chars
				print "Path-Name: $swishpath\n";
				print "Content-Length: ".(length($xml)+1)."\n";
				print "Document-Type: XML\n\n$xml\n";
			}
		}
	}
	print STDERR "\n";
}

# call this to commit index
$index->close;

1;
__END__
##########################################################################

=head1 NAME

isis2xml.pl - read isis file and dump XML

=head1 DESCRIPTION

This command will read ISIS data file using OpenIsis perl module and
create XML file for usage with I<SWISH-E>
indexer. Dispite it's name, this script B<isn't general xml generator>
from isis files (isis allready has something like that). Output of this
script is tailor-made for SWISH-E.

=head1 AUTHOR

Dobrica Pavlinusic <dpavlin@rot13.org>

=head1 COPYRIGHT

GNU Public License (GPL) v2 or later

=head1 SEE ALSO

SWISH-E web site at http://www.swish-e.org

=cut
