package client;

use warnings;
use strict;
use autodie;

use File::Slurp;
use Data::Dump qw/dump/;
use File::Path;

use server;
use format;
use ip;
use ping;
use kvm;

our $debug = $server::debug;

sub mkbasedir {
	my $path = shift;
	$path =~ s{(^.*)/[^/]+$}{$1};
	mkdir $path unless -d $path;
	return $path;
}

sub mac_path { $server::conf . '/mac/' . $_[0] }
sub  ip_path { $server::conf . '/ip/'  . join('/', @_) }
sub conf_value {
	my $path = shift;
	my $value;
	if ( -l $path ) {
		$value = readlink $path;
		$value =~ s{.*/([^/]+)$}{$1};
	} elsif ( -f $path ) {
		$value = read_file $path;
	} else {
		warn "W: $path not file or symlink\n";
	}
	return $value;
}

sub conf {
	my $ip  = shift;
	my $name = shift;
	my ( $default, $value );
	if ( $#_ == 0 ) {
		$value = shift;
	} elsif ( $#_ == 1 && $_[0] eq 'default' ) {
		$default = $_[1]
	}

	my $path = ip_path $ip;
	mkdir $path unless -d $path;
	$path .= '/' . $name;

	if ( defined $value ) {
		mkbasedir  $path;
		write_file $path, $value;
		warn "update $path = $value";
	} elsif ( ! -e $path && defined $default ) {
		mkbasedir  $path;
		write_file $path, $default;
		warn "default $path = $default";
		$value = $default;
	} elsif ( -f $path ) {
		$value = read_file $path;
		chomp $value;
	} else {
		warn "# $name missing $path\n" if $debug;
	}
	return $value;
}

sub all_conf {
	my $ip = shift;
	my $path = ip_path $ip || return;
	my $conf;
	foreach my $file ( glob("$path/*"), glob("$path/*/*") ) {
		my $name = $file;
		$name =~ s{^$path/+}{} || die "can't remove $path from $name";
		$conf->{ $name } = read_file $file if -f $file;
	}
	return $conf;
}
sub next_ip($) {
	my $mac = shift;
	$mac = format::mac($mac);

	if ( $server::new_clients > 0 ) {
		warn "# clients left: ", --$server::new_clients;
	} else {
		warn "W: no new clients accepted";
		return '0.0.0.0';
	}

	my $prefix = $server::ip;
	$prefix =~ s{\.\d+$}{.};
	my $addr = $server::ip_from || die;
	my $ip = $prefix . $addr;

	while ( -e ip_path($ip) || ping::host($ip) ) {
		$ip = $prefix . $addr++;
		die "all addresses allocated!" if $addr == $server::ip_to;
		warn "skip $ip\n";
	}

	warn "next_ip $ip\n";

	save_ip_mac( $ip, $mac );

	return $ip;
}

sub save_ip_mac {
	my ($ip,$mac) = @_;
	$mac = format::mac($mac);
	return if $mac eq '00:00:00:00:00:00' || $ip eq '0.0.0.0';

	mkdir ip_path($ip) unless -e ip_path($ip);

	my $mac_path = mac_path($mac);
	unlink $mac_path if -l $mac_path;	# XXX audit?
	symlink ip_path($ip), $mac_path;
	write_file( ip_path($ip,'mac'), $mac );
}

sub ip_from_mac($) {
	my $mac = shift;
	$mac = format::mac($mac);

	my $mac_path = mac_path $mac;
	return unless -e $mac_path;

	my $ip;

	if ( -f $mac_path ) {
		$ip = read_file $mac_path;
		unlink $mac_path;
		symlink ip_path($ip), $mac_path;
		warn "I: upgrade to mac symlink $mac_path\n";
	} elsif ( -l $mac_path ) {
		$ip = conf_value $mac_path;
	} else {
		die "$mac_path not file or symlink";
	}

	return $ip;
}

sub mac_from_ip($) {
	my $ip = shift;
	conf_value ip_path($ip, 'mac');
}

sub change_ip($$) {
	my ($old, $new) = @_;
	return if $old eq $new;
	my $mac = mac_from_ip($old) || die "no mac for $old";
	rename ip_path($old), ip_path($new);
	unlink mac_path($mac);
	symlink ip_path($new), mac_path($mac);
	return $new;
}

sub all_ips {
	sort { ip::to_int($a) cmp ip::to_int($b) }
	map {
		my $ip = $_;
		$ip =~ s{^.+/ip/}{};
		autocreate_params( $ip );
		$ip;
	} glob("$server::conf/ip/*") 
}

sub remove {
	my $ip = shift;
	if ( my $mac = mac_from_ip $ip ) {
		unlink "$server::conf/mac/$mac";
	}
	rmtree "$server::conf/ip/$ip";
}

sub arp_mac_dev {
	my $arp = {
		map {
			my @c = split(/\s+/,$_);
			if ( $#c == 5 ) {
				client::save_ip_mac( $c[0], $c[3] );
				( uc $c[3] => $c[5] )
			} else {
			}
		} read_file('/proc/net/arp')
	};

	warn "# arp ",dump( $arp );
	return $arp;
}

sub rebuild_mac_links {
	warn "# rebuild mac links";
	foreach my $ip ( all_ips ) {
		my $mac = ip_path $ip, 'mac';
		if ( -e $mac ) {
			$mac = read_file $mac;
			chomp $mac;
			save_ip_mac( $ip, $mac );
			warn "## $ip $mac\n";
		}
	}
}

sub autocreate_params {
	my $ip = shift;
	my $mac = mac_from_ip $ip;
	if ( $mac =~ m{^AC:DE:48:00:00} && ! defined conf( $ip, 'kvm' ) ) {
		conf( $ip, 'kvm', default => kvm::nr_from_mac( $mac ) );
		warn "# create kvm for $ip";
	}
}

1;
