package httpd;

use warnings;
use strict;
use autodie;

=head1 httpd

Start with:

  perl -Ilib/PXElator -Mhttpd -e httpd::start

=cut

use Data::Dump qw/dump/;
use Carp qw/confess/;
use File::Slurp;
#use JSON;
use IO::Socket::INET;
use Regexp::Common qw/net/;

sub menu {qq{

<div style="font-size: 80%; color: #888">
<a href=/>home</a>
<a href=/server>server</a>
<a href=/brctl>brctl</a>
<a href=/ip>ip</a>
<a href=/nmap>nmap</a>
<a href=/client>client</a>
</div>

}}

our $port = 7777;

use server;
our $debug = server::debug;
our $url = "http://$server::ip:$port";

use html;
our $static_pids;
use progress_bar;
use config;
use client;
use log;
use x11;
use amt;
use boolean;
use daemons;

use kvm;
use browser;
use network;
use ip;
use wireshark;
use syslogd;
use nmap;
use ping;
use wol;

use CouchDB;

sub static {
	my ($client,$path) = @_;

	my $full = "$server::base_dir/tftp/$path";

	return if ! -f $full;

	if ( my $pid = fork ) {
		# parent
		close($client);
		$static_pids->{$pid} = $path;
		return 1;
	}

	my $type = 'application/octet-stream';
	$type = 'text/html' if $path =~ m{\.htm};
	$type = 'application/javascript' if $path =~ m{\.js};
	$type = 'text/plain' if $path =~ m{\.txt};

	my $size = -s $full || return;

	print $client "HTTP/1.0 200 OK\r\nContent-Type: $type\r\nContent-Length: $size\r\nConnection: close\r\n\r\n";

	open(my $fh, $full);

	my $block = 1400; # try not to fragment packages (pxelinux seems to have problems with it)
	my $buff;
	my $pos = 0;

	CouchDB::audit( 'static', { pid => $$, path => $path, type => $type, size => $size, block => $block, peerhost => $client->peerhost });

	progress_bar::start;

	while( my $len = read $fh, $buff, $block ) {
		print $client $buff;
		$client->flush;
		$pos += $len;
		progress_bar::tick( $path, $pos, $size );
	}
	close($fh);
	close($client);

	print STDERR "\n";

	exit(0);
}

sub ok {
	qq|HTTP/1.0 200 OK\r\nContent-Type: text/html\r\nConnection: close\r\n\r\n| . menu()
}

sub redirect {
	my $to = shift;
	$to ||= $url;
	qq|HTTP/1.1 302 Found\r\nContent-type: text/html\r\nLocation: $to\r\n\r\n|
}

