bin/BackupPC_archive

   1 #!/bin/perl
   2 #============================================================= -*-perl-*-
   3 #
   4 # BackupPC_archive: Archive files for an archive client.
   5 #
   6 # DESCRIPTION
   7 #
   8 #   Usage: BackupPC_archive <user> <archiveclient> <reqFileName>
   9 #
  10 # AUTHOR
  11 #   Craig Barratt  <cbarratt@users.sourceforge.net>
  12 #
  13 # COPYRIGHT
  14 #   Copyright (C) 2001-2003  Craig Barratt
  15 #
  16 #   This program is free software; you can redistribute it and/or modify
  17 #   it under the terms of the GNU General Public License as published by
  18 #   the Free Software Foundation; either version 2 of the License, or
  19 #   (at your option) any later version.
  20 #
  21 #   This program is distributed in the hope that it will be useful,
  22 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 #   GNU General Public License for more details.
  25 #
  26 #   You should have received a copy of the GNU General Public License
  27 #   along with this program; if not, write to the Free Software
  28 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  29 #
  30 #========================================================================
  31 #
  32 # Version 2.1.0_CVS, released 8 Feb 2004.
  33 #
  34 # See http://backuppc.sourceforge.net.
  35 #
  36 #========================================================================
  37
  38 use strict;
  39 no  utf8;
  40 use lib "/usr/local/BackupPC/lib";
  41 use BackupPC::Lib;
  42 use BackupPC::FileZIO;
  43 use BackupPC::Xfer::Archive;
  44
  45 use vars qw( %ArchiveReq );
  46
  47 ###########################################################################
  48 # Initialize
  49 ###########################################################################
  50
  51 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
  52 my $TopDir = $bpc->TopDir();
  53 my $BinDir = $bpc->BinDir();
  54 my %Conf   = $bpc->Conf();
  55 my $NeedPostCmd;
  56
  57 my($user, $host, $client, $reqFileName, %stat);
  58
  59 $bpc->ChildInit();
  60
  61 if ( @ARGV != 3 ) {
  62     print("usage: $0 <user> <archiveclient> <reqFileName>\n");
  63     exit(1);
  64 }
  65 $user = $1 if ( $ARGV[0] =~ /(.+)/ );
  66 $client = $1 if ( $ARGV[1] =~ /(.+)/ );
  67 if ( $ARGV[2] !~ /^([\w.]+)$/ ) {
  68     print("$0: bad reqFileName (arg #3): $ARGV[2]\n");
  69     exit(1);
  70 }
  71 $reqFileName = $1;
  72
  73 my $startTime = time();
  74
  75 my $Dir     = "$TopDir/pc/$client";
  76 my @xferPid = ();
  77
  78 #
  79 # Catch various signals
  80 #
  81 $SIG{INT}  = \&catch_signal;
  82 $SIG{ALRM} = \&catch_signal;
  83 $SIG{TERM} = \&catch_signal;
  84 $SIG{PIPE} = \&catch_signal;
  85 $SIG{STOP} = \&catch_signal;
  86 $SIG{TSTP} = \&catch_signal;
  87 $SIG{TTIN} = \&catch_signal;
  88 my $Pid = $$;
  89
  90 mkpath($Dir, 0, 0777) if ( !-d $Dir );
  91 if ( !-f "$Dir/LOCK" ) {
  92     open(LOCK, ">", "$Dir/LOCK") && close(LOCK);
  93 }
  94 open(LOG, ">>", "$Dir/LOG");
  95 select(LOG); $| = 1; select(STDOUT);
  96
  97
  98 #
  99 # Read the request file
 100 #
 101
 102 if ( !(my $ret = do "$Dir/$reqFileName") ) {
 103     my $err;
 104     if ( $@ ) {
 105         $err = "couldn't parse $Dir/$reqFileName: $@";
 106     } elsif ( !defined($ret) ) {
 107         $err = "couldn't do $Dir/$reqFileName: $!";
 108     } else {
 109         $err = "couldn't run $Dir/$reqFileName";
 110     }
 111     $stat{hostError} = $err;
 112     exit(ArchiveCleanup($client));
 113 }
 114
 115 #
 116 # Re-read config file, so we can include the PC-specific config
 117 #
 118 if ( defined(my $error = $bpc->ConfigRead($client)) ) {
 119     $stat{hostError} = "Can't read PC's config file: $error";
 120     exit(ArchiveCleanup($client));
 121 }
 122 %Conf = $bpc->Conf();
 123
 124 #
 125 # Make sure we eventually timeout if there is no activity from
 126 # the data transport program.
 127 #
 128 alarm($Conf{ClientTimeout});
 129
 130 #
 131 # See if the host name is aliased
 132 #
 133 if ( $Conf{ClientNameAlias} ne "" ) {
 134     $host = $Conf{ClientNameAlias};
 135 } else {
 136     $host = $client;
 137 }
 138
 139 #
 140 # Setup file extension for compression and open ArchiveLOG output file
 141 #
 142 $Conf{CompressLevel} = 0 if ( !BackupPC::FileZIO->compOk );
 143 my $fileExt = $Conf{CompressLevel} > 0 ? ".z" : "";
 144 my $ArchiveLOG = BackupPC::FileZIO->open("$Dir/ArchiveLOG$fileExt", 1,
 145                                      $Conf{CompressLevel});
 146 my($logMsg, $xfer);
 147
 148 $stat{xferOK} = 1;
 149 $stat{hostAbort} = undef;
 150 $stat{hostError} = $stat{lastOutputLine} = undef;
 151 local(*RH, *WH);
 152
 153 #
 154 # Run an optional pre-archive command
 155 #
 156 UserCommandRun("ArchivePreUserCmd");
 157 $NeedPostCmd = 1;
 158
 159 $xfer = BackupPC::Xfer::Archive->new($bpc);
 160
 161 #
 162 # Run the transport program
 163 #
 164
 165 my $xferArgs = {
 166     client       => $client,
 167     host         => $host,
 168     user         => $ArchiveReq{user},
 169     type         => "archive",
 170     XferLOG      => $ArchiveLOG,
 171     XferMethod   => $Conf{XferMethod},
 172     pathHdrSrc   => $ArchiveReq{pathHdrSrc},
 173     pathHdrDest  => $ArchiveReq{pathHdrDest},
 174     HostList     => \@{$ArchiveReq{HostList}},
 175     BackupList   => \@{$ArchiveReq{BackupList}},
 176     archiveloc   => $ArchiveReq{archiveloc},
 177     parfile      => $ArchiveReq{parfile},
 178     compression  => $ArchiveReq{compression},
 179     compext      => $ArchiveReq{compext},
 180     splitsize    => $ArchiveReq{splitsize},
 181     pidHandler   => \&pidHandler,
 182 };
 183
 184 $xfer->args($xferArgs);
 185
 186 if ( !defined($logMsg = $xfer->start()) ) {
 187     UserCommandRun("ArchivePostUserCmd") if ( $NeedPostCmd );
 188     $stat{hostError} = "xfer start failed: ", $xfer->errStr;
 189     exit(ArchiveCleanup($client));
 190 }
 191
 192 print(LOG $bpc->timeStamp, "Starting archive\n");
 193 print("started_archive\n");
 194 $xfer->run();
 195 $stat{xferOK} = 0 if ( defined($stat{hostError} = $xfer->errStr) );
 196 alarm(0);
 197
 198 exit(ArchiveCleanup($client));
 199
 200 ###########################################################################
 201 # Subroutines
 202 ###########################################################################
 203
 204 sub catch_signal
 205 {
 206     my $signame = shift;
 207
 208     #
 209     # Children quit quietly on ALRM
 210     #
 211     exit(1) if ( $Pid != $$ && $signame eq "ALRM" );
 212
 213     #
 214     # Ignore signals in children
 215     #
 216     return if ( $Pid != $$ );
 217
 218     #
 219     # Note: needs to be tested for each kind of XferMethod
 220     #
 221     print(LOG $bpc->timeStamp, "cleaning up after signal $signame\n");
 222     $SIG{$signame} = 'IGNORE';
 223     $ArchiveLOG->write(\"exiting after signal $signame\n");
 224     $stat{xferOK} = 0;
 225     if ( $signame eq "INT" ) {
 226         $stat{hostError} = "aborted by user (signal=$signame)";
 227     } else {
 228         $stat{hostError} = "aborted by signal=$signame";
 229     }
 230     exit(ArchiveCleanup($client));
 231 }
 232
 233 #
 234 # Cleanup and update the archive status
 235 #
 236 sub ArchiveCleanup
 237 {
 238     my($client) = @_;
 239
 240     $stat{xferOK} = 0 if ( $stat{hostError} || $stat{hostAbort} );
 241
 242     if ( !$stat{xferOK} ) {
 243         #
 244         # kill off the tranfer program, first nicely then forcefully
 245         #
 246         if ( @xferPid ) {
 247             kill($bpc->sigName2num("INT"), @xferPid);
 248             sleep(1);
 249             kill($bpc->sigName2num("KILL"), @xferPid);
 250         }
 251     }
 252
 253     my $lastNum  = -1;
 254     my @Archives;
 255
 256     @Archives = $bpc->ArchiveInfoRead($client);
 257     for ( my $i = 0 ; $i < @Archives ; $i++ ) {
 258         $lastNum = $Archives[$i]{num} if ( $lastNum < $Archives[$i]{num} );
 259     }
 260     $lastNum++;
 261
 262     #
 263     # Run an optional post-archive command
 264     #
 265     UserCommandRun("ArchivePostUserCmd") if ( $NeedPostCmd );
 266
 267     rename("$Dir/ArchiveLOG$fileExt", "$Dir/ArchiveLOG.$lastNum$fileExt");
 268     rename("$Dir/$reqFileName", "$Dir/ArchiveInfo.$lastNum");
 269     my $endTime = time();
 270
 271     #
 272     # If the archive failed, clean up
 273     #
 274     if ( !$stat{xferOK} ) {
 275         #
 276         # wait a short while and see if the system is still alive
 277         #
 278         $stat{hostError} = $stat{lastOutputLine} if ( $stat{hostError} eq "" );
 279         sleep(2);
 280         $stat{hostAbort} = 1;
 281         $ArchiveLOG->write(\"Archive failed: $stat{hostError}")
 282                                             if ( defined($ArchiveLOG) );
 283     }
 284
 285     $ArchiveLOG->close() if ( defined($ArchiveLOG) );
 286
 287     #
 288     # Add the new archive information to the archive file
 289     #
 290     @Archives = $bpc->ArchiveInfoRead($client);
 291     my $i = @Archives;
 292     $Archives[$i]{num}           = $lastNum;
 293     $Archives[$i]{startTime}     = $startTime;
 294     $Archives[$i]{endTime}       = $endTime;
 295     $Archives[$i]{result}        = $stat{xferOK} ? "ok" : "failed";
 296     $Archives[$i]{errorMsg}      = $stat{hostError};
 297
 298     while ( @Archives > $Conf{ArchiveInfoKeepCnt} ) {
 299         my $num = $Archives[0]{num};
 300         unlink("$Dir/ArchiveLOG.$num.z");
 301         unlink("$Dir/ArchiveLOG.$num");
 302         unlink("$Dir/ArchiveInfo.$num");
 303         shift(@Archives);
 304     }
 305     $bpc->ArchiveInfoWrite($client, @Archives);
 306
 307     if ( !$stat{xferOK} ) {
 308         print(LOG $bpc->timeStamp, "Archive failed ($stat{hostError})\n");
 309         print("archive failed: $stat{hostError}\n");
 310         return 1;
 311     } else {
 312         print(LOG $bpc->timeStamp, "Archive Complete\n");
 313         print("archive complete\n");
 314         return;
 315     }
 316 }
 317
 318 #
 319 # The Xfer method might tell us from time to time about processes
 320 # it forks.  We tell BackupPC about this (for status displays) and
 321 # keep track of the pids in case we cancel the backup
 322 #
 323 sub pidHandler
 324 {
 325     @xferPid = @_;
 326     @xferPid = grep(/./, @xferPid);
 327     return if ( !@xferPid );
 328     my @pids = @xferPid;
 329     my $str = join(",", @pids);
 330     $ArchiveLOG->write(\"Xfer PIDs are now $str\n") if ( defined($ArchiveLOG) );
 331     print("xferPids $str\n");
 332 }
 333
 334 #
 335 # Run an optional pre- or post-dump command
 336 #
 337 sub UserCommandRun
 338 {
 339     my($type) = @_;
 340
 341     return if ( !defined($Conf{$type}) );
 342     my $vars = {
 343         xfer         => $xfer,
 344         client       => $client,
 345         host         => $host,
 346         user         => $user,
 347         share        => $ArchiveReq{shareDest},
 348         XferMethod   => $Conf{XferMethod},
 349         HostList     => \@{$ArchiveReq{HostList}},
 350         BackupList   => \@{$ArchiveReq{BackupList}},
 351         archiveloc   => $ArchiveReq{archiveloc},
 352         parfile      => $ArchiveReq{parfile},
 353         compression  => $ArchiveReq{compression},
 354         compext      => $ArchiveReq{compext},
 355         splitsize    => $ArchiveReq{splitsize},
 356         sshPath      => $Conf{SshPath},
 357         LOG          => *LOG,
 358         XferLOG      => $ArchiveLOG,
 359         stat         => \%stat,
 360         xferOK       => $stat{xferOK} || 0,
 361         type         => $type,
 362     };
 363     my $cmd = $bpc->cmdVarSubstitute($Conf{$type}, $vars);
 364     $ArchiveLOG->write(\"Executing $type: @$cmd\n");
 365     #
 366     # Run the user's command, dumping the stdout/stderr into the
 367     # Xfer log file.  Also supply the optional $vars and %Conf in
 368     # case the command is really perl code instead of a shell
 369     # command.
 370     #
 371     $bpc->cmdSystemOrEval($cmd,
 372             sub {
 373                 $ArchiveLOG->write(\$_[0]);
 374             },
 375             $vars, \%Conf);
 376 }