package httpd;

use warnings;
use strict;
use autodie;

=head1 httpd

Start with:

  perl -Ilib/PXElator -Mhttpd -e httpd::start

=cut

use Data::Dump qw/dump/;
use Carp qw/confess/;
use File::Slurp;
#use JSON;
use IO::Socket::INET;
use Regexp::Common qw/net/;

sub menu {qq{

<div style="font-size: 80%; color: #888">
<a href=/>home</a>
<a href=/server>server</a>
<a href=/client>client</a>
</div>

}}

our $pids;
$pids = { httpd => $$ } unless defined $pids; # keep pids on refresh

sub DESTROY {
	warn "pids ",dump( $pids );
	foreach ( values %$pids ) {
		warn "kill $_";
		kill 1,$_ || kill 9, $_;
	}
}

our $port = 7777;

use server;
our $debug = server::debug;
our $url = "http://$server::ip:$port";

use html;
our $static_pids;
use progress_bar;
use config;
use client;
use log;

sub static {
	my ($client,$path) = @_;

	my $full = "$server::base_dir/tftp/$path";

	return if ! -f $full;

	if ( my $pid = fork ) {
		# parent
		close($client);
		print "http static child $pid\n";
		$static_pids->{$pid} = $path;
		return 1;
	}

	my $type = 'application/octet-stream';
	$type = 'text/html' if $path =~ m{\.htm};
	$type = 'application/javascript' if $path =~ m{\.js};
	$type = 'text/plain' if $path =~ m{\.txt};

	my $size = -s $full || return;

	print $client "HTTP/1.0 200 OK\r\nContent-Type: $type\r\nContent-Length: $size\r\nConnection: close\r\n\r\n";

	open(my $fh, $full);

	my $block = 1400; # try not to fragment packages (pxelinux seems to have problems with it)
	my $buff;
	my $pos = 0;

	warn "static $path $type $size block: $block\n";

	progress_bar::start;

	while( my $len = read $fh, $buff, $block ) {
		print $client $buff;
		$client->flush;
		$pos += $len;
		progress_bar::tick( $path, $pos, $size );
	}
	close($fh);
	close($client);

	print STDERR "\n";

	warn "exit static child";

	exit(0);
}

use boolean;

use kvm;
use qemu; $pids->{qemu} = 'stopped';

$SIG{CHLD} = 'IGNORE';

sub start_stop {
	my $daemon = shift;
	my $pid = $pids->{$daemon} || 'not started';

	warn "start_stop $daemon $pid\n";

	if ( $pid =~ m{^\d+$} ) {
		my $pstree = `pstree -p $pid`;
		my @pids = $pstree =~ m{\((\d+)\)}g;
		warn "pstree $pstree pids ",dump( @pids );
		kill 1, $_ foreach reverse @pids;
		$pids->{$daemon} = 'stopped';
		return qq|$daemon pid $pid stopped|;
	} else {
		if ( $pid = fork ) {
			# parent
			$pids->{$daemon} = $pid;
			warn "forked $daemon $pid\n";
			return qq|$daemon pid $pid started|;
		} elsif ( defined $pid ) {
			# child
			my $invoke = 'start';
			$invoke = $1 if $daemon =~ s{/(.+)}{};
			if ( $daemon =~ m{dhcpd|tftpd|dnsd} ) {
				my $exec = "perl -I$server::base_dir/lib -I$server::base_dir/lib/PXElator -M$daemon -e ${daemon}::${invoke}";
				warn "exec $exec";
				exec "xterm -T $daemon -n $daemon -e $exec";
			} else {
				my $eval = $daemon . '::' . $invoke . '(' . ( @_ ? dump(@_) : '' ) . ')';
				warn "eval $eval";
				eval $eval;
				warn "can't start $daemon: $@" if $@;
			}
			exit;
		} else {
			die "fork error $!";
		}
	}
}

my $ok =       qq|HTTP/1.0 200 OK\r\nContent-Type: text/html\r\nConnection: close\r\n\r\n| . menu();
my $redirect = qq|HTTP/1.1 302 Found\r\nContent-type: text/html\r\nLocation: $url\r\n\r\n|;

