package WebPAC::Input::Excel;

use warnings;
use strict;

use WebPAC::Input;
use Spreadsheet::ParseExcel;
use Spreadsheet::ParseExcel::Utility qw/int2col/;

=head1 NAME

WebPAC::Input::Excel - support for Microsoft Excell and compatibile files

=head1 VERSION

Version 0.01

=cut

our $VERSION = '0.01';


=head1 SYNOPSIS

Open Microsoft Excell, or compatibile format (for e.g. from OpenOffice.org
or Gnuemeric) in C<.xls> format.

 my $isis = new WebPAC::Input::Excel();
 $isis->open( path => '/path/to/workbook.xls' );

=head1 FUNCTIONS

=head2 open_db

Returns handle to database and size

  my ($db,$size) = $open_db(
  	path => '/path/to/workbook.xls'
	worksheet => 'name of sheet',
  }

C<worksheet> is case and white-space insensitive name of worksheet in Excel
file to use. If not specified, it will use first worksheet in file.

=cut

my $sheet;

sub open_db {
	my $self = shift;

	my $arg = {@_};

	my $log = $self->_get_logger();

	$log->logdie("can't open excel file $arg->{path}: $!") unless (-r $arg->{path} && -f $arg->{path});

	my $workbook = Spreadsheet::ParseExcel::Workbook->Parse($arg->{path});

	my ($size, $wanted_worksheet);

	if ($wanted_worksheet = $arg->{worksheet}) {
		my $name;
		do {
			$sheet = shift @{ $workbook->{Worksheet} };
			$name = $sheet->{Name};
			$name =~ s/\s\s+/ /g;
		} until ($name =~ m/^\s*\Q$wanted_worksheet\E\s*$/i);

	} else {

		$sheet = shift @{ $workbook->{Worksheet} };
	
	}

	$size = $sheet->{MaxRow} - $sheet->{MinRow};

	$log->warn("opening Excel file '$arg->{path}', using ",
		$wanted_worksheet ? '' : 'first ',
		"worksheet: $sheet->{Name} [$size rows]"
	);

	return (42, $size);
}

=head2 fetch_rec

Return record with ID C<$mfn> from database

  my $rec = $self->fetch_rec( $db, $mfn );

}

=cut

sub fetch_rec {
	my $self = shift;

	my (undef, $mfn) = @_;

	my $log = $self->_get_logger();

	$log->logdie("can't find sheet hash") unless (defined($sheet));
	$log->logdie("sheet hash isn't Spreadsheet::ParseExcel::Worksheet") unless ($sheet->isa('Spreadsheet::ParseExcel::Worksheet'));

	my $rec;

	my $row = $sheet->{MinRow} + $mfn - 1;

	$log->debug("fetch_rec( $mfn ) row: $row cols: ",$sheet->{MinCol}," - ",$sheet->{MaxCol});

	foreach my $col ( $sheet->{MinCol} ... $sheet->{MaxCol} ) {
		if (my $v = $sheet->{Cells}->[$row]->[$col]->{Val}) {
			$rec->{ int2col($col) } = $v;
		}
	}

	# add mfn only to records with data
	$rec->{'000'} = [ $mfn ] if ($rec);
	
	return $rec;
}

=head1 AUTHOR

Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>

=head1 COPYRIGHT & LICENSE

Copyright 2005-2006 Dobrica Pavlinusic, All Rights Reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

=cut

1; # End of WebPAC::Input::Excel
