#!/usr/local/bin/perl

use strict;
#use lib "__INSTALLDIR__/lib";
# FIXME
use lib "/data/backuppc/lib";

use DBI;
use BackupPC::Lib;
use BackupPC::SearchLib;
use Time::HiRes qw/time/;
use POSIX qw/strftime/;
use Term::Menus;

use Data::Dumper;

my $debug = 0;
$|=1;

my $start_t = time();

my $t_fmt = '%Y-%m-%d %H:%M:%S';

# don't check for user
my $bpc = BackupPC::Lib->new(undef, undef, 1) || die;
my %Conf = $bpc->Conf();
%BackupPC::SearchLib::Conf = %Conf;

my $dsn = $Conf{SearchDSN} || die "Need SearchDSN in config.pl\n";
my $user = $Conf{SearchUser} || '';

my $dbh = DBI->connect($dsn, $user, "", { RaiseError => 1, AutoCommit => 1 });

my $tar_dir = $Conf{InstallDir}.'/';
$tar_dir .= $Conf{GzipTempDir} || die "GzipTempDir isn't defined in configuration";

die "problem with $tar_dir, check GzipTempDir in configuration\n" unless (-d $tar_dir && -w $tar_dir);

my $iso_dir = $Conf{InstallDir}.'/';
$iso_dir .= $Conf{ISOTempDir} || die "ISOTempDir isn't defined in configuration";
die "problem with $iso_dir, check ISOTempDir in configuration\n" unless (-d $iso_dir && -w $iso_dir);

#---- subs ----

sub fmt_time {
	my $t = shift || return;
	my $out = "";
	my ($ss,$mm,$hh) = gmtime($t);
	$out .= "${hh}h" if ($hh);
	$out .= sprintf("%02d:%02d", $mm,$ss);
	return $out;
}

sub curr_time {
	return strftime($t_fmt,localtime());
}

#----- main

my $sth = $dbh->prepare( qq{
select
	id,dvd_nr,total_size,note,username,
	archive.date as date,
	count(archive_burned.archive_id) as copies
from archive
	left outer join archive_burned on archive.id=archive_burned.archive_id
group by id,dvd_nr,total_size,note,username,archive.date
order by date asc
} );

$sth->execute();

sub fmt_archive($) {
	my $row = shift || die;

	$row->{'date'} =~ s/\.\d+$//;
	$row->{'copies'} =~ s/^\s*0+\s*$/no/;
	$row->{'total_size'} /= (1024*1024);

	my $copies = 'copies';
	$copies = 'copy' if ($row->{'copies'} == 1);

	return
		sprintf("%d by %s on %s, %s %s [%.2f Mb]",
			$row->{'dvd_nr'},
			$row->{'username'},
			$row->{'date'},
			$row->{'copies'}, $copies,
			$row->{'total_size'},
		);
}

my @burned;
my @not_burned;

while (my $row = $sth->fetchrow_hashref) {
	if ($row->{'copies'}) {
		push @burned, fmt_archive($row);
	} else {
		push @not_burned, fmt_archive($row);
	}
}

my %Menu_archive = (
	Label => 'Menu_archive',

	Item_1 => {
		Text => 'DVD #]Convey[',
		Convey => [ @not_burned ],
		Default => '*',
	},
	Item_2 => {
		Text => 'DVD #]Convey[',
		Convey => [ @burned ],
	},

	Select => 'Many',

	Banner => "Select one or more DVD media for burning",
);

my @archives_to_burn = Menu(\%Menu_archive);

print "\n";

sub skip($) {
	my $msg = shift;
	print "WARNING: $msg, skipping...\n";
	goto SKIP;
}

my $sth_archive_backup = $dbh->prepare( qq{
	select
		backup_id,
		hosts.name as host,
		shares.name as share,
		backups.num as num
	from archive_backup
	join archive on archive_id = archive.id
	join backups on backup_id = backups.id
	join hosts on hostid = hosts.id
	join shares on shareid = shares.id
	where archive.dvd_nr = ?
});

foreach my $arc (@archives_to_burn) {
	exit if ($arc eq ']quit[');

	my $dvd_nr = $1 if ($arc =~ m/DVD #(\d+)/);
	die "BUG: can't find dvd_nr in $arc\n" unless ($dvd_nr);

	my $tmp_dir = "/$iso_dir/$dvd_nr";

	my $t = time();

	print "Working on DVD #$dvd_nr in $tmp_dir\n";

	my $iso_file = "${iso_dir}/${dvd_nr}.iso";

	skip "ISO $iso_file allready exists" if (-e $iso_file);

	$sth_archive_backup->execute($dvd_nr);

	print "Running mkisofs now...\n";

	my $cmd = qq{ mkisofs -A BackupPC -gui -J -r -T --input-charset ISO-8859-2 -V $dvd_nr -o $iso_file -path-list - };

	open(my $mkisofs, "| $cmd 2>&1") || skip "can't run $cmd: $!";

	while (my $row = $sth_archive_backup->fetchrow_hashref) {
		my $tar_file = BackupPC::SearchLib::getGzipName($row->{'host'}, $row->{'share'}, $row->{'num'});
		skip "can't find increment $tar_file: $!" unless (-r "$tar_dir/$tar_file");
		print $mkisofs "$tar_dir/$tar_file\n";
	}

	while(! -e $iso_file) {
		sleep 1;
	}

	print "Created $iso_file in ", fmt_time(time() - $t), "\n";

SKIP:

}

#my $tar_file = BackupPC::SearchLib::getGzipName($row->{'host'}, $row->{'share'}, $row->{'num'});
#print curr_time, sprintf(" %s:%s %-3d ", $row->{'host'}, $row->{'share'}, $row->{'num'}), " -> $tar_file ";

$sth->finish;
$dbh->disconnect;