sub get_request {
	my ( $client, $path, $param ) = @_;

	server->refresh;

	warn "get_request $path ", $param ? dump( $param ) : '', "\n";

	if ( my $found = static( $client,$path ) ) {
		warn "static $found" if $debug;
	} elsif ( $path eq '/' ) {

		my @rows = (
			'debug',	qq|<a href=/our/debug/| . boolean::toggle($debug) . qq|>$debug</a>|,
		);

		my $debug_proc = '';

		warn 'pids: ', dump( $pids ) if $debug;
		foreach my $name ( sort keys %$pids ) {
			my $pid = $pids->{$name} || next;

			my $html = qq|<a href=/start_stop/$name>$pid</a>|;

			my $proc = "/proc/$pid/status";

			if ( -e $proc ) {
				if ( $debug ) {
					$html .= qq| <a name=$pid href=#proc-$pid>?</a>|;

					$debug_proc
						.= qq|<a name=proc-$pid href=#$pid>$proc</a><pre style="font-size: 10%">|
						.  read_file($proc)
						.  qq|</pre>|
						;
				}

				if ( $name->can('start_fork') ) {
					$html .= qq| <a href=/start_stop/kvm/$_>$_</a>| foreach $name->start_fork;
				}

				if ( $name->can('actions') ) {
					$html .= qq| <a href=/action/kvm/$_>$_</a>| foreach $name->actions;
				}
			}

			push @rows, ( $name => $html );
		}

		my $below_table = '';

		warn 'static_pids: ', dump( $static_pids ) if $debug;
		foreach my $pid ( keys %$static_pids ) {
			my $path = $static_pids->{$pid};
			if ( -d "/proc/$pid" ) {
				push @rows, ( $path => qq|<a href=/kill/static/$pid>$pid</a>| );
			} elsif ( $param->{clean_completed_downloads} ) {
				delete $static_pids->{$pid}
			} else {
				push @rows, ( $path => "$pid competed" );
				$below_table = qq|<a href="/?clean_completed_downloads=1">clean completed downloads</a>|;
			}
		}

		print $client $ok
			, html::table( 2, @rows )
			, $below_table
			, html::tabs( log::mac_changes )
			, $debug_proc
			;

	} elsif ( $path =~ m{^/server} ) {
		print $client $ok
			, html::table( 2, map { ( $_, eval '$server::'.$_ ) } ( 'ip', 'netmask', 'ip_from', 'ip_to', 'domain_name', 'base_dir' ) )
			;
	} elsif ( $path =~ m!^/client(?:/$RE{net}{IPv4}{-keep})?! ) {
		my $ip = $1 || $client->peerhost;
		if ( $ip ne $server::ip ) {
			my $hostname = client::conf( $ip, 'hostname' => $param->{hostname} );
			my $deploy   = client::conf( $ip, 'deploy'   => $param->{deploy}   );
			print $client $ok
				, qq|<form method=get>|
				, html::table( 2,
					'ip' => $ip,
					'mac' => client::mac( $ip ),
					'hostname' => qq|<input type=text name=hostname value=$hostname>|,
					'deploy' => html::select( 'deploy', $deploy, config::available ),
				)
				, qq|<input type=submit value=change></form>|
				, qq|<h2>PXElinux $deploy</h2><pre>|
				, config::for_ip( $ip )
				, qq|</pre>|
				;
		} else {
			print $client $ok
				, qq|<h2>Clients on $server::ip</h2>|
				, qq|<ul>|
				, join("\n",
					map {
						my $ip = $_;
						$ip =~ s{^.+/ip/}{};
						qq|<li><a href=/client/$ip>$ip</a> |, client::mac($ip), ' ', client::conf( $ip, 'hostname' ), qq|</li>|;
					}
					glob("$server::conf/ip/*") 
				)
				, qq|</ul>|
				;
		}
	} elsif ( $path =~ m{^/our/(\w+)/(\S+)} ) {
		eval 'our $' . $1 . ' = ' . $2;
		warn $@ if $@;
		print $client $redirect, qq|<big>$1 = $2</big><br>Location: <a href="$url">$url</a>|;
		server::debug( $debug ) if $1 eq 'debug';
	} elsif ( $path =~ m{^/start_stop/(\S+)} ) {
		print $client $redirect, start_stop($1);
	} elsif ( $path =~ m{^/action/([^/]+)/(.+)} ) {
		$1->$2();
		print $client $redirect;
	} elsif ( $path =~ m{^/kill/static/(\d+)} ) {
		print $client $redirect;
		kill 1, $1 || kill 9, $2 && warn "killed $1";
	} else {
		print $client "HTTP/1.0 404 $path\r\nConnection: close\r\nContent-type: text/html\r\n\r\n<big>404 $path</big>";
		warn "404 $path";
	}

}

use browser;
use network;

sub start {

	warn 'tap ', network::tap();

	my $server = IO::Socket::INET->new(
			Proto     => 'tcp',
			LocalPort => $httpd::port,
			Listen    => SOMAXCONN,
			Reuse     => 1
	) || die "can't start server on $url: $!";

	print "url $url\n";

	start_stop 'browser', $url;
	start_stop 'dhcpd';
	start_stop 'tftpd';
	start_stop 'dnsd';
	start_stop 'kvm';

	while (1) {
		my $client = $server->accept() || next; # ALARM trickle us
		my $request = <$client>;

		warn "request $request\n" if $debug;

		if ($request =~ m{^GET (/.*) HTTP/1.[01]}) {
			my $path = $1;
			my $param;
			if ( $path =~ s{\?(.+)}{} ) {
				foreach my $p ( split(/[&;]/, $1) ) {
					my ($n,$v) = split(/=/, $p, 2);
					$param->{$n} = $v;
				}
				warn "param: ",dump( $param ) if $debug;
			}
			get_request $client, $path, $param;
		} else {
			print $client "HTTP/1.0 500 No method\r\nConnection: close\r\nContent-type: text/plain\r\n\r\n500 $request";
			warn "500 $request";
		}

		print $client menu() if $client->connected;

	}

	die "server died";
}

warn "loaded";

1;
