cleanup dhcpd server

diff --git a/lib/PXElator/dhcpd.pm b/lib/PXElator/dhcpd.pm
new file mode 100755 (executable)
index 0000000..4b8bd0c
--- /dev/null
+++ b/lib/PXElator/dhcpd.pm
@@ -0,0 +1,199 @@
+#!/usr/bin/perl
+
+=head1 dhcpd
+
+start with:
+
+ perl -Ilib/PXElator -Ilib -Mdhcpd -e start
+
+based on L<http://www.perlmonks.org/index.pl?node_id=325248>
+
+=cut
+
+use strict;
+use warnings;
+
+use autodie;
+
+use IO::Socket::INET;
+use File::Slurp;
+use Data::Dump qw/dump/;
+use Net::Ping;
+use Module::Refresh;
+
+use lib '..';
+use Net::DHCP::Packet;
+use Net::DHCP::Constants 0.67;
+
+use server;
+
+my $debug = 1;
+
+our ( $file, $gpxe_file );
+our ( $ip_from, $ip_to ) = ( 10, 100 );
+
+if ( ! $server::ip ) {
+       my $server_ip = `/sbin/ifconfig`;
+       $server_ip =~ s/^.+?addr:([\d\.]+).*$/$1/gs;
+       $server::ip = $server_ip;
+}
+
+warn "server ip $server::ip\n";
+
+my $addr = $ip_from;
+
+sub client_ip {
+       my ( $mac ) = @_;
+
+       my $conf = "conf/$server::ip";
+       mkdir $conf unless -e $conf;
+
+       if ( -e "$conf/mac/$mac" ) {
+               my $ip = read_file "$conf/mac/$mac";
+               print "$mac old $ip\n";
+               return $ip;
+       }
+
+       mkdir $_ foreach grep { ! -e $_ } map { "$conf/$_" } ( 'ip', 'mac' );
+
+       my $p = Net::Ping->new;
+
+       my $prefix = $server::ip;
+       $prefix =~ s{\.\d+$}{.};
+       my $ip = $prefix . $addr;
+       while ( -e "conf/ip/$ip" || $p->ping( $ip ) ) {
+               $ip = $prefix . $addr++;
+               die "all addresses allocated!" if $addr == $ip_to;
+       }
+
+       write_file "$conf/mac/$mac", $ip;
+       if ( -l "$conf/ip/$ip" && readlink "$conf/ip/$ip" ne "$conf/mac/$mac") {
+               unlink     "$conf/ip/$ip";
+               symlink    "$conf/mac/$mac", "$conf/ip/$ip";
+               warn "$mac IP changed to $ip";
+       }
+
+       print "$mac NEW $ip\n";
+
+       return $ip;
+}
+
+our $transaction = 0; # FIXME predictible transaction numbers
+
+sub process_packet {
+       my $sock = shift;
+
+       my $buf;
+       $sock->recv($buf, 1024);
+       my $size = 'empty';
+       $size = length($buf) . ' bytes' if defined $buf;
+
+       print "packet from ",$sock->peerhost,":",$sock->peerport," $size\n";
+       return unless $buf;
+
+       my $dhcp = Net::DHCP::Packet->new($buf);
+       $dhcp->comment( $transaction++ );
+
+       warn "recv: ", $dhcp->toString;
+
+       my $mac = substr($dhcp->chaddr(),0,$dhcp->hlen()*2);
+       my $ip = client_ip($mac);
+
+=for later
+
+       my $user_class = $dhcp->getOptionValue(DHO_USER_CLASS());
+
+       if ( $user_class eq 'gPXE' ) {
+               $file = $gpxe_file;
+       } elsif ( ! $file ) {
+               $file = 'undionly.kpxe';
+       }
+
+=cut
+
+       my $packet = {
+               Op              => BOOTREPLY(),
+               Hops    => $dhcp->hops(),
+               Xid             => $dhcp->xid(),
+               Flags   => $dhcp->flags(),
+               Ciaddr  => $dhcp->ciaddr(),
+               Yiaddr  => $ip,
+               Siaddr  => $server::ip,
+               Giaddr  => $dhcp->giaddr(),
+               Chaddr  => $dhcp->chaddr(),
+               File    => $file,
+       };
+
+       my $messagetype = $dhcp->getOptionValue(DHO_DHCP_MESSAGE_TYPE());
+
+       if ($messagetype eq DHCPDISCOVER()) {
+               warn "DHCP DISCOVER";
+               $packet->{Comment} = $dhcp->comment();
+               $packet->{DHO_DHCP_MESSAGE_TYPE()} = DHCPOFFER();
+       } elsif ($messagetype eq DHCPREQUEST()) {
+               my $requested_ip = $dhcp->getOptionValue(DHO_DHCP_REQUESTED_ADDRESS());
+               warn "DHCP REQUEST $requested_ip";
+               if ( $ip eq $requested_ip ) {
+                       $packet->{DHO_DHCP_MESSAGE_TYPE()}      = DHCPACK();
+                       $packet->{DHO_DHCP_LEASE_TIME()}        = 5 * 60; # 5 min
+#                      $packet->{DHO_DHCP_SERVER_IDENTIFIER()} = $server::ip;          # FIXME
+                       $packet->{DHO_SUBNET_MASK()}            = '255.255.255.0';
+                       $packet->{DHO_ROUTERS()}                = $server::ip;
+#                      $packet->{DHO_DOMAIN_NAME()}            = 'pxelator.lan';
+#                      $packet->{DHO_NAME_SERVERS()}           = $server::ip;
+#                      $packet->{DHO_ROOT_PATH()}              = '/exports/foobar';
+               } else {
+                       $packet->{DHO_DHCP_MESSAGE_TYPE()} = DHCPNAK();
+                       $packet->{DHO_DHCP_MESSAGE()} = "Bad request, expected $ip";
+               }
+       } elsif ($messagetype eq DHCPINFORM()) {
+               warn "DHCP INFORM ignored";
+       } else {
+               warn "$messagetype igored (bootp?)";
+       }
+
+       warn ">> $mac == $ip server: $server::ip", $file ? " file: $file\n" : "\n";
+
+       $packet = new Net::DHCP::Packet( %$packet );
+       warn "## ",$packet->toString(),"\n" if $debug;
+
+       my $reply = IO::Socket::INET->new(
+               LocalAddr => $server::ip,
+               LocalPort => 67,
+               Proto => "udp",
+               Broadcast => 1,
+               PeerAddr => '255.255.255.255',
+               PeerPort => 68,
+               Reuse => 1,
+       ) or die "socket: $@";
+
+       my $buff = $packet->serialize();
+       $reply->send( $buff, 0 ) or die "Error sending: $!\n";
+
+#      system("arp -s $ip $mac"),
+
+}
+
+sub start {
+
+       my $sock = IO::Socket::INET->new(
+               LocalPort       => 67,
+#              LocalAddr       => 'localhost',
+#              LocalAddr       => '10.0.0.100',
+               LocalAddr       => '0.0.0.0',
+               Proto           => 'udp',
+               ReuseAddr       => 1,
+#              PeerPort        => getservbyname('bootpc', 'udp'),
+               Broadcast       => 1,
+               Type            => SOCK_DGRAM,
+       ) or die "Failed to bind to socket: $@";
+
+       print "DHCP listen on ",$sock->sockhost,":",$sock->sockport,"\n";
+
+       while (1) {
+               Module::Refresh->refresh;
+               process_packet $sock;
+       }
+}
+
+1;