sub get_request {
	my ( $client, $path, $param ) = @_;

	server->refresh;

	CouchDB::audit( 'request', { path => $path, param => $param, peerhost => $client->peerhost } );

	if ( my $found = static( $client,$path ) ) {
		warn "static $found" if $debug;
	} elsif ( $path eq '/' ) {

		my @rows;

		my $debug_proc = '';

warn "XXX pids = ", dump( $daemons::pids );

		foreach my $name ( sort keys %$daemons::pids ) {
			my $pid = $daemons::pids->{$name}; # || next;

			my $html;

			my $proc = "/proc/$pid/status";

			if ( -e $proc ) {
				$html .= qq|<a href=/start_stop/$name>$pid</a>|;
				if ( $debug ) {
					$html .= qq| <a name=$pid href=#proc-$pid>?</a>| if $name->can('start');

					$debug_proc
						.= qq|<a name=proc-$pid href=#$pid>$proc</a><pre style="font-size: 10%">|
						.  read_file($proc)
						.  qq|</pre>|
						;
				}

				if ( $name->can('fork_if_active') ) {
					$html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $name->fork_if_active;
				}

				if ( $name->can('actions') ) {
					$html .= qq| <a href=/action/$name/$_>$_</a>| foreach $name->actions;
				}
			} else {
				if ( $pid =~ m{^\d+$} ) {
					$html .= qq|$pid exited |
				} else {
					$html .= qq|$pid |;
				}
				$html .= qq|<a href=/start_stop/$name>restart</a>| if $pid || $name->can('start');
				if ( $name->can('fork_actions') ) {
					$html .= qq| <a href=/start_stop/$name/$_>$_</a>| foreach $name->fork_actions;
				}
			}

			die "no html generated" unless $html;

			push @rows, ( $name => $html );
		}

		my $below_table = '';

		warn 'static_pids: ', dump( $static_pids ) if $debug;
		foreach my $pid ( keys %$static_pids ) {
			my $path = $static_pids->{$pid};
			if ( -d "/proc/$pid" ) {
				push @rows, ( $path => qq|<a href=/kill/static/$pid>$pid</a>| );
			} elsif ( $param->{clean_completed_downloads} ) {
				delete $static_pids->{$pid}
			} else {
				push @rows, ( $path => "$pid competed" );
				$below_table = qq|<a href="/?clean_completed_downloads=1">clean completed downloads</a>|;
			}
		}

		print $client ok
			, html::table( 2, @rows )
			, $below_table
			, html::tabs( log::mac_changes )
			, $debug_proc
			;

	} elsif ( $path =~ m{^/server} ) {
		print $client ok
			, html::table( 2,
				'debug' => qq|<a href=/our/debug/| . boolean::toggle($debug) . qq|>$debug</a>|,
				 map {
					( $_, html::tt eval '$server::'.$_ )
				 } ( 'ip', 'netmask', 'ip_from', 'ip_to', 'domain_name', 'base_dir', 'conf' )
			)
			;
	} elsif ( $path =~ m!^/client(?:/$RE{net}{IPv4}{-keep})?! ) {
		my $ip = $1;

		if ( $param->{action} eq 'remove' ) {
			client::remove( $param->{change_ip} );
			print $client redirect("$url/client");
			return;
		} elsif ( $param->{action} eq 'change' ) {
			if ( my $new_ip = client::change_ip( $ip, $param->{change_ip} ) ) {
				print $client redirect("$url/client#$new_ip");
				return;
			}
		}

 		if ( ! $ip ) {
			my $peer_ip = $client->peerhost;

			my $netmask  = ip::to_int $server::netmask;
			my $network  = ip::to_int($server::ip) & $netmask;
			my $from_int = $network | $server::ip_from;
			my $to_int   = $network | $server::ip_to;
			my $ip_int   = ip::to_int $peer_ip;

			# show edit for clients in our dhcp range
 			if ( $ip_int >= $from_int && $ip_int <= $to_int ) {
				$ip = $peer_ip;
			}
		}

		if ( $ip && $ip ne $server::ip ) {
			my $hostname = client::conf( $ip, 'hostname' => $param->{hostname} );

			my $nmap = qq|<a href=/nmap?scan=$ip>nmap</a>|;

			my @table = (
				'ip' => qq|<input type=text name=change_ip value="$ip" onChange="document.getElementById('old_ip').style.display = '';"><span id=old_ip style="display: none; color: #888;">old: $ip<span>|,
				'hostname' => qq|<input type=text name=hostname value="$hostname">|,
				'ping' => ping::host($ip) ? qq|<span style="color:green">up</span> $nmap| : qq|<a href=/wol/$ip title=wol>down</a> $nmap|,
			);

			my $config;

			if ( my $mac = client::mac_from_ip( $ip ) ) {
				my $deploy = client::conf( $ip, 'deploy' => $param->{deploy} );
				push @table, (
					'mac' => format::mac( $mac => 'html' ),
					'deploy' => html::select( 'deploy', $deploy, config::available )
				);
				if ( $config = config::for_ip( $ip ) ) {
					$config = qq|<h2>config</h2>| . html::pre( $config );
				}
			}

			print $client ok
				, qq|<form method=get>|
				, html::table( 2, @table ),
				, qq|
					<input type=submit name=action value=change>
					<input type=submit name=action value=remove style="color: red">
					</form>|
				, $config
				;

			if ( my $amt = client::conf( $ip, 'amt' ) ) {
				print $client qq|<h2>AMT</h2>|, amt::info( $amt, $ip );
			}

		} else {

			my @ping;
			if ( my $host = $param->{ping_target} ) {
				@ping = ( $host );
			} elsif ( $param->{ping} ) {
				@ping = client::all_ips;
			}

			my $ping = ping::fping( @ping ) if @ping;
			my $arp = client::arp_mac_dev;

			print $client ok
				, qq|<h2>Clients on $server::ip</h2>|
				, html::table( -5,
					'ip', 'mac', 'dev', 'hostname', 'conf',
					map {
						my $ip = $_;
						my $conf = client::all_conf( $ip );
						my $mac = delete $conf->{mac} || '';
						my $style;
						$style
							= 'style="color:'
							. ( $ping->{$ip} ? 'green' : 'red' )
							. '"'
							if $ping;
						$style ||= '';
						(
							qq|<a $style name=$ip href=/client/$ip>$ip</a>|
							, format::mac( $mac => 'html' )
							, $arp->{$mac}
							, delete $conf->{hostname}
							, join("\n", map {
								my $name = $_;
								my $html = $conf->{$name};
								if ( $name eq 'amt' ) {
									$html = qq|<a title="$html" href=http://$ip:16992/logon.htm>logon</a>|;
								}
								$html = qq|<pre style="display: inline">$html</pre>|
								unless
#0 &&
								$html =~ s{\b(\S+)\t(\S+)\t(\S+)\b}{<b title="$1/$2">$3</b> }gs;
								qq|<em>$name</em> $html<br>|
							} keys %$conf )
						);
					} client::all_ips
				)
				;
			print $client qq|
				<form method=get>
				<input type=text   name=ping_target   size=15>
				<input type=submit name=ping value=ping>
				</form>
			|;
		}
	} elsif ( $path =~ m{^/brctl} ) {
		print $client ok, html::table( -4,
			map {
				my @c = split(/\t+/,$_,4);
				if ( $#c == 1 ) {
					( '', '', '', $c[1] )
				} else {
					@c
				}
			} split(/\n/, `brctl show`)
		);
	} elsif ( $path =~ m{^/ip/?(\w+)?} ) {
		print $client ok
			, join("\n", map { qq|<a href=/ip/$_>$_</a>| } ( qw/link addr route neigh ntable tunnel maddr mroute xfrm/ ))
			, ip::html( $1 )
			;
	} elsif ( $path =~ m{^/nmap} ) {
		if ( my $scan = $param->{scan} ) {
			nmap::scan( $scan );
			print $client redirect("$url/client#$scan");
		} else {
			print $client ok, qq|
				<form method=get>
				<input type=text name=scan>
				<input type=submit value=scan>
				</form>
			|;
		}
	} elsif ( $path =~ m{^/wol/(\S+)} ) {
		print $client redirect( "$url/client/$1" ), wol::power_on($1);
	} elsif ( $path =~ m{^/our/(\w+)/(\S+)} ) {
		eval 'our $' . $1 . ' = ' . $2;
		warn $@ if $@;
		print $client redirect($url), qq|<big>$1 = $2</big><br>Location: <a href="$url">$url</a>|;
		server::debug( $debug ) if $1 eq 'debug';
	} elsif ( $path =~ m{^/start_stop/(\S+)} ) {
		print $client redirect, daemons::start_stop($1);
	} elsif ( $path =~ m{^/action/([^/]+)/(.+)} ) {
		$1->$2();
		print $client redirect;
	} elsif ( $path =~ m{^/kill/static/(\d+)} ) {
		print $client redirect;
		kill 1, $1 || kill 9, $2 && warn "killed $1";
	} else {
		print $client "HTTP/1.0 404 $path\r\nConnection: close\r\nContent-type: text/html\r\n\r\n<big>404 $path</big>";
		warn "404 $path";
	}

}

