package client;

use warnings;
use strict;
use autodie;

use server;
use File::Slurp;
use Net::Ping;
use format;

sub mac_path { $server::conf . '/mac/' . $_[0] }
sub  ip_path { $server::conf . '/ip/'  . join('/', @_) }

sub conf {
	my $ip  = shift;
	my $name = shift;
	my ( $default, $value );
	if ( $#_ == 0 ) {
		$value = shift;
	} elsif ( $#_ == 1 && $_[0] eq 'default' ) {
		$default = $_[1]
	}

	my $path = ip_path $ip;
	mkdir $path unless -d $path;
	$path .= '/' . $name;

	if ( defined $value ) {
		write_file $path, $value;
		warn "update $path = $value";
	} elsif ( ! -e $path && defined $default ) {
		write_file $path, $default;
		warn "default $path = $default";
		$value = $default;
	} elsif ( -e $path ) {
		if ( -l $path ) {
			$value = readlink $path;
			$value =~ s{.*/([^/]+)$}{$1};
		} else {
			$value = read_file $path;
		}
	}
	return $value;
}

sub mac {
	my $ip = shift;
	my $mac = client::conf( $ip, 'mac' ) || return '';
	format::mac( $ip, @_ );
}

sub next_ip($) {
	my $mac = shift;

	my $p = Net::Ping->new;

	my $prefix = $server::ip;
	$prefix =~ s{\.\d+$}{.};
	my $addr = $server::ip_from || die;
	my $ip = $prefix . $addr;

	while ( -e ip_path($ip) || $p->ping( $ip, 0.7 ) ) {
		$ip = $prefix . $addr++;
		die "all addresses allocated!" if $addr == $server::ip_to;
		warn "skip $ip\n";
	}

	warn "next_ip $ip\n";

	mkdir ip_path($ip);

	symlink ip_path($ip), mac_path($mac);
	write_file ip_path($ip,'mac'), $mac;

	return $ip;

}

sub ip_from_mac($) {
	my $mac = shift;

	$mac = lc $mac;
	$mac =~ s{:}{}g;

	my $mac_path = mac_path $mac;
	return unless -e $mac_path;

	my $ip;

	if ( -f $mac_path ) {
		$ip = read_file $mac_path;
		unlink $mac_path;
		symlink ip_path($ip), $mac_path;
		warn "I: upgrade to mac symlink $mac_path\n";
	} elsif ( -l $mac_path ) {
		$ip = readlink $mac_path;
		$ip =~ s{^.+/([^/]+)$}{$1};
	} else {
		die "$mac_path not file or symlink";
	}

	return $ip;
}

sub mac_from_ip($) {
	my $ip = shift;
	return read_file ip_path($ip, 'mac');
}

sub change_ip($$) {
	my ($old, $new) = @_;
	my $mac = mac_from_ip($old);
	rename ip_path($old), ip_path($new);
	unlink mac_path($mac);
	symlink ip_path($new), mac_path($mac);
}

1;
