9dfd6c1d603bc673d6e4af07047a2fa3cab33d7d
[BackupPC.git] / bin / BackupPC_dump
1 #!/usr/bin/perl
2 #============================================================= -*-perl-*-
3 #
4 # BackupPC_dump: Dump a single client.
5 #
6 # DESCRIPTION
7 #
8 #   Usage: BackupPC_dump [-i] [-f] [-F] [-I] [-d] [-e] [-v] <client>
9 #
10 #   Flags:
11 #
12 #     -i   Do an incremental dump, overriding any scheduling (but a full
13 #          dump will be done if no dumps have yet succeeded)
14 #
15 #     -f   Do a full dump, overriding any scheduling.
16 #
17 #     -I   Do an increment dump if the regular schedule requires a
18 #          full or incremental, otherwise do nothing (a full is done
19 #          if no dumps have yet succeeded)
20 #
21 #     -F   Do a full dump if the regular schedule requires a
22 #          full or incremental, otherwise do nothing
23 #
24 #     -d   Host is a DHCP pool address, and the client argument
25 #          just an IP address.  We lookup the NetBios name from
26 #          the IP address.
27 #
28 #     -e   Just do an dump expiry check for the client.  Don't do anything
29 #          else.  This is used periodically by BackupPC to make sure that
30 #          dhcp hosts have correctly expired old backups.  Without this,
31 #          dhcp hosts that are no longer on the network will not expire
32 #          old backups.
33 #
34 #     -v   verbose.  for manual usage: prints failure reasons in more detail.
35 #
36 #   BackupPC_dump is run periodically by BackupPC to backup $client.
37 #   The file $TopDir/pc/$client/backups is read to decide whether a
38 #   full or incremental backup needs to be run.  If no backup is
39 #   scheduled, or a ping to $client fails, then BackupPC_dump quits.
40 #
41 #   The backup is done using the selected XferMethod (smb, tar, rsync,
42 #   backuppcd etc), extracting the dump into $TopDir/pc/$client/new.
43 #   The xfer output is put into $TopDir/pc/$client/XferLOG.
44 #
45 #   If the dump succeeds (based on parsing the output of the XferMethod):
46 #     - $TopDir/pc/$client/new is renamed to $TopDir/pc/$client/nnn, where
47 #           nnn is the next sequential dump number.
48 #     - $TopDir/pc/$client/XferLOG is renamed to $TopDir/pc/$client/XferLOG.nnn.
49 #     - $TopDir/pc/$client/backups is updated.
50 #
51 #   If the dump fails:
52 #     - $TopDir/pc/$client/new is moved to $TopDir/trash for later removal.
53 #     - $TopDir/pc/$client/XferLOG is renamed to $TopDir/pc/$client/XferLOG.bad
54 #           for later viewing.
55 #
56 #   BackupPC_dump communicates to BackupPC via printing to STDOUT.
57 #
58 # AUTHOR
59 #   Craig Barratt  <cbarratt@users.sourceforge.net>
60 #
61 # COPYRIGHT
62 #   Copyright (C) 2001-2009  Craig Barratt
63 #
64 #   This program is free software; you can redistribute it and/or modify
65 #   it under the terms of the GNU General Public License as published by
66 #   the Free Software Foundation; either version 2 of the License, or
67 #   (at your option) any later version.
68 #
69 #   This program is distributed in the hope that it will be useful,
70 #   but WITHOUT ANY WARRANTY; without even the implied warranty of
71 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
72 #   GNU General Public License for more details.
73 #
74 #   You should have received a copy of the GNU General Public License
75 #   along with this program; if not, write to the Free Software
76 #   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
77 #
78 #========================================================================
79 #
80 # Version 3.2.0beta0, released 5 April 2009.
81 #
82 # See http://backuppc.sourceforge.net.
83 #
84 #========================================================================
85
86 use strict;
87 no  utf8;
88 use lib "/usr/local/BackupPC/lib";
89 use BackupPC::Lib;
90 use BackupPC::FileZIO;
91 use BackupPC::Storage;
92 use BackupPC::Xfer;
93 use Encode;
94 use Socket;
95 use File::Path;
96 use File::Find;
97 use Getopt::Std;
98
99 ###########################################################################
100 # Initialize
101 ###########################################################################
102
103 die("BackupPC::Lib->new failed\n") if ( !(my $bpc = BackupPC::Lib->new) );
104 my $TopDir = $bpc->TopDir();
105 my $BinDir = $bpc->BinDir();
106 my %Conf   = $bpc->Conf();
107 my $NeedPostCmd;
108 my $Hosts;
109 my $SigName;
110 my $Abort;
111
112 $bpc->ChildInit();
113
114 my %opts;
115 if ( !getopts("defivFI", \%opts) || @ARGV != 1 ) {
116     print("usage: $0 [-d] [-e] [-f] [-i] [-F] [-I] [-v] <client>\n");
117     exit(1);
118 }
119 if ( $ARGV[0] !~ /^([\w\.\s-]+)$/ ) {
120     print("$0: bad client name '$ARGV[0]'\n");
121     exit(1);
122 }
123 if ( (defined($opts{f}) + defined($opts{i}) + defined($opts{F}) + defined($opts{I})) > 1 ) {
124     print("$0: exiting because you can only use one of -f, -i, -F, and -I\n");
125     exit(1);
126 }
127
128 my $client = $1;   # BackupPC's client name (might not be real host name)
129 my $hostIP;        # this is the IP address
130 my $host;          # this is the real host name
131
132 my($clientURI, $user);
133
134 $bpc->verbose(1) if ( $opts{v} );
135
136 if ( $opts{d} ) {
137     #
138     # The client name $client is simply a DHCP address.  We need to check
139     # if there is any machine at this address, and if so, get the actual
140     # host name via NetBios using nmblookup.
141     #
142     $hostIP = $client;
143     if ( $bpc->CheckHostAlive($hostIP) < 0 ) {
144         print(STDERR "Exiting because CheckHostAlive($hostIP) failed\n")
145                             if ( $opts{v} );
146         exit(1);
147     }
148     if ( $Conf{NmbLookupCmd} eq "" ) {
149         print(STDERR "Exiting because \$Conf{NmbLookupCmd} is empty\n")
150                             if ( $opts{v} );
151         exit(1);
152     }
153     ($client, $user) = $bpc->NetBiosInfoGet($hostIP);
154     if ( $client !~ /^([\w\.\s-]+)$/ ) {
155         print(STDERR "Exiting because NetBiosInfoGet($hostIP) returned"
156                    . " '$client', an invalid host name\n") if ( $opts{v} );
157         exit(1)
158     }
159     $Hosts = $bpc->HostInfoRead($client);
160     $host = $client;
161 } else {
162     $Hosts = $bpc->HostInfoRead($client);
163 }
164 if ( !defined($Hosts->{$client}) ) {
165     print(STDERR "Exiting because host $client does not exist in the"
166                . " hosts file\n") if ( $opts{v} );
167     exit(1)
168 }
169
170 my $Dir     = "$TopDir/pc/$client";
171 my @xferPid = ();
172 my $tarPid  = -1;
173 my $completionPercent;
174
175 #
176 # Re-read config file, so we can include the PC-specific config
177 #
178 $clientURI = $bpc->uriEsc($client);
179 if ( defined(my $error = $bpc->ConfigRead($client)) ) {
180     print("dump failed: Can't read PC's config file: $error\n");
181     exit(1);
182 }
183 %Conf = $bpc->Conf();
184
185 #
186 # Catch various signals
187 #
188 $SIG{INT}  = \&catch_signal;
189 $SIG{ALRM} = \&catch_signal;
190 $SIG{TERM} = \&catch_signal;
191 $SIG{PIPE} = \&catch_signal;
192 $SIG{STOP} = \&catch_signal;
193 $SIG{TSTP} = \&catch_signal;
194 $SIG{TTIN} = \&catch_signal;
195 my $Pid = $$;
196
197 #
198 # Make sure we eventually timeout if there is no activity from
199 # the data transport program.
200 #
201 alarm($Conf{ClientTimeout});
202
203 mkpath($Dir, 0, 0777) if ( !-d $Dir );
204 if ( !-f "$Dir/LOCK" ) {
205     open(LOCK, ">", "$Dir/LOCK") && close(LOCK);
206 }
207
208 my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
209 my $logPath = sprintf("$Dir/LOG.%02d%04d", $mon + 1, $year + 1900);
210
211 if ( !-f $logPath ) {
212     #
213     # Compress and prune old log files
214     #
215     my $lastLog = $Conf{MaxOldPerPCLogFiles} - 1;
216     foreach my $file ( $bpc->sortedPCLogFiles($client) ) {
217         if ( $lastLog <= 0 ) {
218             unlink($file);
219             next;
220         }
221         $lastLog--;
222         next if ( $file =~ /\.z$/ || !$Conf{CompressLevel} );
223         BackupPC::FileZIO->compressCopy($file,
224                                         "$file.z",
225                                         undef,
226                                         $Conf{CompressLevel}, 1);
227     }
228 }
229
230 open(LOG, ">>", $logPath);
231 select(LOG); $| = 1; select(STDOUT);
232
233 #
234 # For the -e option we just expire backups and quit
235 #
236 if ( $opts{e} ) {
237     BackupExpire($client);
238     exit(0);
239 }
240
241 #
242 # For archive hosts we don't bother any further
243 #
244 if ($Conf{XferMethod} eq "archive" ) {
245     print(STDERR "Exiting because the XferMethod is set to archive\n")
246                 if ( $opts{v} );
247     exit(0);
248 }
249
250 ###########################################################################
251 # Figure out what to do and do it
252 ###########################################################################
253
254 #
255 # See if we should skip this host during a certain range
256 # of times.
257 #
258 my $err = $bpc->ServerConnect($Conf{ServerHost}, $Conf{ServerPort});
259 if ( $err ne "" ) {
260     print("Can't connect to server ($err)\n");
261     print(LOG $bpc->timeStamp, "Can't connect to server ($err)\n");
262     exit(1);
263 }
264 my $reply = $bpc->ServerMesg("status host($clientURI)");
265 $reply = $1 if ( $reply =~ /(.*)/s );
266 my(%StatusHost);
267 eval($reply);
268 $bpc->ServerDisconnect();
269
270 #
271 # For DHCP tell BackupPC which host this is
272 #
273 if ( $opts{d} ) {
274     if ( $StatusHost{activeJob} ) {
275         # oops, something is already running for this host
276         print(STDERR "Exiting because backup is already running for $client\n")
277                         if ( $opts{v} );
278         exit(0);
279     }
280     print("DHCP $hostIP $clientURI\n");
281 }
282
283 my($needLink, @Backups, $type);
284 my($incrBaseTime, $incrBaseBkupNum, $incrBaseLevel, $incrLevel);
285 my $lastFullTime = 0;
286 my $lastIncrTime = 0;
287 my $partialIdx = -1;
288 my $partialNum;
289 my $partialFileCnt;
290 my $lastBkupNum;
291 my $lastPartial = 0;
292
293 #
294 # Maintain backward compatibility with $Conf{FullPeriod} == -1 or -2
295 # meaning disable backups
296 #
297 $Conf{BackupsDisable} = -$Conf{FullPeriod}
298             if ( !$Conf{BackupsDisable} && $Conf{FullPeriod} < 0 );
299
300 if ( $Conf{BackupsDisable} == 1 && !$opts{f} && !$opts{i}
301         || $Conf{BackupsDisable} == 2 ) {
302     print(STDERR "Exiting because backups are disabled with"
303        . " \$Conf{BackupsDisable} = $Conf{BackupsDisable}\n") if ( $opts{v} );
304     #
305     # Tell BackupPC to ignore old failed backups on hosts that
306     # have backups disabled.
307     #
308     print("backups disabled\n")
309                 if ( defined($StatusHost{errorTime})
310                      && $StatusHost{reason} ne "Reason_backup_done"
311                      && time - $StatusHost{errorTime} > 4 * 24 * 3600 );
312     NothingToDo($needLink);
313 }
314
315 if ( !$opts{i} && !$opts{f} && $Conf{BlackoutGoodCnt} >= 0
316              && $StatusHost{aliveCnt} >= $Conf{BlackoutGoodCnt} ) {
317     my($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
318     my($currHours) = $hour + $min / 60 + $sec / 3600;
319     my $blackout;
320
321     foreach my $p ( @{$Conf{BlackoutPeriods}} ) {
322         #
323         # Allow blackout to span midnight (specified by hourBegin
324         # being greater than hourEnd)
325         #
326         next if ( ref($p->{weekDays}) ne "ARRAY" 
327                     || !defined($p->{hourBegin})
328                     || !defined($p->{hourEnd})
329                 );
330         my $matchWday = $wday;
331         if ( $p->{hourBegin} > $p->{hourEnd} ) {
332             $blackout = $p->{hourBegin} <= $currHours
333                           || $currHours <= $p->{hourEnd};
334             if ( $currHours <= $p->{hourEnd} ) {
335                 #
336                 # This is after midnight, so decrement the weekday for the
337                 # weekday check (eg: Monday 11pm-1am means Monday 2300 to
338                 # Tuesday 0100, not Monday 2300-2400 plus Monday 0000-0100).
339                 #
340                 $matchWday--;
341                 $matchWday += 7 if ( $matchWday < 0 );
342             }
343         } else {
344             $blackout = $p->{hourBegin} <= $currHours
345                           && $currHours <= $p->{hourEnd};
346         }
347         if ( $blackout && grep($_ == $matchWday, @{$p->{weekDays}}) ) {
348 #           print(LOG $bpc->timeStamp, "skipping because of blackout"
349 #                      . " (alive $StatusHost{aliveCnt} times)\n");
350             print(STDERR "Skipping $client because of blackout\n")
351                             if ( $opts{v} );
352             NothingToDo($needLink);
353         }
354     }
355 }
356
357 if ( !$opts{i} && !$opts{f} && $StatusHost{backoffTime} > time ) {
358     printf(LOG "%sskipping because of user requested delay (%.1f hours left)\n",
359                 $bpc->timeStamp, ($StatusHost{backoffTime} - time) / 3600);
360     NothingToDo($needLink);
361 }
362
363 #
364 # Now see if there are any old backups we should delete
365 #
366 BackupExpire($client);
367
368 my(@lastIdxByLevel, $incrCntSinceFull);
369
370 #
371 # Read Backup information, and find times of the most recent full and
372 # incremental backups.  Also figure out which backup we will use
373 # as a starting point for an incremental.
374 #
375 @Backups = $bpc->BackupInfoRead($client);
376 for ( my $i = 0 ; $i < @Backups ; $i++ ) {
377     $needLink = 1 if ( $Backups[$i]{nFilesNew} eq ""
378                         || -f "$Dir/NewFileList.$Backups[$i]{num}" );
379     if ( $Backups[$i]{type} eq "full" ) {
380         $incrCntSinceFull = 0;
381         $lastBkupNum = $Backups[$i]{num};
382         $lastIdxByLevel[0] = $i;
383         if ( $lastFullTime < $Backups[$i]{startTime} ) {
384             $lastFullTime = $Backups[$i]{startTime};
385         }
386     } elsif ( $Backups[$i]{type} eq "incr" ) {
387         $incrCntSinceFull++;
388         $lastBkupNum = $Backups[$i]{num};
389         $lastIdxByLevel[$Backups[$i]{level}] = $i;
390         $lastIncrTime = $Backups[$i]{startTime}
391                 if ( $lastIncrTime < $Backups[$i]{startTime} );
392     } elsif ( $Backups[$i]{type} eq "partial" ) {
393         $partialIdx     = $i;
394         $lastPartial    = $Backups[$i]{startTime};
395         $partialNum     = $Backups[$i]{num};
396         $partialFileCnt = $Backups[$i]{nFiles};
397     }
398 }
399
400 #
401 # Decide whether we do nothing, or a full or incremental backup.
402 #
403 my $needs_full = (time - $lastFullTime > $Conf{FullPeriod} * 24 * 3600
404                && time - $lastIncrTime > $Conf{IncrPeriod} * 24 * 3600);
405 my $needs_incr = (time - $lastIncrTime > $Conf{IncrPeriod} * 24 * 3600
406                && time - $lastFullTime > $Conf{IncrPeriod} * 24 * 3600);
407
408 if ( $lastFullTime == 0
409         || $opts{f}
410         || (!$opts{i} && !$opts{I} && $needs_full)
411         || ( $opts{F} && $needs_incr) ) {
412     $type = "full";
413     $incrLevel = 0;
414     $incrBaseBkupNum = $lastBkupNum;
415 } elsif ( $opts{i}
416         || $needs_incr
417         || ($opts{I} && $needs_full) ) {
418     $type = "incr";
419     #
420     # For an incremental backup, figure out which level we should
421     # do and the index of the reference backup, which is the most
422     # recent backup at any lower level.
423     #
424     @{$Conf{IncrLevels}} = [$Conf{IncrLevels}]
425                             unless ref($Conf{IncrLevels}) eq "ARRAY";
426     @{$Conf{IncrLevels}} = [1] if ( !@{$Conf{IncrLevels}} );
427     $incrCntSinceFull = $incrCntSinceFull % @{$Conf{IncrLevels}};
428     $incrLevel = $Conf{IncrLevels}[$incrCntSinceFull];
429     for ( my $i = 0 ; $i < $incrLevel ; $i++ ) {
430         my $idx = $lastIdxByLevel[$i];
431         next if ( !defined($idx) );
432         if ( !defined($incrBaseTime)
433                 || $Backups[$idx]{startTime} > $incrBaseTime ) {
434             $incrBaseBkupNum = $Backups[$idx]{num};
435             $incrBaseLevel   = $Backups[$idx]{level};
436             $incrBaseTime    = $Backups[$idx]{startTime};
437         }
438     }
439     #
440     # Can't find any earlier lower-level backup!  Shouldn't
441     # happen - just do full instead
442     #
443     if ( !defined($incrBaseBkupNum) || $incrLevel < 1 ) {
444         $type = "full";
445         $incrBaseBkupNum = $lastBkupNum;
446     }
447 } else {
448     NothingToDo($needLink);
449 }
450
451 #
452 # Create top-level directories if they don't exist
453 #
454 foreach my $dir ( (
455             "$Conf{TopDir}",
456             "$Conf{TopDir}/pool",
457             "$Conf{TopDir}/cpool",
458             "$Conf{TopDir}/pc",
459             "$Conf{TopDir}/trash",
460         ) ) {
461     next if ( -d $dir );
462     mkpath($dir, 0, 0750);
463     if ( !-d $dir ) {
464         print("Failed to create $dir\n");
465         printf(LOG "%sFailed to create directory %s\n", $bpc->timeStamp, $dir);
466         print("link $clientURI\n") if ( $needLink );
467         exit(1);
468     } else {
469         printf(LOG "%sCreated directory %s\n", $bpc->timeStamp, $dir);
470     }
471 }
472
473 if ( !$bpc->HardlinkTest($Dir, "$TopDir/cpool") ) {
474     print(LOG $bpc->timeStamp, "Can't create a test hardlink between a file"
475                . " in $Dir and $TopDir/cpool.  Either these are different"
476                . " file systems, or this file system doesn't support hardlinks,"
477                . " or these directories don't exist, or there is a permissions"
478                . " problem, or the file system is out of inodes or full.  Use"
479                . " df, df -i, and ls -ld to check each of these possibilities."
480                . " Quitting...\n");
481     print("test hardlink between $Dir and $TopDir/cpool failed\n");
482     print("link $clientURI\n") if ( $needLink );
483     exit(1);
484 }
485
486 if ( !$opts{d} ) {
487     #
488     # In the non-DHCP case, make sure the host can be looked up
489     # via NS, or otherwise find the IP address via NetBios.
490     #
491     if ( $Conf{ClientNameAlias} ne "" ) {
492         $host = $Conf{ClientNameAlias};
493     } else {
494         $host = $client;
495     }
496     if ( !defined(gethostbyname($host)) ) {
497         #
498         # Ok, NS doesn't know about it.  Maybe it is a NetBios name
499         # instead.
500         #
501         print(STDERR "Name server doesn't know about $host; trying NetBios\n")
502                         if ( $opts{v} );
503         if ( !defined($hostIP = $bpc->NetBiosHostIPFind($host)) ) {
504             print(LOG $bpc->timeStamp, "Can't find host $host via netbios\n");
505             print("host not found\n");
506             exit(1);
507         }
508     } else {
509         $hostIP = $host;
510     }
511 }
512
513 #
514 # Check if $host is alive
515 #
516 my $delay = $bpc->CheckHostAlive($hostIP);
517 if ( $delay < 0 ) {
518     print(LOG $bpc->timeStamp, "no ping response\n");
519     print("no ping response\n");
520     print("link $clientURI\n") if ( $needLink );
521     exit(1);
522 } elsif ( $delay > $Conf{PingMaxMsec} ) {
523     printf(LOG "%sping too slow: %.4gmsec\n", $bpc->timeStamp, $delay);
524     printf("ping too slow: %.4gmsec (threshold is %gmsec)\n",
525                     $delay, $Conf{PingMaxMsec});
526     print("link $clientURI\n") if ( $needLink );
527     exit(1);
528 }
529
530 #
531 # Make sure it is really the machine we expect (only for fixed addresses,
532 # since we got the DHCP address above).
533 #
534 if ( !$opts{d} && (my $errMsg = CorrectHostCheck($hostIP, $host)) ) {
535     print(LOG $bpc->timeStamp, "dump failed: $errMsg\n");
536     print("dump failed: $errMsg\n");
537     exit(1);
538 } elsif ( $opts{d} ) {
539     print(LOG $bpc->timeStamp, "$host is dhcp $hostIP, user is $user\n");
540 }
541
542 #
543 # Get a clean directory $Dir/new
544 #
545 $bpc->RmTreeDefer("$TopDir/trash", "$Dir/new") if ( -d "$Dir/new" );
546
547 #
548 # Setup file extension for compression and open XferLOG output file
549 #
550 if ( $Conf{CompressLevel} && !BackupPC::FileZIO->compOk ) {
551     print(LOG $bpc->timeStamp, "dump failed: can't find Compress::Zlib\n");
552     print("dump failed: can't find Compress::Zlib\n");
553     exit(1);
554 }
555 my $fileExt = $Conf{CompressLevel} > 0 ? ".z" : "";
556 my $XferLOG = BackupPC::FileZIO->open("$Dir/XferLOG$fileExt", 1,
557                                      $Conf{CompressLevel});
558 if ( !defined($XferLOG) ) {
559     print(LOG $bpc->timeStamp, "dump failed: unable to open/create"
560                              . " $Dir/XferLOG$fileExt\n");
561     print("dump failed: unable to open/create $Dir/XferLOG$fileExt\n");
562     exit(1);
563 }
564
565 #
566 # Ignore the partial dump in the case of an incremental
567 # or when the partial is too old.  A partial is a partial full.
568 #
569 if ( $type ne "full" || time - $lastPartial > $Conf{PartialAgeMax} * 24*3600 ) {
570     $partialNum = undef;
571     $partialIdx = -1;
572 }
573
574 #
575 # If this is a partial, copy the old XferLOG file
576 #
577 if ( $partialNum ) {
578     my($compress, $fileName);
579     if ( -f "$Dir/XferLOG.$partialNum.z" ) {
580         $fileName = "$Dir/XferLOG.$partialNum.z";
581         $compress = 1;
582     } elsif ( -f "$Dir/XferLOG.$partialNum" ) {
583         $fileName = "$Dir/XferLOG.$partialNum";
584         $compress = 0;
585     }
586     if ( my $oldLOG = BackupPC::FileZIO->open($fileName, 0, $compress) ) {
587         my $data;
588         while ( $oldLOG->read(\$data, 65536) > 0 ) {
589             $XferLOG->write(\$data);
590         }
591         $oldLOG->close;
592     }
593 }
594
595 $XferLOG->writeTeeStderr(1) if ( $opts{v} );
596 unlink("$Dir/NewFileList") if ( -f "$Dir/NewFileList" );
597
598 my $startTime     = time();
599 my $tarErrs       = 0;
600 my $nFilesExist   = 0;
601 my $sizeExist     = 0;
602 my $sizeExistComp = 0;
603 my $nFilesTotal   = 0;
604 my $sizeTotal     = 0;
605 my($logMsg, %stat, $xfer, $ShareNames, $noFilesErr);
606 my $newFilesFH;
607
608 $ShareNames = BackupPC::Xfer::getShareNames(\%Conf);
609
610 #
611 # Run an optional pre-dump command
612 #
613 UserCommandRun("DumpPreUserCmd");
614 if ( $? && $Conf{UserCmdCheckStatus} ) {
615     print(LOG $bpc->timeStamp,
616             "DumpPreUserCmd returned error status $?... exiting\n");
617     $XferLOG->write(\"DumpPreUserCmd returned error status $?... exiting\n");
618     $stat{hostError} = "DumpPreUserCmd returned error status $?";
619     BackupFailCleanup();
620 }
621 $NeedPostCmd = 1;
622
623 #
624 # Now backup each of the shares
625 #
626 for my $shareName ( @$ShareNames ) {
627     local(*RH, *WH);
628
629     #
630     # Convert $shareName to utf8 octets
631     #
632     $shareName = encode("utf8", $shareName);
633     $stat{xferOK} = $stat{hostAbort} = undef;
634     $stat{hostError} = $stat{lastOutputLine} = undef;
635     if ( -d "$Dir/new/$shareName" ) {
636         print(LOG $bpc->timeStamp,
637                   "unexpected repeated share name $shareName skipped\n");
638         next;
639     }
640
641     UserCommandRun("DumpPreShareCmd", $shareName);
642     if ( $? && $Conf{UserCmdCheckStatus} ) {
643         print(LOG $bpc->timeStamp,
644                 "DumpPreShareCmd returned error status $?... exiting\n");
645         UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
646         $XferLOG->write(\"DumpPreShareCmd returned error status $?... exiting\n");
647         $stat{hostError} = "DumpPreShareCmd returned error status $?";
648         BackupFailCleanup();
649     }
650
651     $xfer = BackupPC::Xfer::create($Conf{XferMethod}, $bpc);
652     if ( !defined($xfer) ) {
653         my $errStr = BackupPC::Xfer::errStr();
654         print(LOG $bpc->timeStamp, "dump failed: $errStr\n");
655         UserCommandRun("DumpPostShareCmd", $shareName) if ( $NeedPostCmd );
656         UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
657         $XferLOG->write(\"BackupPC::Xfer::create failed: $errStr\n");
658         $stat{hostError} = $errStr;
659         BackupFailCleanup();
660     }
661
662     my $useTar = $xfer->useTar;
663
664     if ( $useTar ) {
665         #
666         # This xfer method outputs a tar format file, so we start a
667         # BackupPC_tarExtract to extract the data.
668         #
669         # Create a socketpair to connect the Xfer method to BackupPC_tarExtract
670         # WH is the write handle for writing, provided to the transport
671         # program, and RH is the other end of the socket for reading,
672         # provided to BackupPC_tarExtract.
673         #
674         if ( socketpair(RH, WH, AF_UNIX, SOCK_STREAM, PF_UNSPEC) ) {
675             shutdown(RH, 1);    # no writing to this socket
676             shutdown(WH, 0);    # no reading from this socket
677             setsockopt(RH, SOL_SOCKET, SO_RCVBUF, 8 * 65536);
678             setsockopt(WH, SOL_SOCKET, SO_SNDBUF, 8 * 65536);
679         } else {
680             #
681             # Default to pipe() if socketpair() doesn't work.
682             #
683             pipe(RH, WH);
684         }
685
686         #
687         # fork a child for BackupPC_tarExtract.  TAR is a file handle
688         # on which we (the parent) read the stdout & stderr from
689         # BackupPC_tarExtract.
690         #
691         if ( !defined($tarPid = open(TAR, "-|")) ) {
692             print(LOG $bpc->timeStamp, "can't fork to run tar\n");
693             print("can't fork to run tar\n");
694             close(RH);
695             close(WH);
696             last;
697         }
698         binmode(TAR);
699         if ( !$tarPid ) {
700             #
701             # This is the tar child.  Close the write end of the pipe,
702             # clone STDERR to STDOUT, clone STDIN from RH, and then
703             # exec BackupPC_tarExtract.
704             #
705             setpgrp 0,0;
706             close(WH);
707             close(STDERR);
708             open(STDERR, ">&STDOUT");
709             close(STDIN);
710             open(STDIN, "<&RH");
711             alarm(0);
712             exec("$BinDir/BackupPC_tarExtract", $client, $shareName,
713                          $Conf{CompressLevel});
714             print(LOG $bpc->timeStamp,
715                         "can't exec $BinDir/BackupPC_tarExtract\n");
716             exit(0);
717         }
718     } elsif ( !defined($newFilesFH) ) {
719         #
720         # We need to create the NewFileList output file
721         #
722         local(*NEW_FILES);
723         open(NEW_FILES, ">", "$TopDir/pc/$client/NewFileList")
724                      || die("can't open $TopDir/pc/$client/NewFileList");
725         $newFilesFH = *NEW_FILES;
726         binmode(NEW_FILES);
727     }
728
729     #
730     # Run the transport program
731     #
732     $xfer->args({
733         host         => $host,
734         client       => $client,
735         hostIP       => $hostIP,
736         shareName    => $shareName,
737         pipeRH       => *RH,
738         pipeWH       => *WH,
739         XferLOG      => $XferLOG,
740         newFilesFH   => $newFilesFH,
741         outDir       => $Dir,
742         type         => $type,
743         incrBaseTime => $incrBaseTime,
744         incrBaseBkupNum => $incrBaseBkupNum,
745         backups      => \@Backups,
746         compress     => $Conf{CompressLevel},
747         XferMethod   => $Conf{XferMethod},
748         logLevel     => $Conf{XferLogLevel},
749         partialNum   => $partialNum,
750         pidHandler   => \&pidHandler,
751         completionPercent => \&completionPercent,
752     });
753
754     if ( !defined($logMsg = $xfer->start()) ) {
755         my $errStr = "xfer start failed: " . $xfer->errStr . "\n";
756         print(LOG $bpc->timeStamp, $errStr);
757         #
758         # kill off the tar process, first nicely then forcefully
759         #
760         if ( $tarPid > 0 ) {
761             kill($bpc->sigName2num("INT"), $tarPid);
762             sleep(1);
763             kill($bpc->sigName2num("KILL"), $tarPid);
764         }
765         if ( @xferPid ) {
766             kill($bpc->sigName2num("INT"), @xferPid);
767             sleep(1);
768             kill($bpc->sigName2num("KILL"), @xferPid);
769         }
770         UserCommandRun("DumpPostShareCmd", $shareName) if ( $NeedPostCmd );
771         UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
772         $XferLOG->write(\"xfer start failed: $errStr\n");
773         $stat{hostError} = $errStr;
774         BackupFailCleanup();
775     }
776
777     @xferPid = $xfer->xferPid;
778
779     if ( $useTar ) {
780         #
781         # The parent must close both handles on the pipe since the children
782         # are using these handles now.
783         #
784         close(RH);
785         close(WH);
786     }
787     print(LOG $bpc->timeStamp, $logMsg, "\n");
788     $XferLOG->write(\"$logMsg\n");
789     print("started $type dump, share=$shareName\n");
790
791     pidHandler(@xferPid);
792
793     if ( $useTar ) {
794         #
795         # Parse the output of the transfer program and BackupPC_tarExtract
796         # while they run.  Since we might be reading from two or more children
797         # we use a select.
798         #
799         my($FDread, $tarOut, $mesg);
800         vec($FDread, fileno(TAR), 1) = 1;
801         $xfer->setSelectMask(\$FDread);
802
803         SCAN: while ( 1 ) {
804             my $ein = $FDread;
805             last if ( $FDread =~ /^\0*$/ );
806             select(my $rout = $FDread, undef, $ein, undef);
807             if ( vec($rout, fileno(TAR), 1) ) {
808                 if ( sysread(TAR, $mesg, 8192) <= 0 ) {
809                     vec($FDread, fileno(TAR), 1) = 0;
810                     close(TAR);
811                 } else {
812                     $tarOut .= $mesg;
813                 }
814             }
815             while ( $tarOut =~ /(.*?)[\n\r]+(.*)/s ) {
816                 $_ = $1;
817                 $tarOut = $2;
818                 if ( /^  / ) {
819                     $XferLOG->write(\"$_\n");
820                 } else {
821                     $XferLOG->write(\"tarExtract: $_\n");
822                 }
823                 if ( /^BackupPC_tarExtact aborting \((.*)\)/ ) {
824                     $stat{hostError} = $1;
825                 }
826                 if ( /^Done: (\d+) errors, (\d+) filesExist, (\d+) sizeExist, (\d+) sizeExistComp, (\d+) filesTotal, (\d+) sizeTotal/ ) {
827                     $tarErrs       += $1;
828                     $nFilesExist   += $2;
829                     $sizeExist     += $3;
830                     $sizeExistComp += $4;
831                     $nFilesTotal   += $5;
832                     $sizeTotal     += $6;
833                 }
834             }
835             last if ( !$xfer->readOutput(\$FDread, $rout) );
836             while ( my $str = $xfer->logMsgGet ) {
837                 print(LOG $bpc->timeStamp, "xfer: $str\n");
838             }
839             if ( $xfer->getStats->{fileCnt} == 1 ) {
840                 #
841                 # Make sure it is still the machine we expect.  We do this while
842                 # the transfer is running to avoid a potential race condition if
843                 # the ip address was reassigned by dhcp just before we started
844                 # the transfer.
845                 #
846                 if ( my $errMsg = CorrectHostCheck($hostIP, $host) ) {
847                     $stat{hostError} = $errMsg if ( $stat{hostError} eq "" );
848                     last SCAN;
849                 }
850             }
851         }
852     } else {
853         #
854         # otherwise the xfer module does everything for us
855         #
856         my @results = $xfer->run();
857         $tarErrs       += $results[0];
858         $nFilesExist   += $results[1];
859         $sizeExist     += $results[2];
860         $sizeExistComp += $results[3];
861         $nFilesTotal   += $results[4];
862         $sizeTotal     += $results[5];
863     }
864
865     #
866     # Merge the xfer status (need to accumulate counts)
867     #
868     my $newStat = $xfer->getStats;
869     if ( $newStat->{fileCnt} == 0 ) {
870        $noFilesErr ||= "No files dumped for share $shareName";
871     }
872     foreach my $k ( (keys(%stat), keys(%$newStat)) ) {
873         next if ( !defined($newStat->{$k}) );
874         if ( $k =~ /Cnt$/ ) {
875             $stat{$k} += $newStat->{$k};
876             delete($newStat->{$k});
877             next;
878         }
879         if ( !defined($stat{$k}) ) {
880             $stat{$k} = $newStat->{$k};
881             delete($newStat->{$k});
882             next;
883         }
884     }
885
886     if ( $NeedPostCmd ) {
887         UserCommandRun("DumpPostShareCmd", $shareName);
888         if ( $? && $Conf{UserCmdCheckStatus} ) {
889             print(LOG $bpc->timeStamp,
890                     "DumpPostShareCmd returned error status $?... exiting\n");
891             $stat{hostError} = "DumpPostShareCmd returned error status $?";
892         }
893     }
894
895     $stat{xferOK} = 0 if ( $stat{hostError} || $stat{hostAbort} );
896     if ( !$stat{xferOK} ) {
897         #
898         # kill off the transfer program, first nicely then forcefully
899         #
900         if ( @xferPid ) {
901             kill($bpc->sigName2num("INT"), @xferPid);
902             sleep(1);
903             kill($bpc->sigName2num("KILL"), @xferPid);
904         }
905         #
906         # kill off the tar process, first nicely then forcefully
907         #
908         if ( $tarPid > 0 ) {
909             kill($bpc->sigName2num("INT"), $tarPid);
910             sleep(1);
911             kill($bpc->sigName2num("KILL"), $tarPid);
912         }
913         #
914         # don't do any more shares on this host
915         #
916         last;
917     }
918 }
919
920 #
921 # If this is a full, and any share had zero files then consider the dump bad
922 #
923 if ( $type eq "full" && $stat{hostError} eq ""
924             && length($noFilesErr) && $Conf{BackupZeroFilesIsFatal} ) {
925     $stat{hostError} = $noFilesErr;
926     $stat{xferOK} = 0;
927 }
928
929 $stat{xferOK} = 0 if ( $Abort );
930
931 #
932 # If there is no "new" directory then the backup is bad
933 #
934 if ( $stat{xferOK} && !-d "$Dir/new" ) {
935     $stat{hostError} = "No backup directory $Dir/new"
936                             if ( $stat{hostError} eq "" );
937     $stat{xferOK} = 0;
938 }
939
940 #
941 # Do one last check to make sure it is still the machine we expect.
942 #
943 if ( $stat{xferOK} && (my $errMsg = CorrectHostCheck($hostIP, $host)) ) {
944     $stat{hostError} = $errMsg;
945     $stat{xferOK} = 0;
946 }
947
948 UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
949 if ( $? && $Conf{UserCmdCheckStatus} ) {
950     print(LOG $bpc->timeStamp,
951             "DumpPostUserCmd returned error status $?... exiting\n");
952     $stat{hostError} = "DumpPostUserCmd returned error status $?";
953     $stat{xferOK} = 0;
954 }
955 close($newFilesFH) if ( defined($newFilesFH) );
956
957 my $endTime = time();
958
959 #
960 # If the dump failed, clean up
961 #
962 if ( !$stat{xferOK} ) {
963     $stat{hostError} = $stat{lastOutputLine} if ( $stat{hostError} eq "" );
964     if ( $stat{hostError} ) {
965         print(LOG $bpc->timeStamp,
966                   "Got fatal error during xfer ($stat{hostError})\n");
967         $XferLOG->write(\"Got fatal error during xfer ($stat{hostError})\n");
968     }
969     if ( !$Abort ) {
970         #
971         # wait a short while and see if the system is still alive
972         #
973         sleep(5);
974         if ( $bpc->CheckHostAlive($hostIP) < 0 ) {
975             $stat{hostAbort} = 1;
976         }
977         if ( $stat{hostAbort} ) {
978             $stat{hostError} = "lost network connection during backup";
979         }
980         print(LOG $bpc->timeStamp, "Backup aborted ($stat{hostError})\n");
981         $XferLOG->write(\"Backup aborted ($stat{hostError})\n");
982     } else {
983         $XferLOG->write(\"Backup aborted by user signal\n");
984     }
985
986     #
987     # Close the log file and call BackupFailCleanup, which exits.
988     #
989     BackupFailCleanup();
990 }
991
992 my $newNum = BackupSave();
993
994 my $otherCount = $stat{xferErrCnt} - $stat{xferBadFileCnt}
995                                    - $stat{xferBadShareCnt};
996 $stat{fileCnt}         ||= 0;
997 $stat{byteCnt}         ||= 0;
998 $stat{xferErrCnt}      ||= 0;
999 $stat{xferBadFileCnt}  ||= 0;
1000 $stat{xferBadShareCnt} ||= 0;
1001 print(LOG $bpc->timeStamp,
1002           "$type backup $newNum complete, $stat{fileCnt} files,"
1003         . " $stat{byteCnt} bytes,"
1004         . " $stat{xferErrCnt} xferErrs ($stat{xferBadFileCnt} bad files,"
1005         . " $stat{xferBadShareCnt} bad shares, $otherCount other)\n");
1006
1007 BackupExpire($client);
1008
1009 print("$type backup complete\n");
1010
1011 ###########################################################################
1012 # Subroutines
1013 ###########################################################################
1014
1015 sub NothingToDo
1016 {
1017     my($needLink) = @_;
1018
1019     print("nothing to do\n");
1020     print("link $clientURI\n") if ( $needLink );
1021     exit(0);
1022 }
1023
1024 sub catch_signal
1025 {
1026     my $sigName = shift;
1027
1028     #
1029     # The first time we receive a signal we try to gracefully
1030     # abort the backup.  This allows us to keep a partial dump
1031     # with the in-progress file deleted and attribute caches
1032     # flushed to disk etc.
1033     #
1034     if ( !length($SigName) ) {
1035         my $reason;
1036         if ( $sigName eq "INT" ) {
1037             $reason = "aborted by user (signal=$sigName)";
1038         } else {
1039             $reason = "aborted by signal=$sigName";
1040         }
1041         if ( $Pid == $$ ) {
1042             #
1043             # Parent logs a message
1044             #
1045             print(LOG $bpc->timeStamp,
1046                     "Aborting backup up after signal $sigName\n");
1047
1048             #
1049             # Tell xfer to abort, but only if we actually started one
1050             #
1051             $xfer->abort($reason) if ( defined($xfer) );
1052
1053             #
1054             # Send ALRMs to BackupPC_tarExtract if we are using it
1055             #
1056             if ( $tarPid > 0 ) {
1057                 kill($bpc->sigName2num("ARLM"), $tarPid);
1058             }
1059
1060             #
1061             # Schedule a 20 second timer in case the clean
1062             # abort doesn't complete
1063             #
1064             alarm(20);
1065         } else {
1066             #
1067             # Children ignore anything other than ALRM and INT
1068             #
1069             if ( $sigName ne "ALRM" && $sigName ne "INT" ) {
1070                 return;
1071             }
1072
1073             #
1074             # The child also tells xfer to abort
1075             #
1076             $xfer->abort($reason);
1077
1078             #
1079             # Schedule a 15 second timer in case the clean
1080             # abort doesn't complete
1081             #
1082             alarm(15);
1083         }
1084         $SigName = $sigName;
1085         $Abort = 1;
1086         return;
1087     }
1088
1089     #
1090     # This is a second signal: time to clean up.
1091     #
1092     if ( $Pid != $$ && ($sigName eq "ALRM" || $sigName eq "INT") ) {
1093         #
1094         # Children quit quietly on ALRM or INT
1095         #
1096         exit(1)
1097     }
1098
1099     #
1100     # Ignore other signals in children
1101     #
1102     return if ( $Pid != $$ );
1103
1104     $SIG{$sigName} = 'IGNORE';
1105     UserCommandRun("DumpPostUserCmd") if ( $NeedPostCmd );
1106     $XferLOG->write(\"exiting after signal $sigName\n");
1107     if ( @xferPid ) {
1108         kill($bpc->sigName2num("INT"), @xferPid);
1109         sleep(1);
1110         kill($bpc->sigName2num("KILL"), @xferPid);
1111     }
1112     if ( $tarPid > 0 ) {
1113         kill($bpc->sigName2num("INT"), $tarPid);
1114         sleep(1);
1115         kill($bpc->sigName2num("KILL"), $tarPid);
1116     }
1117     if ( $sigName eq "INT" ) {
1118         $stat{hostError} = "aborted by user (signal=$sigName)";
1119     } else {
1120         $stat{hostError} = "received signal=$sigName";
1121     }
1122     BackupFailCleanup();
1123 }
1124
1125 sub CheckForNewFiles
1126 {
1127     if ( -f _ && $File::Find::name !~ /\/fattrib$/ ) {
1128         $nFilesTotal++;
1129     } elsif ( -d _ ) {
1130         #
1131         # No need to check entire tree
1132         #
1133         $File::Find::prune = 1 if ( $nFilesTotal );
1134     }
1135 }
1136
1137 sub BackupFailCleanup
1138 {
1139     my $fileExt = $Conf{CompressLevel} > 0 ? ".z" : "";
1140     my $keepPartial = 0;
1141
1142     #
1143     # We keep this backup if it is a full and we actually backed
1144     # up some files.  If the prior backup was a partial too, we
1145     # only keep this backup if it has more files than the previous
1146     # partial.
1147     #
1148     if ( $type eq "full" ) {
1149         if ( $nFilesTotal == 0 && $xfer->getStats->{fileCnt} == 0 ) {
1150             #
1151             # Xfer didn't report any files, but check in the new
1152             # directory just in case.
1153             #
1154             find(\&CheckForNewFiles, "$Dir/new");
1155         }
1156         my $str;
1157         if ( $nFilesTotal > $partialFileCnt
1158                 || $xfer->getStats->{fileCnt} > $partialFileCnt ) {
1159             #
1160             # If the last backup wasn't a partial then
1161             # $partialFileCnt is undefined, so the above
1162             # test is simply $nFilesTotal > 0
1163             #
1164             $keepPartial = 1;
1165             if ( $partialFileCnt ) {
1166                 $str = "Saving this as a partial backup\n";
1167             } else {
1168                 $str = sprintf("Saving this as a partial backup, replacing the"
1169                          . " prior one (got %d and %d files versus %d)\n",
1170                          $nFilesTotal, $xfer->getStats->{fileCnt}, $partialFileCnt);
1171             }
1172         } else {
1173             $str = sprintf("Not saving this as a partial backup since it has fewer"
1174                      . " files than the prior one (got %d and %d files versus %d)\n",
1175                      $nFilesTotal, $xfer->getStats->{fileCnt}, $partialFileCnt);
1176         }
1177         $XferLOG->write(\$str);
1178     }
1179
1180     #
1181     # Don't keep partials if they are disabled
1182     #
1183     $keepPartial = 0 if ( $Conf{PartialAgeMax} < 0 );
1184
1185     if ( !$keepPartial ) {
1186         #
1187         # No point in saving this dump; get rid of eveything.
1188         #
1189         $XferLOG->close();
1190         unlink("$Dir/timeStamp.level0")    if ( -f "$Dir/timeStamp.level0" );
1191         unlink("$Dir/SmbLOG.bad")          if ( -f "$Dir/SmbLOG.bad" );
1192         unlink("$Dir/SmbLOG.bad$fileExt")  if ( -f "$Dir/SmbLOG.bad$fileExt" );
1193         unlink("$Dir/XferLOG.bad")         if ( -f "$Dir/XferLOG.bad" );
1194         unlink("$Dir/XferLOG.bad$fileExt") if ( -f "$Dir/XferLOG.bad$fileExt" );
1195         unlink("$Dir/NewFileList")         if ( -f "$Dir/NewFileList" );
1196         rename("$Dir/XferLOG$fileExt", "$Dir/XferLOG.bad$fileExt");
1197         $bpc->RmTreeDefer("$TopDir/trash", "$Dir/new") if ( -d "$Dir/new" );
1198         print("dump failed: $stat{hostError}\n");
1199         $XferLOG->close();
1200         print("link $clientURI\n") if ( $needLink );
1201         exit(1);
1202     }
1203     #
1204     # Ok, now we should save this as a partial dump
1205     #
1206     $type = "partial";
1207     my $newNum = BackupSave();
1208     print("dump failed: $stat{hostError}\n");
1209     print("link $clientURI\n") if ( $needLink );
1210     print(LOG $bpc->timeStamp, "Saved partial dump $newNum\n");
1211     exit(2);
1212 }
1213
1214 #
1215 # Decide which old backups should be expired by moving them
1216 # to $TopDir/trash.
1217 #
1218 sub BackupExpire
1219 {
1220     my($client) = @_;
1221     my($Dir) = "$TopDir/pc/$client";
1222     my(@Backups) = $bpc->BackupInfoRead($client);
1223     my($cntFull, $cntIncr, $firstFull, $firstIncr, $oldestIncr,
1224        $oldestFull, $changes);
1225
1226     if ( $Conf{FullKeepCnt} <= 0 ) {
1227         print(LOG $bpc->timeStamp,
1228                   "Invalid value for \$Conf{FullKeepCnt}=$Conf{FullKeepCnt}\n");
1229         print(STDERR
1230             "Invalid value for \$Conf{FullKeepCnt}=$Conf{FullKeepCnt}\n")
1231                             if ( $opts{v} );
1232         return;
1233     }
1234     while ( 1 ) {
1235         $cntFull = $cntIncr = 0;
1236         $oldestIncr = $oldestFull = 0;
1237         for ( my $i = 0 ; $i < @Backups ; $i++ ) {
1238             if ( $Backups[$i]{type} eq "full" ) {
1239                 $firstFull = $i if ( $cntFull == 0 );
1240                 $cntFull++;
1241             } elsif ( $Backups[$i]{type} eq "incr" ) {
1242                 $firstIncr = $i if ( $cntIncr == 0 );
1243                 $cntIncr++;
1244             }
1245         }
1246         $oldestIncr = (time - $Backups[$firstIncr]{startTime}) / (24 * 3600)
1247                         if ( $cntIncr > 0 );
1248         $oldestFull = (time - $Backups[$firstFull]{startTime}) / (24 * 3600)
1249                         if ( $cntFull > 0 );
1250
1251         #
1252         # With multi-level incrementals, several of the following
1253         # incrementals might depend upon this one, so we have to
1254         # delete all of the them.  Figure out if that is possible
1255         # by counting the number of consecutive incrementals that
1256         # are unfilled and have a level higher than this one.
1257         #
1258         my $cntIncrDel = 1;
1259         my $earliestIncr = $oldestIncr;
1260
1261         for ( my $i = $firstIncr + 1 ; $i < @Backups ; $i++ ) {
1262             last if ( $Backups[$i]{level} <= $Backups[$firstIncr]{level}
1263                    || !$Backups[$i]{noFill} );
1264             $cntIncrDel++;
1265             $earliestIncr = (time - $Backups[$i]{startTime}) / (24 * 3600);
1266         }
1267
1268         if ( $cntIncr >= $Conf{IncrKeepCnt} + $cntIncrDel
1269                 || ($cntIncr >= $Conf{IncrKeepCntMin} + $cntIncrDel
1270                     && $earliestIncr > $Conf{IncrAgeMax}) ) {
1271             #
1272             # Only delete an incr backup if the Conf settings are satisfied
1273             # for all $cntIncrDel incrementals.  Since BackupRemove() does
1274             # a splice() we need to do the deletes in the reverse order.
1275             # 
1276             for ( my $i = $firstIncr + $cntIncrDel - 1 ;
1277                     $i >= $firstIncr ; $i-- ) {
1278                 print(LOG $bpc->timeStamp,
1279                           "removing incr backup $Backups[$i]{num}\n");
1280                 BackupRemove($client, \@Backups, $i);
1281                 $changes++;
1282             }
1283             next;
1284         }
1285
1286         #
1287         # Delete any old full backups, according to $Conf{FullKeepCntMin}
1288         # and $Conf{FullAgeMax}.
1289         #
1290         # First make sure that $Conf{FullAgeMax} is at least bigger
1291         # than $Conf{FullPeriod} * $Conf{FullKeepCnt}, including
1292         # the exponential array case.
1293         #
1294         my $fullKeepCnt = $Conf{FullKeepCnt};
1295         $fullKeepCnt = [$fullKeepCnt] if ( ref($fullKeepCnt) ne "ARRAY" );
1296         my $fullAgeMax;
1297         my $fullPeriod = int(0.5 + $Conf{FullPeriod});
1298         $fullPeriod = 7 if ( $fullPeriod <= 0 );
1299         for ( my $i = 0 ; $i < @$fullKeepCnt ; $i++ ) {
1300             $fullAgeMax += $fullKeepCnt->[$i] * $fullPeriod;
1301             $fullPeriod *= 2;
1302         }
1303         $fullAgeMax += $fullPeriod;     # add some buffer
1304
1305         if ( $cntFull > $Conf{FullKeepCntMin}
1306                && $oldestFull > $Conf{FullAgeMax}
1307                && $oldestFull > $fullAgeMax
1308                && $Conf{FullKeepCntMin} > 0
1309                && $Conf{FullAgeMax} > 0
1310                && (@Backups <= $firstFull + 1
1311                         || !$Backups[$firstFull + 1]{noFill}) ) {
1312             #
1313             # Only delete a full backup if the Conf settings are satisfied.
1314             # We also must make sure that either this backup is the most
1315             # recent one, or the next backup is filled.
1316             # (We can't deleted a full backup if the next backup is not
1317             # filled.)
1318             # 
1319             print(LOG $bpc->timeStamp,
1320                    "removing old full backup $Backups[$firstFull]{num}\n");
1321             BackupRemove($client, \@Backups, $firstFull);
1322             $changes++;
1323             next;
1324         }
1325
1326         #
1327         # Do new-style full backup expiry, which includes the the case
1328         # where $Conf{FullKeepCnt} is an array.
1329         #
1330         last if ( !BackupFullExpire($client, \@Backups) );
1331         $changes++;
1332     }
1333     $bpc->BackupInfoWrite($client, @Backups) if ( $changes );
1334 }
1335
1336 #
1337 # Handle full backup expiry, using exponential periods.
1338 #
1339 sub BackupFullExpire
1340 {
1341     my($client, $Backups) = @_;
1342     my $fullCnt = 0;
1343     my $fullPeriod = $Conf{FullPeriod};
1344     my $origFullPeriod = $fullPeriod;
1345     my $fullKeepCnt = $Conf{FullKeepCnt};
1346     my $fullKeepIdx = 0;
1347     my(@delete, @fullList);
1348
1349     #
1350     # Don't delete anything if $Conf{FullPeriod} or $Conf{FullKeepCnt} are
1351     # not defined - possibly a corrupted config.pl file.
1352     #
1353     return if ( !defined($Conf{FullPeriod}) || !defined($Conf{FullKeepCnt}) );
1354
1355     #
1356     # If regular backups are still disabled with $Conf{FullPeriod} < 0,
1357     # we still expire backups based on a typical FullPeriod value - weekly.
1358     #
1359     $fullPeriod = 7 if ( $fullPeriod <= 0 );
1360
1361     $fullKeepCnt = [$fullKeepCnt] if ( ref($fullKeepCnt) ne "ARRAY" );
1362
1363     for ( my $i = 0 ; $i < @$Backups ; $i++ ) {
1364         next if ( $Backups->[$i]{type} ne "full" );
1365         push(@fullList, $i);
1366     }
1367     for ( my $k = @fullList - 1 ; $k >= 0 ; $k-- ) {
1368         my $i = $fullList[$k];
1369         my $prevFull = $fullList[$k-1] if ( $k > 0 );
1370         #
1371         # Don't delete any full that is followed by an unfilled backup,
1372         # since it is needed for restore.
1373         #
1374         my $noDelete = $i + 1 < @$Backups ? $Backups->[$i+1]{noFill} : 0;
1375
1376         if ( !$noDelete && 
1377               ($fullKeepIdx >= @$fullKeepCnt
1378               || $k > 0
1379                  && $fullKeepIdx > 0
1380                  && $Backups->[$i]{startTime} - $Backups->[$prevFull]{startTime}
1381                              < ($fullPeriod - $origFullPeriod / 2) * 24 * 3600
1382                )
1383             ) {
1384             #
1385             # Delete the full backup
1386             #
1387             #print("Deleting backup $i ($prevFull)\n");
1388             unshift(@delete, $i);
1389         } else {
1390             $fullCnt++;
1391             while ( $fullKeepIdx < @$fullKeepCnt
1392                      && $fullCnt >= $fullKeepCnt->[$fullKeepIdx] ) {
1393                 $fullKeepIdx++;
1394                 $fullCnt = 0;
1395                 $fullPeriod = 2 * $fullPeriod;
1396             }
1397         }
1398     }
1399     #
1400     # Now actually delete the backups
1401     #
1402     for ( my $i = @delete - 1 ; $i >= 0 ; $i-- ) {
1403         print(LOG $bpc->timeStamp,
1404                "removing full backup $Backups->[$delete[$i]]{num}\n");
1405         BackupRemove($client, $Backups, $delete[$i]);
1406     }
1407     return @delete;
1408 }
1409
1410 #
1411 # Removes any partial backups
1412 #
1413 sub BackupPartialRemove
1414 {
1415     my($client, $Backups) = @_;
1416
1417     for ( my $i = @$Backups - 1 ; $i >= 0 ; $i-- ) {
1418         next if ( $Backups->[$i]{type} ne "partial" );
1419         BackupRemove($client, $Backups, $i);
1420     }
1421 }
1422
1423 sub BackupSave
1424 {
1425     my @Backups = $bpc->BackupInfoRead($client);
1426     my $num  = -1;
1427     my $newFilesFH;
1428
1429     #
1430     # Since we got a good backup we should remove any partial dumps
1431     # (the new backup might also be a partial, but that's ok).
1432     #
1433     BackupPartialRemove($client, \@Backups);
1434     $needLink = 1 if ( -f "$Dir/NewFileList" );
1435
1436     #
1437     # Number the new backup
1438     #
1439     for ( my $i = 0 ; $i < @Backups ; $i++ ) {
1440         $num = $Backups[$i]{num} if ( $num < $Backups[$i]{num} );
1441     }
1442     $num++;
1443     $bpc->RmTreeDefer("$TopDir/trash", "$Dir/$num") if ( -d "$Dir/$num" );
1444     if ( !rename("$Dir/new", "$Dir/$num") ) {
1445         print(LOG $bpc->timeStamp, "Rename $Dir/new -> $Dir/$num failed\n");
1446         $stat{xferOK} = 0;
1447         return;
1448     }
1449
1450     #
1451     # Add the new backup information to the backup file
1452     #
1453     my $i = @Backups;
1454     $Backups[$i]{num}           = $num;
1455     $Backups[$i]{type}          = $type;
1456     $Backups[$i]{startTime}     = $startTime;
1457     $Backups[$i]{endTime}       = $endTime;
1458     $Backups[$i]{size}          = $sizeTotal;
1459     $Backups[$i]{nFiles}        = $nFilesTotal;
1460     $Backups[$i]{xferErrs}      = $stat{xferErrCnt} || 0;
1461     $Backups[$i]{xferBadFile}   = $stat{xferBadFileCnt} || 0;
1462     $Backups[$i]{xferBadShare}  = $stat{xferBadShareCnt} || 0;
1463     $Backups[$i]{nFilesExist}   = $nFilesExist;
1464     $Backups[$i]{sizeExist}     = $sizeExist;
1465     $Backups[$i]{sizeExistComp} = $sizeExistComp;
1466     $Backups[$i]{tarErrs}       = $tarErrs;
1467     $Backups[$i]{compress}      = $Conf{CompressLevel};
1468     $Backups[$i]{noFill}        = $type eq "incr" ? 1 : 0;
1469     $Backups[$i]{level}         = $incrLevel;
1470     $Backups[$i]{mangle}        = 1;     # name mangling always on for v1.04+
1471     $Backups[$i]{xferMethod}    = $Conf{XferMethod};
1472     $Backups[$i]{charset}       = $Conf{ClientCharset};
1473     $Backups[$i]{version}       = $bpc->Version();
1474     #
1475     # Save the main backups file
1476     #
1477     $bpc->BackupInfoWrite($client, @Backups);
1478     #
1479     # Save just this backup's info in case the main backups file
1480     # gets corrupted
1481     #
1482     BackupPC::Storage->backupInfoWrite($Dir, $Backups[$i]{num},
1483                                              $Backups[$i]);
1484
1485     unlink("$Dir/timeStamp.level0") if ( -f "$Dir/timeStamp.level0" );
1486     foreach my $ext ( qw(bad bad.z) ) {
1487         next if ( !-f "$Dir/XferLOG.$ext" );
1488         unlink("$Dir/XferLOG.$ext.old") if ( -f "$Dir/XferLOG.$ext" );
1489         rename("$Dir/XferLOG.$ext", "$Dir/XferLOG.$ext.old");
1490     }
1491
1492     #
1493     # Now remove the bad files, replacing them if possible with links to
1494     # earlier backups.
1495     #
1496     foreach my $f ( $xfer->getBadFiles ) {
1497         my $j;
1498         my $shareM = $bpc->fileNameEltMangle($f->{share});
1499         my $fileM  = $bpc->fileNameMangle($f->{file});
1500         unlink("$Dir/$num/$shareM/$fileM");
1501         for ( $j = $i - 1 ; $j >= 0 ; $j-- ) {
1502             my $file;
1503             if ( $Backups[$j]{mangle} ) {
1504                 $file = "$shareM/$fileM";
1505             } else {
1506                 $file = "$f->{share}/$f->{file}";
1507             }
1508             next if ( !-f "$Dir/$Backups[$j]{num}/$file" );
1509
1510             my($exists, $digest, $origSize, $outSize, $errs)
1511                                 = BackupPC::PoolWrite::LinkOrCopy(
1512                                       $bpc,
1513                                       "$Dir/$Backups[$j]{num}/$file",
1514                                       $Backups[$j]{compress},
1515                                       "$Dir/$num/$shareM/$fileM",
1516                                       $Conf{CompressLevel});
1517             if ( !$exists ) {
1518                 #
1519                 # the hard link failed, most likely because the target
1520                 # file has too many links.  We have copied the file
1521                 # instead, so add this to the new file list.
1522                 #
1523                 if ( !defined($newFilesFH) ) {
1524                     my $str = "Appending to NewFileList for $shareM/$fileM\n";
1525                     $XferLOG->write(\$str);
1526                     open($newFilesFH, ">>", "$TopDir/pc/$client/NewFileList")
1527                          || die("can't open $TopDir/pc/$client/NewFileList");
1528                     binmode($newFilesFH);
1529                 }
1530                 if ( -f "$Dir/$num/$shareM/$fileM" ) {
1531                     print($newFilesFH "$digest $origSize $shareM/$fileM\n");
1532                 } else {
1533                     my $str = "Unable to link/copy $num/$f->{share}/$f->{file}"
1534                             . " to $Backups[$j]{num}/$f->{share}/$f->{file}\n";
1535                     $XferLOG->write(\$str);
1536                 }
1537             } else {
1538                 my $str = "Bad file $num/$f->{share}/$f->{file} replaced"
1539                         . " by link to"
1540                         . " $Backups[$j]{num}/$f->{share}/$f->{file}\n";
1541                 $XferLOG->write(\$str);
1542             }
1543             last;
1544         }
1545         if ( $j < 0 ) {
1546             my $str = "Removed bad file $num/$f->{share}/$f->{file}"
1547                     . " (no older copy to link to)\n";
1548             $XferLOG->write(\$str);
1549         }
1550     }
1551     close($newFilesFH) if ( defined($newFilesFH) );
1552     $XferLOG->close();
1553     rename("$Dir/XferLOG$fileExt", "$Dir/XferLOG.$num$fileExt");
1554     rename("$Dir/NewFileList", "$Dir/NewFileList.$num");
1555
1556     return $num;
1557 }
1558
1559 #
1560 # Removes a specific backup
1561 #
1562 sub BackupRemove
1563 {
1564     my($client, $Backups, $idx) = @_;
1565     my($Dir) = "$TopDir/pc/$client";
1566
1567     if ( $Backups->[$idx]{num} eq "" ) {
1568         print("BackupRemove: ignoring empty backup number for idx $idx\n");
1569         return;
1570     }
1571
1572     $bpc->RmTreeDefer("$TopDir/trash",
1573                       "$Dir/$Backups->[$idx]{num}");
1574     unlink("$Dir/SmbLOG.$Backups->[$idx]{num}")
1575                 if ( -f "$Dir/SmbLOG.$Backups->[$idx]{num}" );
1576     unlink("$Dir/SmbLOG.$Backups->[$idx]{num}.z")
1577                 if ( -f "$Dir/SmbLOG.$Backups->[$idx]{num}.z" );
1578     unlink("$Dir/XferLOG.$Backups->[$idx]{num}")
1579                 if ( -f "$Dir/XferLOG.$Backups->[$idx]{num}" );
1580     unlink("$Dir/XferLOG.$Backups->[$idx]{num}.z")
1581                 if ( -f "$Dir/XferLOG.$Backups->[$idx]{num}.z" );
1582     splice(@{$Backups}, $idx, 1);
1583 }
1584
1585 sub CorrectHostCheck
1586 {
1587     my($hostIP, $host) = @_;
1588     return if ( $hostIP eq $host && !$Conf{FixedIPNetBiosNameCheck}
1589                 || $Conf{NmbLookupCmd} eq "" );
1590     my($netBiosHost, $netBiosUser) = $bpc->NetBiosInfoGet($hostIP);
1591     return "host $host has mismatching netbios name $netBiosHost"
1592                 if ( lc($netBiosHost) ne lc(substr($host, 0, 15)) );
1593     return;
1594 }
1595
1596 #
1597 # The Xfer method might tell us from time to time about processes
1598 # it forks.  We tell BackupPC about this (for status displays) and
1599 # keep track of the pids in case we cancel the backup
1600 #
1601 sub pidHandler
1602 {
1603     @xferPid = @_;
1604     @xferPid = grep(/./, @xferPid);
1605     return if ( !@xferPid && $tarPid < 0 );
1606     my @pids = @xferPid;
1607     push(@pids, $tarPid) if ( $tarPid > 0 );
1608     my $str = join(",", @pids);
1609     $XferLOG->write(\"Xfer PIDs are now $str\n") if ( defined($XferLOG) );
1610     print("xferPids $str\n");
1611 }
1612
1613 #
1614 # The Xfer method might tell us from time to time about progress
1615 # in the backup or restore
1616 #
1617 sub completionPercent
1618 {
1619     my($percent) = @_;
1620
1621     $percent = 100 if ( $percent > 100 );
1622     $percent =   0 if ( $percent <   0 );
1623     if ( !defined($completionPercent)
1624         || int($completionPercent + 0.5) != int($percent) ) {
1625             printf("completionPercent %.0f\n", $percent);
1626     }
1627     $completionPercent = $percent;
1628 }
1629
1630 #
1631 # Run an optional pre- or post-dump command
1632 #
1633 sub UserCommandRun
1634 {
1635     my($cmdType, $sharename) = @_;
1636
1637     return if ( !defined($Conf{$cmdType}) );
1638     my $vars = {
1639         xfer       => $xfer,
1640         client     => $client,
1641         host       => $host,
1642         hostIP     => $hostIP,
1643         user       => $Hosts->{$client}{user},
1644         moreUsers  => $Hosts->{$client}{moreUsers},
1645         share      => $ShareNames->[0],
1646         shares     => $ShareNames,
1647         XferMethod => $Conf{XferMethod},
1648         sshPath    => $Conf{SshPath},
1649         LOG        => *LOG,
1650         XferLOG    => $XferLOG,
1651         stat       => \%stat,
1652         xferOK     => $stat{xferOK} || 0,
1653         hostError  => $stat{hostError},
1654         type       => $type,
1655         cmdType    => $cmdType,
1656     };
1657
1658     if ($cmdType eq 'DumpPreShareCmd' || $cmdType eq 'DumpPostShareCmd') {
1659         $vars->{share} = $sharename;
1660     }
1661
1662     my $cmd = $bpc->cmdVarSubstitute($Conf{$cmdType}, $vars);
1663     $XferLOG->write(\"Executing $cmdType: @$cmd\n");
1664     #
1665     # Run the user's command, dumping the stdout/stderr into the
1666     # Xfer log file.  Also supply the optional $vars and %Conf in
1667     # case the command is really perl code instead of a shell
1668     # command.
1669     #
1670     $bpc->cmdSystemOrEval($cmd,
1671             sub {
1672                 $XferLOG->write(\$_[0]);
1673                 print(LOG $bpc->timeStamp, "Output from $cmdType: ", $_[0]);
1674             },
1675             $vars, \%Conf);
1676 }