sub start {

	warn 'network ', network::setup();

	daemons::start_stop 'browser', $url;
	daemons::start_stop $_ foreach ( qw/dhcpd tftpd dnsd syslogd/ );
	daemons::start_stop 'kvm' unless $ENV{DEV}; # skip kvm statup when running on real device

	my $server = IO::Socket::INET->new(
			Proto     => 'tcp',
			LocalAddr => $server::ip,
			LocalPort => $httpd::port,
			Listen    => SOMAXCONN,
			Reuse     => 1
	) || die "can't start server on $url: $!";

	print "url $url\n";

	while (1) {
		my $client = $server->accept() || next; # ALARM trickle us
		my $request = <$client>;

		warn "request $request\n" if $debug;

		if ($request =~ m{^GET (/.*) HTTP/1.[01]}) {
			my $path = $1;
			$path =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/ge;
			my $param;
			if ( $path =~ s{\?(.+)}{} ) {
				foreach my $p ( split(/[&;]/, $1) ) {
					my ($n,$v) = split(/=/, $p, 2);
					$param->{$n} = $v;
				}
				warn "param: ",dump( $param ) if $debug;
			}
			get_request $client, $path, $param;
		} else {
			print $client "HTTP/1.0 500 No method\r\nConnection: close\r\nContent-type: text/plain\r\n\r\n500 $request";
			warn "500 $request";
		}

		print $client menu() if $client->connected;

	}

	die "server died";
}

warn "loaded";

1;
