package WebPAC::Common;

use warnings;
use strict;

use Log::Log4perl qw/get_logger :levels/;
use Time::HiRes qw/time/;

# If ture, enable logging debug
my $log_debug = 0;

=head1 NAME

WebPAC::Common - internal methods called from other WebPAC modules

=head1 VERSION

Version 0.01

=cut

our $VERSION = '0.01';

=head1 SYNOPSYS

This module defines common functions, and is used as base for other, more
specific modules.

=head1 FUNCTIONS

=head2 progress_bar

Draw progress bar on STDERR.

 $webpac->progress_bar($current, $max);

=cut

sub progress_bar {
	my $self = shift;

	my ($curr,$max) = @_;

	my $log = $self->_get_logger();

	$log->logconfess("no current value!") if (! $curr);
	$log->logconfess("no maximum value!") if (! $max);

	if ($curr > $max) {
		$max = $curr;
		$log->debug("overflow to $curr");
	}

	$self->{'last_pcnt'} ||= 1;
	$self->{'start_t'} ||= time();

	my $p = int($curr * 100 / $max) || 1;

	# reset on re-run
	if ($p < $self->{'last_pcnt'}) {
		$self->{'last_pcnt'} = $p;
		$self->{'start_t'} = time();
	}

	if ($p != $self->{'last_pcnt'}) {

		my $t = time();
		my $rate = ($curr / ($t - $self->{'start_t'} || 1));
		my $eta = ($max-$curr) / ($rate || 1);
		printf STDERR ("%5d [%-38s] %-5d %0.1f/s %s\r",$curr,"=" x ($p/3)."$p%>", $max, $rate, $self->fmt_time($eta));
		$self->{'last_pcnt'} = $p;
		$self->{'last_curr'} = $curr;
	}
	print STDERR "\n" if ($p == 100);
}

=head2 fmt_time

Format time (in seconds) for display.

 print $webpac->fmt_time(time());

This method is called by L<progress_bar> to display remaining time.

=cut

sub fmt_time {
	my $self = shift;

	my $t = shift || 0;
	my $out = "";

	my ($ss,$mm,$hh) = gmtime($t);
	$out .= "${hh}h" if ($hh);
	$out .= sprintf("%02d:%02d", $mm,$ss);
	$out .= "  " if ($hh == 0);
	return $out;
}

#
#
#

=head1 INTERNAL METHODS

Here is a quick list of internal methods, mostly useful to turn debugging
on them (see L<LOGGING> below for explanation).

=cut

=head2 _eval

Internal function to eval code without C<strict 'subs'>.

=cut

sub _eval {
	my $self = shift;

	my $code = shift || return;

	my $log = $self->_get_logger();

	no strict 'subs';
	my $ret = eval $code;
	if ($@) {
		$log->error("problem with eval code [$code]: $@");
	}

	$log->debug("eval: ",$code," [",$ret,"]");

	return $ret || undef;
}

=head2 _init_logger

This function will init C<Log::Log4perl> using provided configuration file.

  $webpac->_init_logger('/path/to/log.conf');

If no path to configuration file is given, dummy empty configuration
will be created. If any mode which inherits from this one is called
with C<debug> flag, it will turn logging to debug level.

This function will also read C<log_conf> value from current object and try
to read that as configuration file if it exists, if it doesn't it will
fallback to default C<conf/log.conf>.

You can disable all logging by adding C<no_log> to constructor of WebPAC
object. Object in C<Test::Exception> class will disable logging
automatically.

=cut

sub _init_logger {
	my $self = shift;
	my $file = shift;
	$file ||= $self->{'log_conf'};
	$file = 'conf/log.conf';
	my $name = (caller(2))[3] || caller;

	my $conf = q( );
	if ($self->{'no_log'}) {
		warn "# $name disabled logging\n" if ($log_debug);
	} elsif ($self->{'debug'}) {
		$conf = << '_log4perl_';

log4perl.rootLogger=INFO, SCREEN

log4perl.logger.WebPAC.=DEBUG

log4perl.appender.SCREEN=Log::Log4perl::Appender::Screen
log4perl.appender.SCREEN.layout=PatternLayout
log4perl.appender.SCREEN.layout.ConversionPattern=%d %p> %F{1}:%L %M - %m%n

_log4perl_
		warn "# $name is using debug logger\n" if ($log_debug);
	} elsif ($name =~ m/Test::Exception/o) {
		warn "# disabled logging for Text::Exception\n" if ($log_debug);
	} elsif (-e $file) {
		warn "# $name is using $file logger\n" if ($log_debug);
		Log::Log4perl->init($file);
		return 1;
	} else {
		warn "# $name is using null logger\n" if ($log_debug);
	}
	Log::Log4perl->init( \$conf );

	return 1;
}


=head2 _get_logger

Get C<Log::Log4perl> object with a twist: domains are defined for each
method

 my $log = $webpac->_get_logger();

=cut

sub _get_logger {
	my $self = shift;

	my $name = (caller(2))[3] || caller;
	$self->{'_logger_'} ||= $self->_init_logger;

	warn "# get_logger( $name )\n" if ($log_debug);

	return get_logger($name);
}


=head1 LOGGING

Logging in WebPAC is performed by L<Log::Log4perl> with config file
C<log.conf>.

Methods defined above have different levels of logging, so
it's descriptions will be useful to turn (mostry B<debug> logging) on
or off to see why WabPAC isn't perforing as you expect it (it might even
be a bug!).

B<This is different from normal Log4perl behaviour>. To repeat, you can
also use method names, and not only classes (which are just few)
to filter logging.


