package WebPAC::Validate;

use warnings;
use strict;

use blib;

use base 'WebPAC::Common';
use File::Slurp;
use List::Util qw/first/;
use Data::Dump qw/dump/;
use WebPAC::Normalize qw/_pack_subfields_hash/;
use Storable qw/dclone/;

=head1 NAME

WebPAC::Validate - provide simple validation for records

=head1 VERSION

Version 0.07

=cut

our $VERSION = '0.07';

=head1 SYNOPSIS

This module provide a simple way to validate your file against a simple
configuration file in following format:

  # field 10 doesn't have any subfields
  10
  # same with 101
  101
  # field 200 have valid subfields a-g
  # and field e is repeatable
  200 a b c d e* f g
  # field 205 can have only subfield a
  # and must exists
  205! a
  # while 210 can have a c or d
  210 a c d

=head1 FUNCTIONS

=head2 new

Create new validation object

  my $validate = new WebPAC::Validate(
  	path => 'conf/validate/file',
  );

=cut

sub new {
	my $class = shift;
	my $self = {@_};
	bless($self, $class);

	my $log = $self->_get_logger();

	foreach my $p (qw/path/) {
		$log->logconfess("need $p") unless ($self->{$p});
	}

	my $v_file = read_file( $self->{path} ) ||
		$log->logdie("can't open validate path $self->{path}: $!");

	my $v;
	my $curr_line = 1;

	foreach my $l (split(/[\n\r]+/, $v_file)) {
		$curr_line++;

		# skip comments and whitespaces
		next if ($l =~ /^#/ || $l =~ /^\s*$/);

		$l =~ s/^\s+//;
		$l =~ s/\s+$//;

		my @d = split(/\s+/, $l);

		my $fld = shift @d;

		if ($fld =~ s/!$//) {
			$self->{must_exist}->{$fld}++;
		}

		$log->logdie("need field name in line $curr_line: $l") unless (defined($fld));

		if (@d) {
			$v->{$fld} = [ map {
				my $sf = $_;
				if ( $sf =~ s/!(\*)?$/$1/ ) {
					$self->{must_exist_sf}->{ $fld }->{ $sf }++;
				};
				$sf;
			} @d ];
		} else {
			$v->{$fld} = 1;
		}

	}

	$log->debug("current validation rules: ", dump($v));

	$self->{rules} = $v;

	$log->info("validation uses rules from $self->{path}");

	$self ? return $self : return undef;
}

=head2 validate_errors

Validate record and return errors

  my @errors = $validate->validate_errors( $rec, $rec_dump );

=cut

sub validate_errors {
	my $self = shift;

	my $log = $self->_get_logger();

	my $rec = shift || $log->logdie("validate_errors need record");
	my $rec_dump = shift;

	$log->logdie("rec isn't HASH") unless (ref($rec) eq 'HASH');
	$log->logdie("can't find validation rules") unless (my $r = $self->{rules});

	my $errors;

	$log->debug("rec = ", sub { dump($rec) }, "keys = ", keys %{ $rec });

	my $fields;

	foreach my $f (keys %{ $rec }) {

		next if (!defined($f) || $f eq '' || $f eq '000');

		$fields->{$f}++;

		if ( ! defined($r->{$f}) ) {
			$errors->{field}->{ $f }->{unexpected} = "this field is not expected";
			next;
		}


		if (ref($rec->{$f}) ne 'ARRAY') {
			$errors->{field}->{ $f }->{not_repeatable} = "probably bug in parsing input data";
			next;
		}

		foreach my $v (@{ $rec->{$f} }) {
			# can we have subfields?
			if (ref($r->{$f}) eq 'ARRAY') {
				# are values hashes? (has subfields)
				if (! defined($v)) {
#					$errors->{field}->{$f}->{empty} = undef;
#					$errors->{dump} = $rec_dump if ($rec_dump);
				} elsif (ref($v) ne 'HASH') {
					$errors->{field}->{$f}->{missing_subfield} = join(",", @{ $r->{$f} }) . " required";
					next;
				} else {

					my $h = dclone( $v );

					my $sf_repeatable;

					delete($v->{subfields}) if (defined($v->{subfields}));

					my $subfields;

					foreach my $sf (keys %{ $v }) {

						$subfields->{ $sf }++;

						# is non-repeatable but with multiple values?
						if ( ! first { $_ eq $sf.'*' } @{$r->{$f}} ) {
							if ( ref($v->{$sf}) eq 'ARRAY' ) {
								$sf_repeatable->{$sf}++;
							};
							if (! first { $_ eq $sf } @{ $r->{$f} }) {
								$errors->{field}->{ $f }->{subfield}->{extra}->{$sf}++;
							}
						}

					}
					if (my @r_sf = sort keys( %$sf_repeatable )) {

						foreach my $sf (@r_sf) {
							$errors->{field}->{$f}->{subfield}->{extra_repeatable}->{$sf}++;
							$errors->{field}->{$f}->{dump} =
								join('', _pack_subfields_hash( $h, 1 ) );
						}

					}

					if ( defined( $self->{must_exist_sf}->{$f} ) ) {
						foreach my $sf (sort keys %{ $self->{must_exist_sf}->{$f} }) {
#warn "====> $f $sf must exist\n";
							$errors->{field}->{$f}->{subfield}->{missing}->{$sf}++
								unless defined( $subfields->{$sf} );
						}
					}

				}
			} elsif (ref($v) eq 'HASH') {
				$errors->{field}->{$f}->{unexpected_subfields}++;
				$errors->{field}->{$f}->{dump} =
					join('', _pack_subfields_hash( $v, 1 ) );
			}
		}
	}

	foreach my $must (sort keys %{ $self->{must_exist} }) {
		next if ($fields->{$must});
		$errors->{field}->{$must}->{missing}++;
		$errors->{dump} = $rec_dump if ($rec_dump);
	}

	if ($errors) {
		$log->debug("errors: ", sub { dump( $errors ) } );

		my $mfn = $rec->{'000'}->[0] || $log->logconfess("record ", dump( $rec ), " doesn't have MFN");
		$self->{errors}->{$mfn} = $errors;
	}

	#$log->logcluck("return from this function is ARRAY") unless wantarray;

	return $errors;
}

=head2 reset_errors

Clean all accumulated errors for this input

  $validate->reset_errors;

=cut

sub reset_errors {
	my $self = shift;
	delete ($self->{errors});
}

=head2 all_errors

Return hash with all errors

  print dump( $validate->all_errors );

=cut

sub all_errors {
	my $self = shift;
	return $self->{errors};
}

=head2 report

Produce nice humanly readable report of errors

  print $validate->report;

=cut

sub report {
	my $self = shift;

	sub unroll {
		my ($rest,$o, $dump) = @_;

#warn "# rest: $rest o: $o\n";

		return unless ($rest);

		if (ref($rest) ne 'HASH') {
			$o .= "($rest)";
			return ($o,$dump);
		}

		foreach my $k (sort keys %{ $rest }) {

			if ($k eq 'dump') {
				$dump = $rest->{dump};
				warn "## dump: $dump\n";
				next;
			}
			my $u;
			($u, $dump) = unroll($rest->{$k}, $o, $dump);
			$o .= "$k $u";


		}
		return ($o,$dump);
	}

	my $out = '';

	foreach my $mfn (sort keys %{ $self->{errors} }) {
		my ($msg,$dump) = unroll( $self->{errors}->{$mfn}, '', '' );
		$out .= "MFN $mfn\n$msg\t$dump\n\n";
	}

	return $out;
}

=head1 AUTHOR

Dobrica Pavlinusic, C<< <dpavlin@rot13.org> >>

=head1 COPYRIGHT & LICENSE

Copyright 2006 Dobrica Pavlinusic, All Rights Reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

=cut

1; # End of WebPAC::Validate
