#!/usr/bin/perl

use warnings;
use strict;

# Advanced search syntax:
# http://images.isiknowledge.com/WOK46/help/WOS/h_advanced_examples.html

our $q = 'AD=Croatia';
my $range_size = 500;
my $overlap    = 3; # between previous and this range
my $skip_results = 1;
my $cites_by_year = 1;

my $max_cites = 5000; # ISI limit to get cites

if ( 0 ) {
	$q = 'TS=psychology AND AD=Croatia';
	$range_size = 50;
	$overlap    = 0;
	$max_cites  = 50;
}

use WWW::Mechanize;
use Data::Dump qw(dump);
use File::Path;

our $mech = WWW::Mechanize->new(
	autocheck => 1,
	cookie_jar => undef,
);

our $step = 0;
our @ranges;

my $dir = '/tmp/isi/';
rmtree $dir if -e $dir;
mkdir $dir;

sub save_mech {
	my $path = shift;
	$step++;
	my $base_path = sprintf('%s/%04d', $dir,$step);
	$path ||= $base_path;
	$path .= $mech->{ct} =~ m{html}i ? '.html' : '.txt';
	$mech->save_content( $path );
	warn "# [$step] $path ", -s $path, " ", $mech->ct, "\n";
	open(my $dump, '>', "$base_path.dump.txt");
	$mech->dump_all($dump);
}

warn "# get session";
$mech->get( 'http://isiknowledge.com/?DestApp=WOS' );
save_mech;

sub search {
	warn "# advanced serach";
	$mech->follow_link( url_regex => qr/AdvancedSearch/ );
	save_mech;

	warn "# cookie_jar ", dump $mech->cookie_jar;

	my $q_this = $q;

	if ( @ranges ) {
		$q_this .= ' AND (' . join(' OR ', map { "PY=$_" } @{ shift @ranges } ) . ')';
	}

	warn "# submit_form search: $q_this\n";
	$mech->submit_form(
		fields => {
			'value(input1)' => $q_this,
		},
	);
	save_mech;

	warn "# summary";
	$mech->follow_link( url_regex => qr/summary/ );
	save_mech;
}

sub get_results {
	my $desc = shift;
	my $from = 1;

	while ( 1 ) {

		my $to = $from + $range_size;

		warn "# submit_form results $from - $to\n";

		$mech->submit_form(
			form_name => 'summary_output_form',
			fields => {
				record_select_type => 'range',
				mark_from => $from,
				mark_to => $to,
				mark_id => 'WOS',

				qo_fields => 'fullrecord',
				citedref => 'citedref',

				save_options => 'plain_text',

				fields => 'Full',
				format => 'save',
			},
			button => 'save',
		);
		save_mech;


		if ( $mech->content =~ m{invalid API call} ) {
			$mech->back;
			last;
		}


		my $path = "/tmp/isi.$q.$from-$to";
		$path .= '.' . $desc if $desc;

		warn "save $from - $to into $path\n";
		$mech->follow_link( url_regex => qr/save_file/ );
		save_mech $path;

		$from += $range_size - $overlap;

		$mech->back;
		$mech->back;
		#save_mech;
	}
}


sub citations {
	warn "# citation report";
	$mech->follow_link( url_regex => qr/search_mode=CitationReport/ );
	save_mech;

	warn "view citing articles";
	$mech->follow_link( url_regex => qr/search_mode=TotalCitingArticles/ );
	save_mech;
}

sub years {
	my $years_url = $mech->find_link( url_regex => qr/ra_name=/ );
	if ( ! $years_url ) {
		warn "W: can't find ra_name link\n";
		return;
	}
	$years_url = $years_url->url_abs;
	warn "## $years_url";
	if ( $years_url !~ s{ra_name=\w+}{ra_name=PublicationYear} ) {
		warn "W: no ra_name in $years_url\n";
		return;
	}
	warn "# refine years (hidden by javascript)";
#	warn "http://apps.isiknowledge.com/RAMore.do?product=WOS&search_mode=TotalCitingArticles&SID=T1o6bChdN9PGP1LN1Nh&qid=3&ra_mode=more&ra_name=PublicationYear&db_id=WOS&viewType=raMore\n$years_url\n";
	$mech->get( $years_url );
	save_mech;

	my $html = $mech->content;
	my $years;
	while ( $html =~ s{<label.+?PublicationYear.+?>(\d{4})\s\(([\d,]+)\)</label>}{} ) {
		my ( $year, $count ) = ( $1, $2 );
		$count =~ s{,}{}g;
		$years->{$year} = $count;
	}
	warn "# years ",dump $years;
	$mech->back;

	my @y = sort keys %$years;

	@ranges = ();

	if ( $cites_by_year ) {
		push @ranges, [ $_ ] foreach @y;
		warn "# cites_by_year ranges ", dump @ranges;
		return;
	}

	my $y = shift @y;
	my $size = $years->{$y};

	my $cites_range;
	$cites_range = [$y] if $y;

	foreach my $y ( @y ) {
		if ( $size + $years->{$y} > $max_cites ) {
			push @ranges, $cites_range;
			warn "# cites_range $size years ",dump( $cites_range ),$/;

			$cites_range = [];
			$size = 0;
		}
		$size += $years->{$y};
		push @$cites_range, $y;
	}

	if ( $cites_range ) {
		push @ranges, $cites_range;
		warn "# cites_range $size years ",dump( $cites_range ), " FINAL\n"
	}

	warn '# ranges ', dump @ranges;
	@ranges = () if $#ranges == 1; # just take all

	return $years;
}

search;
years;
get_results unless $skip_results;


citations;

do {
	my $part;
	if ( @ranges ) {
		$part .= $ranges[0]->[0] . '.';
		search;
		citations;
	}
	$part .= 'citing';
	get_results $part;
} while ( @ranges );

