#!/usr/bin/perl

use warnings;
use strict;

use CGI qw/:standard/;
use CGI::Carp qw/fatalsToBrowser/;
use File::Slurp;
use YAML;
use Search::Estraier;
use Data::Page;
use Data::Dump qw/dump/;

my $range_around = 5;
my $entries_per_page = 30;

print header;

sub dump_yaml {
	my $name = shift;
	print qq|<pre># $name\n|, YAML::Dump( @_ ), qq|</pre>|;
}

sub show_pager {
	my ($pager,$coderef) = @_;

	my @show_pages;
	my $after_current = 0;

	if ( $pager->current_page <= $range_around + 2 ) {
		@show_pages = ( $pager->first_page .. $pager->current_page );
		$after_current = $range_around - $pager->current_page;
	} else {
		@show_pages = ( $pager->first_page, '', $pager->current_page - $range_around .. $pager->current_page );
	}

	if ( $pager->current_page + $after_current + $range_around + 1 >= $pager->last_page ) {
		push @show_pages, ( $pager->current_page + 1 .. $pager->last_page );
	} else {
		push @show_pages, ( $pager->current_page + 1 .. $pager->current_page + $after_current + $range_around, '', $pager->last_page );
	}

	dump_yaml( 'show_pages', \@show_pages );

	return '' unless $#show_pages;

	my ( $prev, $next ) = ( '&lt;&lt;', '&gt;&gt;' );

	return
		  $pager->previous_page ? $coderef->( $pager->previous_page, $prev ) : $prev
		, join( ' ', map {
			if ( $_ == $pager->current_page ) {
				qq|<span class=current_page>$_</span>|;
			} elsif ( $_ eq '' ) {
				qq|<span class=skip>...</span>|;
			} else {
				$coderef->( $_ );
			}
		} @show_pages )
		, $pager->next_page ? $coderef->( $pager->next_page, $next ) : $next
		;
		
}

my $path = $ENV{PATH_INFO} || 'ecas';
my $dir = $0;
$dir =~ s{/[^/]+.cgi}{};

my $config = YAML::LoadFile( "$dir/$path/config.yml" );

my $database = (keys %{ $config->{databases} })[0];
die "$database not in $path" unless $path =~ m{\Q$database\E};

my $html_markup = "$dir/$path/html.pm";
my $html_markup_skip;
if ( -e $html_markup ) {
	require $html_markup;
	$html_markup = $database . '::html';
} else {
	undef $html_markup;
}

my $estraier = YAML::LoadFile( "$dir/../var/estraier/$database.yaml" );

my $db = $config->{databases}->{$database};

my @attr = keys %{ $estraier->{attr} }; # FIXME replace with real gnerated lookup

print
	start_html(
		-title => $db->{name},
		-style => '../../style.css',
	),
	h1( $db->{name} ),
	qq|<div id=description>|, $db->{description}, qq|</div>|,
	start_form( -action => self_url( query => 0 ) ),
		radio_group(
			-name => 'attr',
			-values => [ @attr ],
#			-linebreak => 0,
		),
		textfield( -name => 'search' ),
		submit,
		textfield( -name => 'entries_per_page', -default => $entries_per_page ),
		textfield( -name => 'current_page', -default => 1 ),
;

print	end_form;

if ( my $search = param('search') ) {

	print qq|<div id="results">|;

	my $node = Search::Estraier::Node->new(
		url => $config->{hyperestraier}->{masterurl} . '/node/' . $database,
		croak_on_error => 1,
	);

	param( 'entries_per_page', $entries_per_page ) unless param('entries_per_page'); # FIXME not needed?
	my $pager = Data::Page->new;
	$pager->total_entries( param('current_page') * param('entries_per_page') );
	$pager->$_( param($_) ) foreach ( qw/entries_per_page current_page/ );

	dump_yaml( 'pager', $pager );

	my $cond = Search::Estraier::Condition->new;
	$cond->set_phrase( $search );
	$cond->set_skip( $pager->skipped );
	$cond->set_max(  $pager->entries_per_page );
	my $nres = $node->search( $cond, 0 );
	$pager->total_entries( $nres->hits );

	dump_yaml( 'cond', $cond );

	if ( ! $nres ) {
		my $no_results = "No results for search '%s'";
		printf qq|<div class="error">$no_results</div>|, $search;
	} else {

		my $results = "Got %d results for search '%s'";
		printf qq|<div class="message">$results</div>|, $nres->hits, $search;

		print
			qq|<div class=pager>|,
			join(' ', show_pager( $pager,
				sub {
					my ($page,$label) = @_;
					param( 'current_page', $page );
					my $url = self_url( -query => 1 );
					$label = $page unless defined $label;
					qq|<a href="$url">$label</a>|;
				}
			)),
			qq|</div>|
		;

		my $start = $pager->first;
		print qq|<ol start=$start>|;

		foreach my $i ( 1 .. $nres->doc_num ) {
			my $rdoc = $nres->get_doc( $i - 1 );
			print qq|<li>|;
			foreach my $attr ( @attr ) {
				my $v = $rdoc->attr( $attr );
				if ( defined $v && $html_markup && ! $html_markup_skip->{$attr} ) {
					eval "\$v = $html_markup->$attr( \$v );";
					if ( $@ ) {
						warn "disable html markup for $attr: $@";
						$html_markup_skip->{$attr} = $@;
					}
				}
				next unless defined $v;
				print qq|<div><label>$attr</label><span class=$attr>$v</span></div>\n|;
			}
			print qq|</li>\n|;
		}
		print qq|</ol>|;
	}
	print qq|</div>|;

	dump_yaml( 'pager', $pager );

}

dump_yaml( 'estraier', $estraier );
dump_yaml( 'db', $db );
dump_yaml( 'html_markup_skip', $html_markup_skip );

print	end_html;